gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2016 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/../bfd/development.sh
  28
  29 AC_PROG_CC
  30 AC_PROG_CXX
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33 ACX_LARGEFILE
  34 AM_PROG_CC_STDC
  35 AM_PROG_INSTALL_STRIP
  36
  37 AC_CONFIG_AUX_DIR(..)
  38 AC_CANONICAL_SYSTEM
  39 AC_ARG_PROGRAM
  40
  41 # See if we are building with C++, and substitute COMPILER.
  42 GDB_AC_BUILD_WITH_CXX
  43
  44 # Dependency checking.
  45 ZW_CREATE_DEPDIR
  46 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  47
  48 # Check for the 'make' the user wants to use.
  49 AC_CHECK_PROGS(MAKE, make)
  50 MAKE_IS_GNU=
  51 case "`$MAKE --version 2>&1 | sed 1q`" in
  52   *GNU*)
  53     MAKE_IS_GNU=yes
  54     ;;
  55 esac
  56 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  57 AC_PROG_MAKE_SET
  58
  59 gnulib_extra_configure_args=
  60 # If large-file support is disabled, make sure gnulib does the same.
  61 if test "$enable_largefile" = no; then
  62 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  63 fi
  64
  65 # Configure gnulib.  We need to build gnulib under some other
  66 # directory not "gnulib", to avoid the problem of both GDB and
  67 # GDBserver wanting to build it in the same directory, when building
  68 # in the source dir.
  69 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"],
  70                   ["$gnulib_extra_configure_args"])
  71
  72 dnl List of object files and targets accumulated by configure.
  73
  74 CONFIG_OBS=
  75 CONFIG_DEPS=
  76 CONFIG_SRCS=
  77 ENABLE_CFLAGS=
  78
  79 CONFIG_ALL=
  80 CONFIG_CLEAN=
  81 CONFIG_INSTALL=
  82 CONFIG_UNINSTALL=
  83
  84 dnl Set up for gettext.
  85 ZW_GNU_GETTEXT_SISTER_DIR
  86
  87 localedir='${datadir}/locale'
  88 AC_SUBST(localedir)
  89
  90 if test x"$USE_NLS" = xyes; then
  91    CONFIG_ALL="$CONFIG_ALL all-po"
  92    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  93    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  94    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  95 fi
  96
  97 GNULIB=build-gnulib/import
  98
  99 # For Makefile dependencies.
 100 GNULIB_STDINT_H=
 101 if test x"$STDINT_H" != x; then
 102   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 103 fi
 104 AC_SUBST(GNULIB_STDINT_H)
 105
 106 PACKAGE=gdb
 107 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
 108 AC_SUBST(PACKAGE)
 109
 110 # We never need to detect it in this sub-configure.
 111 # But preserve it for config.status --recheck.
 112 AC_ARG_VAR(MAKEINFO,
 113   [Parent configure detects if it is of sufficient version.])
 114 AC_ARG_VAR(MAKEINFOFLAGS,
 115   [Parameters for MAKEINFO.])
 116
 117 MAKEINFO_EXTRA_FLAGS=""
 118 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 119   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 120   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 121     gdb_cv_have_makeinfo_click=yes
 122   else
 123     gdb_cv_have_makeinfo_click=no
 124   fi])
 125 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 126   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 127 fi
 128 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 129
 130 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 131     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 132     [${libdir}/debug])
 133
 134 # We can't pass paths as command line arguments.
 135 # Mingw32 tries to be clever and will convert the paths for us.
 136 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 137 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 138 # This breaks GDB's relocatable path conversions since paths passed in
 139 # config.h would not get so translated, the path prefixes no longer match.
 140 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 141
 142 # GDB's datadir relocation
 143
 144 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 145     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 146     [${datadir}/gdb])
 147
 148 AC_ARG_WITH(relocated-sources,
 149 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 150 [reloc_srcdir="${withval}"
 151  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 152               [Relocated directory for source files. ])
 153 ])
 154
 155 AC_MSG_CHECKING([for default auto-load directory])
 156 AC_ARG_WITH(auto-load-dir,
 157 AS_HELP_STRING([--with-auto-load-dir=PATH],
 158   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 159   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 160 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 161 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 162               [Directories from which to load auto-loaded scripts.])
 163 AC_MSG_RESULT([$with_auto_load_dir])
 164
 165 AC_MSG_CHECKING([for default auto-load safe-path])
 166 AC_ARG_WITH(auto-load-safe-path,
 167 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 168   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 169 AS_HELP_STRING([--without-auto-load-safe-path],
 170                [do not restrict auto-loaded files locations]),
 171     [if test "$with_auto_load_safe_path" = "no"; then
 172      with_auto_load_safe_path="/"
 173      fi],
 174 [with_auto_load_safe_path="$with_auto_load_dir"])
 175 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 176 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 177               [Directories safe to hold auto-loaded files.])
 178 AC_MSG_RESULT([$with_auto_load_safe_path])
 179
 180 AC_CONFIG_SUBDIRS(testsuite)
 181
 182 # Check whether to support alternative target configurations
 183 AC_ARG_ENABLE(targets,
 184 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 185 [case "${enableval}" in
 186   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 187             ;;
 188   no)       enable_targets= ;;
 189   *)        enable_targets=$enableval ;;
 190 esac])
 191
 192 # Check whether to enable 64-bit support on 32-bit hosts
 193 AC_ARG_ENABLE(64-bit-bfd,
 194 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 195 [case "${enableval}" in
 196   yes)  want64=true  ;;
 197   no)   want64=false ;;
 198   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 199 esac],[want64=false])dnl
 200
 201 # Provide defaults for some variables set by the per-host and per-target
 202 # configuration.
 203 gdb_host_obs=posix-hdep.o
 204
 205 if test "${target}" = "${host}"; then
 206   gdb_native=yes
 207 else
 208   gdb_native=no
 209 fi
 210
 211 . $srcdir/configure.host
 212
 213 # Add in the common host objects.
 214 . $srcdir/common/common.host
 215 gdb_host_obs="$gdb_host_obs $common_host_obs"
 216
 217 # Accumulate some settings from configure.tgt over all enabled targets
 218
 219 TARGET_OBS=
 220 all_targets=
 221 HAVE_NATIVE_GCORE_TARGET=
 222
 223 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 224 do
 225   if test "$targ_alias" = "all"; then
 226     all_targets=true
 227   else
 228     # Canonicalize the secondary target names.
 229     result=`$ac_config_sub $targ_alias 2>/dev/null`
 230     if test -n "$result"; then
 231         targ=$result
 232     else
 233         targ=$targ_alias
 234     fi
 235
 236     . ${srcdir}/configure.tgt
 237
 238     AS_IF([test -z "${gdb_target_obs}"],
 239       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 240
 241     # Target-specific object files
 242     for i in ${gdb_target_obs}; do
 243         case " $TARGET_OBS " in
 244         *" ${i} "*) ;;
 245         *)
 246           TARGET_OBS="$TARGET_OBS ${i}"
 247           ;;
 248         esac
 249     done
 250
 251     # Check whether this target needs 64-bit CORE_ADDR
 252     if test x${want64} = xfalse; then
 253       . ${srcdir}/../bfd/config.bfd
 254     fi
 255
 256     # Check whether this target is native and supports gcore.
 257     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 258        && $gdb_have_gcore; then
 259       HAVE_NATIVE_GCORE_TARGET=1
 260     fi
 261   fi
 262 done
 263
 264 if test x${all_targets} = xtrue; then
 265
 266   # We want all 64-bit targets if we either:
 267   #  - run on a 64-bit host  or
 268   #  - already require 64-bit support for some other target  or
 269   #  - the --enable-64-bit-bfd option was supplied
 270   # Otherwise we only support all 32-bit targets.
 271   #
 272   # NOTE: This test must be in sync with the corresponding
 273   #       tests in BFD!
 274
 275   if test x${want64} = xfalse; then
 276     AC_CHECK_SIZEOF(long)
 277     if test "x${ac_cv_sizeof_long}" = "x8"; then
 278       want64=true
 279     fi
 280   fi
 281   if test x${want64} = xtrue; then
 282     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 283   else
 284     TARGET_OBS='$(ALL_TARGET_OBS)'
 285   fi
 286 fi
 287
 288 AC_SUBST(TARGET_OBS)
 289 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 290
 291 # For other settings, only the main target counts.
 292 gdb_sim=
 293 gdb_osabi=
 294 build_gdbserver=
 295 targ=$target; . ${srcdir}/configure.tgt
 296
 297 # Fetch the default architecture and default target vector from BFD.
 298 targ=$target; . $srcdir/../bfd/config.bfd
 299
 300 # We only want the first architecture, so strip off the others if
 301 # there is more than one.
 302 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 303
 304 if test "x$targ_archs" != x; then
 305   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 306     [Define to BFD's default architecture. ])
 307 fi
 308 if test "x$targ_defvec" != x; then
 309   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 310     [Define to BFD's default target vector. ])
 311 fi
 312
 313 # The CLI cannot be disabled yet, but may be in the future.
 314
 315 # Enable CLI.
 316 AC_ARG_ENABLE(gdbcli,
 317 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 318   [case $enableval in
 319     yes)
 320       ;;
 321     no)
 322       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 323     *)
 324       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 325   esac],
 326   [enable_gdbcli=yes])
 327 if test x"$enable_gdbcli" = xyes; then
 328   if test -d $srcdir/cli; then
 329     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 330     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 331     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 332     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 333   fi
 334 fi
 335
 336 # Enable MI.
 337 AC_ARG_ENABLE(gdbmi,
 338 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 339   [case $enableval in
 340     yes | no)
 341       ;;
 342     *)
 343       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 344   esac],
 345   [enable_gdbmi=yes])
 346 if test x"$enable_gdbmi" = xyes; then
 347   if test -d $srcdir/mi; then
 348     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 349     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 350     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 351     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 352   fi
 353 fi
 354
 355 # Enable TUI.
 356 AC_ARG_ENABLE(tui,
 357 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 358   [case $enableval in
 359     yes | no | auto)
 360       ;;
 361     *)
 362       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 363   esac],enable_tui=auto)
 364
 365 # Enable gdbtk.
 366 AC_ARG_ENABLE(gdbtk,
 367 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 368   [case $enableval in
 369     yes | no)
 370       ;;
 371     *)
 372       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 373   esac],
 374   [if test -d $srcdir/gdbtk; then
 375     enable_gdbtk=yes
 376   else
 377     enable_gdbtk=no
 378   fi])
 379 # We unconditionally disable gdbtk tests on selected platforms.
 380 case $host_os in
 381   go32* | windows*)
 382     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 383     enable_gdbtk=no ;;
 384 esac
 385
 386 # Libunwind support for ia64.
 387
 388 AC_ARG_WITH(libunwind-ia64,
 389 AS_HELP_STRING([--with-libunwind-ia64],
 390                [use libunwind frame unwinding for ia64 targets]),,
 391             [with_libunwind_ia64=auto])
 392
 393 # Backward compatibility option.
 394 if test "${with_libunwind+set}" = set; then
 395   if test x"$with_libunwind_ia64" != xauto; then
 396     AC_MSG_ERROR(
 397       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 398   fi
 399   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 400   with_libunwind_ia64="$with_libunwind"
 401 fi
 402
 403 case "$with_libunwind_ia64" in
 404   yes | no)
 405     ;;
 406   auto)
 407     AC_CHECK_HEADERS(libunwind-ia64.h)
 408     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 409     ;;
 410   *)
 411     AC_MSG_ERROR(
 412       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 413     ;;
 414 esac
 415
 416 if test x"$with_libunwind_ia64" = xyes; then
 417   AC_CHECK_HEADERS(libunwind-ia64.h)
 418   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 419     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 420   fi
 421   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 422   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 423   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 424 fi
 425
 426 opt_curses=no
 427 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 428
 429 prefer_curses=no
 430 if test "$opt_curses" = "yes"; then
 431   prefer_curses=yes
 432 fi
 433
 434 # Profiling support.
 435 AC_ARG_ENABLE(profiling,
 436 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 437   [case $enableval in
 438     yes | no)
 439       ;;
 440     *)
 441       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 442   esac],
 443  [enable_profiling=no])
 444
 445 AC_CHECK_FUNCS(monstartup _mcleanup)
 446 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 447 [AC_TRY_LINK(
 448 [#include <stdlib.h>
 449 extern char _etext;
 450 ],
 451 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 452 if test $ac_cv_var__etext = yes; then
 453   AC_DEFINE(HAVE__ETEXT, 1,
 454             [Define to 1 if your system has the _etext variable. ])
 455 fi
 456 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 457 [AC_TRY_LINK(
 458 [#include <stdlib.h>
 459 extern char etext;
 460 ],
 461 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 462 if test $ac_cv_var_etext = yes; then
 463   AC_DEFINE(HAVE_ETEXT, 1,
 464             [Define to 1 if your system has the etext variable. ])
 465 fi
 466 if test "$enable_profiling" = yes ; then
 467   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 468     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 469   fi
 470   PROFILE_CFLAGS=-pg
 471   OLD_CFLAGS="$CFLAGS"
 472   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 473
 474   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 475     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 476      ac_cv_cc_supports_pg=no)])
 477
 478   if test $ac_cv_cc_supports_pg = no; then
 479     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 480   fi
 481
 482   CFLAGS="$OLD_CFLAGS"
 483 fi
 484
 485 ACX_PKGVERSION([GDB])
 486 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 487 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 488 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 489
 490 # --------------------- #
 491 # Checks for programs.  #
 492 # --------------------- #
 493
 494 AC_PROG_AWK
 495 AC_PROG_INSTALL
 496 AC_PROG_LN_S
 497 AC_PROG_RANLIB
 498 AC_PROG_YACC
 499
 500 AC_CHECK_TOOL(AR, ar)
 501 AC_CHECK_TOOL(DLLTOOL, dlltool)
 502 AC_CHECK_TOOL(WINDRES, windres)
 503
 504 case $host_os in
 505   gnu*)
 506     # Needed for GNU Hurd hosts.
 507     AC_CHECK_TOOL(MIG, mig)
 508     if test x"$MIG" = x; then
 509       AC_MSG_ERROR([MIG not found but required for $host hosts])
 510     fi
 511     ;;
 512 esac
 513
 514 # ---------------------- #
 515 # Checks for libraries.  #
 516 # ---------------------- #
 517
 518 # We might need to link with -lm; most simulators need it.
 519 AC_CHECK_LIB(m, main)
 520
 521 # We need to link with -lw to get `wctype' on Solaris before Solaris
 522 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 523 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 524 # is known to have this problem).  Therefore we avoid libw if we can.
 525 AC_CHECK_FUNC(wctype, [],
 526   [AC_CHECK_LIB(w, wctype)])
 527
 528 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 529 AC_SEARCH_LIBS(gethostbyname, nsl)
 530
 531 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 532 AC_SEARCH_LIBS(socketpair, socket)
 533
 534 # Link in zlib if we can.  This allows us to read compressed debug sections.
 535 AM_ZLIB
 536
 537 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 538 AC_SEARCH_LIBS(kinfo_getvmmap, util,
 539   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 540             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 541
 542 AM_ICONV
 543
 544 # GDB may fork/exec the iconv program to get the list of supported character
 545 # sets.  Allow the user to specify where to find it.
 546 # There are several factors affecting the choice of option name:
 547 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 548 #   the build-time location of libiconv files.
 549 # - The program we need to find is iconv, which comes with glibc.  The user
 550 #   doesn't necessarily have libiconv installed.  Therefore naming this
 551 #   --with-libiconv-foo feels wrong.
 552 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 553 #   defined to work on directories not files (though it really doesn't know
 554 #   the difference).
 555 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 556 #   with --with-libiconv-prefix.
 557 # Putting these together is why the option name is --with-iconv-bin.
 558
 559 AC_ARG_WITH(iconv-bin,
 560 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 561 [iconv_bin="${withval}"
 562  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 563                     [Path of directory of iconv program.])
 564  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 565 ])
 566
 567 # For the TUI, we need enhanced curses functionality.
 568 if test x"$enable_tui" != xno; then
 569   prefer_curses=yes
 570 fi
 571
 572 curses_found=no
 573 if test x"$prefer_curses" = xyes; then
 574   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 575   # curses library because the latter might not provide all the
 576   # functionality we need.  However, this leads to problems on systems
 577   # where the linker searches /usr/local/lib, but the compiler doesn't
 578   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 579   # default installation of ncurses on alpha*-dec-osf* will lead to such
 580   # a situation.
 581   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 582
 583   if test "$ac_cv_search_waddstr" != no; then
 584     curses_found=yes
 585   fi
 586 fi
 587
 588 # Check whether we should enable the TUI, but only do so if we really
 589 # can.
 590 if test x"$enable_tui" != xno; then
 591   if test -d $srcdir/tui; then
 592     if test "$curses_found" != no; then
 593       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 594       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 595       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 596       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 597     else
 598       if test x"$enable_tui" = xyes; then
 599         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 600       else
 601         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 602       fi
 603     fi
 604   fi
 605 fi
 606
 607 # Since GDB uses Readline, we need termcap functionality.  In many
 608 # cases this will be provided by the curses library, but some systems
 609 # have a seperate termcap library, or no curses library at all.
 610
 611 case $host_os in
 612   cygwin*)
 613     if test -d $srcdir/libtermcap; then
 614       LIBS="../libtermcap/libtermcap.a $LIBS"
 615       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 616     fi ;;
 617   go32* | *djgpp*)
 618     ac_cv_search_tgetent="none required"
 619     ;;
 620 esac
 621
 622 # These are the libraries checked by Readline.
 623 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 624
 625 if test "$ac_cv_search_tgetent" = no; then
 626   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 627 fi
 628
 629 AC_ARG_WITH([system-readline],
 630   [AS_HELP_STRING([--with-system-readline],
 631                   [use installed readline library])])
 632
 633 if test "$with_system_readline" = yes; then
 634   READLINE=-lreadline
 635   READLINE_DEPS=
 636   READLINE_CFLAGS=
 637   READLINE_TEXI_INCFLAG=
 638 else
 639   READLINE='$(READLINE_DIR)/libreadline.a'
 640   READLINE_DEPS='$(READLINE)'
 641   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 642   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 643 fi
 644 AC_SUBST(READLINE)
 645 AC_SUBST(READLINE_DEPS)
 646 AC_SUBST(READLINE_CFLAGS)
 647 AC_SUBST(READLINE_TEXI_INCFLAG)
 648
 649 # Generate jit-reader.h
 650
 651 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 652 TARGET_PTR=
 653
 654 AC_CHECK_SIZEOF(unsigned long long)
 655 AC_CHECK_SIZEOF(unsigned long)
 656 AC_CHECK_SIZEOF(unsigned __int128)
 657
 658 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 659   TARGET_PTR="unsigned long"
 660 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 661   TARGET_PTR="unsigned long long"
 662 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 663   TARGET_PTR="unsigned __int128"
 664 else
 665   TARGET_PTR="unsigned long"
 666 fi
 667
 668 AC_SUBST(TARGET_PTR)
 669 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 670
 671 AC_SEARCH_LIBS(dlopen, dl)
 672
 673 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 674                 [directory to load the JIT readers from],
 675                 [${libdir}/gdb])
 676
 677 AC_ARG_WITH(expat,
 678   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 679   [], [with_expat=auto])
 680 AC_MSG_CHECKING([whether to use expat])
 681 AC_MSG_RESULT([$with_expat])
 682
 683 if test "${with_expat}" = no; then
 684   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 685   HAVE_LIBEXPAT=no
 686 else
 687   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 688                         [XML_Parser p = XML_ParserCreate (0);])
 689   if test "$HAVE_LIBEXPAT" != yes; then
 690     if test "$with_expat" = yes; then
 691       AC_MSG_ERROR([expat is missing or unusable])
 692     else
 693       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 694     fi
 695   else
 696     save_LIBS=$LIBS
 697     LIBS="$LIBS $LIBEXPAT"
 698     AC_CHECK_FUNCS(XML_StopParser)
 699     LIBS=$save_LIBS
 700   fi
 701 fi
 702
 703 # --------------------- #
 704 # Check for libpython.  #
 705 # --------------------- #
 706
 707 dnl Utility to simplify finding libpython.
 708 dnl $1 = pythonX.Y
 709 dnl $2 = the shell variable to assign the result to
 710 dnl      If libpython is found we store $version here.
 711 dnl $3 = additional flags to add to CPPFLAGS
 712 dnl $4 = additional flags to add to LIBS
 713
 714 AC_DEFUN([AC_TRY_LIBPYTHON],
 715 [
 716   version=$1
 717   define([have_libpython_var],$2)
 718   new_CPPFLAGS=$3
 719   new_LIBS=$4
 720   AC_MSG_CHECKING([for ${version}])
 721   save_CPPFLAGS=$CPPFLAGS
 722   save_LIBS=$LIBS
 723   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 724   LIBS="$LIBS $new_LIBS"
 725   found_usable_python=no
 726   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 727                                  [[Py_Initialize ();]]),
 728                  [have_libpython_var=${version}
 729                   found_usable_python=yes
 730                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 731                   PYTHON_LIBS=$new_LIBS])
 732   CPPFLAGS=$save_CPPFLAGS
 733   LIBS=$save_LIBS
 734   AC_MSG_RESULT([${found_usable_python}])
 735 ])
 736
 737 dnl There are several different values for --with-python:
 738 dnl
 739 dnl no -   Don't include python support.
 740 dnl yes -  Include python support, error if it's missing.
 741 dnl        If we find python in $PATH, use it to fetch configure options,
 742 dnl        otherwise assume the compiler can find it with no help from us.
 743 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 744 dnl auto - Same as "yes", but if python is missing from the system,
 745 dnl        fall back to "no".
 746 dnl /path/to/python/exec-prefix -
 747 dnl        Use the python located in this directory.
 748 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 749 dnl        the compilation parameters.  Otherwise use
 750 dnl        -I/path/to/python/exec-prefix/include,
 751 dnl        -L/path/to/python/exec-prefix/lib.
 752 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 753 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 754 dnl        but is deprecated.
 755 dnl /path/to/python/executable -
 756 dnl        Run python-config.py with this version of python to fetch the
 757 dnl        compilation parameters.
 758 dnl        NOTE: This needn't be the real python executable.
 759 dnl        In a cross-compilation scenario (build != host), this could be
 760 dnl        a shell script that provides what python-config.py provides for
 761 dnl        --ldflags, --includes, --exec-prefix.
 762 dnl python-executable -
 763 dnl        Find python-executable in $PATH, and then handle the same as
 764 dnl        /path/to/python/executable.
 765 dnl
 766 dnl If a python program is specified, it is used to run python-config.py and
 767 dnl is passed --ldflags, --includes, --exec-prefix.
 768
 769 AC_ARG_WITH(python,
 770   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 771   [], [with_python=auto])
 772 AC_MSG_CHECKING([whether to use python])
 773 AC_MSG_RESULT([$with_python])
 774
 775 if test "${with_python}" = no; then
 776   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 777   have_libpython=no
 778 else
 779   case "${with_python}" in
 780   [[\\/]]* | ?:[[\\/]]*)
 781     if test -d ${with_python}; then
 782       # Assume the python binary is ${with_python}/bin/python.
 783       python_prog="${with_python}/bin/python"
 784       python_prefix=
 785       # If python does not exit ${with_python}/bin, then try in
 786       # ${with_python}.  On Windows/MinGW, this is where the Python
 787       # executable is.
 788       if test ! -x "${python_prog}"; then
 789         python_prog="${with_python}/python"
 790         python_prefix=
 791       fi
 792       if test ! -x "${python_prog}"; then
 793         # Fall back to gdb 7.0/7.1 behaviour.
 794         python_prog=missing
 795         python_prefix=${with_python}
 796       fi
 797     elif test -x "${with_python}"; then
 798       # While we can't run python compiled for $host (unless host == build),
 799       # the user could write a script that provides the needed information,
 800       # so we support that.
 801       python_prog=${with_python}
 802       python_prefix=
 803     else
 804       AC_ERROR(invalid value for --with-python)
 805     fi
 806     ;;
 807   */*)
 808     # Disallow --with-python=foo/bar.
 809     AC_ERROR(invalid value for --with-python)
 810     ;;
 811   *)
 812     # The user has either specified auto, yes, or the name of the python
 813     # program assumed to be in $PATH.
 814     python_prefix=
 815     case "${with_python}" in
 816     yes | auto)
 817       if test ${build} = ${host}; then
 818         AC_PATH_PROG(python_prog_path, python, missing)
 819         if test "${python_prog_path}" = missing; then
 820           python_prog=missing
 821         else
 822           python_prog=${python_prog_path}
 823         fi
 824       else
 825         # Not much we can do except assume the cross-compiler will find the
 826         # right files.
 827         python_prog=missing
 828       fi
 829       ;;
 830     *)
 831       # While we can't run python compiled for $host (unless host == build),
 832       # the user could write a script that provides the needed information,
 833       # so we support that.
 834       python_prog="${with_python}"
 835       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 836       if test "${python_prog_path}" = missing; then
 837         AC_ERROR(unable to find python program ${python_prog})
 838       fi
 839       ;;
 840     esac
 841   esac
 842
 843   if test "${python_prog}" != missing; then
 844     # We have a python program to use, but it may be too old.
 845     # Don't flag an error for --with-python=auto (the default).
 846     have_python_config=yes
 847     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 848     if test $? != 0; then
 849       have_python_config=failed
 850       if test "${with_python}" != auto; then
 851         AC_ERROR(failure running python-config --includes)
 852       fi
 853     fi
 854     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 855     if test $? != 0; then
 856       have_python_config=failed
 857       if test "${with_python}" != auto; then
 858         AC_ERROR(failure running python-config --ldflags)
 859       fi
 860     fi
 861     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 862     if test $? != 0; then
 863       have_python_config=failed
 864       if test "${with_python}" != auto; then
 865         AC_ERROR(failure running python-config --exec-prefix)
 866       fi
 867     fi
 868   else
 869     # We do not have a python executable we can use to determine where
 870     # to find the Python headers and libs.  We cannot guess the include
 871     # path from the python_prefix either, because that include path
 872     # depends on the Python version.  So, there is nothing much we can
 873     # do except assume that the compiler will be able to find those files.
 874     python_includes=
 875     python_libs=
 876     have_python_config=no
 877   fi
 878
 879   # If we have python-config, only try the configuration it provides.
 880   # Otherwise fallback on the old way of trying different versions of
 881   # python in turn.
 882
 883   have_libpython=no
 884   if test "${have_python_config}" = yes; then
 885     # Determine the Python version by extracting "-lpython<version>"
 886     # part of the python_libs. <version> is usually X.Y with X and Y
 887     # being decimal numbers, but can also be XY (seen on Windows).
 888     #
 889     # The extraction is performed using sed with a regular expression.
 890     # Initially, the regexp used was using the '?' quantifier to make
 891     # the dot in the version number optional.  Unfortunately, this
 892     # does not work with non-GNU versions of sed because, because of
 893     # what looks like a limitation (the '?' quantifier does not work
 894     # with back-references).  We work around this limitation by using
 895     # the '*' quantifier instead.  It means that, in theory, we might
 896     # match unexpected version strings such as "-lpython2..7", but
 897     # this seems unlikely in practice.  And even if that happens,
 898     # an error will be triggered later on, when checking that version
 899     # number.
 900     python_version=`echo " ${python_libs} " \
 901                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 902     case "${python_version}" in
 903     python*)
 904       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 905                        ${python_includes}, ${python_libs})
 906       ;;
 907     *)
 908       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 909       ;;
 910     esac
 911   elif test "${have_python_config}" != failed; then
 912     if test "${have_libpython}" = no; then
 913       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 914                        ${python_includes}, "${python_libs} -lpython2.7")
 915     fi
 916     if test "${have_libpython}" = no; then
 917       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 918                        ${python_includes}, "${python_libs} -lpython2.6")
 919     fi
 920     if test ${have_libpython} = no; then
 921       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 922                        ${python_includes}, "${python_libs} -lpython2.5")
 923     fi
 924     if test ${have_libpython} = no; then
 925       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 926                        ${python_includes}, "${python_libs} -lpython2.4")
 927     fi
 928   fi
 929   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 930     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 931   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 932     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 933   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 934     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 935   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 936     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 937   fi
 938
 939   if test "${have_libpython}" = no; then
 940     case "${with_python}" in
 941     yes)
 942       AC_MSG_ERROR([python is missing or unusable])
 943       ;;
 944     auto)
 945       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 946       ;;
 947     *)
 948       AC_MSG_ERROR([no usable python found at ${with_python}])
 949       ;;
 950     esac
 951   else
 952     if test -n "${python_prefix}"; then
 953       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 954                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 955       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 956     fi
 957   fi
 958 fi
 959
 960 if test "${have_libpython}" != no; then
 961   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 962   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 963   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 964   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 965   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 966   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 967
 968   # Flags needed to compile Python code (taken from python-config --cflags).
 969   # We cannot call python-config directly because it will output whatever was
 970   # used when compiling the Python interpreter itself, including flags which
 971   # would make the python-related objects be compiled differently from the
 972   # rest of GDB (e.g., -O2 and -fPIC).
 973   if test "${GCC}" = yes; then
 974     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 975   fi
 976
 977   if test "x${tentative_python_cflags}" != x; then
 978     AC_MSG_CHECKING(compiler flags for python code)
 979     for flag in ${tentative_python_cflags}; do
 980       # Check that the compiler accepts it
 981       saved_CFLAGS="$CFLAGS"
 982       CFLAGS="$CFLAGS $flag"
 983       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 984       CFLAGS="$saved_CFLAGS"
 985     done
 986     AC_MSG_RESULT(${PYTHON_CFLAGS})
 987   fi
 988
 989   # On x64 Windows, Python's include headers, and pyconfig.h in
 990   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 991   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 992   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 993   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 994   # The issue was reported to the Python community, but still isn't
 995   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 996
 997   case "$gdb_host" in
 998     mingw64)
 999            if test "${GCC}" = yes; then
1000              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1001            fi
1002            ;;
1003   esac
1004
1005   # Note that "python -m threading" cannot be used to check for
1006   # threading support due to a bug in Python 2.7.3
1007   # (http://bugs.python.org/issue15567).
1008   AC_MSG_CHECKING(whether python supports threads)
1009   saved_CPPFLAGS="${CPPFLAGS}"
1010   CPPFLAGS="${PYTHON_CPPFLAGS}"
1011   # Note that the test is reversed so that python_has_threads=yes on
1012   # unexpected failures.
1013   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1014 #include <Python.h>
1015 #ifdef WITH_THREAD
1016 # error
1017 #endif
1018   ]]), [python_has_threads=no], [python_has_threads=yes])
1019   AC_MSG_RESULT(${python_has_threads})
1020   CPPFLAGS="${saved_CPPFLAGS}"
1021 else
1022   # Even if Python support is not compiled in, we need to have this file
1023   # included so that the "python" command, et.al., still exists.
1024   CONFIG_OBS="$CONFIG_OBS python.o"
1025   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1026 fi
1027 AC_SUBST(PYTHON_CFLAGS)
1028 AC_SUBST(PYTHON_CPPFLAGS)
1029 AC_SUBST(PYTHON_LIBS)
1030 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1031
1032 # -------------------- #
1033 # Check for libguile.  #
1034 # -------------------- #
1035
1036 dnl Utility to simplify finding libguile.
1037 dnl $1 = pkg-config-program
1038 dnl $2 = space-separate list of guile versions to try
1039 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1040 dnl $4 = the shell variable to assign the result to
1041 dnl      If libguile is found we store "yes" here.
1042
1043 AC_DEFUN([AC_TRY_LIBGUILE],
1044 [
1045   pkg_config=$1
1046   guile_version_list=$2
1047   flag_errors=$3
1048   define([have_libguile_var],$4)
1049   found_usable_guile=checking
1050   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1051   for guile_version in ${guile_version_list}; do
1052     ${pkg_config} --exists ${guile_version} 2>/dev/null
1053     if test $? != 0; then
1054       continue
1055     fi
1056     dnl pkg-config says the package exists, so if we get an error now,
1057     dnl that's bad.
1058     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1059     if test $? != 0; then
1060       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1061     fi
1062     new_LIBS=`${pkg_config} --libs ${guile_version}`
1063     if test $? != 0; then
1064       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1065     fi
1066     dnl If we get this far, great.
1067     found_usable_guile=${guile_version}
1068     break
1069   done
1070   if test "${found_usable_guile}" = "checking"; then
1071     if test "${flag_errors}" = "yes"; then
1072       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1073     else
1074       found_usable_guile=no
1075     fi
1076   fi
1077   dnl One final sanity check.
1078   dnl The user could have said --with-guile=python-2.7.
1079   if test "${found_usable_guile}" != no; then
1080     save_CPPFLAGS=$CPPFLAGS
1081     save_LIBS=$LIBS
1082     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1083     LIBS="$LIBS $new_LIBS"
1084     AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "libguile.h"]],
1085                                    [[scm_init_guile ();]]),
1086                    [have_libguile_var=yes
1087                     GUILE_CPPFLAGS=$new_CPPFLAGS
1088                     GUILE_LIBS=$new_LIBS],
1089                    [found_usable_guile=no])
1090     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1091     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1092       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1093                 [Define if Guile supports manual finalization.])
1094     )
1095     CPPFLAGS=$save_CPPFLAGS
1096     LIBS=$save_LIBS
1097     if test "${found_usable_guile}" = no; then
1098       if test "${flag_errors}" = yes; then
1099         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1100       fi
1101     fi
1102   fi
1103   AC_MSG_RESULT([${found_usable_guile}])
1104 ])
1105
1106 dnl There are several different values for --with-guile:
1107 dnl
1108 dnl no -   Don't include guile support.
1109 dnl yes -  Include guile support, error if it's missing.
1110 dnl        The pkg-config program must be in $PATH.
1111 dnl auto - Same as "yes", but if guile is missing from the system,
1112 dnl        fall back to "no".
1113 dnl guile-version [guile-version-choice-2 ...] -
1114 dnl        A space-separated list of guile package versions to try.
1115 dnl        These are passed to pkg-config as-is.
1116 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1117 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1118 dnl /path/to/pkg-config -
1119 dnl        Use this pkg-config program.
1120 dnl        NOTE: This needn't be the "real" pkg-config program.
1121 dnl        It could be a shell script.  It is invoked as:
1122 dnl        pkg-config --exists $version
1123 dnl        pkg-config --cflags $version
1124 dnl        pkg-config --libs $version
1125 dnl        pkg-config --variable guild $version
1126 dnl        The script will be called with $version having each value in
1127 dnl        $try_guile_versions until --exists indicates success.
1128
1129 AC_ARG_WITH(guile,
1130   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1131   [], [with_guile=auto])
1132 AC_MSG_CHECKING([whether to use guile])
1133 AC_MSG_RESULT([$with_guile])
1134
1135 dnl We check guile with pkg-config.
1136 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1137
1138 try_guile_versions="guile-2.2 guile-2.0"
1139 have_libguile=no
1140 case "${with_guile}" in
1141 no)
1142   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1143   ;;
1144 auto)
1145   if test "${pkg_config_prog_path}" = "missing"; then
1146     AC_MSG_WARN([pkg-config not found, guile support disabled])
1147   else
1148     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1149   fi
1150   ;;
1151 yes)
1152   if test "${pkg_config_prog_path}" = "missing"; then
1153     AC_MSG_ERROR([pkg-config not found])
1154   fi
1155   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1156   ;;
1157 [[\\/]]* | ?:[[\\/]]*)
1158   if test -x "${with_guile}"; then
1159     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1160   else
1161     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1162   fi
1163   ;;
1164 "" | */*)
1165   # Disallow --with=guile="" and --with-guile=foo/bar.
1166   AC_MSG_ERROR([invalid value for --with-guile])
1167   ;;
1168 *)
1169   # A space separate list of guile versions to try, in order.
1170   if test "${pkg_config_prog_path}" = "missing"; then
1171     AC_MSG_ERROR([pkg-config not found])
1172   fi
1173   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1174   ;;
1175 esac
1176
1177 if test "${have_libguile}" != no; then
1178   dnl Get the name of the 'guild' program.
1179   case "${with_guile}" in
1180   [[\\/]]* | ?:[[\\/]]*)
1181     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1182     ;;
1183   *)
1184     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1185     ;;
1186   esac
1187
1188   dnl Make sure guild can handle this host.
1189   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1190   dnl If not, disable guile support.
1191   if test "$ac_cv_guild_ok" = no; then
1192     have_libguile=no
1193     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1194   fi
1195 fi
1196
1197 if test "${have_libguile}" != no; then
1198   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1199   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1200   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1201   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1202   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1203   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1204
1205   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1206   save_LIBS="$LIBS"
1207   save_CPPFLAGS="$CPPFLAGS"
1208   LIBS="$GUILE_LIBS"
1209   CPPFLAGS="$GUILE_CPPFLAGS"
1210   AC_CHECK_FUNCS([scm_new_smob])
1211   LIBS="$save_LIBS"
1212   CPPFLAGS="$save_CPPFLAGS"
1213 else
1214   # Even if Guile support is not compiled in, we need to have these files
1215   # included.
1216   CONFIG_OBS="$CONFIG_OBS guile.o"
1217   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1218 fi
1219 AC_SUBST(GUILE_CPPFLAGS)
1220 AC_SUBST(GUILE_LIBS)
1221 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1222
1223 # --------------------- #
1224 # Check for libmcheck.  #
1225 # --------------------- #
1226
1227 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1228 # but turn it off if Python is enabled with threads, since -lmcheck is
1229 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1230 # and for releases.
1231 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1232    && $development; then
1233   libmcheck_default=yes
1234 else
1235   libmcheck_default=no
1236 fi
1237 GDB_AC_LIBMCHECK(${libmcheck_default})
1238
1239 if test "$ENABLE_LIBMCHECK" = "yes" \
1240         -a "${have_libpython}" != "no" \
1241         -a "${python_has_threads}" = "yes" ; then
1242   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1243 fi
1244
1245 AC_ARG_WITH(intel_pt,
1246   AS_HELP_STRING([--with-intel-pt], [include Intel Processor Trace support (auto/yes/no)]),
1247   [], [with_intel_pt=auto])
1248 AC_MSG_CHECKING([whether to use intel pt])
1249 AC_MSG_RESULT([$with_intel_pt])
1250
1251 if test "${with_intel_pt}" = no; then
1252   AC_MSG_WARN([Intel Processor Trace support disabled; some features may be unavailable.])
1253   HAVE_LIBIPT=no
1254 else
1255   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1256 #include <linux/perf_event.h>
1257 #ifndef PERF_ATTR_SIZE_VER5
1258 # error
1259 #endif
1260   ]]), [perf_event=yes], [perf_event=no])
1261   if test "$perf_event" != yes; then
1262     if test "$with_intel_pt" = yes; then
1263       AC_MSG_ERROR([linux/perf_event.h missing or too old])
1264     else
1265       AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
1266     fi
1267   fi
1268
1269   AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
1270   if test "$HAVE_LIBIPT" != yes; then
1271     if test "$with_intel_pt" = yes; then
1272       AC_MSG_ERROR([libipt is missing or unusable])
1273     else
1274       AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
1275     fi
1276   fi
1277 fi
1278
1279 # ------------------------- #
1280 # Checks for header files.  #
1281 # ------------------------- #
1282
1283 AC_HEADER_STDC
1284 # elf_hp.h is for HP/UX 64-bit shared library support.
1285 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1286                   thread_db.h \
1287                   sys/fault.h \
1288                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1289                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1290                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1291                   termios.h termio.h \
1292                   sgtty.h elf_hp.h \
1293                   dlfcn.h])
1294 AC_CHECK_HEADERS(sys/proc.h, [], [],
1295 [#if HAVE_SYS_PARAM_H
1296 # include <sys/param.h>
1297 #endif
1298 ])
1299 AC_CHECK_HEADERS(sys/user.h, [], [],
1300 [#if HAVE_SYS_PARAM_H
1301 # include <sys/param.h>
1302 #endif
1303 ])
1304
1305 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1306 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1307 # think that we don't have <curses.h> if we're using GCC.
1308 case $host_os in
1309   solaris2.[[789]])
1310     if test "$GCC" = yes; then
1311       AC_DEFINE(_MSE_INT_H, 1,
1312         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1313    Solaris 2.[789] when using GCC. ])
1314     fi ;;
1315 esac
1316 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1317 AC_CHECK_HEADERS(term.h, [], [],
1318 [#if HAVE_CURSES_H
1319 # include <curses.h>
1320 #endif
1321 ])
1322
1323 # ------------------------- #
1324 # Checks for declarations.  #
1325 # ------------------------- #
1326
1327 libiberty_INIT
1328
1329 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1330 AM_LC_MESSAGES
1331
1332 # ----------------------- #
1333 # Checks for structures.  #
1334 # ----------------------- #
1335
1336 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1337
1338 # ------------------ #
1339 # Checks for types.  #
1340 # ------------------ #
1341
1342 AC_CHECK_TYPES(socklen_t, [], [],
1343 [#include <sys/types.h>
1344 #include <sys/socket.h>
1345 ])
1346
1347 # ------------------------------------- #
1348 # Checks for compiler characteristics.  #
1349 # ------------------------------------- #
1350
1351 AC_C_CONST
1352 AC_C_INLINE
1353 AC_C_BIGENDIAN
1354
1355 # ------------------------------ #
1356 # Checks for library functions.  #
1357 # ------------------------------ #
1358
1359 AC_FUNC_MMAP
1360 AC_FUNC_VFORK
1361 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1362                 pipe poll pread pread64 pwrite resize_term \
1363                 sbrk setpgid setpgrp setsid \
1364                 sigaction sigprocmask sigsetmask socketpair \
1365                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1366                 setrlimit getrlimit posix_madvise waitpid \
1367                 ptrace64 sigaltstack mkdtemp setns])
1368 AM_LANGINFO_CODESET
1369 GDB_AC_COMMON
1370
1371 # Check the return and argument types of ptrace.
1372 GDB_AC_PTRACE
1373
1374 dnl AC_FUNC_SETPGRP does not work when cross compiling
1375 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1376 if test "$cross_compiling" = no; then
1377   AC_FUNC_SETPGRP
1378 else
1379   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1380     [AC_TRY_COMPILE([
1381 #include <unistd.h>
1382 ], [
1383   if (setpgrp(1,1) == -1)
1384     exit (0);
1385   else
1386     exit (1);
1387 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1388 if test $ac_cv_func_setpgrp_void = yes; then
1389   AC_DEFINE(SETPGRP_VOID, 1)
1390 fi
1391 fi
1392
1393 # Assume we'll default to using the included libiberty regex.
1394 gdb_use_included_regex=yes
1395
1396 # However, if the system regex is GNU regex, then default to *not*
1397 # using the included regex.
1398 AC_CACHE_CHECK(
1399   [for GNU regex],
1400   [gdb_cv_have_gnu_regex],
1401   [AC_TRY_COMPILE(
1402     [#include <gnu-versions.h>],
1403     [#define REGEX_INTERFACE_VERSION 1
1404 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1405 # error "Version mismatch"
1406 #endif],
1407     gdb_cv_have_gnu_regex=yes,
1408     gdb_cv_have_gnu_regex=no)])
1409 if test $gdb_cv_have_gnu_regex = yes; then
1410   gdb_use_included_regex=no
1411 fi
1412
1413 AC_ARG_WITH(included-regex,
1414   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1415   gdb_with_regex=$withval,
1416   gdb_with_regex=$gdb_use_included_regex)
1417 if test "$gdb_with_regex" = yes; then
1418   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1419     [Define to 1 if the regex included in libiberty should be used.])
1420 fi
1421
1422 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1423 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1424 [#include <sys/param.h>
1425 #include <sys/proc.h>
1426 ])
1427
1428 # See if <sys/lwp.h> defines `struct lwp`.
1429 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1430 [AC_TRY_COMPILE([#include <sys/param.h>
1431 #include <sys/lwp.h>], [struct lwp l;],
1432 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1433 if test $gdb_cv_struct_lwp = yes; then
1434   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1435             [Define to 1 if your system has struct lwp.])
1436 fi
1437
1438 # See if <machine/reg.h> degines `struct reg'.
1439 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1440 [AC_TRY_COMPILE([#include <sys/types.h>
1441 #include <machine/reg.h>], [struct reg r;],
1442 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1443 if test $gdb_cv_struct_reg = yes; then
1444   AC_DEFINE(HAVE_STRUCT_REG, 1,
1445             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1446 fi
1447
1448 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1449 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1450 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1451                  [#include <sys/types.h>
1452 #include <machine/reg.h>])
1453
1454 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1455 # Older amd64 Linux's don't have the fs_base and gs_base members of
1456 # `struct user_regs_struct'.
1457 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1458                  [], [], [#include <sys/user.h>])
1459
1460 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1461 AC_MSG_CHECKING(for PTRACE_GETREGS)
1462 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1463 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1464                 [PTRACE_GETREGS;],
1465                 [gdb_cv_have_ptrace_getregs=yes],
1466                 [gdb_cv_have_ptrace_getregs=no])])
1467 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1468 if test $gdb_cv_have_ptrace_getregs = yes; then
1469   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1470   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1471 fi
1472
1473 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1474 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1475 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1476 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1477                 [PTRACE_GETFPXREGS;],
1478                 [gdb_cv_have_ptrace_getfpxregs=yes],
1479                 [gdb_cv_have_ptrace_getfpxregs=no])])
1480 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1481 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1482   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1483   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1484 fi
1485
1486 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1487 AC_MSG_CHECKING(for PT_GETDBREGS)
1488 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1489 [AC_TRY_COMPILE([#include <sys/types.h>
1490 #include <sys/ptrace.h>],
1491                 [PT_GETDBREGS;],
1492                 [gdb_cv_have_pt_getdbregs=yes],
1493                 [gdb_cv_have_pt_getdbregs=no])])
1494 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1495 if test $gdb_cv_have_pt_getdbregs = yes; then
1496   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1497   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1498 fi
1499
1500 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1501 AC_MSG_CHECKING(for PT_GETXMMREGS)
1502 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1503 [AC_TRY_COMPILE([#include <sys/types.h>
1504 #include <sys/ptrace.h>],
1505                 [PT_GETXMMREGS;],
1506                 [gdb_cv_have_pt_getxmmregs=yes],
1507                 [gdb_cv_have_pt_getxmmregs=no])])
1508 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1509 if test $gdb_cv_have_pt_getxmmregs = yes; then
1510   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1511   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1512 fi
1513
1514 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1515 # Older FreeBSD versions don't have the pl_tdname member of
1516 # `struct ptrace_lwpinfo'.
1517 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1518                  [#include <sys/ptrace.h>])
1519
1520
1521 # Detect which type of /proc is in use, such as for Solaris.
1522
1523 if test "${target}" = "${host}"; then
1524   case "${host}" in
1525   *-*-sysv4.2* | *-*-sysv5* )
1526       AC_DEFINE(NEW_PROC_API, 1,
1527       [Define if you want to use new multi-fd /proc interface.])
1528       ;;
1529   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1530       AC_DEFINE(NEW_PROC_API, 1,
1531       [Define if you want to use new multi-fd /proc interface.])
1532       ;;
1533   mips-sgi-irix5*)
1534       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1535       AC_DEFINE([_KMEMUSER], 1,
1536       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1537        around a <sys/proc.h> problem on IRIX 5.])
1538       ;;
1539   esac
1540 fi
1541
1542 if test "$ac_cv_header_sys_procfs_h" = yes; then
1543   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1544   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1545   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1546   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1547   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1548   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1549   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1550   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1551   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1552   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1553   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1554
1555
1556   dnl Check for broken prfpregset_t type
1557
1558   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1559   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1560   dnl instead of the struct itself).  We detect this here, and work
1561   dnl around it in gdb_proc_service.h.
1562
1563   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1564     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1565     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1566       [AC_TRY_RUN([#include <sys/procfs.h>
1567        int main ()
1568        {
1569          if (sizeof (prfpregset_t) == sizeof (void *))
1570            return 1;
1571          return 0;
1572        }],
1573        gdb_cv_prfpregset_t_broken=no,
1574        gdb_cv_prfpregset_t_broken=yes,
1575        gdb_cv_prfpregset_t_broken=yes)])
1576     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1577     if test $gdb_cv_prfpregset_t_broken = yes; then
1578       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1579       [Define if the prfpregset_t type is broken.])
1580     fi
1581   fi
1582 fi
1583
1584 # Check if the compiler supports the `long long' type.
1585
1586 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1587                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1588 [[extern long long foo;]],
1589 [[switch (foo & 2) { case 0: return 1; }]])],
1590                                   gdb_cv_c_long_long=yes,
1591                                   gdb_cv_c_long_long=no)])
1592 if test $gdb_cv_c_long_long != yes; then
1593   # libdecnumber requires long long.
1594   AC_MSG_ERROR([Compiler must support long long for GDB.])
1595 fi
1596
1597 # Check if the compiler and runtime support printing long longs.
1598
1599 AC_CACHE_CHECK([for long long support in printf],
1600                gdb_cv_printf_has_long_long,
1601                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1602 [[char buf[32];
1603   long long l = 0;
1604   l = (l << 16) + 0x0123;
1605   l = (l << 16) + 0x4567;
1606   l = (l << 16) + 0x89ab;
1607   l = (l << 16) + 0xcdef;
1608   sprintf (buf, "0x%016llx", l);
1609   return (strcmp ("0x0123456789abcdef", buf));]])],
1610                               gdb_cv_printf_has_long_long=yes,
1611                               gdb_cv_printf_has_long_long=no,
1612                               gdb_cv_printf_has_long_long=no)])
1613 if test $gdb_cv_printf_has_long_long = yes; then
1614   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1615             [Define to 1 if the "%ll" format works to print long longs.])
1616 fi
1617
1618 # Check if the compiler and runtime support printing decfloats.
1619
1620 AC_CACHE_CHECK([for decfloat support in printf],
1621                gdb_cv_printf_has_decfloat,
1622                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1623 [[char buf[64];
1624   _Decimal32 d32 = 1.2345df;
1625   _Decimal64 d64 = 1.2345dd;
1626   _Decimal128 d128 = 1.2345dl;
1627   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1628   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1629                               gdb_cv_printf_has_decfloat=yes,
1630                               gdb_cv_printf_has_decfloat=no,
1631                               gdb_cv_printf_has_decfloat=no)])
1632 if test $gdb_cv_printf_has_decfloat = yes; then
1633   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1634             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1635 fi
1636
1637 # Check if the compiler supports the `long double' type.  We can't use
1638 # AC_C_LONG_DOUBLE because that one does additional checks on the
1639 # constants defined in <float.h> that fail on some systems,
1640 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1641
1642 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1643                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1644                                   gdb_cv_c_long_double=yes,
1645                                   gdb_cv_c_long_double=no)])
1646 if test $gdb_cv_c_long_double = yes; then
1647   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1648            [Define to 1 if the compiler supports long double.])
1649 fi
1650
1651 # Check if the compiler and runtime support printing long doubles.
1652
1653 AC_CACHE_CHECK([for long double support in printf],
1654                gdb_cv_printf_has_long_double,
1655                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1656 [[char buf[16];
1657   long double f = 3.141592653;
1658   sprintf (buf, "%Lg", f);
1659   return (strncmp ("3.14159", buf, 7));]])],
1660                               gdb_cv_printf_has_long_double=yes,
1661                               gdb_cv_printf_has_long_double=no,
1662                               gdb_cv_printf_has_long_double=no)])
1663 if test $gdb_cv_printf_has_long_double = yes; then
1664   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1665             [Define to 1 if the "%Lg" format works to print long doubles.])
1666 fi
1667
1668 # Check if the compiler and runtime support scanning long doubles.
1669
1670 AC_CACHE_CHECK([for long double support in scanf],
1671                gdb_cv_scanf_has_long_double,
1672                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1673 [[#include <stdio.h>]],
1674 [[char *buf = "3.141592653";
1675   long double f = 0;
1676   sscanf (buf, "%Lg", &f);
1677   return !(f > 3.14159 && f < 3.14160);]])],
1678                               gdb_cv_scanf_has_long_double=yes,
1679                               gdb_cv_scanf_has_long_double=no,
1680                               gdb_cv_scanf_has_long_double=no)])
1681 if test $gdb_cv_scanf_has_long_double = yes; then
1682   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1683             [Define to 1 if the "%Lg" format works to scan long doubles.])
1684 fi
1685
1686 case ${host_os} in
1687 aix*)
1688   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1689     SAVE_LDFLAGS=$LDFLAGS
1690
1691     case $GCC in
1692     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1693     *) gdb_cv_bigtoc=-bbigtoc ;;
1694     esac
1695
1696     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1697     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1698     LDFLAGS="${SAVE_LDFLAGS}"
1699   ])
1700   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1701   ;;
1702 esac
1703
1704 AC_MSG_CHECKING(for the dynamic export flag)
1705 dynamic_list=false
1706 if test "${gdb_native}" = yes; then
1707    # The dynamically loaded libthread_db needs access to symbols in the gdb
1708    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1709    # may not be supported there.
1710    old_LDFLAGS="$LDFLAGS"
1711    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1712    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1713    LDFLAGS="$LDFLAGS $RDYNAMIC"
1714    if test "${have_libpython}" = no; then
1715      AC_TRY_LINK([], [], [dynamic_list=true])
1716    else
1717      # Workaround http://bugs.python.org/issue4434 where static
1718      # libpythonX.Y.a would get its symbols required for
1719      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1720      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1721      old_CFLAGS="$CFLAGS"
1722      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1723      old_LIBS="$LIBS"
1724      LIBS="$LIBS $PYTHON_LIBS"
1725      AC_RUN_IFELSE(
1726        AC_LANG_PROGRAM(
1727          [#include "]${have_libpython}[/Python.h"],
1728          [int err;
1729           Py_Initialize ();
1730           err = PyRun_SimpleString ("import itertools\n");
1731           Py_Finalize ();
1732           return err == 0 ? 0 : 1;]),
1733        [dynamic_list=true], [], [true])
1734      LIBS="$old_LIBS"
1735      CFLAGS="$old_CFLAGS"
1736    fi
1737    LDFLAGS="$old_LDFLAGS"
1738 fi
1739 if $dynamic_list; then
1740   found="-Wl,--dynamic-list"
1741   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1742 else
1743   found="-rdynamic"
1744   RDYNAMIC="-rdynamic"
1745 fi
1746 AC_SUBST(RDYNAMIC)
1747 AC_MSG_RESULT($found)
1748
1749 dnl For certain native configurations, we need to check whether thread
1750 dnl support can be built in or not.
1751 dnl
1752 dnl Note that we only want this if we are both native (host == target),
1753 dnl and not doing a canadian cross build (build == host).
1754
1755 if test ${build} = ${host} -a ${host} = ${target} ; then
1756    case ${host_os} in
1757    solaris*)
1758       # See if thread_db library is around for Solaris thread debugging.
1759       # Note that we must explicitly test for version 1 of the library
1760       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1761       # the same API.
1762       AC_MSG_CHECKING(for Solaris thread debugging library)
1763       if test -f /usr/lib/libthread_db.so.1 ; then
1764          AC_MSG_RESULT(yes)
1765          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1766          [Define if using Solaris thread debugging.])
1767          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1768          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1769          AC_CHECK_LIB(dl, dlopen)
1770          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1771          # Sun randomly tweaked the prototypes in <proc_service.h>
1772          # at one point.
1773          AC_MSG_CHECKING(if <proc_service.h> is old)
1774          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1775             AC_TRY_COMPILE([
1776                 #include <proc_service.h>
1777                 ps_err_e ps_pdwrite
1778                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1779             ],, gdb_cv_proc_service_is_old=no,
1780                 gdb_cv_proc_service_is_old=yes)
1781          ])
1782          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1783          if test $gdb_cv_proc_service_is_old = yes; then
1784             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1785             [Define if <proc_service.h> on solaris uses int instead of
1786              size_t, and assorted other type changes.])
1787          fi
1788       else
1789          AC_MSG_RESULT(no)
1790       fi
1791       ;;
1792    aix*)
1793       AC_MSG_CHECKING(for AiX thread debugging library)
1794       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1795                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1796                                    [#ifndef PTHDB_VERSION_3
1797                                     #error
1798                                     #endif],
1799                                    gdb_cv_have_aix_thread_debug=yes,
1800                                    gdb_cv_have_aix_thread_debug=no)])
1801       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1802       if test $gdb_cv_have_aix_thread_debug = yes; then
1803          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1804          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1805          LIBS="$LIBS -lpthdebug"
1806
1807          # Older versions of AIX do not provide the declaration for
1808          # the getthrds function (it appears that it was introduced
1809          # with AIX 6.x).
1810          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1811       fi
1812       ;;
1813    esac
1814    AC_SUBST(CONFIG_LDFLAGS)
1815 fi
1816
1817 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1818 dnl other error codes.
1819 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1820    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1821                   gdb_cv_thread_db_h_has_td_notalloc,
1822      AC_TRY_COMPILE(
1823        [#include <thread_db.h>],
1824        [int i = TD_NOTALLOC;],
1825        gdb_cv_thread_db_h_has_td_notalloc=yes,
1826        gdb_cv_thread_db_h_has_td_notalloc=no
1827      )
1828    )
1829    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1830                   gdb_cv_thread_db_h_has_td_version,
1831      AC_TRY_COMPILE(
1832        [#include <thread_db.h>],
1833        [int i = TD_VERSION;],
1834        gdb_cv_thread_db_h_has_td_version=yes,
1835        gdb_cv_thread_db_h_has_td_version=no
1836      )
1837    )
1838    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1839                   gdb_cv_thread_db_h_has_td_notls,
1840      AC_TRY_COMPILE(
1841        [#include <thread_db.h>],
1842        [int i = TD_NOTLS;],
1843        gdb_cv_thread_db_h_has_td_notls=yes,
1844        gdb_cv_thread_db_h_has_td_notls=no
1845      )
1846    )
1847 fi
1848 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1849   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1850             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1851 fi
1852 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1853   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1854             [Define if <thread_db.h> has the TD_VERSION error code.])
1855 fi
1856 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1857   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1858             [Define if <thread_db.h> has the TD_NOTLS error code.])
1859 fi
1860
1861 dnl Check if we can disable the virtual address space randomization.
1862 dnl The functionality of setarch -R.
1863 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1864 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1865 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1866 #       define ADDR_NO_RANDOMIZE 0x0040000
1867 #      endif
1868        /* Test the flag could be set and stays set.  */
1869        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1870        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1871            return 1])])
1872 AC_RUN_IFELSE([PERSONALITY_TEST],
1873               [have_personality=true],
1874               [have_personality=false],
1875               [AC_LINK_IFELSE([PERSONALITY_TEST],
1876                               [have_personality=true],
1877                               [have_personality=false])])
1878 if $have_personality
1879 then
1880     AC_DEFINE([HAVE_PERSONALITY], 1,
1881               [Define if you support the personality syscall.])
1882 fi
1883
1884 dnl Set the host's .gdbinit filename.
1885 case $host_os in
1886   go32* | *djgpp*)
1887     gdbinit=gdb.ini
1888     ;;
1889   *)
1890     gdbinit=.gdbinit
1891     ;;
1892 esac
1893 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1894
1895 dnl Handle optional features that can be enabled.
1896
1897 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1898 # except that the argument to --with-sysroot is optional.
1899 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1900 if test "x$with_sysroot" = xyes; then
1901   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1902 fi
1903 AC_ARG_WITH(sysroot,
1904   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1905                  [search for usr/lib et al within DIR]),
1906   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1907 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1908               [search for usr/lib et al within DIR])
1909 AC_SUBST(TARGET_SYSTEM_ROOT)
1910 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1911
1912 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1913     [automatically load a system-wide gdbinit file],
1914     [])
1915
1916 AM_GDB_WARNINGS
1917
1918 # In the Cygwin environment, we need some additional flags.
1919 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1920 [AC_EGREP_CPP(^lose$, [
1921 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1922 lose
1923 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1924
1925
1926 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1927 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1928 case ${host} in
1929   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1930   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1931   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1932 esac
1933 AC_SUBST(SER_HARDWIRE)
1934
1935 # libreadline needs libuser32.a in a cygwin environment
1936 WIN32LIBS=
1937 if test x$gdb_cv_os_cygwin = xyes; then
1938     WIN32LIBS="-luser32"
1939     case "${target}" in
1940         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1941         ;;
1942     esac
1943 fi
1944
1945 # The ser-tcp.c module requires sockets.
1946 case ${host} in
1947   *mingw32*)
1948     AC_DEFINE(USE_WIN32API, 1,
1949               [Define if we should use the Windows API, instead of the
1950                POSIX API.  On Windows, we use the Windows API when
1951                building for MinGW, but the POSIX API when building
1952                for Cygwin.])
1953     WIN32LIBS="$WIN32LIBS -lws2_32"
1954     ;;
1955 esac
1956 AC_SUBST(WIN32LIBS)
1957
1958 # Add ELF support to GDB, but only if BFD includes ELF support.
1959 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1960                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1961 if test $gdb_cv_var_elf = yes; then
1962   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1963   AC_DEFINE(HAVE_ELF, 1,
1964             [Define if ELF support should be included.])
1965   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1966   if test "$plugins" = "yes"; then
1967     AC_SEARCH_LIBS(dlopen, dl)
1968   fi
1969 fi
1970
1971 # Add macho support to GDB, but only if BFD includes it.
1972 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1973                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1974 if test $gdb_cv_var_macho = yes; then
1975   CONFIG_OBS="$CONFIG_OBS machoread.o"
1976 fi
1977
1978 # Add any host-specific objects to GDB.
1979 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1980
1981 # If building on ELF, look for lzma support for embedded compressed debug info.
1982 if test $gdb_cv_var_elf = yes; then
1983   AC_ARG_WITH(lzma,
1984     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1985     [], [with_lzma=auto])
1986   AC_MSG_CHECKING([whether to use lzma])
1987   AC_MSG_RESULT([$with_lzma])
1988
1989   if test "${with_lzma}" != no; then
1990     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1991                           [lzma_index_iter iter;
1992                            lzma_index_iter_init (&iter, 0);
1993                            lzma_mf_is_supported (LZMA_MF_HC3);])
1994     if test "$HAVE_LIBLZMA" != yes; then
1995       if test "$with_lzma" = yes; then
1996         AC_MSG_ERROR([missing liblzma for --with-lzma])
1997       fi
1998     fi
1999   fi
2000 fi
2001
2002 LIBGUI="../libgui/src/libgui.a"
2003 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
2004 AC_SUBST(LIBGUI)
2005 AC_SUBST(GUI_CFLAGS_X)
2006
2007 WIN32LDAPP=
2008 AC_SUBST(WIN32LIBS)
2009 AC_SUBST(WIN32LDAPP)
2010
2011 case "${host}" in
2012 *-*-cygwin* | *-*-mingw* )
2013     configdir="win"
2014     ;;
2015 *)
2016     configdir="unix"
2017     ;;
2018 esac
2019
2020 GDBTKLIBS=
2021 if test "${enable_gdbtk}" = "yes"; then
2022
2023     # Gdbtk must have an absolute path to srcdir in order to run
2024     # properly when not installed.
2025     here=`pwd`
2026     cd ${srcdir}
2027     GDBTK_SRC_DIR=`pwd`
2028     cd $here
2029
2030     SC_PATH_TCLCONFIG
2031
2032     # If $no_tk is nonempty, then we can't do Tk, and there is no
2033     # point to doing Tcl.
2034     SC_PATH_TKCONFIG
2035
2036     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2037         SC_LOAD_TCLCONFIG
2038
2039         # Check for in-tree tcl
2040         here=`pwd`
2041         cd ${srcdir}/..
2042         topdir=`pwd`
2043         cd ${here}
2044
2045         intree="no"
2046         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2047           intree="yes"
2048         fi
2049
2050         # Find Tcl private headers
2051         if test x"${intree}" = xno; then
2052           CY_AC_TCL_PRIVATE_HEADERS
2053           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2054           TCL_LIBRARY="${TCL_LIB_SPEC}"
2055           TCL_DEPS=""
2056         else
2057           # If building tcl in the same src tree, private headers
2058           # are not needed, but we need to be sure to use the right
2059           # headers library
2060           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2061           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2062           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2063         fi
2064         AC_SUBST(TCL_INCLUDE)
2065         AC_SUBST(TCL_LIBRARY)
2066         AC_SUBST(TCL_DEPS)
2067
2068         SC_LOAD_TKCONFIG
2069
2070         # Check for in-tree Tk
2071         intree="no"
2072         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2073           intree="yes"
2074         fi
2075
2076         # Find Tk private headers
2077         if test x"${intree}" = xno; then
2078           CY_AC_TK_PRIVATE_HEADERS
2079           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2080           TK_LIBRARY=${TK_LIB_SPEC}
2081           TK_DEPS=""
2082         else
2083           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2084           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2085           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2086         fi
2087         AC_SUBST(TK_INCLUDE)
2088         AC_SUBST(TK_LIBRARY)
2089         AC_SUBST(TK_DEPS)
2090         AC_SUBST(TK_XINCLUDES)
2091
2092         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2093
2094         # Include some libraries that Tcl and Tk want.
2095         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2096         # Yes, the ordering seems wrong here.  But it isn't.
2097         # TK_LIBS is the list of libraries that need to be linked
2098         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2099         # were in LIBS then any link tests after this point would
2100         # try to include things like `$(LIBGUI)', which wouldn't work.
2101         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2102
2103         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2104         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2105         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2106         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2107         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2108         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2109         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2110
2111         if test x$gdb_cv_os_cygwin = xyes; then
2112           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2113           WIN32LDAPP="-Wl,--subsystem,console"
2114           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2115         fi
2116
2117         AC_CONFIG_SUBDIRS(gdbtk)
2118     fi
2119 fi
2120
2121 AC_SUBST(X_CFLAGS)
2122 AC_SUBST(X_LDFLAGS)
2123 AC_SUBST(X_LIBS)
2124 AC_SUBST(GDBTKLIBS)
2125 AC_SUBST(GDBTK_CFLAGS)
2126 AC_SUBST(GDBTK_SRC_DIR)
2127
2128 AC_PATH_X
2129
2130 # Unlike the sim directory, whether a simulator is linked is controlled by
2131 # presence of a gdb_sim definition in the target configure.tgt entry.
2132 # This code just checks for a few cases where we'd like to ignore those
2133 # definitions, even when they're present in the '.mt' file.  These cases
2134 # are when --disable-sim is specified, or if the simulator directory is
2135 # not part of the source tree.
2136 #
2137 AC_ARG_ENABLE(sim,
2138 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2139 [echo "enable_sim = $enable_sim";
2140  echo "enableval = ${enableval}";
2141  case "${enableval}" in
2142   yes) ignore_sim=false ;;
2143   no)  ignore_sim=true ;;
2144   *)   ignore_sim=false ;;
2145  esac],
2146 [ignore_sim=false])
2147
2148 if test ! -d "${srcdir}/../sim"; then
2149   ignore_sim=true
2150 fi
2151
2152 SIM=
2153 SIM_OBS=
2154 if test "${ignore_sim}" = "false"; then
2155   if test x"${gdb_sim}" != x ; then
2156     SIM="${gdb_sim}"
2157     SIM_OBS="remote-sim.o"
2158     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2159
2160     # Some tdep code should only be compiled in when the ppc sim is
2161     # built.  PR sim/13418.
2162     case $target in
2163       powerpc*-*-*)
2164         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2165         ;;
2166     esac
2167   fi
2168 fi
2169 AC_SUBST(SIM)
2170 AC_SUBST(SIM_OBS)
2171
2172 AC_SUBST(ENABLE_CFLAGS)
2173 AC_SUBST(PROFILE_CFLAGS)
2174
2175 AC_SUBST(CONFIG_OBS)
2176 AC_SUBST(CONFIG_DEPS)
2177 AC_SUBST(CONFIG_SRCS)
2178 AC_SUBST(CONFIG_ALL)
2179 AC_SUBST(CONFIG_CLEAN)
2180 AC_SUBST(CONFIG_INSTALL)
2181 AC_SUBST(CONFIG_UNINSTALL)
2182
2183 # List of host floatformats.
2184 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2185 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2186 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2187
2188 # target_subdir is used by the testsuite to find the target libraries.
2189 target_subdir=
2190 if test "${host}" != "${target}"; then
2191     target_subdir="${target_alias}/"
2192 fi
2193 AC_SUBST(target_subdir)
2194
2195 frags=
2196 if test "${gdb_native}" = "yes"; then
2197   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2198   if test ! -f ${host_makefile_frag}; then
2199     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2200   fi
2201   frags="$frags $host_makefile_frag"
2202 else
2203   host_makefile_frag=/dev/null
2204 fi
2205
2206 AC_SUBST_FILE(host_makefile_frag)
2207 AC_SUBST(frags)
2208
2209 changequote(,)dnl
2210 if test "${gdb_native}" = "yes"; then
2211 # We pick this up from the host configuration file (.mh) because we
2212 # do not have a native configuration Makefile fragment.
2213 nativefile=`sed -n '
2214 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2215 ' ${host_makefile_frag}`
2216 fi
2217 changequote([,])
2218
2219 if test x"${gdb_osabi}" != x ; then
2220     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2221                        [Define to the default OS ABI for this configuration.])
2222 fi
2223
2224 # Enable multi-ice-gdb-server.
2225 AC_ARG_ENABLE(multi-ice,
2226 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2227   [case $enableval in
2228     yes | no)
2229       ;;
2230     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2231   esac])
2232 if test "x$enable_multi_ice" = xyes; then
2233    AC_CONFIG_SUBDIRS(multi-ice)
2234 fi
2235
2236 AC_ARG_ENABLE(gdbserver,
2237 AS_HELP_STRING([--enable-gdbserver],
2238                [automatically build gdbserver (yes/no/auto, default is auto)]),
2239 [case "${enableval}" in
2240   yes| no|auto) ;;
2241   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2242 esac],[enable_gdbserver=auto])
2243
2244 # We only build gdbserver automatically in a native configuration, and
2245 # only if the user did not explicitly disable its build.
2246 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2247   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2248   if test "x$build_gdbserver" = xyes; then
2249     AC_MSG_RESULT(yes)
2250     AC_CONFIG_SUBDIRS(gdbserver)
2251     gdbserver_build_enabled=yes
2252   else
2253     AC_MSG_RESULT(no)
2254   fi
2255 fi
2256
2257 # If the user explicitly request the gdbserver to be built, verify that
2258 # we were in fact able to enable it.
2259 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2260   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2261 fi
2262
2263 # Check for babeltrace and babeltrace-ctf
2264 AC_ARG_WITH(babeltrace,
2265   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2266   [], [with_babeltrace=auto])
2267 AC_MSG_CHECKING([whether to use babeltrace])
2268 AC_MSG_RESULT([$with_babeltrace])
2269
2270 if test "x$with_babeltrace" = "xno"; then
2271   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2272 else
2273   # Append -Werror to CFLAGS so that configure can catch the warning
2274   # "assignment from incompatible pointer type", which is related to
2275   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2276   # in GDB, while babeltrace 1.0.3 is broken.
2277   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2278   # safe to save and restore CFLAGS here.
2279   saved_CFLAGS=$CFLAGS
2280   CFLAGS="$CFLAGS -Werror"
2281   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2282                         [#include <babeltrace/babeltrace.h>
2283                          #include <babeltrace/ctf/events.h>
2284                          #include <babeltrace/ctf/iterator.h>],
2285                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2286                         struct bt_ctf_event *event = NULL;
2287                         const struct bt_definition *scope;
2288
2289                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2290                         scope = bt_ctf_get_top_level_scope (event,
2291                                                            BT_STREAM_EVENT_HEADER);
2292                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2293                         ])
2294   CFLAGS=$saved_CFLAGS
2295
2296   if test "$HAVE_LIBBABELTRACE" != yes; then
2297      if test "$with_babeltrace" = yes; then
2298        AC_MSG_ERROR([babeltrace is missing or unusable])
2299      else
2300        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2301      fi
2302   fi
2303 fi
2304
2305 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2306 # to an empty version.
2307
2308 files=
2309 links=
2310
2311 rm -f nm.h
2312 if test "${nativefile}" != ""; then
2313     case "${nativefile}" in
2314       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2315       * ) GDB_NM_FILE="${nativefile}"
2316     esac
2317     files="${files} ${GDB_NM_FILE}"
2318     links="${links} nm.h"
2319     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2320 fi
2321 AC_SUBST(GDB_NM_FILE)
2322
2323 AC_LINK_FILES($files, $links)
2324
2325 dnl Check for exe extension set on certain hosts (e.g. Win32)
2326 AC_EXEEXT
2327
2328 dnl  Detect the character set used by this host.
2329 dnl  At the moment, we just assume it's UTF-8.
2330 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2331           [Define to be a string naming the default host character set.])
2332
2333 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2334 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2335 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2336 AC_CONFIG_FILES([Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile],
2337 [
2338 case x$CONFIG_HEADERS in
2339 xconfig.h:config.in)
2340 echo > stamp-h ;;
2341 esac
2342 ])
2343
2344 AC_OUTPUT