gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   3 dnl 2005, 2006
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 2 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; if not, write to the Free Software
  20 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor,
  21 dnl Boston, MA 02110-1301, USA.
  22
  23 dnl Process this file with autoconf to produce a configure script.
  24
  25 AC_PREREQ(2.59)dnl
  26 AC_INIT(main.c)
  27 AC_CONFIG_HEADER(config.h:config.in)
  28 AM_MAINTAINER_MODE
  29
  30 AC_PROG_CC
  31 AC_GNU_SOURCE
  32 AC_AIX
  33 AC_ISC_POSIX
  34 AM_PROG_CC_STDC
  35
  36 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  37 AC_CANONICAL_SYSTEM
  38
  39 dnl List of object files and targets accumulated by configure.
  40
  41 CONFIG_OBS=
  42 CONFIG_DEPS=
  43 CONFIG_SRCS=
  44 ENABLE_CFLAGS=
  45
  46 CONFIG_ALL=
  47 CONFIG_CLEAN=
  48 CONFIG_INSTALL=
  49 CONFIG_UNINSTALL=
  50
  51 dnl Set up for gettext.
  52 ZW_GNU_GETTEXT_SISTER_DIR
  53
  54 localedir='${datadir}/locale'
  55 AC_SUBST(localedir)
  56
  57 if test x"$USE_NLS" = xyes; then
  58    CONFIG_ALL="$CONFIG_ALL all-po"
  59    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  60    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  61    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  62 fi
  63
  64 PACKAGE=gdb
  65 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  66 AC_SUBST(PACKAGE)
  67
  68 debugdir=${libdir}/debug
  69
  70 AC_ARG_WITH(separate-debug-dir,
  71 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  72 [debugdir="${withval}"])
  73
  74 AC_DEFINE_DIR(DEBUGDIR, debugdir,
  75               [Global directory for separate debug files. ])
  76 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
  77
  78 if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
  79   if test "x$prefix" = xNONE; then
  80     test_prefix=/usr/local
  81   else
  82     test_prefix=$prefix
  83   fi
  84 else
  85   test_prefix=$exec_prefix
  86 fi
  87 case ${debugdir} in
  88 "${test_prefix}"|"${test_prefix}/"*|\
  89 '${exec_prefix}'|'${exec_prefix}/'*)
  90   AC_DEFINE(DEBUGDIR_RELOCATABLE, 1, [Define if the debug directory should be relocated when GDB is moved.])
  91   ;;
  92 esac
  93
  94 AC_CONFIG_SUBDIRS(doc testsuite)
  95
  96 # Provide defaults for some variables set by the per-host and per-target
  97 # configuration.
  98 gdb_host_obs=posix-hdep.o
  99
 100 if test "${target}" = "${host}"; then
 101   gdb_native=yes
 102 else
 103   gdb_native=no
 104 fi
 105
 106 . $srcdir/configure.host
 107
 108 . $srcdir/configure.tgt
 109
 110 # Fetch the default architecture and default target vector from BFD.
 111 targ=$target; . $srcdir/../bfd/config.bfd
 112
 113 # We only want the first architecture, so strip off the others if
 114 # there is more than one.
 115 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 116
 117 if test "x$targ_archs" != x; then
 118   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 119     [Define to BFD's default architecture. ])
 120 fi
 121 if test "x$targ_defvec" != x; then
 122   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 123     [Define to BFD's default target vector. ])
 124 fi
 125
 126 AC_ARG_PROGRAM
 127
 128 # The CLI cannot be disabled yet, but may be in the future.
 129
 130 # Enable CLI.
 131 AC_ARG_ENABLE(gdbcli,
 132 [  --disable-gdbcli        disable command-line interface (CLI)],
 133   [case $enableval in
 134     yes)
 135       ;;
 136     no)
 137       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 138     *)
 139       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 140   esac],
 141   [enable_gdbcli=yes])
 142 if test x"$enable_gdbcli" = xyes; then
 143   if test -d $srcdir/cli; then
 144     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 145     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 146     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 147     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 148   fi
 149 fi
 150
 151 # Enable MI.
 152 AC_ARG_ENABLE(gdbmi,
 153 [  --disable-gdbmi         disable machine-interface (MI)],
 154   [case $enableval in
 155     yes | no)
 156       ;;
 157     *)
 158       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 159   esac],
 160   [enable_gdbmi=yes])
 161 if test x"$enable_gdbmi" = xyes; then
 162   if test -d $srcdir/mi; then
 163     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 164     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 165     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 166     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 167   fi
 168 fi
 169
 170 # Enable TUI.
 171 AC_ARG_ENABLE(tui,
 172 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 173   [case $enableval in
 174     yes | no)
 175       ;;
 176     *)
 177       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 178   esac],enable_tui=yes)
 179
 180 # Enable gdbtk.
 181 AC_ARG_ENABLE(gdbtk,
 182 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 183   [case $enableval in
 184     yes | no)
 185       ;;
 186     *)
 187       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 188   esac],
 189   [if test -d $srcdir/gdbtk -a -d $srcdir/../itcl; then
 190     enable_gdbtk=yes
 191   else
 192     enable_gdbtk=no
 193   fi])
 194 # We unconditionally disable gdbtk tests on selected platforms.
 195 case $host_os in
 196   go32* | windows*)
 197     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 198     enable_gdbtk=no ;;
 199 esac
 200
 201 # Libunwind support.
 202 AC_ARG_WITH(libunwind,
 203 [  --with-libunwind            Use libunwind frame unwinding support],
 204 [case "${withval}" in
 205   yes)  enable_libunwind=yes ;;
 206   no)   enable_libunwind=no ;;
 207   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 208 esac],[
 209   AC_CHECK_HEADERS(libunwind.h)
 210   AC_CHECK_HEADERS(libunwind-ia64.h)
 211   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 212     enable_libunwind=yes;
 213   fi
 214 ])
 215
 216 if test x"$enable_libunwind" = xyes; then
 217   AC_CHECK_HEADERS(libunwind.h)
 218   AC_CHECK_HEADERS(libunwind-ia64.h)
 219   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 220   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 221   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 222   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 223 fi
 224
 225 # Profiling support.
 226 AC_ARG_ENABLE(profiling,
 227 [  --enable-profiling      enable profiling of GDB],
 228   [case $enableval in
 229     yes | no)
 230       ;;
 231     *)
 232       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 233   esac],
 234  [enable_profiling=no])
 235
 236 AC_CHECK_FUNCS(monstartup _mcleanup)
 237 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 238 [AC_TRY_LINK(
 239 [#include <stdlib.h>
 240 extern char _etext;
 241 ],
 242 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 243 if test $ac_cv_var__etext = yes; then
 244   AC_DEFINE(HAVE__ETEXT, 1,
 245             [Define to 1 if your system has the _etext variable. ])
 246 fi
 247 if test "$enable_profiling" = yes ; then
 248   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 249     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 250   fi
 251   PROFILE_CFLAGS=-pg
 252   OLD_CFLAGS="$CFLAGS"
 253   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 254
 255   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 256     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 257      ac_cv_cc_supports_pg=no)])
 258
 259   if test $ac_cv_cc_supports_pg = no; then
 260     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 261   fi
 262
 263   CFLAGS="$OLD_CFLAGS"
 264 fi
 265
 266 # --------------------- #
 267 # Checks for programs.  #
 268 # --------------------- #
 269
 270 AC_PROG_AWK
 271 AC_PROG_INSTALL
 272 AC_PROG_LN_S
 273 AC_PROG_RANLIB
 274 AC_PROG_YACC
 275
 276 AC_CHECK_TOOL(AR, ar)
 277 AC_CHECK_TOOL(DLLTOOL, dlltool)
 278 AC_CHECK_TOOL(WINDRES, windres)
 279
 280 # Needed for GNU/Hurd.
 281 AC_CHECK_TOOL(MIG, mig)
 282
 283 # ---------------------- #
 284 # Checks for libraries.  #
 285 # ---------------------- #
 286
 287 # We might need to link with -lm; most simulators need it.
 288 AC_CHECK_LIB(m, main)
 289
 290 # We need to link with -lw to get `wctype' on Solaris before Solaris
 291 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 292 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 293 # is known to have this problem).  Therefore we avoid libw if we can.
 294 AC_CHECK_FUNC(wctype, [],
 295   [AC_CHECK_LIB(w, wctype)])
 296
 297 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 298 AC_SEARCH_LIBS(gethostbyname, nsl)
 299
 300 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 301 AC_SEARCH_LIBS(socketpair, socket)
 302
 303 # For the TUI, we need enhanced curses functionality.
 304 #
 305 # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 306 # curses library because the latter might not provide all the
 307 # functionality we need.  However, this leads to problems on systems
 308 # where the linker searches /usr/local/lib, but the compiler doesn't
 309 # search /usr/local/include, if ncurses is installed in /usr/local.  A
 310 # default installation of ncurses on alpha*-dec-osf* will lead to such
 311 # a situation.
 312 AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 313
 314 # Since GDB uses Readline, we need termcap functionality.  In many
 315 # cases this will be provided by the curses library, but some systems
 316 # have a seperate termcap library, or no curses library at all.
 317
 318 case $host_os in
 319   cygwin*)
 320     if test -d $srcdir/libtermcap; then
 321       LIBS="../libtermcap/libtermcap.a $LIBS"
 322       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 323     fi ;;
 324   go32* | *djgpp*)
 325     ac_cv_search_tgetent="none required"
 326     ;;
 327   *mingw32*)
 328     ac_cv_search_tgetent="none required"
 329     CONFIG_OBS="$CONFIG_OBS win32-termcap.o"
 330     ;;
 331 esac
 332
 333 # These are the libraries checked by Readline.
 334 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 335
 336 if test "$ac_cv_search_tgetent" = no; then
 337   AC_MSG_ERROR([no termcap library found])
 338 fi
 339
 340 AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 341                       [XML_Parser p = XML_ParserCreate (0);])
 342 if test "$HAVE_LIBEXPAT" != yes; then
 343   AC_MSG_WARN([expat is missing or unusable; some features may be disabled.])
 344 else
 345   save_LIBS=$LIBS
 346   LIBS="$LIBS $LIBEXPAT"
 347   AC_CHECK_FUNCS(XML_StopParser)
 348   LIBS=$save_LIBS
 349 fi
 350
 351 # ------------------------- #
 352 # Checks for header files.  #
 353 # ------------------------- #
 354
 355 AC_HEADER_DIRENT
 356 AC_HEADER_STAT
 357 AC_HEADER_STDC
 358 AC_CHECK_HEADERS(nlist.h)
 359 AC_CHECK_HEADERS(link.h, [], [],
 360 [#if HAVE_SYS_TYPES_H
 361 # include <sys/types.h>
 362 #endif
 363 #if HAVE_NLIST_H
 364 # include <nlist.h>
 365 #endif
 366 ])
 367 AC_CHECK_HEADERS(machine/reg.h)
 368 AC_CHECK_HEADERS(poll.h sys/poll.h)
 369 AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h)
 370 AC_CHECK_HEADERS(stddef.h)
 371 AC_CHECK_HEADERS(stdlib.h)
 372 AC_CHECK_HEADERS(stdint.h)
 373 AC_CHECK_HEADERS(string.h memory.h strings.h)
 374 AC_CHECK_HEADERS(sys/fault.h)
 375 AC_CHECK_HEADERS(sys/file.h)
 376 AC_CHECK_HEADERS(sys/filio.h)
 377 AC_CHECK_HEADERS(sys/ioctl.h)
 378 AC_CHECK_HEADERS(sys/param.h)
 379 AC_CHECK_HEADERS(sys/resource.h)
 380 AC_CHECK_HEADERS(sys/proc.h, [], [],
 381 [#if HAVE_SYS_PARAM_H
 382 # include <sys/param.h>
 383 #endif
 384 ])
 385 AC_CHECK_HEADERS(sys/procfs.h)
 386 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 387 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 388 AC_CHECK_HEADERS(sys/select.h)
 389 AC_CHECK_HEADERS(sys/syscall.h)
 390 AC_CHECK_HEADERS(sys/types.h)
 391 AC_CHECK_HEADERS(sys/user.h, [], [],
 392 [#if HAVE_SYS_PARAM_H
 393 # include <sys/param.h>
 394 #endif
 395 ])
 396 AC_CHECK_HEADERS(sys/wait.h wait.h)
 397 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 398 AC_CHECK_HEADERS(unistd.h)
 399
 400 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 401 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 402 # think that we don't have <curses.h> if we're using GCC.
 403 case $host_os in
 404   solaris2.[[789]])
 405     if test "$GCC" = yes; then
 406       AC_DEFINE(_MSE_INT_H, 1,
 407         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 408    Solaris 2.[789] when using GCC. ])
 409     fi ;;
 410 esac
 411 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h)
 412 AC_CHECK_HEADERS(ncurses/term.h)
 413 AC_CHECK_HEADERS(term.h, [], [],
 414 [#if HAVE_CURSES_H
 415 # include <curses.h>
 416 #endif
 417 ])
 418
 419 # FIXME: kettenis/20030102: In most cases we include these
 420 # unconditionally, so what's the point in checking these?
 421 AC_CHECK_HEADERS(ctype.h time.h)
 422
 423 # Create a header we can use portably to get the standard integer types.
 424 GCC_HEADER_STDINT(gdb_stdint.h)
 425
 426 # ------------------------- #
 427 # Checks for declarations.  #
 428 # ------------------------- #
 429
 430 AC_CHECK_DECLS([free, malloc, realloc])
 431 AC_CHECK_DECLS([strerror, strstr])
 432 AC_CHECK_DECLS([getopt, snprintf, vsnprintf])
 433
 434 # ----------------------- #
 435 # Checks for structures.  #
 436 # ----------------------- #
 437
 438 AC_CHECK_MEMBERS([struct stat.st_blocks])
 439 AC_CHECK_MEMBERS([struct stat.st_blksize])
 440
 441 # ------------------ #
 442 # Checks for types.  #
 443 # ------------------ #
 444
 445 AC_TYPE_SIGNAL
 446 AC_CHECK_TYPES(socklen_t, [], [],
 447 [#include <sys/types.h>
 448 #include <sys/socket.h>
 449 ])
 450 AC_CHECK_TYPES(uintptr_t, [], [], [#include <stdint.h>])
 451
 452 # ------------------------------------- #
 453 # Checks for compiler characteristics.  #
 454 # ------------------------------------- #
 455
 456 AC_C_CONST
 457 AC_C_INLINE
 458
 459 # ------------------------------ #
 460 # Checks for library functions.  #
 461 # ------------------------------ #
 462
 463 AC_FUNC_ALLOCA
 464 AC_FUNC_MMAP
 465 AC_FUNC_VFORK
 466 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 467 AC_CHECK_FUNCS(getrusage)
 468 AC_CHECK_FUNCS(getuid getgid)
 469 AC_CHECK_FUNCS(poll)
 470 AC_CHECK_FUNCS(pread64)
 471 AC_CHECK_FUNCS(sbrk)
 472 AC_CHECK_FUNCS(setpgid setpgrp)
 473 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 474 AC_CHECK_FUNCS(socketpair)
 475 AC_CHECK_FUNCS(syscall)
 476 AC_CHECK_FUNCS(ttrace)
 477 AC_CHECK_FUNCS(wborder)
 478
 479 # Check the return and argument types of ptrace.  No canned test for
 480 # this, so roll our own.
 481 gdb_ptrace_headers='
 482 #if HAVE_SYS_TYPES_H
 483 # include <sys/types.h>
 484 #endif
 485 #if HAVE_SYS_PTRACE_H
 486 # include <sys/ptrace.h>
 487 #endif
 488 #if HAVE_UNISTD_H
 489 # include <unistd.h>
 490 #endif
 491 '
 492 # There is no point in checking if we don't have a prototype.
 493 AC_CHECK_DECLS(ptrace, [], [
 494   : ${gdb_cv_func_ptrace_ret='int'}
 495   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 496 ], $gdb_ptrace_headers)
 497 # Check return type.
 498 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 499   AC_TRY_COMPILE($gdb_ptrace_headers,
 500     [extern int ptrace ();],
 501     gdb_cv_func_ptrace_ret='int',
 502     gdb_cv_func_ptrace_ret='long'))
 503 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 504   [Define as the return type of ptrace.])
 505 # Check argument types.
 506 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 507 for gdb_arg1 in 'int' 'long'; do
 508  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 509   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long'; do
 510    for gdb_arg4 in 'int' 'long'; do
 511      AC_TRY_COMPILE($gdb_ptrace_headers, [
 512 extern $gdb_cv_func_ptrace_ret
 513   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 514 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 515     break 4;])
 516     for gdb_arg5 in 'int *' 'int' 'long'; do
 517      AC_TRY_COMPILE($gdb_ptrace_headers, [
 518 extern $gdb_cv_func_ptrace_ret
 519   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 520 ], [
 521 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 522     break 5;])
 523     done
 524    done
 525   done
 526  done
 527 done
 528 # Provide a safe default value.
 529 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 530 ])
 531 ac_save_IFS=$IFS; IFS=','
 532 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 533 IFS=$ac_save_IFS
 534 shift
 535 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
 536   [Define to the type of arg 3 for ptrace.])
 537 if test -n "$[5]"; then
 538   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
 539     [Define to the type of arg 5 for ptrace.])
 540 fi
 541
 542 dnl AC_FUNC_SETPGRP does not work when cross compiling
 543 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 544 if test "$cross_compiling" = no; then
 545   AC_FUNC_SETPGRP
 546 else
 547   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 548     [AC_TRY_COMPILE([
 549 #include <unistd.h>
 550 ], [
 551   if (setpgrp(1,1) == -1)
 552     exit (0);
 553   else
 554     exit (1);
 555 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 556 if test $ac_cv_func_setpgrp_void = yes; then
 557   AC_DEFINE(SETPGRP_VOID, 1)
 558 fi
 559 fi
 560
 561 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 562 # since sigsetjmp might only be defined as a macro.
 563 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 564 [AC_TRY_COMPILE([
 565 #include <setjmp.h>
 566 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 567 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 568 if test $gdb_cv_func_sigsetjmp = yes; then
 569   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 570 fi
 571
 572 # Assume we'll default to using the included libiberty regex.
 573 gdb_use_included_regex=yes
 574
 575 # However, if the system regex is GNU regex, then default to *not*
 576 # using the included regex.
 577 AC_CACHE_CHECK(
 578   [for GNU regex],
 579   [gdb_cv_have_gnu_regex],
 580   [AC_TRY_COMPILE(
 581     [#include <gnu-versions.h>],
 582     [#define REGEX_INTERFACE_VERSION 1
 583 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 584 # error "Version mismatch"
 585 #endif],
 586     gdb_cv_have_gnu_regex=yes,
 587     gdb_cv_have_gnu_regex=no)])
 588 if test $gdb_cv_have_gnu_regex = yes; then
 589   gdb_use_included_regex=no
 590 fi
 591
 592 AC_ARG_WITH(included-regex,
 593   [  --without-included-regex don't use included regex; this is the default
 594                           on systems with version 2 of the GNU C library
 595                           (use with caution on other system)],
 596   gdb_with_regex=$withval,
 597   gdb_with_regex=$gdb_use_included_regex)
 598 if test "$gdb_with_regex" = yes; then
 599   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 600     [Define to 1 if the regex included in libiberty should be used.])
 601 fi
 602
 603 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
 604 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
 605 [#include <sys/param.h>
 606 #include <sys/proc.h>
 607 ])
 608
 609 # See if <sys/lwp.h> defines `struct lwp`.
 610 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
 611 [AC_TRY_COMPILE([#include <sys/param.h>
 612 #include <sys/lwp.h>], [struct lwp l;],
 613 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
 614 if test $gdb_cv_struct_lwp = yes; then
 615   AC_DEFINE(HAVE_STRUCT_LWP, 1,
 616             [Define to 1 if your system has struct lwp.])
 617 fi
 618
 619 # See if <machine/reg.h> degines `struct reg'.
 620 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 621 [AC_TRY_COMPILE([#include <sys/types.h>
 622 #include <machine/reg.h>], [struct reg r;],
 623 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 624 if test $gdb_cv_struct_reg = yes; then
 625   AC_DEFINE(HAVE_STRUCT_REG, 1,
 626             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 627 fi
 628
 629 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 630 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 631 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
 632                  [#include <machine/reg.h>])
 633
 634 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 635 AC_MSG_CHECKING(for PTRACE_GETREGS)
 636 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 637 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 638                 [PTRACE_GETREGS;],
 639                 [gdb_cv_have_ptrace_getregs=yes],
 640                 [gdb_cv_have_ptrace_getregs=no])])
 641 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 642 if test $gdb_cv_have_ptrace_getregs = yes; then
 643   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 644   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
 645 fi
 646
 647 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 648 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 649 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 650 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 651                 [PTRACE_GETFPXREGS;],
 652                 [gdb_cv_have_ptrace_getfpxregs=yes],
 653                 [gdb_cv_have_ptrace_getfpxregs=no])])
 654 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 655 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 656   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 657   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
 658 fi
 659
 660 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 661 AC_MSG_CHECKING(for PT_GETDBREGS)
 662 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 663 [AC_TRY_COMPILE([#include <sys/types.h>
 664 #include <sys/ptrace.h>],
 665                 [PT_GETDBREGS;],
 666                 [gdb_cv_have_pt_getdbregs=yes],
 667                 [gdb_cv_have_pt_getdbregs=no])])
 668 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 669 if test $gdb_cv_have_pt_getdbregs = yes; then
 670   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
 671   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
 672 fi
 673
 674 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 675 AC_MSG_CHECKING(for PT_GETXMMREGS)
 676 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 677 [AC_TRY_COMPILE([#include <sys/types.h>
 678 #include <sys/ptrace.h>],
 679                 [PT_GETXMMREGS;],
 680                 [gdb_cv_have_pt_getxmmregs=yes],
 681                 [gdb_cv_have_pt_getxmmregs=no])])
 682 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 683 if test $gdb_cv_have_pt_getxmmregs = yes; then
 684   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
 685   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
 686 fi
 687
 688 # If we are configured native on GNU/Linux, work around problems with
 689 # sys/procfs.h
 690 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 691
 692 if test "${target}" = "${host}"; then
 693   case "${host}" in
 694   i[[3456]]86-*-linux*)
 695         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED, 2,
 696         [Define on a GNU/Linux system to work around problems in sys/procfs.h.])
 697         AC_DEFINE(sys_quotactl, 1,
 698         [Define on a GNU/Linux system to work around problems in sys/procfs.h.])
 699         ;;
 700   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 701       AC_DEFINE(NEW_PROC_API, 1,
 702       [Define if you want to use new multi-fd /proc interface
 703        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
 704       ;;
 705   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]])
 706       AC_DEFINE(NEW_PROC_API, 1,
 707       [Define if you want to use new multi-fd /proc interface
 708        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
 709       ;;
 710   mips-sgi-irix5*)
 711       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
 712       AC_DEFINE([_KMEMUSER], 1,
 713       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
 714        around a <sys/proc.h> problem on IRIX 5.])
 715       ;;
 716   esac
 717 fi
 718
 719 if test "$ac_cv_header_sys_procfs_h" = yes; then
 720   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 721   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 722   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 723   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 724   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 725   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 726   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 727   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 728   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 729   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 730   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 731   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 732   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 733   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 734
 735
 736   dnl Check for broken prfpregset_t type
 737
 738   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 739   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 740   dnl instead of the struct itself).  We detect this here, and work
 741   dnl around it in gdb_proc_service.h.
 742
 743   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 744     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 745     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 746       [AC_TRY_RUN([#include <sys/procfs.h>
 747        int main ()
 748        {
 749          if (sizeof (prfpregset_t) == sizeof (void *))
 750            return 1;
 751          return 0;
 752        }],
 753        gdb_cv_prfpregset_t_broken=no,
 754        gdb_cv_prfpregset_t_broken=yes,
 755        gdb_cv_prfpregset_t_broken=yes)])
 756     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 757     if test $gdb_cv_prfpregset_t_broken = yes; then
 758       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
 759       [Define if the prfpregset_t type is broken.])
 760     fi
 761   fi
 762
 763   dnl Check for PIOCSET ioctl entry
 764
 765   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 766   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 767   [AC_TRY_COMPILE([#include <unistd.h>
 768 #include <sys/types.h>
 769 #include <sys/procfs.h>
 770 ], [
 771     int dummy;;
 772     dummy = ioctl(0, PIOCSET, &dummy);
 773   ],
 774   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 775   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 776   if test $gdb_cv_have_procfs_piocset = yes; then
 777     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
 778     [Define if ioctl argument PIOCSET is available.])
 779   fi
 780 fi
 781
 782 dnl For native ports (host == target), check to see what kind of
 783 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 784 if test ${host} = ${target} ; then
 785   dnl Check for struct link_map with l_ members which are indicative
 786   dnl of SVR4-like shared libraries
 787
 788   AC_MSG_CHECKING(for member l_addr in struct link_map)
 789   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 790     [AC_TRY_COMPILE([#include <link.h>],
 791                     [struct link_map lm; (void) lm.l_addr;],
 792                     gdb_cv_have_struct_link_map_with_l_members=yes,
 793                     gdb_cv_have_struct_link_map_with_l_members=no)])
 794   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 795   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 796     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
 797     [Define if <link.h> exists and defines struct link_map which has
 798      members with an ``l_'' prefix.  (For Solaris, SVR4, and
 799      SVR4-like systems.)])
 800   fi
 801
 802   dnl Check for struct link_map with lm_ members which are indicative
 803   dnl of SunOS-like shared libraries
 804
 805   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 806   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 807     [AC_TRY_COMPILE([#include <sys/types.h>
 808 #include <link.h>],
 809                     [struct link_map lm; (void) lm.lm_addr;],
 810                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 811                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 812   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 813   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 814     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
 815     [Define if <link.h> exists and defines struct link_map which has
 816      members with an ``lm_'' prefix.  (For SunOS.)])
 817   fi
 818
 819   dnl Check for struct so_map with som_ members which are found on
 820   dnl some *BSD systems.
 821
 822   AC_MSG_CHECKING(for member som_addr in struct so_map)
 823   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 824     [AC_TRY_COMPILE([#include <sys/types.h>
 825 #ifdef HAVE_NLIST_H
 826 #include <nlist.h>
 827 #endif
 828 #include <link.h>],
 829                     [struct so_map lm; (void) lm.som_addr;],
 830                     gdb_cv_have_struct_so_map_with_som_members=yes,
 831                     gdb_cv_have_struct_so_map_with_som_members=no)])
 832   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 833   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 834     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
 835     [Define if <link.h> exists and defines a struct so_map which has
 836      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
 837   fi
 838
 839   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 840   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 841
 842   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 843   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 844     [AC_TRY_COMPILE([#define _SYSCALL32
 845 #include <sys/link.h>], [struct link_map32 l;],
 846      gdb_cv_have_struct_link_map32=yes,
 847      gdb_cv_have_struct_link_map32=no)])
 848   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 849   if test $gdb_cv_have_struct_link_map32 = yes; then
 850     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
 851     [Define if <sys/link.h> has struct link_map32])
 852     AC_DEFINE(_SYSCALL32, 1,
 853     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
 854   fi
 855 fi
 856
 857 # Check if the compiler supports the `long long' type.
 858
 859 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
 860                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 861 [[extern long long foo;]],
 862 [[switch (foo & 2) { case 0: return 1; }]])],
 863                                   gdb_cv_c_long_long=yes,
 864                                   gdb_cv_c_long_long=no)])
 865 if test $gdb_cv_c_long_long = yes; then
 866   AC_DEFINE(CC_HAS_LONG_LONG, 1,
 867             [Define to 1 if the compiler supports long long.])
 868 fi
 869
 870 # Check if the compiler and runtime support printing long longs.
 871
 872 AC_CACHE_CHECK([for long long support in printf],
 873                gdb_cv_printf_has_long_long,
 874                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 875 [[char buf[32];
 876   long long l = 0;
 877   l = (l << 16) + 0x0123;
 878   l = (l << 16) + 0x4567;
 879   l = (l << 16) + 0x89ab;
 880   l = (l << 16) + 0xcdef;
 881   sprintf (buf, "0x%016llx", l);
 882   return (strcmp ("0x0123456789abcdef", buf));]])],
 883                               gdb_cv_printf_has_long_long=yes,
 884                               gdb_cv_printf_has_long_long=no,
 885                               gdb_cv_printf_has_long_long=no)])
 886 if test $gdb_cv_printf_has_long_long = yes; then
 887   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
 888             [Define to 1 if the "%ll" format works to print long longs.])
 889 fi
 890
 891 # Check if the compiler supports the `long double' type.  We can't use
 892 # AC_C_LONG_DOUBLE because that one does additional checks on the
 893 # constants defined in <float.h> that fail on some systems,
 894 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
 895
 896 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
 897                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
 898                                   gdb_cv_c_long_double=yes,
 899                                   gdb_cv_c_long_double=no)])
 900 if test $gdb_cv_c_long_double = yes; then
 901   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
 902            [Define to 1 if the compiler supports long double.])
 903 fi
 904
 905 # Check if the compiler and runtime support printing long doubles.
 906
 907 AC_CACHE_CHECK([for long double support in printf],
 908                gdb_cv_printf_has_long_double,
 909                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 910 [[char buf[16];
 911   long double f = 3.141592653;
 912   sprintf (buf, "%Lg", f);
 913   return (strncmp ("3.14159", buf, 7));]])],
 914                               gdb_cv_printf_has_long_double=yes,
 915                               gdb_cv_printf_has_long_double=no,
 916                               gdb_cv_printf_has_long_double=no)])
 917 if test $gdb_cv_printf_has_long_double = yes; then
 918   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
 919             [Define to 1 if the "%Lg" format works to print long doubles.])
 920 fi
 921
 922 # Check if the compiler and runtime support scanning long doubles.
 923
 924 AC_CACHE_CHECK([for long double support in scanf],
 925                gdb_cv_scanf_has_long_double,
 926                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 927 [[#include <stdio.h>]],
 928 [[char *buf = "3.141592653";
 929   long double f = 0;
 930   sscanf (buf, "%Lg", &f);
 931   return !(f > 3.14159 && f < 3.14160);]])],
 932                               gdb_cv_scanf_has_long_double=yes,
 933                               gdb_cv_scanf_has_long_double=no,
 934                               gdb_cv_scanf_has_long_double=no)])
 935 if test $gdb_cv_scanf_has_long_double = yes; then
 936   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
 937             [Define to 1 if the "%Lg" format works to scan long doubles.])
 938 fi
 939
 940 case ${host_os} in
 941 aix*)
 942   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 943     SAVE_LDFLAGS=$LDFLAGS
 944
 945     case $GCC in
 946     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 947     *) gdb_cv_bigtoc=-bbigtoc ;;
 948     esac
 949
 950     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 951     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 952     LDFLAGS="${SAVE_LDFLAGS}"
 953   ])
 954   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
 955   ;;
 956 esac
 957
 958
 959 dnl For certain native configurations, we need to check whether thread
 960 dnl support can be built in or not.
 961 dnl
 962 dnl Note that we only want this if we are both native (host == target),
 963 dnl and not doing a canadian cross build (build == host).
 964
 965 if test ${build} = ${host} -a ${host} = ${target} ; then
 966    case ${host_os} in
 967    hpux*)
 968       AC_MSG_CHECKING(for HPUX/OSF thread support)
 969       if test -f /usr/include/dce/cma_config.h ; then
 970          if test "$GCC" = "yes" ; then
 971             AC_MSG_RESULT(yes)
 972             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT, 1,
 973             [Define if you have HPUX threads])
 974             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
 975             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 976          else
 977             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 978          fi
 979       else
 980          AC_MSG_RESULT(no)
 981       fi
 982       ;;
 983    solaris*)
 984       # See if thread_db library is around for Solaris thread debugging.
 985       # Note that we must explicitly test for version 1 of the library
 986       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
 987       # the same API.
 988       AC_MSG_CHECKING(for Solaris thread debugging library)
 989       if test -f /usr/lib/libthread_db.so.1 ; then
 990          AC_MSG_RESULT(yes)
 991          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
 992          [Define if using Solaris thread debugging.])
 993          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 994          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 995          AC_CHECK_LIB(dl, dlopen)
 996          if test "$GCC" = "yes" ; then
 997             # The GNU linker requires the -export-dynamic option to make
 998             # all symbols visible in the dynamic symbol table.
 999             hold_ldflags=$LDFLAGS
1000             AC_MSG_CHECKING(for the ld -export-dynamic flag)
1001             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
1002             AC_TRY_LINK(, [int i;], found=yes, found=no)
1003             LDFLAGS=$hold_ldflags
1004             AC_MSG_RESULT($found)
1005             if test $found = yes; then
1006                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
1007             fi
1008          fi
1009          # Sun randomly tweaked the prototypes in <proc_service.h>
1010          # at one point.
1011          AC_MSG_CHECKING(if <proc_service.h> is old)
1012          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1013             AC_TRY_COMPILE([
1014                 #include <proc_service.h>
1015                 ps_err_e ps_pdwrite
1016                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1017             ],, gdb_cv_proc_service_is_old=no,
1018                 gdb_cv_proc_service_is_old=yes)
1019          ])
1020          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1021          if test $gdb_cv_proc_service_is_old = yes; then
1022             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1023             [Define if <proc_service.h> on solaris uses int instead of
1024              size_t, and assorted other type changes.])
1025          fi
1026       else
1027          AC_MSG_RESULT(no)
1028       fi
1029       ;;
1030    aix*)
1031       AC_MSG_CHECKING(for AiX thread debugging library)
1032       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1033                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1034                                    [#ifndef PTHDB_VERSION_3
1035                                     #error
1036                                     #endif],
1037                                    gdb_cv_have_aix_thread_debug=yes,
1038                                    gdb_cv_have_aix_thread_debug=no)])
1039       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1040       if test $gdb_cv_have_aix_thread_debug = yes; then
1041          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1042          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1043          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1044       fi
1045       ;;
1046    esac
1047    AC_SUBST(CONFIG_LDFLAGS)
1048 fi
1049
1050 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1051 dnl other error codes.
1052 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1053    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1054                   gdb_cv_thread_db_h_has_td_notalloc,
1055      AC_TRY_COMPILE(
1056        [#include <thread_db.h>],
1057        [int i = TD_NOTALLOC;],
1058        gdb_cv_thread_db_h_has_td_notalloc=yes,
1059        gdb_cv_thread_db_h_has_td_notalloc=no
1060      )
1061    )
1062    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1063                   gdb_cv_thread_db_h_has_td_version,
1064      AC_TRY_COMPILE(
1065        [#include <thread_db.h>],
1066        [int i = TD_VERSION;],
1067        gdb_cv_thread_db_h_has_td_version=yes,
1068        gdb_cv_thread_db_h_has_td_version=no
1069      )
1070    )
1071    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1072                   gdb_cv_thread_db_h_has_td_notls,
1073      AC_TRY_COMPILE(
1074        [#include <thread_db.h>],
1075        [int i = TD_NOTLS;],
1076        gdb_cv_thread_db_h_has_td_notls=yes,
1077        gdb_cv_thread_db_h_has_td_notls=no
1078      )
1079    )
1080 fi
1081 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1082   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1083             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1084 fi
1085 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1086   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1087             [Define if <thread_db.h> has the TD_VERSION error code.])
1088 fi
1089 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1090   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1091             [Define if <thread_db.h> has the TD_NOTLS error code.])
1092 fi
1093
1094 dnl See if we have a sys/syscall header file that has __NR_tkill.
1095 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1096    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1097                   gdb_cv_sys_syscall_h_has_tkill,
1098      AC_TRY_COMPILE(
1099        [#include <sys/syscall.h>],
1100        [int i = __NR_tkill;],
1101        gdb_cv_sys_syscall_h_has_tkill=yes,
1102        gdb_cv_sys_syscall_h_has_tkill=no
1103      )
1104    )
1105 fi
1106 dnl See if we can issue tkill syscall.
1107 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1108   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1109 fi
1110
1111 dnl Handle optional features that can be enabled.
1112
1113 AC_ARG_WITH(sysroot,
1114 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
1115 [
1116  case ${with_sysroot} in
1117  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1118  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1119  esac
1120
1121  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1122
1123  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1124   if test "x$prefix" = xNONE; then
1125    test_prefix=/usr/local
1126   else
1127    test_prefix=$prefix
1128   fi
1129  else
1130   test_prefix=$exec_prefix
1131  fi
1132  case ${TARGET_SYSTEM_ROOT} in
1133  "${test_prefix}"|"${test_prefix}/"*|\
1134  '${exec_prefix}'|'${exec_prefix}/'*)
1135    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1136    TARGET_SYSTEM_ROOT_DEFINE="$t"
1137    ;;
1138  esac
1139 ], [
1140  TARGET_SYSTEM_ROOT=
1141  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1142 ])
1143 AC_SUBST(TARGET_SYSTEM_ROOT)
1144 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1145
1146 AC_ARG_ENABLE(werror,
1147   [  --enable-werror    treat compile warnings as errors],
1148   [case "${enableval}" in
1149      yes | y) ERROR_ON_WARNING="yes" ;;
1150      no | n)  ERROR_ON_WARNING="no" ;;
1151      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1152    esac])
1153
1154 # Enable -Werror by default when using gcc
1155 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1156     ERROR_ON_WARNING=yes
1157 fi
1158
1159 WERROR_CFLAGS=""
1160 if test "${ERROR_ON_WARNING}" = yes ; then
1161     WERROR_CFLAGS="-Werror"
1162 fi
1163
1164 # The entries after -Wno-pointer-sign are disabled warnings which may
1165 # be enabled in the future, which can not currently be used to build
1166 # GDB.
1167 # NOTE: If you change this list, remember to update
1168 # gdb/doc/gdbint.texinfo.
1169 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1170 -Wformat-nonliteral -Wno-pointer-sign \
1171 -Wno-unused -Wno-switch"
1172
1173 AC_ARG_ENABLE(build-warnings,
1174 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1175 [case "${enableval}" in
1176   yes)  ;;
1177   no)   build_warnings="-w";;
1178   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1179         build_warnings="${build_warnings} ${t}";;
1180   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1181         build_warnings="${t} ${build_warnings}";;
1182   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1183 esac
1184 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1185   echo "Setting compiler warning flags = $build_warnings" 6>&1
1186 fi])dnl
1187 AC_ARG_ENABLE(gdb-build-warnings,
1188 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1189 [case "${enableval}" in
1190   yes)  ;;
1191   no)   build_warnings="-w";;
1192   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1193         build_warnings="${build_warnings} ${t}";;
1194   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1195         build_warnings="${t} ${build_warnings}";;
1196   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1197 esac
1198 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1199   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1200 fi])dnl
1201 WARN_CFLAGS=""
1202 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1203 then
1204     AC_MSG_CHECKING(compiler warning flags)
1205     # Separate out the -Werror flag as some files just cannot be
1206     # compiled with it enabled.
1207     for w in ${build_warnings}; do
1208         case $w in
1209         -Werr*) WERROR_CFLAGS=-Werror ;;
1210         *) # Check that GCC accepts it
1211             saved_CFLAGS="$CFLAGS"
1212             CFLAGS="$CFLAGS $w"
1213             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1214             CFLAGS="$saved_CFLAGS"
1215         esac
1216     done
1217     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1218 fi
1219 AC_SUBST(WARN_CFLAGS)
1220 AC_SUBST(WERROR_CFLAGS)
1221
1222 # In the Cygwin environment, we need some additional flags.
1223 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1224 [AC_EGREP_CPP(lose, [
1225 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1226 lose
1227 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1228
1229
1230 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1231 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1232 case ${host} in
1233   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1234   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1235   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1236 esac
1237 AC_SUBST(SER_HARDWIRE)
1238
1239 # libreadline needs libuser32.a in a cygwin environment
1240 WIN32LIBS=
1241 if test x$gdb_cv_os_cygwin = xyes; then
1242     WIN32LIBS="-luser32"
1243     case "${target}" in
1244         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1245         ;;
1246     esac
1247 fi
1248
1249 # The ser-tcp.c module requires sockets.
1250 case ${host} in
1251   *mingw32*)
1252     AC_DEFINE(USE_WIN32API, 1,
1253               [Define if we should use the Windows API, instead of the
1254                POSIX API.  On Windows, we use the Windows API when
1255                building for MinGW, but the POSIX API when building
1256                for Cygwin.])
1257     WIN32LIBS="$WIN32LIBS -lws2_32"
1258     ;;
1259 esac
1260 AC_SUBST(WIN32LIBS)
1261
1262 # Add any host-specific objects to GDB.
1263 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1264
1265 LIBGUI="../libgui/src/libgui.a"
1266 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1267 AC_SUBST(LIBGUI)
1268 AC_SUBST(GUI_CFLAGS_X)
1269
1270 WIN32LDAPP=
1271 AC_SUBST(WIN32LIBS)
1272 AC_SUBST(WIN32LDAPP)
1273
1274 case "${host}" in
1275 *-*-cygwin*)
1276     configdir="win"
1277     ;;
1278 *)
1279     configdir="unix"
1280     ;;
1281 esac
1282
1283 GDBTKLIBS=
1284 if test "${enable_gdbtk}" = "yes"; then
1285
1286     # Gdbtk must have an absolute path to srcdir in order to run
1287     # properly when not installed.
1288     here=`pwd`
1289     cd ${srcdir}
1290     GDBTK_SRC_DIR=`pwd`
1291     cd $here
1292
1293     CY_AC_PATH_TCLCONFIG
1294     if test -z "${no_tcl}"; then
1295         CY_AC_LOAD_TCLCONFIG
1296         CY_AC_PATH_TKCONFIG
1297
1298         # now look for Tcl library stuff
1299
1300         tcldir="../tcl/${configdir}/"
1301
1302         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1303
1304         # If $no_tk is nonempty, then we can't do Tk, and there is no
1305         # point to doing Tcl.
1306         if test -z "${no_tk}"; then
1307            CY_AC_LOAD_TKCONFIG
1308            CY_AC_PATH_TCLH
1309            CY_AC_PATH_TKH
1310            CY_AC_PATH_ITCLH
1311            CY_AC_PATH_ITKH
1312
1313
1314            # now look for Tk library stuff
1315
1316            tkdir="../tk/${configdir}/"
1317
1318            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1319
1320            # now look for Itcl library stuff
1321
1322            CY_AC_PATH_ITCLCONFIG
1323            if test -z "${no_itcl}"; then
1324              CY_AC_LOAD_ITCLCONFIG
1325
1326              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1327              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1328            fi
1329
1330
1331            # now look for Itk library stuff
1332            CY_AC_PATH_ITKCONFIG
1333            if test -z "${no_itcl}"; then
1334              CY_AC_LOAD_ITKCONFIG
1335
1336              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1337              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1338            fi
1339
1340            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1341
1342            # Include some libraries that Tcl and Tk want.
1343            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1344            # Yes, the ordering seems wrong here.  But it isn't.
1345            # TK_LIBS is the list of libraries that need to be linked
1346            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1347            # were in LIBS then any link tests after this point would
1348            # try to include things like `$(LIBGUI)', which wouldn't work.
1349            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1350
1351            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1352            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1353            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1354            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1355            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1356            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1357            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1358
1359            if test x$gdb_cv_os_cygwin = xyes; then
1360               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1361               WIN32LDAPP="-Wl,--subsystem,console"
1362               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1363            fi
1364         fi
1365     fi
1366
1367     AC_CONFIG_SUBDIRS(gdbtk)
1368 fi
1369
1370 AC_SUBST(X_CFLAGS)
1371 AC_SUBST(X_LDFLAGS)
1372 AC_SUBST(X_LIBS)
1373 AC_SUBST(TCL_DEPS)
1374 AC_SUBST(TK_DEPS)
1375 AC_SUBST(ITCLLIB)
1376 AC_SUBST(ITCL_DEPS)
1377 AC_SUBST(ITKLIB)
1378 AC_SUBST(ITK_DEPS)
1379 AC_SUBST(GDBTKLIBS)
1380 AC_SUBST(GDBTK_CFLAGS)
1381 AC_SUBST(GDBTK_SRC_DIR)
1382
1383 AC_PATH_X
1384
1385 # Check whether we should enable the TUI, but only do so if we really
1386 # can.
1387 if test x"$enable_tui" = xyes; then
1388   if test -d $srcdir/tui; then
1389     if test "$ac_cv_search_waddstr" != no; then
1390       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
1391       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
1392       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
1393       CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
1394       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
1395       CONFIG_ALL="${CONFIG_ALL} all-tui"
1396       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
1397       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
1398       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
1399     else
1400       AC_MSG_WARN([no enhanced curses library found; disabling TUI])
1401     fi
1402   fi
1403 fi
1404
1405 # Unlike the sim directory, whether a simulator is linked is controlled by
1406 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1407 # This code just checks for a few cases where we'd like to ignore those
1408 # definitions, even when they're present in the '.mt' file.  These cases
1409 # are when --disable-sim is specified, or if the simulator directory is
1410 # not part of the source tree.
1411 #
1412 AC_ARG_ENABLE(sim,
1413 [  --enable-sim            Link gdb with simulator],
1414 [echo "enable_sim = $enable_sim";
1415  echo "enableval = ${enableval}";
1416  case "${enableval}" in
1417   yes) ignore_sim=false ;;
1418   no)  ignore_sim=true ;;
1419   *)   ignore_sim=false ;;
1420  esac],
1421 [ignore_sim=false])
1422
1423 if test ! -d "${srcdir}/../sim"; then
1424   ignore_sim=true
1425 fi
1426
1427 if test "${ignore_sim}" = "true"; then
1428     IGNORE_SIM="SIM="
1429     IGNORE_SIM_OBS="SIM_OBS="
1430 else
1431     IGNORE_SIM=""
1432     IGNORE_SIM_OBS=""
1433     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
1434 fi
1435 AC_SUBST(IGNORE_SIM)
1436 AC_SUBST(IGNORE_SIM_OBS)
1437
1438 AC_SUBST(ENABLE_CFLAGS)
1439 AC_SUBST(PROFILE_CFLAGS)
1440
1441 AC_SUBST(CONFIG_OBS)
1442 AC_SUBST(CONFIG_DEPS)
1443 AC_SUBST(CONFIG_SRCS)
1444 AC_SUBST(CONFIG_ALL)
1445 AC_SUBST(CONFIG_CLEAN)
1446 AC_SUBST(CONFIG_INSTALL)
1447 AC_SUBST(CONFIG_UNINSTALL)
1448
1449 # List of host floatformats.
1450 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1451 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1452 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1453
1454 # target_subdir is used by the testsuite to find the target libraries.
1455 target_subdir=
1456 if test "${host}" != "${target}"; then
1457     target_subdir="${target_alias}/"
1458 fi
1459 AC_SUBST(target_subdir)
1460
1461 frags=
1462 if test "${gdb_native}" = "yes"; then
1463   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1464   if test ! -f ${host_makefile_frag}; then
1465     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1466   fi
1467   frags="$frags $host_makefile_frag"
1468 else
1469   host_makefile_frag=/dev/null
1470 fi
1471
1472 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1473 if test ! -f ${target_makefile_frag}; then
1474   AC_MSG_ERROR("*** Gdb does not support target ${target}")
1475 fi
1476 frags="$frags $target_makefile_frag"
1477
1478 AC_SUBST_FILE(host_makefile_frag)
1479 AC_SUBST_FILE(target_makefile_frag)
1480 AC_SUBST(frags)
1481
1482 changequote(,)dnl
1483 hostfile=`sed -n '
1484 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1485 ' ${host_makefile_frag}`
1486
1487 targetfile=`sed -n '
1488 s/^[    ]*DEPRECATED_TM_FILE[   ]*=[    ]*\([^  ]*\)/\1/p
1489 ' ${target_makefile_frag}`
1490
1491 if test "${gdb_native}" = "yes"; then
1492 # We pick this up from the host configuration file (.mh) because we
1493 # do not have a native configuration Makefile fragment.
1494 nativefile=`sed -n '
1495 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1496 ' ${host_makefile_frag}`
1497 fi
1498 changequote([,])
1499
1500 if test x"${gdb_osabi}" != x ; then
1501     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1502                        [Define to the default OS ABI for this configuration.])
1503 fi
1504
1505 # Enable multi-ice-gdb-server.
1506 AC_ARG_ENABLE(multi-ice,
1507 [  --enable-multi-ice      build the multi-ice-gdb-server],
1508   [case $enableval in
1509     yes | no)
1510       ;;
1511     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1512   esac])
1513 if test "x$enable_multi_ice" = xyes; then
1514    AC_CONFIG_SUBDIRS(multi-ice)
1515 fi
1516
1517 # We only build gdbserver automatically in a native configuration.
1518 if test "$gdb_native" = "yes"; then
1519   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1520   if test "x$build_gdbserver" = xyes; then
1521     AC_MSG_RESULT(yes)
1522     AC_CONFIG_SUBDIRS(gdbserver)
1523   else
1524     AC_MSG_RESULT(no)
1525   fi
1526 fi
1527
1528 # If hostfile (XM_FILE) and/or targetfile (DEPRECATED_TM_FILE) and/or
1529 # nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1530 # to an empty version.
1531
1532 files=
1533 links=
1534
1535 rm -f xm.h
1536 xm_h=""
1537 if test "${hostfile}" != ""; then
1538     xm_h=xm.h
1539     case "${hostfile}" in
1540       xm-*.h ) GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}" ;;
1541       * ) GDB_XM_FILE="${hostfile}"
1542     esac
1543     files="${files} ${GDB_XM_FILE}"
1544     links="${links} xm.h"
1545     AC_DEFINE_UNQUOTED(GDB_XM_FILE, "${GDB_XM_FILE}", [hostfile])
1546 fi
1547 AC_SUBST(xm_h)
1548
1549 rm -f tm.h
1550 tm_h=""
1551 if test "${targetfile}" != ""; then
1552     tm_h=tm.h
1553     case "${targetfile}" in
1554       tm-*.h ) GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}" ;;
1555       * ) GDB_TM_FILE="${targetfile}"
1556     esac
1557     files="${files} ${GDB_TM_FILE}"
1558     links="${links} tm.h"
1559     AC_DEFINE_UNQUOTED(GDB_TM_FILE, "${GDB_TM_FILE}", [targetfile])
1560 fi
1561 AC_SUBST(tm_h)
1562
1563 rm -f nm.h
1564 nm_h=""
1565 if test "${nativefile}" != ""; then
1566     nm_h=nm.h
1567     case "${nativefile}" in
1568       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1569       * ) GDB_NM_FILE="${nativefile}"
1570     esac
1571     files="${files} ${GDB_NM_FILE}"
1572     links="${links} nm.h"
1573     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
1574 fi
1575 AC_SUBST(nm_h)
1576
1577 AC_LINK_FILES($files, $links)
1578
1579 dnl Check for exe extension set on certain hosts (e.g. Win32)
1580 AC_EXEEXT
1581
1582 dnl  Detect the character set used by this host.
1583
1584 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1585 dnl  superset of ASCII containing the characters needed for French,
1586 dnl  German, Spanish, Italian, and possibly others), but if were
1587 dnl  *were* to support any host character sets other than ISO-8859-1,
1588 dnl  here's where we'd detect it.
1589 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1590           [Define to be a string naming the default host character set.])
1591
1592 AM_ICONV
1593
1594 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1595 [
1596 dnl Autoconf doesn't provide a mechanism for modifying definitions
1597 dnl provided by makefile fragments.
1598 dnl
1599
1600 changequote(,)dnl
1601 sed -e '/^DEPRECATED_TM_FILE[   ]*=/s,^DEPRECATED_TM_FILE[      ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1602 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1603 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1604 mv -f Makefile.tmp Makefile
1605 changequote([,])dnl
1606
1607
1608 case x$CONFIG_HEADERS in
1609 xconfig.h:config.in)
1610 echo > stamp-h ;;
1611 esac
1612 ],
1613 [
1614 gdb_host_cpu=$gdb_host_cpu
1615 gdb_target_cpu=$gdb_target_cpu
1616 nativefile=$nativefile
1617 ])
1618
1619 exit 0