gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   3 dnl 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_USE_SYSTEM_EXTENSIONS
  30 gl_EARLY
  31 ACX_LARGEFILE
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # Dependency checking.
  38 ZW_CREATE_DEPDIR
  39 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  40
  41 # Check for the 'make' the user wants to use.
  42 AC_CHECK_PROGS(MAKE, make)
  43 MAKE_IS_GNU=
  44 case "`$MAKE --version 2>&1 | sed 1q`" in
  45   *GNU*)
  46     MAKE_IS_GNU=yes
  47     ;;
  48 esac
  49 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  50 AC_PROG_MAKE_SET
  51
  52 dnl List of object files and targets accumulated by configure.
  53
  54 CONFIG_OBS=
  55 CONFIG_DEPS=
  56 CONFIG_SRCS=
  57 ENABLE_CFLAGS=
  58
  59 CONFIG_ALL=
  60 CONFIG_CLEAN=
  61 CONFIG_INSTALL=
  62 CONFIG_UNINSTALL=
  63
  64 dnl Set up for gettext.
  65 ZW_GNU_GETTEXT_SISTER_DIR
  66
  67 localedir='${datadir}/locale'
  68 AC_SUBST(localedir)
  69
  70 if test x"$USE_NLS" = xyes; then
  71    CONFIG_ALL="$CONFIG_ALL all-po"
  72    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  73    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  74    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  75 fi
  76
  77 gl_INIT
  78
  79 # For Makefile dependencies.
  80 GNULIB_STDINT_H=
  81 if test x"$STDINT_H" != x; then
  82   GNULIB_STDINT_H=gnulib/$STDINT_H
  83 fi
  84 AC_SUBST(GNULIB_STDINT_H)
  85
  86 PACKAGE=gdb
  87 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  88 AC_SUBST(PACKAGE)
  89
  90 # GDB does not use automake, but gnulib does.  This line lets us
  91 # generate its Makefile.in.
  92 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
  93
  94 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
  95     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
  96     [${libdir}/debug])
  97
  98 # GDB's datadir relocation
  99
 100 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 101     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 102     [${datadir}/gdb])
 103
 104 AC_ARG_WITH(relocated-sources,
 105 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 106 [reloc_srcdir="${withval}"
 107  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 108               [Relocated directory for source files. ])
 109 ])
 110
 111 AC_CONFIG_SUBDIRS(testsuite)
 112
 113 # Check whether to support alternative target configurations
 114 AC_ARG_ENABLE(targets,
 115 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 116 [case "${enableval}" in
 117   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 118             ;;
 119   no)       enable_targets= ;;
 120   *)        enable_targets=$enableval ;;
 121 esac])
 122
 123 # Check whether to enable 64-bit support on 32-bit hosts
 124 AC_ARG_ENABLE(64-bit-bfd,
 125 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 126 [case "${enableval}" in
 127   yes)  want64=true  ;;
 128   no)   want64=false ;;
 129   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 130 esac],[want64=false])dnl
 131
 132 # Provide defaults for some variables set by the per-host and per-target
 133 # configuration.
 134 gdb_host_obs=posix-hdep.o
 135
 136 if test "${target}" = "${host}"; then
 137   gdb_native=yes
 138 else
 139   gdb_native=no
 140 fi
 141
 142 . $srcdir/configure.host
 143
 144 # Accumulate some settings from configure.tgt over all enabled targets
 145
 146 TARGET_OBS=
 147 all_targets=
 148
 149 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 150 do
 151   if test "$targ_alias" = "all"; then
 152     all_targets=true
 153   else
 154     # Canonicalize the secondary target names.
 155     result=`$ac_config_sub $targ_alias 2>/dev/null`
 156     if test -n "$result"; then
 157         targ=$result
 158     else
 159         targ=$targ_alias
 160     fi
 161
 162     . ${srcdir}/configure.tgt
 163
 164     AS_IF([test -z "${gdb_target_obs}"],
 165       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 166
 167     # Target-specific object files
 168     for i in ${gdb_target_obs}; do
 169         case " $TARGET_OBS " in
 170         *" ${i} "*) ;;
 171         *)
 172           TARGET_OBS="$TARGET_OBS ${i}"
 173           ;;
 174         esac
 175     done
 176
 177     # Check whether this target needs 64-bit CORE_ADDR
 178     if test x${want64} = xfalse; then
 179       . ${srcdir}/../bfd/config.bfd
 180     fi
 181   fi
 182 done
 183
 184 if test x${all_targets} = xtrue; then
 185
 186   # We want all 64-bit targets if we either:
 187   #  - run on a 64-bit host  or
 188   #  - already require 64-bit support for some other target  or
 189   #  - the --enable-64-bit-bfd option was supplied
 190   # Otherwise we only support all 32-bit targets.
 191   #
 192   # NOTE: This test must be in sync with the corresponding
 193   #       tests in BFD!
 194
 195   if test x${want64} = xfalse; then
 196     AC_CHECK_SIZEOF(long)
 197     if test "x${ac_cv_sizeof_long}" = "x8"; then
 198       want64=true
 199     fi
 200   fi
 201   if test x${want64} = xtrue; then
 202     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 203   else
 204     TARGET_OBS='$(ALL_TARGET_OBS)'
 205   fi
 206 fi
 207
 208 AC_SUBST(TARGET_OBS)
 209
 210 # For other settings, only the main target counts.
 211 gdb_sim=
 212 gdb_osabi=
 213 build_gdbserver=
 214 targ=$target; . ${srcdir}/configure.tgt
 215
 216 # Fetch the default architecture and default target vector from BFD.
 217 targ=$target; . $srcdir/../bfd/config.bfd
 218
 219 # We only want the first architecture, so strip off the others if
 220 # there is more than one.
 221 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 222
 223 if test "x$targ_archs" != x; then
 224   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 225     [Define to BFD's default architecture. ])
 226 fi
 227 if test "x$targ_defvec" != x; then
 228   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 229     [Define to BFD's default target vector. ])
 230 fi
 231
 232 # The CLI cannot be disabled yet, but may be in the future.
 233
 234 # Enable CLI.
 235 AC_ARG_ENABLE(gdbcli,
 236 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 237   [case $enableval in
 238     yes)
 239       ;;
 240     no)
 241       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 242     *)
 243       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 244   esac],
 245   [enable_gdbcli=yes])
 246 if test x"$enable_gdbcli" = xyes; then
 247   if test -d $srcdir/cli; then
 248     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 249     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 250     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 251     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 252   fi
 253 fi
 254
 255 # Enable MI.
 256 AC_ARG_ENABLE(gdbmi,
 257 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 258   [case $enableval in
 259     yes | no)
 260       ;;
 261     *)
 262       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 263   esac],
 264   [enable_gdbmi=yes])
 265 if test x"$enable_gdbmi" = xyes; then
 266   if test -d $srcdir/mi; then
 267     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 268     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 269     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 270     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 271   fi
 272 fi
 273
 274 # Enable TUI.
 275 AC_ARG_ENABLE(tui,
 276 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 277   [case $enableval in
 278     yes | no | auto)
 279       ;;
 280     *)
 281       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 282   esac],enable_tui=auto)
 283
 284 # Enable gdbtk.
 285 AC_ARG_ENABLE(gdbtk,
 286 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 287   [case $enableval in
 288     yes | no)
 289       ;;
 290     *)
 291       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 292   esac],
 293   [if test -d $srcdir/gdbtk; then
 294     enable_gdbtk=yes
 295   else
 296     enable_gdbtk=no
 297   fi])
 298 # We unconditionally disable gdbtk tests on selected platforms.
 299 case $host_os in
 300   go32* | windows*)
 301     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 302     enable_gdbtk=no ;;
 303 esac
 304
 305 # Libunwind support.
 306 AC_ARG_WITH(libunwind,
 307 AS_HELP_STRING([--with-libunwind], [use libunwind frame unwinding support]),
 308 [case "${withval}" in
 309   yes)  enable_libunwind=yes ;;
 310   no)   enable_libunwind=no ;;
 311   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 312 esac],[
 313   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 314   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 315     enable_libunwind=yes;
 316   fi
 317 ])
 318
 319 if test x"$enable_libunwind" = xyes; then
 320   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 321   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 322   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 323   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 324   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 325 fi
 326
 327 opt_curses=no
 328 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 329
 330 prefer_curses=no
 331 if test "$opt_curses" = "yes"; then
 332   prefer_curses=yes
 333 fi
 334
 335 # Profiling support.
 336 AC_ARG_ENABLE(profiling,
 337 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 338   [case $enableval in
 339     yes | no)
 340       ;;
 341     *)
 342       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 343   esac],
 344  [enable_profiling=no])
 345
 346 AC_CHECK_FUNCS(monstartup _mcleanup)
 347 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 348 [AC_TRY_LINK(
 349 [#include <stdlib.h>
 350 extern char _etext;
 351 ],
 352 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 353 if test $ac_cv_var__etext = yes; then
 354   AC_DEFINE(HAVE__ETEXT, 1,
 355             [Define to 1 if your system has the _etext variable. ])
 356 fi
 357 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 358 [AC_TRY_LINK(
 359 [#include <stdlib.h>
 360 extern char etext;
 361 ],
 362 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 363 if test $ac_cv_var_etext = yes; then
 364   AC_DEFINE(HAVE_ETEXT, 1,
 365             [Define to 1 if your system has the etext variable. ])
 366 fi
 367 if test "$enable_profiling" = yes ; then
 368   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 369     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 370   fi
 371   PROFILE_CFLAGS=-pg
 372   OLD_CFLAGS="$CFLAGS"
 373   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 374
 375   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 376     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 377      ac_cv_cc_supports_pg=no)])
 378
 379   if test $ac_cv_cc_supports_pg = no; then
 380     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 381   fi
 382
 383   CFLAGS="$OLD_CFLAGS"
 384 fi
 385
 386 ACX_PKGVERSION([GDB])
 387 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 388 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 389 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 390
 391 # --------------------- #
 392 # Checks for programs.  #
 393 # --------------------- #
 394
 395 AC_PROG_AWK
 396 AC_PROG_INSTALL
 397 AC_PROG_LN_S
 398 AC_PROG_RANLIB
 399 AC_PROG_YACC
 400
 401 AC_CHECK_TOOL(AR, ar)
 402 AC_CHECK_TOOL(DLLTOOL, dlltool)
 403 AC_CHECK_TOOL(WINDRES, windres)
 404
 405 # Needed for GNU/Hurd.
 406 AC_CHECK_TOOL(MIG, mig)
 407
 408 # ---------------------- #
 409 # Checks for libraries.  #
 410 # ---------------------- #
 411
 412 # We might need to link with -lm; most simulators need it.
 413 AC_CHECK_LIB(m, main)
 414
 415 # We need to link with -lw to get `wctype' on Solaris before Solaris
 416 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 417 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 418 # is known to have this problem).  Therefore we avoid libw if we can.
 419 AC_CHECK_FUNC(wctype, [],
 420   [AC_CHECK_LIB(w, wctype)])
 421
 422 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 423 AC_SEARCH_LIBS(gethostbyname, nsl)
 424
 425 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 426 AC_SEARCH_LIBS(socketpair, socket)
 427
 428 # Link in zlib if we can.  This allows us to read compressed debug sections.
 429 AM_ZLIB
 430
 431 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 432 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 433
 434 AM_ICONV
 435
 436 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 437 # There is a very specific comment in /usr/include/curses.h explaining that
 438 # termcap routines built into libcurses must not be used.
 439 #
 440 # The symptoms we observed so far is GDB unexpectedly changing
 441 # the terminal settings when tgetent is called - this is particularly
 442 # visible as the output is missing carriage returns, and so rapidly
 443 # becomes very hard to read.
 444 #
 445 # The readline configure script has already decided that libtermcap
 446 # was enough for its purposes, and so decided to build readline using
 447 # libtermcap.  Since the TUI mode requires curses, building GDB with
 448 # TUI enabled results in both libraries to be used at the same time,
 449 # which is not allowed.  This basically means that GDB with TUI is
 450 # broken on alpha-osf.
 451
 452 case $host_os in
 453   osf* )
 454     if test x"$enable_tui" = xyes; then
 455       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 456     fi
 457     if test x"$enable_tui" = xauto; then
 458       enable_tui=no
 459     fi
 460     ;;
 461 esac
 462
 463 # For the TUI, we need enhanced curses functionality.
 464 if test x"$enable_tui" != xno; then
 465   prefer_curses=yes
 466 fi
 467
 468 curses_found=no
 469 if test x"$prefer_curses" = xyes; then
 470   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 471   # curses library because the latter might not provide all the
 472   # functionality we need.  However, this leads to problems on systems
 473   # where the linker searches /usr/local/lib, but the compiler doesn't
 474   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 475   # default installation of ncurses on alpha*-dec-osf* will lead to such
 476   # a situation.
 477   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 478
 479   if test "$ac_cv_search_waddstr" != no; then
 480     curses_found=yes
 481   fi
 482 fi
 483
 484 # Check whether we should enable the TUI, but only do so if we really
 485 # can.
 486 if test x"$enable_tui" != xno; then
 487   if test -d $srcdir/tui; then
 488     if test "$curses_found" != no; then
 489       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 490       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 491       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 492       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 493       CONFIG_ALL="${CONFIG_ALL} all-tui"
 494       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 495       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 496       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 497     else
 498       if test x"$enable_tui" = xyes; then
 499         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 500       else
 501         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 502       fi
 503     fi
 504   fi
 505 fi
 506
 507 # Since GDB uses Readline, we need termcap functionality.  In many
 508 # cases this will be provided by the curses library, but some systems
 509 # have a seperate termcap library, or no curses library at all.
 510
 511 case $host_os in
 512   cygwin*)
 513     if test -d $srcdir/libtermcap; then
 514       LIBS="../libtermcap/libtermcap.a $LIBS"
 515       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 516     fi ;;
 517   go32* | *djgpp*)
 518     ac_cv_search_tgetent="none required"
 519     ;;
 520   *mingw32*)
 521     ac_cv_search_tgetent="none required"
 522     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 523     ;;
 524 esac
 525
 526 # These are the libraries checked by Readline.
 527 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 528
 529 if test "$ac_cv_search_tgetent" = no; then
 530   AC_MSG_ERROR([no termcap library found])
 531 fi
 532
 533 AC_ARG_WITH([system-readline],
 534   [AS_HELP_STRING([--with-system-readline],
 535                   [use installed readline library])])
 536
 537 if test "$with_system_readline" = yes; then
 538   READLINE=-lreadline
 539   READLINE_DEPS=
 540   READLINE_CFLAGS=
 541   READLINE_TEXI_INCFLAG=
 542
 543   # readline-6.0 started to use the name `_rl_echoing_p'.
 544   # `$(READLINE_DIR)/' of bundled readline would not resolve in configure.
 545
 546   AC_MSG_CHECKING([for readline_echoing_p])
 547   save_LIBS=$LIBS
 548   LIBS="$LIBS $READLINE"
 549   AC_LINK_IFELSE(AC_LANG_PROGRAM(,[[extern int readline_echoing_p;
 550                                     return readline_echoing_p;]]),
 551                  [READLINE_ECHOING_P=yes],
 552                  [READLINE_ECHOING_P=no
 553                   AC_DEFINE([readline_echoing_p], [_rl_echoing_p],
 554                             [readline-6.0 started to use different name.])])
 555   LIBS="$save_LIBS"
 556   AC_MSG_RESULT([$READLINE_ECHOING_P])
 557 else
 558   READLINE='$(READLINE_DIR)/libreadline.a'
 559   READLINE_DEPS='$(READLINE)'
 560   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 561   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 562 fi
 563 AC_SUBST(READLINE)
 564 AC_SUBST(READLINE_DEPS)
 565 AC_SUBST(READLINE_CFLAGS)
 566 AC_SUBST(READLINE_TEXI_INCFLAG)
 567
 568 AC_ARG_WITH(expat,
 569   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 570   [], [with_expat=auto])
 571 AC_MSG_CHECKING([whether to use expat])
 572 AC_MSG_RESULT([$with_expat])
 573
 574 if test "${with_expat}" = no; then
 575   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 576   HAVE_LIBEXPAT=no
 577 else
 578   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 579                         [XML_Parser p = XML_ParserCreate (0);])
 580   if test "$HAVE_LIBEXPAT" != yes; then
 581     if test "$with_expat" = yes; then
 582       AC_MSG_ERROR([expat is missing or unusable])
 583     else
 584       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 585     fi
 586   else
 587     save_LIBS=$LIBS
 588     LIBS="$LIBS $LIBEXPAT"
 589     AC_CHECK_FUNCS(XML_StopParser)
 590     LIBS=$save_LIBS
 591   fi
 592 fi
 593
 594 dnl Utility to simplify finding libpython.
 595 dnl $1 = pythonX.Y
 596 dnl $2 = the shell variable to assign the result to
 597 dnl      If libpython is found we store $version here.
 598 dnl $3 = additional flags to add to CPPFLAGS
 599 dnl $4 = additional flags to add to LIBS
 600
 601 AC_DEFUN([AC_TRY_LIBPYTHON],
 602 [
 603   version=$1
 604   define([have_libpython_var],$2)
 605   new_CPPFLAGS=$3
 606   new_LIBS=$4
 607   AC_MSG_CHECKING([for ${version}])
 608   save_CPPFLAGS=$CPPFLAGS
 609   save_LIBS=$LIBS
 610   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 611   LIBS="$LIBS $new_LIBS"
 612   found_usable_python=no
 613   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "${version}/Python.h"]],
 614                                  [[Py_Initialize ();]]),
 615                  [have_libpython_var=${version}
 616                   found_usable_python=yes],
 617                  [CPPFLAGS=$save_CPPFLAGS
 618                   LIBS=$save_LIBS])
 619   AC_MSG_RESULT([${found_usable_python}])
 620 ])
 621
 622 dnl There are several different values for --with-python:
 623 dnl
 624 dnl no -   Don't include python support.
 625 dnl yes -  Include python support, error if it's missing.
 626 dnl        If we find python in $PATH, use it to fetch configure options,
 627 dnl        otherwise assume the compiler can find it with no help from us.
 628 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 629 dnl auto - Same as "yes", but if python is missing from the system,
 630 dnl        fall back to "no".
 631 dnl /path/to/python/exec-prefix -
 632 dnl        Use the python located in this directory.
 633 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 634 dnl        the compilation parameters.  Otherwise use
 635 dnl        -I/path/to/python/exec-prefix/include,
 636 dnl        -L/path/to/python/exec-prefix/lib.
 637 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 638 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 639 dnl        but is deprecated.
 640 dnl /path/to/python/executable -
 641 dnl        Run python-config.py with this version of python to fetch the
 642 dnl        compilation parameters.
 643 dnl        NOTE: This needn't be the real python executable.
 644 dnl        In a cross-compilation scenario (build != host), this could be
 645 dnl        a shell script that provides what python-config.py provides for
 646 dnl        --ldflags, --includes, --exec-prefix.
 647 dnl python-executable -
 648 dnl        Find python-executable in $PATH, and then handle the same as
 649 dnl        /path/to/python/executable.
 650 dnl
 651 dnl If a python program is specified, it is used to run python-config.py and
 652 dnl is passed --ldflags, --includes, --exec-prefix.
 653
 654 AC_ARG_WITH(python,
 655   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 656   [], [with_python=auto])
 657 AC_MSG_CHECKING([whether to use python])
 658 AC_MSG_RESULT([$with_python])
 659
 660 if test "${with_python}" = no; then
 661   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 662   have_libpython=no
 663 else
 664   case "${with_python}" in
 665   /*)
 666     if test -d ${with_python}; then
 667       # Assume the python binary is ${with_python}/bin/python.
 668       python_prog="${with_python}/bin/python"
 669       python_prefix=
 670       if test ! -x "${python_prog}"; then
 671         # Fall back to gdb 7.0/7.1 behaviour.
 672         python_prog=missing
 673         python_prefix=${with_python}
 674       fi
 675     elif test -x "${with_python}"; then
 676       # While we can't run python compiled for $host (unless host == build),
 677       # the user could write a script that provides the needed information,
 678       # so we support that.
 679       python_prog=${with_python}
 680       python_prefix=
 681     else
 682       AC_ERROR(invalid value for --with-python)
 683     fi
 684     ;;
 685   */*)
 686     # Disallow --with-python=foo/bar.
 687     AC_ERROR(invalid value for --with-python)
 688     ;;
 689   *)
 690     # The user has either specified auto, yes, or the name of the python
 691     # program assumed to be in $PATH.
 692     python_prefix=
 693     case "${with_python}" in
 694     yes | auto)
 695       if test ${build} = ${host}; then
 696         AC_PATH_PROG(python_prog_path, python, missing)
 697         if test "${python_prog_path}" = missing; then
 698           python_prog=missing
 699         else
 700           python_prog=${python_prog_path}
 701         fi
 702       else
 703         # Not much we can do except assume the cross-compiler will find the
 704         # right files.
 705         python_prog=missing
 706       fi
 707       ;;
 708     *)
 709       # While we can't run python compiled for $host (unless host == build),
 710       # the user could write a script that provides the needed information,
 711       # so we support that.
 712       python_prog="${with_python}"
 713       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 714       if test "${python_prog_path}" = missing; then
 715         AC_ERROR(unable to find python program ${python_prog})
 716       fi
 717       ;;
 718     esac
 719   esac
 720
 721   if test "${python_prog}" != missing; then
 722     # We have a python program to use, but it may be too old.
 723     # Don't flag an error for --with-python=auto (the default).
 724     have_python_config=yes
 725     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 726     if test $? != 0; then
 727       have_python_config=failed
 728       if test "${with_python}" != auto; then
 729         AC_ERROR(failure running python-config --includes)
 730       fi
 731     fi
 732     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 733     if test $? != 0; then
 734       have_python_config=failed
 735       if test "${with_python}" != auto; then
 736         AC_ERROR(failure running python-config --ldflags)
 737       fi
 738     fi
 739     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 740     if test $? != 0; then
 741       have_python_config=failed
 742       if test "${with_python}" != auto; then
 743         AC_ERROR(failure running python-config --exec-prefix)
 744       fi
 745     fi
 746   else
 747     # Fall back to gdb 7.0/7.1 behaviour.
 748     if test -z ${python_prefix}; then
 749       python_includes=
 750       python_libs=
 751     else
 752       python_includes="-I${python_prefix}/include"
 753       python_libs="-L${python_prefix}/lib"
 754     fi
 755     have_python_config=no
 756   fi
 757
 758   # Having "/pythonX.Y" in the include path is awkward.
 759   # All those python headers get bubbled up to the top inviting lots
 760   # of random collisions.  GDB originally didn't use python-config to
 761   # find the compilation parameters and includes "pythonX.Y/" in the
 762   # path of the, umm, include file.  So strip away this part of the
 763   # output of python-config --includes.
 764   python_includes=`echo "${python_includes} " \
 765                         | sed -e 's,/python[[0-9]]*[[.]][[0-9]]* , ,g'`
 766
 767   # If we have python-config, only try the configuration it provides.
 768   # Otherwise fallback on the old way of trying different versions of
 769   # python in turn.
 770
 771   have_libpython=no
 772   if test "${have_python_config}" = yes; then
 773     python_version=`echo " ${python_libs} " \
 774                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]][[0-9]]*\) .*$,\1,'`
 775     case "${python_version}" in
 776     python*)
 777       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 778                        ${python_includes}, ${python_libs})
 779       ;;
 780     *)
 781       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 782       ;;
 783     esac
 784   elif test "${have_python_config}" != failed; then
 785     if test "${have_libpython}" = no; then
 786       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 787                        ${python_includes}, "${python_libs} -lpython2.7")
 788     fi
 789     if test "${have_libpython}" = no; then
 790       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 791                        ${python_includes}, "${python_libs} -lpython2.6")
 792     fi
 793     if test ${have_libpython} = no; then
 794       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 795                        ${python_includes}, "${python_libs} -lpython2.5")
 796     fi
 797     if test ${have_libpython} = no; then
 798       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 799                        ${python_includes}, "${python_libs} -lpython2.4")
 800     fi
 801   fi
 802   if test "${have_libpython}" = python2.7; then
 803     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 804   elif test "${have_libpython}" = python2.6; then
 805     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 806   elif test "${have_libpython}" = python2.5; then
 807     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 808   elif test "${have_libpython}" = python2.4; then
 809     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 810   fi
 811
 812   if test "${have_libpython}" = no; then
 813     case "${with_python}" in
 814     yes)
 815       AC_MSG_ERROR([python is missing or unusable])
 816       ;;
 817     auto)
 818       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 819       ;;
 820     *)
 821       AC_MSG_ERROR([no usable python found at ${with_python}])
 822       ;;
 823     esac
 824   else
 825     if test -n "${python_prefix}"; then
 826       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 827                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 828       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 829     fi
 830   fi
 831 fi
 832
 833 if test "${have_libpython}" != no; then
 834   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 835   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 836   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 837   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 838   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 839   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 840
 841   # Flags needed to compile Python code (taken from python-config --cflags).
 842   # We cannot call python-config directly because it will output whatever was
 843   # used when compiling the Python interpreter itself, including flags which
 844   # would make the python-related objects be compiled differently from the
 845   # rest of GDB (e.g., -O2 and -fPIC).
 846   if test "${GCC}" = yes; then
 847     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 848   fi
 849
 850   if test "x${tentative_python_cflags}" != x; then
 851     AC_MSG_CHECKING(compiler flags for python code)
 852     for flag in ${tentative_python_cflags}; do
 853       # Check that the compiler accepts it
 854       saved_CFLAGS="$CFLAGS"
 855       CFLAGS="$CFLAGS $flag"
 856       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 857       CFLAGS="$saved_CFLAGS"
 858     done
 859     AC_MSG_RESULT(${PYTHON_CFLAGS})
 860   fi
 861
 862   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
 863   #    #if _SGIAPI
 864   #    #define siginfo __siginfo
 865   #    #endif
 866   # The problem is that including Python causes some XOPEN macros to be
 867   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
 868   # to false.  So, we work around this issue by defining siginfo ourself
 869   # though the command-line.
 870   case "$gdb_host" in
 871     irix*) if test "${GCC}" = yes; then
 872              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
 873            fi
 874            ;;
 875   esac
 876 else
 877   # Even if Python support is not compiled in, we need to have these files
 878   # included.
 879   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
 880   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
 881         python/py-prettyprint.c python/py-auto-load.c"
 882 fi
 883 AC_SUBST(PYTHON_CFLAGS)
 884
 885 # ------------------------- #
 886 # Checks for header files.  #
 887 # ------------------------- #
 888
 889 AC_HEADER_DIRENT
 890 AC_HEADER_STAT
 891 AC_HEADER_STDC
 892 # elf_hp.h is for HP/UX 64-bit shared library support.
 893 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 894 # unconditionally, so what's the point in checking these?
 895 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
 896                   thread_db.h gnu/libc-version.h signal.h stddef.h \
 897                   stdlib.h string.h memory.h strings.h sys/fault.h \
 898                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
 899                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
 900                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
 901                   sys/types.h sys/wait.h wait.h termios.h termio.h \
 902                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h])
 903 AC_CHECK_HEADERS(link.h, [], [],
 904 [#if HAVE_SYS_TYPES_H
 905 # include <sys/types.h>
 906 #endif
 907 #if HAVE_NLIST_H
 908 # include <nlist.h>
 909 #endif
 910 ])
 911 AC_CHECK_HEADERS(sys/proc.h, [], [],
 912 [#if HAVE_SYS_PARAM_H
 913 # include <sys/param.h>
 914 #endif
 915 ])
 916 AC_CHECK_HEADERS(sys/user.h, [], [],
 917 [#if HAVE_SYS_PARAM_H
 918 # include <sys/param.h>
 919 #endif
 920 ])
 921
 922 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 923 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 924 # think that we don't have <curses.h> if we're using GCC.
 925 case $host_os in
 926   solaris2.[[789]])
 927     if test "$GCC" = yes; then
 928       AC_DEFINE(_MSE_INT_H, 1,
 929         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 930    Solaris 2.[789] when using GCC. ])
 931     fi ;;
 932 esac
 933 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
 934 AC_CHECK_HEADERS(term.h, [], [],
 935 [#if HAVE_CURSES_H
 936 # include <curses.h>
 937 #endif
 938 ])
 939
 940 # ------------------------- #
 941 # Checks for declarations.  #
 942 # ------------------------- #
 943
 944 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
 945                 snprintf, vsnprintf])
 946 AM_LC_MESSAGES
 947
 948 # ----------------------- #
 949 # Checks for structures.  #
 950 # ----------------------- #
 951
 952 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 953
 954 # ------------------ #
 955 # Checks for types.  #
 956 # ------------------ #
 957
 958 AC_TYPE_SIGNAL
 959 AC_CHECK_TYPES(socklen_t, [], [],
 960 [#include <sys/types.h>
 961 #include <sys/socket.h>
 962 ])
 963
 964 # ------------------------------------- #
 965 # Checks for compiler characteristics.  #
 966 # ------------------------------------- #
 967
 968 AC_C_CONST
 969 AC_C_INLINE
 970 AC_C_BIGENDIAN
 971
 972 # ------------------------------ #
 973 # Checks for library functions.  #
 974 # ------------------------------ #
 975
 976 AC_FUNC_ALLOCA
 977 AC_FUNC_MMAP
 978 AC_FUNC_VFORK
 979 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid \
 980                 getgid pipe poll pread64 resize_term sbrk setpgid setpgrp setsid \
 981                 sigaction sigprocmask sigsetmask socketpair syscall \
 982                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
 983                 setrlimit getrlimit posix_madvise waitpid])
 984 AM_LANGINFO_CODESET
 985
 986 # Check the return and argument types of ptrace.  No canned test for
 987 # this, so roll our own.
 988 gdb_ptrace_headers='
 989 #if HAVE_SYS_TYPES_H
 990 # include <sys/types.h>
 991 #endif
 992 #if HAVE_SYS_PTRACE_H
 993 # include <sys/ptrace.h>
 994 #endif
 995 #if HAVE_UNISTD_H
 996 # include <unistd.h>
 997 #endif
 998 '
 999 # There is no point in checking if we don't have a prototype.
1000 AC_CHECK_DECLS(ptrace, [], [
1001   : ${gdb_cv_func_ptrace_ret='int'}
1002   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1003 ], $gdb_ptrace_headers)
1004 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1005 # empty argument list, so check for that explicitly.
1006 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1007   AC_TRY_COMPILE($gdb_ptrace_headers,
1008     [extern long ptrace (enum __ptrace_request, ...);],
1009     gdb_cv_func_ptrace_ret='long',
1010     AC_TRY_COMPILE($gdb_ptrace_headers,
1011       [extern int ptrace ();],
1012       gdb_cv_func_ptrace_ret='int',
1013       gdb_cv_func_ptrace_ret='long')))
1014 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1015   [Define as the return type of ptrace.])
1016 # Check argument types.
1017 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1018   AC_TRY_COMPILE($gdb_ptrace_headers,
1019     [extern long ptrace (enum __ptrace_request, ...);],
1020     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1021 for gdb_arg1 in 'int' 'long'; do
1022  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1023   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1024    for gdb_arg4 in 'int' 'long'; do
1025      AC_TRY_COMPILE($gdb_ptrace_headers, [
1026 extern $gdb_cv_func_ptrace_ret
1027   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1028 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1029     break 4;])
1030     for gdb_arg5 in 'int *' 'int' 'long'; do
1031      AC_TRY_COMPILE($gdb_ptrace_headers, [
1032 extern $gdb_cv_func_ptrace_ret
1033   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1034 ], [
1035 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1036     break 5;])
1037     done
1038    done
1039   done
1040  done
1041 done
1042 # Provide a safe default value.
1043 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1044 ])])
1045 ac_save_IFS=$IFS; IFS=','
1046 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1047 IFS=$ac_save_IFS
1048 shift
1049 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1050   [Define to the type of arg 3 for ptrace.])
1051 if test -n "$[5]"; then
1052   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1053     [Define to the type of arg 5 for ptrace.])
1054 fi
1055
1056 dnl AC_FUNC_SETPGRP does not work when cross compiling
1057 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1058 if test "$cross_compiling" = no; then
1059   AC_FUNC_SETPGRP
1060 else
1061   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1062     [AC_TRY_COMPILE([
1063 #include <unistd.h>
1064 ], [
1065   if (setpgrp(1,1) == -1)
1066     exit (0);
1067   else
1068     exit (1);
1069 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1070 if test $ac_cv_func_setpgrp_void = yes; then
1071   AC_DEFINE(SETPGRP_VOID, 1)
1072 fi
1073 fi
1074
1075 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1076 # since sigsetjmp might only be defined as a macro.
1077 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1078 [AC_TRY_COMPILE([
1079 #include <setjmp.h>
1080 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1081 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1082 if test $gdb_cv_func_sigsetjmp = yes; then
1083   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1084 fi
1085
1086 # Assume we'll default to using the included libiberty regex.
1087 gdb_use_included_regex=yes
1088
1089 # However, if the system regex is GNU regex, then default to *not*
1090 # using the included regex.
1091 AC_CACHE_CHECK(
1092   [for GNU regex],
1093   [gdb_cv_have_gnu_regex],
1094   [AC_TRY_COMPILE(
1095     [#include <gnu-versions.h>],
1096     [#define REGEX_INTERFACE_VERSION 1
1097 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1098 # error "Version mismatch"
1099 #endif],
1100     gdb_cv_have_gnu_regex=yes,
1101     gdb_cv_have_gnu_regex=no)])
1102 if test $gdb_cv_have_gnu_regex = yes; then
1103   gdb_use_included_regex=no
1104 fi
1105
1106 AC_ARG_WITH(included-regex,
1107   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1108   gdb_with_regex=$withval,
1109   gdb_with_regex=$gdb_use_included_regex)
1110 if test "$gdb_with_regex" = yes; then
1111   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1112     [Define to 1 if the regex included in libiberty should be used.])
1113 fi
1114
1115 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1116 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1117 [#include <sys/param.h>
1118 #include <sys/proc.h>
1119 ])
1120
1121 # See if <sys/lwp.h> defines `struct lwp`.
1122 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1123 [AC_TRY_COMPILE([#include <sys/param.h>
1124 #include <sys/lwp.h>], [struct lwp l;],
1125 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1126 if test $gdb_cv_struct_lwp = yes; then
1127   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1128             [Define to 1 if your system has struct lwp.])
1129 fi
1130
1131 # See if <machine/reg.h> degines `struct reg'.
1132 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1133 [AC_TRY_COMPILE([#include <sys/types.h>
1134 #include <machine/reg.h>], [struct reg r;],
1135 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1136 if test $gdb_cv_struct_reg = yes; then
1137   AC_DEFINE(HAVE_STRUCT_REG, 1,
1138             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1139 fi
1140
1141 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1142 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1143 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1144                  [#include <machine/reg.h>])
1145
1146 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1147 AC_MSG_CHECKING(for PTRACE_GETREGS)
1148 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1149 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1150                 [PTRACE_GETREGS;],
1151                 [gdb_cv_have_ptrace_getregs=yes],
1152                 [gdb_cv_have_ptrace_getregs=no])])
1153 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1154 if test $gdb_cv_have_ptrace_getregs = yes; then
1155   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1156   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1157 fi
1158
1159 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1160 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1161 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1162 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1163                 [PTRACE_GETFPXREGS;],
1164                 [gdb_cv_have_ptrace_getfpxregs=yes],
1165                 [gdb_cv_have_ptrace_getfpxregs=no])])
1166 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1167 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1168   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1169   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1170 fi
1171
1172 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1173 AC_MSG_CHECKING(for PT_GETDBREGS)
1174 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1175 [AC_TRY_COMPILE([#include <sys/types.h>
1176 #include <sys/ptrace.h>],
1177                 [PT_GETDBREGS;],
1178                 [gdb_cv_have_pt_getdbregs=yes],
1179                 [gdb_cv_have_pt_getdbregs=no])])
1180 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1181 if test $gdb_cv_have_pt_getdbregs = yes; then
1182   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1183   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1184 fi
1185
1186 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1187 AC_MSG_CHECKING(for PT_GETXMMREGS)
1188 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1189 [AC_TRY_COMPILE([#include <sys/types.h>
1190 #include <sys/ptrace.h>],
1191                 [PT_GETXMMREGS;],
1192                 [gdb_cv_have_pt_getxmmregs=yes],
1193                 [gdb_cv_have_pt_getxmmregs=no])])
1194 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1195 if test $gdb_cv_have_pt_getxmmregs = yes; then
1196   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1197   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1198 fi
1199
1200 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1201
1202 if test "${target}" = "${host}"; then
1203   case "${host}" in
1204   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1205       AC_DEFINE(NEW_PROC_API, 1,
1206       [Define if you want to use new multi-fd /proc interface
1207        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1208       ;;
1209   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1210       AC_DEFINE(NEW_PROC_API, 1,
1211       [Define if you want to use new multi-fd /proc interface
1212        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1213       ;;
1214   mips-sgi-irix5*)
1215       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1216       AC_DEFINE([_KMEMUSER], 1,
1217       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1218        around a <sys/proc.h> problem on IRIX 5.])
1219       ;;
1220   esac
1221 fi
1222
1223 if test "$ac_cv_header_sys_procfs_h" = yes; then
1224   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1225   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1226   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1227   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1228   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1229   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1230   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1231   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1232   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1233   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1234   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1235   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1236   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1237   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1238
1239
1240   dnl Check for broken prfpregset_t type
1241
1242   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1243   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1244   dnl instead of the struct itself).  We detect this here, and work
1245   dnl around it in gdb_proc_service.h.
1246
1247   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1248     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1249     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1250       [AC_TRY_RUN([#include <sys/procfs.h>
1251        int main ()
1252        {
1253          if (sizeof (prfpregset_t) == sizeof (void *))
1254            return 1;
1255          return 0;
1256        }],
1257        gdb_cv_prfpregset_t_broken=no,
1258        gdb_cv_prfpregset_t_broken=yes,
1259        gdb_cv_prfpregset_t_broken=yes)])
1260     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1261     if test $gdb_cv_prfpregset_t_broken = yes; then
1262       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1263       [Define if the prfpregset_t type is broken.])
1264     fi
1265   fi
1266
1267   dnl Check for PIOCSET ioctl entry
1268
1269   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1270   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1271   [AC_TRY_COMPILE([#include <unistd.h>
1272 #include <sys/types.h>
1273 #include <sys/procfs.h>
1274 ], [
1275     int dummy;;
1276     dummy = ioctl(0, PIOCSET, &dummy);
1277   ],
1278   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1279   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1280   if test $gdb_cv_have_procfs_piocset = yes; then
1281     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1282     [Define if ioctl argument PIOCSET is available.])
1283   fi
1284 fi
1285
1286 dnl For native ports (host == target), check to see what kind of
1287 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1288 if test ${host} = ${target} ; then
1289   dnl Check for struct link_map with l_ members which are indicative
1290   dnl of SVR4-like shared libraries
1291
1292   AC_MSG_CHECKING(for member l_addr in struct link_map)
1293   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1294     [AC_TRY_COMPILE([#include <link.h>],
1295                     [struct link_map lm; (void) lm.l_addr;],
1296                     gdb_cv_have_struct_link_map_with_l_members=yes,
1297                     gdb_cv_have_struct_link_map_with_l_members=no)])
1298   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1299   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1300     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1301     [Define if <link.h> exists and defines struct link_map which has
1302      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1303      SVR4-like systems.)])
1304   fi
1305
1306   dnl Check for struct link_map with lm_ members which are indicative
1307   dnl of SunOS-like shared libraries
1308
1309   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1310   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1311     [AC_TRY_COMPILE([#include <sys/types.h>
1312 #include <link.h>],
1313                     [struct link_map lm; (void) lm.lm_addr;],
1314                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1315                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1316   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1317   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1318     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1319     [Define if <link.h> exists and defines struct link_map which has
1320      members with an ``lm_'' prefix.  (For SunOS.)])
1321   fi
1322
1323   dnl Check for struct so_map with som_ members which are found on
1324   dnl some *BSD systems.
1325
1326   AC_MSG_CHECKING(for member som_addr in struct so_map)
1327   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1328     [AC_TRY_COMPILE([#include <sys/types.h>
1329 #ifdef HAVE_NLIST_H
1330 #include <nlist.h>
1331 #endif
1332 #include <link.h>],
1333                     [struct so_map lm; (void) lm.som_addr;],
1334                     gdb_cv_have_struct_so_map_with_som_members=yes,
1335                     gdb_cv_have_struct_so_map_with_som_members=no)])
1336   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1337   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1338     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1339     [Define if <link.h> exists and defines a struct so_map which has
1340      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1341   fi
1342
1343   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1344   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1345
1346   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1347   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1348     [AC_TRY_COMPILE([#define _SYSCALL32
1349 #include <sys/link.h>], [struct link_map32 l;],
1350      gdb_cv_have_struct_link_map32=yes,
1351      gdb_cv_have_struct_link_map32=no)])
1352   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1353   if test $gdb_cv_have_struct_link_map32 = yes; then
1354     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1355     [Define if <sys/link.h> has struct link_map32])
1356     AC_DEFINE(_SYSCALL32, 1,
1357     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1358   fi
1359 fi
1360
1361 # Check if the compiler supports the `long long' type.
1362
1363 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1364                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1365 [[extern long long foo;]],
1366 [[switch (foo & 2) { case 0: return 1; }]])],
1367                                   gdb_cv_c_long_long=yes,
1368                                   gdb_cv_c_long_long=no)])
1369 if test $gdb_cv_c_long_long = yes; then
1370   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1371             [Define to 1 if the compiler supports long long.])
1372 fi
1373
1374 # Check if the compiler and runtime support printing long longs.
1375
1376 AC_CACHE_CHECK([for long long support in printf],
1377                gdb_cv_printf_has_long_long,
1378                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1379 [[char buf[32];
1380   long long l = 0;
1381   l = (l << 16) + 0x0123;
1382   l = (l << 16) + 0x4567;
1383   l = (l << 16) + 0x89ab;
1384   l = (l << 16) + 0xcdef;
1385   sprintf (buf, "0x%016llx", l);
1386   return (strcmp ("0x0123456789abcdef", buf));]])],
1387                               gdb_cv_printf_has_long_long=yes,
1388                               gdb_cv_printf_has_long_long=no,
1389                               gdb_cv_printf_has_long_long=no)])
1390 if test $gdb_cv_printf_has_long_long = yes; then
1391   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1392             [Define to 1 if the "%ll" format works to print long longs.])
1393 fi
1394
1395 # Check if the compiler and runtime support printing decfloats.
1396
1397 AC_CACHE_CHECK([for decfloat support in printf],
1398                gdb_cv_printf_has_decfloat,
1399                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1400 [[char buf[64];
1401   _Decimal32 d32 = 1.2345df;
1402   _Decimal64 d64 = 1.2345dd;
1403   _Decimal128 d128 = 1.2345dl;
1404   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1405   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1406                               gdb_cv_printf_has_decfloat=yes,
1407                               gdb_cv_printf_has_decfloat=no,
1408                               gdb_cv_printf_has_decfloat=no)])
1409 if test $gdb_cv_printf_has_decfloat = yes; then
1410   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1411             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1412 fi
1413
1414 # Check if the compiler supports the `long double' type.  We can't use
1415 # AC_C_LONG_DOUBLE because that one does additional checks on the
1416 # constants defined in <float.h> that fail on some systems,
1417 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1418
1419 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1420                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1421                                   gdb_cv_c_long_double=yes,
1422                                   gdb_cv_c_long_double=no)])
1423 if test $gdb_cv_c_long_double = yes; then
1424   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1425            [Define to 1 if the compiler supports long double.])
1426 fi
1427
1428 # Check if the compiler and runtime support printing long doubles.
1429
1430 AC_CACHE_CHECK([for long double support in printf],
1431                gdb_cv_printf_has_long_double,
1432                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1433 [[char buf[16];
1434   long double f = 3.141592653;
1435   sprintf (buf, "%Lg", f);
1436   return (strncmp ("3.14159", buf, 7));]])],
1437                               gdb_cv_printf_has_long_double=yes,
1438                               gdb_cv_printf_has_long_double=no,
1439                               gdb_cv_printf_has_long_double=no)])
1440 if test $gdb_cv_printf_has_long_double = yes; then
1441   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1442             [Define to 1 if the "%Lg" format works to print long doubles.])
1443 fi
1444
1445 # Check if the compiler and runtime support scanning long doubles.
1446
1447 AC_CACHE_CHECK([for long double support in scanf],
1448                gdb_cv_scanf_has_long_double,
1449                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1450 [[#include <stdio.h>]],
1451 [[char *buf = "3.141592653";
1452   long double f = 0;
1453   sscanf (buf, "%Lg", &f);
1454   return !(f > 3.14159 && f < 3.14160);]])],
1455                               gdb_cv_scanf_has_long_double=yes,
1456                               gdb_cv_scanf_has_long_double=no,
1457                               gdb_cv_scanf_has_long_double=no)])
1458 if test $gdb_cv_scanf_has_long_double = yes; then
1459   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1460             [Define to 1 if the "%Lg" format works to scan long doubles.])
1461 fi
1462
1463 case ${host_os} in
1464 aix*)
1465   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1466     SAVE_LDFLAGS=$LDFLAGS
1467
1468     case $GCC in
1469     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1470     *) gdb_cv_bigtoc=-bbigtoc ;;
1471     esac
1472
1473     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1474     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1475     LDFLAGS="${SAVE_LDFLAGS}"
1476   ])
1477   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1478   ;;
1479 esac
1480
1481 AC_MSG_CHECKING(for the dynamic export flag)
1482 dynamic_list=false
1483 if test "${gdb_native}" = yes; then
1484    # The dynamically loaded libthread_db needs access to symbols in the gdb
1485    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1486    # may not be supported there.
1487    old_LDFLAGS="$LDFLAGS"
1488    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1489    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1490    LDFLAGS="$LDFLAGS $RDYNAMIC"
1491    if test "${have_libpython}" = no; then
1492      AC_TRY_LINK([], [], [dynamic_list=true])
1493    else
1494      # Workaround http://bugs.python.org/issue4434 where static
1495      # libpythonX.Y.a would get its symbols required for
1496      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1497      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1498      old_CFLAGS="$CFLAGS"
1499      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1500      AC_RUN_IFELSE(
1501        AC_LANG_PROGRAM(
1502          [#include "]${have_libpython}[/Python.h"],
1503          [int err;
1504           Py_Initialize ();
1505           err = PyRun_SimpleString ("import itertools\n");
1506           Py_Finalize ();
1507           return err == 0 ? 0 : 1;]),
1508        [dynamic_list=true], [], [true])
1509      CFLAGS="$old_CFLAGS"
1510    fi
1511    LDFLAGS="$old_LDFLAGS"
1512 fi
1513 if $dynamic_list; then
1514   found="-Wl,--dynamic-list"
1515   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1516 else
1517   found="-rdynamic"
1518   RDYNAMIC="-rdynamic"
1519 fi
1520 AC_SUBST(RDYNAMIC)
1521 AC_MSG_RESULT($found)
1522
1523 dnl For certain native configurations, we need to check whether thread
1524 dnl support can be built in or not.
1525 dnl
1526 dnl Note that we only want this if we are both native (host == target),
1527 dnl and not doing a canadian cross build (build == host).
1528
1529 if test ${build} = ${host} -a ${host} = ${target} ; then
1530    case ${host_os} in
1531    solaris*)
1532       # See if thread_db library is around for Solaris thread debugging.
1533       # Note that we must explicitly test for version 1 of the library
1534       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1535       # the same API.
1536       AC_MSG_CHECKING(for Solaris thread debugging library)
1537       if test -f /usr/lib/libthread_db.so.1 ; then
1538          AC_MSG_RESULT(yes)
1539          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1540          [Define if using Solaris thread debugging.])
1541          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1542          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1543          AC_CHECK_LIB(dl, dlopen)
1544          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1545          # Sun randomly tweaked the prototypes in <proc_service.h>
1546          # at one point.
1547          AC_MSG_CHECKING(if <proc_service.h> is old)
1548          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1549             AC_TRY_COMPILE([
1550                 #include <proc_service.h>
1551                 ps_err_e ps_pdwrite
1552                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1553             ],, gdb_cv_proc_service_is_old=no,
1554                 gdb_cv_proc_service_is_old=yes)
1555          ])
1556          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1557          if test $gdb_cv_proc_service_is_old = yes; then
1558             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1559             [Define if <proc_service.h> on solaris uses int instead of
1560              size_t, and assorted other type changes.])
1561          fi
1562       else
1563          AC_MSG_RESULT(no)
1564       fi
1565       ;;
1566    aix*)
1567       AC_MSG_CHECKING(for AiX thread debugging library)
1568       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1569                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1570                                    [#ifndef PTHDB_VERSION_3
1571                                     #error
1572                                     #endif],
1573                                    gdb_cv_have_aix_thread_debug=yes,
1574                                    gdb_cv_have_aix_thread_debug=no)])
1575       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1576       if test $gdb_cv_have_aix_thread_debug = yes; then
1577          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1578          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1579          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1580       fi
1581       ;;
1582    esac
1583    AC_SUBST(CONFIG_LDFLAGS)
1584 fi
1585
1586 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1587 dnl other error codes.
1588 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1589    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1590                   gdb_cv_thread_db_h_has_td_notalloc,
1591      AC_TRY_COMPILE(
1592        [#include <thread_db.h>],
1593        [int i = TD_NOTALLOC;],
1594        gdb_cv_thread_db_h_has_td_notalloc=yes,
1595        gdb_cv_thread_db_h_has_td_notalloc=no
1596      )
1597    )
1598    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1599                   gdb_cv_thread_db_h_has_td_version,
1600      AC_TRY_COMPILE(
1601        [#include <thread_db.h>],
1602        [int i = TD_VERSION;],
1603        gdb_cv_thread_db_h_has_td_version=yes,
1604        gdb_cv_thread_db_h_has_td_version=no
1605      )
1606    )
1607    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1608                   gdb_cv_thread_db_h_has_td_notls,
1609      AC_TRY_COMPILE(
1610        [#include <thread_db.h>],
1611        [int i = TD_NOTLS;],
1612        gdb_cv_thread_db_h_has_td_notls=yes,
1613        gdb_cv_thread_db_h_has_td_notls=no
1614      )
1615    )
1616 fi
1617 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1618   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1619             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1620 fi
1621 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1622   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1623             [Define if <thread_db.h> has the TD_VERSION error code.])
1624 fi
1625 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1626   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1627             [Define if <thread_db.h> has the TD_NOTLS error code.])
1628 fi
1629
1630 dnl See if we have a sys/syscall header file that has __NR_tkill.
1631 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1632    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1633                   gdb_cv_sys_syscall_h_has_tkill,
1634      AC_TRY_COMPILE(
1635        [#include <sys/syscall.h>],
1636        [int i = __NR_tkill;],
1637        gdb_cv_sys_syscall_h_has_tkill=yes,
1638        gdb_cv_sys_syscall_h_has_tkill=no
1639      )
1640    )
1641 fi
1642 dnl See if we can issue tkill syscall.
1643 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1644   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1645 fi
1646
1647 dnl Check if we can disable the virtual address space randomization.
1648 dnl The functionality of setarch -R.
1649 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1650 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1651 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1652 #       define ADDR_NO_RANDOMIZE 0x0040000
1653 #      endif
1654        /* Test the flag could be set and stays set.  */
1655        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1656        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1657            return 1])])
1658 AC_RUN_IFELSE([PERSONALITY_TEST],
1659               [have_personality=true],
1660               [have_personality=false],
1661               [AC_LINK_IFELSE([PERSONALITY_TEST],
1662                               [have_personality=true],
1663                               [have_personality=false])])
1664 if $have_personality
1665 then
1666     AC_DEFINE([HAVE_PERSONALITY], 1,
1667               [Define if you support the personality syscall.])
1668 fi
1669
1670 dnl Handle optional features that can be enabled.
1671
1672 target_sysroot_reloc=0
1673 AC_ARG_WITH(sysroot,
1674 AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@], [search for usr/lib et al within DIR]),
1675 [
1676  case ${with_sysroot} in
1677  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1678  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1679  esac
1680
1681  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1682
1683  if test "x$prefix" = xNONE; then
1684   test_prefix=/usr/local
1685  else
1686   test_prefix=$prefix
1687  fi
1688  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1689   test_exec_prefix=$test_prefix
1690  else
1691   test_exec_prefix=$exec_prefix
1692  fi
1693  case ${TARGET_SYSTEM_ROOT} in
1694  "${test_prefix}"|"${test_prefix}/"*|\
1695  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1696  '${prefix}'|'${prefix}/'*|\
1697  '${exec_prefix}'|'${exec_prefix}/'*)
1698    target_sysroot_reloc=1
1699    ;;
1700  esac
1701 ], [
1702  TARGET_SYSTEM_ROOT=
1703  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1704 ])
1705 TARGET_SYSTEM_ROOT_DEFINE="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE=$target_sysroot_reloc"
1706 AC_SUBST(TARGET_SYSTEM_ROOT)
1707 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1708
1709 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1710     [automatically load a system-wide gdbinit file],
1711     [])
1712
1713 AC_ARG_ENABLE(werror,
1714   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1715   [case "${enableval}" in
1716      yes | y) ERROR_ON_WARNING="yes" ;;
1717      no | n)  ERROR_ON_WARNING="no" ;;
1718      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1719    esac])
1720
1721 # Enable -Werror by default when using gcc
1722 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1723     ERROR_ON_WARNING=yes
1724 fi
1725
1726 WERROR_CFLAGS=""
1727 if test "${ERROR_ON_WARNING}" = yes ; then
1728     WERROR_CFLAGS="-Werror"
1729 fi
1730
1731 # The entries after -Wno-pointer-sign are disabled warnings which may
1732 # be enabled in the future, which can not currently be used to build
1733 # GDB.
1734 # NOTE: If you change this list, remember to update
1735 # gdb/doc/gdbint.texinfo.
1736 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1737 -Wformat-nonliteral -Wno-pointer-sign \
1738 -Wno-unused -Wunused-value -Wunused-function \
1739 -Wno-switch -Wno-char-subscripts"
1740
1741 # Enable -Wno-format by default when using gcc on mingw since many
1742 # GCC versions complain about %I64.
1743 case "${host}" in
1744   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1745 esac
1746
1747 AC_ARG_ENABLE(build-warnings,
1748 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1749 [case "${enableval}" in
1750   yes)  ;;
1751   no)   build_warnings="-w";;
1752   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1753         build_warnings="${build_warnings} ${t}";;
1754   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1755         build_warnings="${t} ${build_warnings}";;
1756   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1757 esac
1758 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1759   echo "Setting compiler warning flags = $build_warnings" 6>&1
1760 fi])dnl
1761 AC_ARG_ENABLE(gdb-build-warnings,
1762 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1763 [case "${enableval}" in
1764   yes)  ;;
1765   no)   build_warnings="-w";;
1766   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1767         build_warnings="${build_warnings} ${t}";;
1768   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1769         build_warnings="${t} ${build_warnings}";;
1770   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1771 esac
1772 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1773   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1774 fi])dnl
1775 WARN_CFLAGS=""
1776 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1777 then
1778     AC_MSG_CHECKING(compiler warning flags)
1779     # Separate out the -Werror flag as some files just cannot be
1780     # compiled with it enabled.
1781     for w in ${build_warnings}; do
1782         case $w in
1783         -Werr*) WERROR_CFLAGS=-Werror ;;
1784         *) # Check that GCC accepts it
1785             saved_CFLAGS="$CFLAGS"
1786             CFLAGS="$CFLAGS $w"
1787             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1788             CFLAGS="$saved_CFLAGS"
1789         esac
1790     done
1791     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1792 fi
1793 AC_SUBST(WARN_CFLAGS)
1794 AC_SUBST(WERROR_CFLAGS)
1795
1796 # In the Cygwin environment, we need some additional flags.
1797 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1798 [AC_EGREP_CPP(lose, [
1799 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1800 lose
1801 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1802
1803
1804 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1805 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1806 case ${host} in
1807   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1808   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1809   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1810 esac
1811 AC_SUBST(SER_HARDWIRE)
1812
1813 # libreadline needs libuser32.a in a cygwin environment
1814 WIN32LIBS=
1815 if test x$gdb_cv_os_cygwin = xyes; then
1816     WIN32LIBS="-luser32"
1817     case "${target}" in
1818         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1819         ;;
1820     esac
1821 fi
1822
1823 # The ser-tcp.c module requires sockets.
1824 case ${host} in
1825   *mingw32*)
1826     AC_DEFINE(USE_WIN32API, 1,
1827               [Define if we should use the Windows API, instead of the
1828                POSIX API.  On Windows, we use the Windows API when
1829                building for MinGW, but the POSIX API when building
1830                for Cygwin.])
1831     WIN32LIBS="$WIN32LIBS -lws2_32"
1832     ;;
1833 esac
1834 AC_SUBST(WIN32LIBS)
1835
1836 # Add ELF support to GDB, but only if BFD includes ELF support.
1837 OLD_CFLAGS=$CFLAGS
1838 OLD_LDFLAGS=$LDFLAGS
1839 OLD_LIBS=$LIBS
1840 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1841 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1842 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1843 # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1844 if test "$plugins" = "yes"; then
1845   LIBS="-ldl $LIBS"
1846 fi
1847 LIBS="-lbfd -liberty $intl $LIBS"
1848 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1849 [AC_TRY_LINK(
1850 [#include <stdlib.h>
1851 #include "bfd.h"
1852 #include "elf-bfd.h"
1853 ],
1854 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1855 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1856 if test $gdb_cv_var_elf = yes; then
1857   CONFIG_OBS="$CONFIG_OBS elfread.o"
1858   AC_DEFINE(HAVE_ELF, 1,
1859             [Define if ELF support should be included.])
1860   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1861   if test "$plugins" = "yes"; then
1862     OLD_LIBS="-ldl $OLD_LIBS"
1863   fi
1864 fi
1865 CFLAGS=$OLD_CFLAGS
1866 LDFLAGS=$OLD_LDFLAGS
1867 LIBS=$OLD_LIBS
1868
1869 # Add any host-specific objects to GDB.
1870 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1871
1872 LIBGUI="../libgui/src/libgui.a"
1873 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1874 AC_SUBST(LIBGUI)
1875 AC_SUBST(GUI_CFLAGS_X)
1876
1877 WIN32LDAPP=
1878 AC_SUBST(WIN32LIBS)
1879 AC_SUBST(WIN32LDAPP)
1880
1881 case "${host}" in
1882 *-*-cygwin* | *-*-mingw* )
1883     configdir="win"
1884     ;;
1885 *)
1886     configdir="unix"
1887     ;;
1888 esac
1889
1890 GDBTKLIBS=
1891 if test "${enable_gdbtk}" = "yes"; then
1892
1893     # Gdbtk must have an absolute path to srcdir in order to run
1894     # properly when not installed.
1895     here=`pwd`
1896     cd ${srcdir}
1897     GDBTK_SRC_DIR=`pwd`
1898     cd $here
1899
1900     SC_PATH_TCLCONFIG
1901
1902     # If $no_tk is nonempty, then we can't do Tk, and there is no
1903     # point to doing Tcl.
1904     SC_PATH_TKCONFIG
1905
1906     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1907         SC_LOAD_TCLCONFIG
1908
1909         # Check for in-tree tcl
1910         here=`pwd`
1911         cd ${srcdir}/..
1912         topdir=`pwd`
1913         cd ${here}
1914
1915         intree="no"
1916         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1917           intree="yes"
1918         fi
1919
1920         # Find Tcl private headers
1921         if test x"${intree}" = xno; then
1922           CY_AC_TCL_PRIVATE_HEADERS
1923           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1924           TCL_LIBRARY="${TCL_LIB_SPEC}"
1925           TCL_DEPS=""
1926         else
1927           # If building tcl in the same src tree, private headers
1928           # are not needed, but we need to be sure to use the right
1929           # headers library
1930           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1931           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1932           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1933         fi
1934         AC_SUBST(TCL_INCLUDE)
1935         AC_SUBST(TCL_LIBRARY)
1936         AC_SUBST(TCL_DEPS)
1937
1938         SC_LOAD_TKCONFIG
1939
1940         # Check for in-tree Tk
1941         intree="no"
1942         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1943           intree="yes"
1944         fi
1945
1946         # Find Tk private headers
1947         if test x"${intree}" = xno; then
1948           CY_AC_TK_PRIVATE_HEADERS
1949           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1950           TK_LIBRARY=${TK_LIB_SPEC}
1951           TK_DEPS=""
1952         else
1953           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1954           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
1955           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
1956         fi
1957         AC_SUBST(TK_INCLUDE)
1958         AC_SUBST(TK_LIBRARY)
1959         AC_SUBST(TK_DEPS)
1960         AC_SUBST(TK_XINCLUDES)
1961
1962         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1963
1964         # Include some libraries that Tcl and Tk want.
1965         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1966         # Yes, the ordering seems wrong here.  But it isn't.
1967         # TK_LIBS is the list of libraries that need to be linked
1968         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1969         # were in LIBS then any link tests after this point would
1970         # try to include things like `$(LIBGUI)', which wouldn't work.
1971         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1972
1973         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1974         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1975         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1976         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1977         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1978         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1979         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1980
1981         if test x$gdb_cv_os_cygwin = xyes; then
1982           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1983           WIN32LDAPP="-Wl,--subsystem,console"
1984           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1985         fi
1986
1987         AC_CONFIG_SUBDIRS(gdbtk)
1988     fi
1989 fi
1990
1991 AC_SUBST(X_CFLAGS)
1992 AC_SUBST(X_LDFLAGS)
1993 AC_SUBST(X_LIBS)
1994 AC_SUBST(GDBTKLIBS)
1995 AC_SUBST(GDBTK_CFLAGS)
1996 AC_SUBST(GDBTK_SRC_DIR)
1997
1998 AC_PATH_X
1999
2000 # Unlike the sim directory, whether a simulator is linked is controlled by
2001 # presence of a gdb_sim definition in the target configure.tgt entry.
2002 # This code just checks for a few cases where we'd like to ignore those
2003 # definitions, even when they're present in the '.mt' file.  These cases
2004 # are when --disable-sim is specified, or if the simulator directory is
2005 # not part of the source tree.
2006 #
2007 AC_ARG_ENABLE(sim,
2008 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2009 [echo "enable_sim = $enable_sim";
2010  echo "enableval = ${enableval}";
2011  case "${enableval}" in
2012   yes) ignore_sim=false ;;
2013   no)  ignore_sim=true ;;
2014   *)   ignore_sim=false ;;
2015  esac],
2016 [ignore_sim=false])
2017
2018 if test ! -d "${srcdir}/../sim"; then
2019   ignore_sim=true
2020 fi
2021
2022 SIM=
2023 SIM_OBS=
2024 if test "${ignore_sim}" = "false"; then
2025   if test x"${gdb_sim}" != x ; then
2026     SIM="${gdb_sim}"
2027     SIM_OBS="remote-sim.o"
2028     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2029   fi
2030 fi
2031 AC_SUBST(SIM)
2032 AC_SUBST(SIM_OBS)
2033
2034 AC_SUBST(ENABLE_CFLAGS)
2035 AC_SUBST(PROFILE_CFLAGS)
2036
2037 AC_SUBST(CONFIG_OBS)
2038 AC_SUBST(CONFIG_DEPS)
2039 AC_SUBST(CONFIG_SRCS)
2040 AC_SUBST(CONFIG_ALL)
2041 AC_SUBST(CONFIG_CLEAN)
2042 AC_SUBST(CONFIG_INSTALL)
2043 AC_SUBST(CONFIG_UNINSTALL)
2044
2045 # List of host floatformats.
2046 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2047 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2048 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2049
2050 # target_subdir is used by the testsuite to find the target libraries.
2051 target_subdir=
2052 if test "${host}" != "${target}"; then
2053     target_subdir="${target_alias}/"
2054 fi
2055 AC_SUBST(target_subdir)
2056
2057 frags=
2058 if test "${gdb_native}" = "yes"; then
2059   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2060   if test ! -f ${host_makefile_frag}; then
2061     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2062   fi
2063   frags="$frags $host_makefile_frag"
2064 else
2065   host_makefile_frag=/dev/null
2066 fi
2067
2068 AC_SUBST_FILE(host_makefile_frag)
2069 AC_SUBST(frags)
2070
2071 changequote(,)dnl
2072 if test "${gdb_native}" = "yes"; then
2073 # We pick this up from the host configuration file (.mh) because we
2074 # do not have a native configuration Makefile fragment.
2075 nativefile=`sed -n '
2076 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2077 ' ${host_makefile_frag}`
2078 fi
2079 changequote([,])
2080
2081 if test x"${gdb_osabi}" != x ; then
2082     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2083                        [Define to the default OS ABI for this configuration.])
2084 fi
2085
2086 # Enable multi-ice-gdb-server.
2087 AC_ARG_ENABLE(multi-ice,
2088 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2089   [case $enableval in
2090     yes | no)
2091       ;;
2092     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2093   esac])
2094 if test "x$enable_multi_ice" = xyes; then
2095    AC_CONFIG_SUBDIRS(multi-ice)
2096 fi
2097
2098 AC_ARG_ENABLE(gdbserver,
2099 AS_HELP_STRING([--enable-gdbserver],
2100                [automatically build gdbserver (yes/no/auto, default is auto)]),
2101 [case "${enableval}" in
2102   yes| no|auto) ;;
2103   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2104 esac],[enable_gdbserver=auto])
2105
2106 # We only build gdbserver automatically in a native configuration, and
2107 # only if the user did not explicitly disable its build.
2108 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2109   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2110   if test "x$build_gdbserver" = xyes; then
2111     AC_MSG_RESULT(yes)
2112     AC_CONFIG_SUBDIRS(gdbserver)
2113     gdbserver_build_enabled=yes
2114   else
2115     AC_MSG_RESULT(no)
2116   fi
2117 fi
2118
2119 # If the user explicitly request the gdbserver to be built, verify that
2120 # we were in fact able to enable it.
2121 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2122   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2123 fi
2124
2125 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2126 # to an empty version.
2127
2128 files=
2129 links=
2130
2131 rm -f nm.h
2132 if test "${nativefile}" != ""; then
2133     case "${nativefile}" in
2134       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2135       * ) GDB_NM_FILE="${nativefile}"
2136     esac
2137     files="${files} ${GDB_NM_FILE}"
2138     links="${links} nm.h"
2139     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2140 fi
2141 AC_SUBST(GDB_NM_FILE)
2142
2143 AC_LINK_FILES($files, $links)
2144
2145 dnl Check for exe extension set on certain hosts (e.g. Win32)
2146 AC_EXEEXT
2147
2148 dnl  Detect the character set used by this host.
2149 dnl  At the moment, we just assume it's UTF-8.
2150 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2151           [Define to be a string naming the default host character set.])
2152
2153 AC_OUTPUT(Makefile .gdbinit:gdbinit.in doc/Makefile gnulib/Makefile data-directory/Makefile,
2154 [
2155 case x$CONFIG_HEADERS in
2156 xconfig.h:config.in)
2157 echo > stamp-h ;;
2158 esac
2159 ])
2160
2161 exit 0