gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2013 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/development.sh
  28
  29 AC_PROG_CC
  30 AC_USE_SYSTEM_EXTENSIONS
  31 ACX_LARGEFILE
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(..)
  35 AC_CANONICAL_SYSTEM
  36 AC_ARG_PROGRAM
  37
  38 # Dependency checking.
  39 ZW_CREATE_DEPDIR
  40 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  41
  42 # Check for the 'make' the user wants to use.
  43 AC_CHECK_PROGS(MAKE, make)
  44 MAKE_IS_GNU=
  45 case "`$MAKE --version 2>&1 | sed 1q`" in
  46   *GNU*)
  47     MAKE_IS_GNU=yes
  48     ;;
  49 esac
  50 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  51 AC_PROG_MAKE_SET
  52
  53 # Configure gnulib.  We need to build gnulib under some other
  54 # directory not "gnulib", to avoid the problem of both GDB and
  55 # GDBserver wanting to build it in the same directory, when building
  56 # in the source dir.
  57 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"])
  58
  59 dnl List of object files and targets accumulated by configure.
  60
  61 CONFIG_OBS=
  62 CONFIG_DEPS=
  63 CONFIG_SRCS=
  64 ENABLE_CFLAGS=
  65
  66 CONFIG_ALL=
  67 CONFIG_CLEAN=
  68 CONFIG_INSTALL=
  69 CONFIG_UNINSTALL=
  70
  71 dnl Set up for gettext.
  72 ZW_GNU_GETTEXT_SISTER_DIR
  73
  74 localedir='${datadir}/locale'
  75 AC_SUBST(localedir)
  76
  77 if test x"$USE_NLS" = xyes; then
  78    CONFIG_ALL="$CONFIG_ALL all-po"
  79    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  80    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  81    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  82 fi
  83
  84 GNULIB=build-gnulib/import
  85
  86 # For Makefile dependencies.
  87 GNULIB_STDINT_H=
  88 if test x"$STDINT_H" != x; then
  89   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  90 fi
  91 AC_SUBST(GNULIB_STDINT_H)
  92
  93 PACKAGE=gdb
  94 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  95 AC_SUBST(PACKAGE)
  96
  97 # We never need to detect it in this sub-configure.
  98 # But preserve it for config.status --recheck.
  99 AC_ARG_VAR(MAKEINFO,
 100   [Parent configure detects if it is of sufficient version.])
 101 AC_ARG_VAR(MAKEINFOFLAGS,
 102   [Parameters for MAKEINFO.])
 103
 104 MAKEINFO_EXTRA_FLAGS=""
 105 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 106   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 107   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 108     gdb_cv_have_makeinfo_click=yes
 109   else
 110     gdb_cv_have_makeinfo_click=no
 111   fi])
 112 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 113   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 114 fi
 115 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 116
 117 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 118     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 119     [${libdir}/debug])
 120
 121 # We can't pass paths as command line arguments.
 122 # Mingw32 tries to be clever and will convert the paths for us.
 123 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 124 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 125 # This breaks GDB's relocatable path conversions since paths passed in
 126 # config.h would not get so translated, the path prefixes no longer match.
 127 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 128
 129 # GDB's datadir relocation
 130
 131 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 132     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 133     [${datadir}/gdb])
 134
 135 AC_ARG_WITH(relocated-sources,
 136 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 137 [reloc_srcdir="${withval}"
 138  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 139               [Relocated directory for source files. ])
 140 ])
 141
 142 AC_MSG_CHECKING([for default auto-load directory])
 143 AC_ARG_WITH(auto-load-dir,
 144 AS_HELP_STRING([--with-auto-load-dir=PATH],
 145   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 146   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 147 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 148 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 149               [Directories from which to load auto-loaded scripts.])
 150 AC_MSG_RESULT([$with_auto_load_dir])
 151
 152 AC_MSG_CHECKING([for default auto-load safe-path])
 153 AC_ARG_WITH(auto-load-safe-path,
 154 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 155   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 156 AS_HELP_STRING([--without-auto-load-safe-path],
 157                [do not restrict auto-loaded files locations]),
 158     [if test "$with_auto_load_safe_path" = "no"; then
 159      with_auto_load_safe_path="/"
 160      fi],
 161 [with_auto_load_safe_path="$with_auto_load_dir"])
 162 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 163 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 164               [Directories safe to hold auto-loaded files.])
 165 AC_MSG_RESULT([$with_auto_load_safe_path])
 166
 167 AC_CONFIG_SUBDIRS(testsuite)
 168
 169 # Check whether to support alternative target configurations
 170 AC_ARG_ENABLE(targets,
 171 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 172 [case "${enableval}" in
 173   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 174             ;;
 175   no)       enable_targets= ;;
 176   *)        enable_targets=$enableval ;;
 177 esac])
 178
 179 # Check whether to enable 64-bit support on 32-bit hosts
 180 AC_ARG_ENABLE(64-bit-bfd,
 181 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 182 [case "${enableval}" in
 183   yes)  want64=true  ;;
 184   no)   want64=false ;;
 185   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 186 esac],[want64=false])dnl
 187
 188 # Provide defaults for some variables set by the per-host and per-target
 189 # configuration.
 190 gdb_host_obs=posix-hdep.o
 191
 192 if test "${target}" = "${host}"; then
 193   gdb_native=yes
 194 else
 195   gdb_native=no
 196 fi
 197
 198 . $srcdir/configure.host
 199
 200 # Accumulate some settings from configure.tgt over all enabled targets
 201
 202 TARGET_OBS=
 203 all_targets=
 204 HAVE_NATIVE_GCORE_TARGET=
 205
 206 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 207 do
 208   if test "$targ_alias" = "all"; then
 209     all_targets=true
 210   else
 211     # Canonicalize the secondary target names.
 212     result=`$ac_config_sub $targ_alias 2>/dev/null`
 213     if test -n "$result"; then
 214         targ=$result
 215     else
 216         targ=$targ_alias
 217     fi
 218
 219     . ${srcdir}/configure.tgt
 220
 221     AS_IF([test -z "${gdb_target_obs}"],
 222       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 223
 224     # Target-specific object files
 225     for i in ${gdb_target_obs}; do
 226         case " $TARGET_OBS " in
 227         *" ${i} "*) ;;
 228         *)
 229           TARGET_OBS="$TARGET_OBS ${i}"
 230           ;;
 231         esac
 232     done
 233
 234     # Check whether this target needs 64-bit CORE_ADDR
 235     if test x${want64} = xfalse; then
 236       . ${srcdir}/../bfd/config.bfd
 237     fi
 238
 239     # Check whether this target is native and supports gcore.
 240     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 241        && $gdb_have_gcore; then
 242       HAVE_NATIVE_GCORE_TARGET=1
 243     fi
 244   fi
 245 done
 246
 247 if test x${all_targets} = xtrue; then
 248
 249   # We want all 64-bit targets if we either:
 250   #  - run on a 64-bit host  or
 251   #  - already require 64-bit support for some other target  or
 252   #  - the --enable-64-bit-bfd option was supplied
 253   # Otherwise we only support all 32-bit targets.
 254   #
 255   # NOTE: This test must be in sync with the corresponding
 256   #       tests in BFD!
 257
 258   if test x${want64} = xfalse; then
 259     AC_CHECK_SIZEOF(long)
 260     if test "x${ac_cv_sizeof_long}" = "x8"; then
 261       want64=true
 262     fi
 263   fi
 264   if test x${want64} = xtrue; then
 265     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 266   else
 267     TARGET_OBS='$(ALL_TARGET_OBS)'
 268   fi
 269 fi
 270
 271 AC_SUBST(TARGET_OBS)
 272 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 273
 274 # For other settings, only the main target counts.
 275 gdb_sim=
 276 gdb_osabi=
 277 build_gdbserver=
 278 targ=$target; . ${srcdir}/configure.tgt
 279
 280 # Fetch the default architecture and default target vector from BFD.
 281 targ=$target; . $srcdir/../bfd/config.bfd
 282
 283 # We only want the first architecture, so strip off the others if
 284 # there is more than one.
 285 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 286
 287 if test "x$targ_archs" != x; then
 288   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 289     [Define to BFD's default architecture. ])
 290 fi
 291 if test "x$targ_defvec" != x; then
 292   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 293     [Define to BFD's default target vector. ])
 294 fi
 295
 296 # The CLI cannot be disabled yet, but may be in the future.
 297
 298 # Enable CLI.
 299 AC_ARG_ENABLE(gdbcli,
 300 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 301   [case $enableval in
 302     yes)
 303       ;;
 304     no)
 305       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 306     *)
 307       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 308   esac],
 309   [enable_gdbcli=yes])
 310 if test x"$enable_gdbcli" = xyes; then
 311   if test -d $srcdir/cli; then
 312     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 313     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 314     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 315     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 316   fi
 317 fi
 318
 319 # Enable MI.
 320 AC_ARG_ENABLE(gdbmi,
 321 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 322   [case $enableval in
 323     yes | no)
 324       ;;
 325     *)
 326       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 327   esac],
 328   [enable_gdbmi=yes])
 329 if test x"$enable_gdbmi" = xyes; then
 330   if test -d $srcdir/mi; then
 331     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 332     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 333     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 334     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 335   fi
 336 fi
 337
 338 # Enable TUI.
 339 AC_ARG_ENABLE(tui,
 340 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 341   [case $enableval in
 342     yes | no | auto)
 343       ;;
 344     *)
 345       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 346   esac],enable_tui=auto)
 347
 348 # Enable gdbtk.
 349 AC_ARG_ENABLE(gdbtk,
 350 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 351   [case $enableval in
 352     yes | no)
 353       ;;
 354     *)
 355       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 356   esac],
 357   [if test -d $srcdir/gdbtk; then
 358     enable_gdbtk=yes
 359   else
 360     enable_gdbtk=no
 361   fi])
 362 # We unconditionally disable gdbtk tests on selected platforms.
 363 case $host_os in
 364   go32* | windows*)
 365     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 366     enable_gdbtk=no ;;
 367 esac
 368
 369 # Libunwind support for ia64.
 370
 371 AC_ARG_WITH(libunwind-ia64,
 372 AS_HELP_STRING([--with-libunwind-ia64],
 373                [use libunwind frame unwinding for ia64 targets]),,
 374             [with_libunwind_ia64=auto])
 375
 376 # Backward compatibility option.
 377 if test "${with_libunwind+set}" = set; then
 378   if test x"$with_libunwind_ia64" != xauto; then
 379     AC_MSG_ERROR(
 380       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 381   fi
 382   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 383   with_libunwind_ia64="$with_libunwind"
 384 fi
 385
 386 case "$with_libunwind_ia64" in
 387   yes | no)
 388     ;;
 389   auto)
 390     AC_CHECK_HEADERS(libunwind-ia64.h)
 391     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 392     ;;
 393   *)
 394     AC_MSG_ERROR(
 395       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 396     ;;
 397 esac
 398
 399 if test x"$with_libunwind_ia64" = xyes; then
 400   AC_CHECK_HEADERS(libunwind-ia64.h)
 401   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 402     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 403   fi
 404   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 405   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 406   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 407 fi
 408
 409 opt_curses=no
 410 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 411
 412 prefer_curses=no
 413 if test "$opt_curses" = "yes"; then
 414   prefer_curses=yes
 415 fi
 416
 417 # Profiling support.
 418 AC_ARG_ENABLE(profiling,
 419 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 420   [case $enableval in
 421     yes | no)
 422       ;;
 423     *)
 424       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 425   esac],
 426  [enable_profiling=no])
 427
 428 AC_CHECK_FUNCS(monstartup _mcleanup)
 429 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 430 [AC_TRY_LINK(
 431 [#include <stdlib.h>
 432 extern char _etext;
 433 ],
 434 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 435 if test $ac_cv_var__etext = yes; then
 436   AC_DEFINE(HAVE__ETEXT, 1,
 437             [Define to 1 if your system has the _etext variable. ])
 438 fi
 439 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 440 [AC_TRY_LINK(
 441 [#include <stdlib.h>
 442 extern char etext;
 443 ],
 444 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 445 if test $ac_cv_var_etext = yes; then
 446   AC_DEFINE(HAVE_ETEXT, 1,
 447             [Define to 1 if your system has the etext variable. ])
 448 fi
 449 if test "$enable_profiling" = yes ; then
 450   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 451     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 452   fi
 453   PROFILE_CFLAGS=-pg
 454   OLD_CFLAGS="$CFLAGS"
 455   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 456
 457   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 458     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 459      ac_cv_cc_supports_pg=no)])
 460
 461   if test $ac_cv_cc_supports_pg = no; then
 462     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 463   fi
 464
 465   CFLAGS="$OLD_CFLAGS"
 466 fi
 467
 468 ACX_PKGVERSION([GDB])
 469 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 470 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 471 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 472
 473 # --------------------- #
 474 # Checks for programs.  #
 475 # --------------------- #
 476
 477 AC_PROG_AWK
 478 AC_PROG_INSTALL
 479 AC_PROG_LN_S
 480 AC_PROG_RANLIB
 481 AC_PROG_YACC
 482
 483 AC_CHECK_TOOL(AR, ar)
 484 AC_CHECK_TOOL(DLLTOOL, dlltool)
 485 AC_CHECK_TOOL(WINDRES, windres)
 486
 487 case $host_os in
 488   gnu*)
 489     # Needed for GNU Hurd hosts.
 490     AC_CHECK_TOOL(MIG, mig)
 491     if test x"$MIG" = x; then
 492       AC_MSG_ERROR([MIG not found but required for $host hosts])
 493     fi
 494     ;;
 495 esac
 496
 497 # ---------------------- #
 498 # Checks for libraries.  #
 499 # ---------------------- #
 500
 501 # We might need to link with -lm; most simulators need it.
 502 AC_CHECK_LIB(m, main)
 503
 504 # We need to link with -lw to get `wctype' on Solaris before Solaris
 505 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 506 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 507 # is known to have this problem).  Therefore we avoid libw if we can.
 508 AC_CHECK_FUNC(wctype, [],
 509   [AC_CHECK_LIB(w, wctype)])
 510
 511 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 512 AC_SEARCH_LIBS(gethostbyname, nsl)
 513
 514 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 515 AC_SEARCH_LIBS(socketpair, socket)
 516
 517 # Link in zlib if we can.  This allows us to read compressed debug sections.
 518 AM_ZLIB
 519
 520 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 521 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 522
 523 AM_ICONV
 524
 525 # GDB may fork/exec the iconv program to get the list of supported character
 526 # sets.  Allow the user to specify where to find it.
 527 # There are several factors affecting the choice of option name:
 528 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 529 #   the build-time location of libiconv files.
 530 # - The program we need to find is iconv, which comes with glibc.  The user
 531 #   doesn't necessarily have libiconv installed.  Therefore naming this
 532 #   --with-libiconv-foo feels wrong.
 533 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 534 #   defined to work on directories not files (though it really doesn't know
 535 #   the difference).
 536 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 537 #   with --with-libiconv-prefix.
 538 # Putting these together is why the option name is --with-iconv-bin.
 539
 540 AC_ARG_WITH(iconv-bin,
 541 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 542 [iconv_bin="${withval}"
 543  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 544                     [Path of directory of iconv program.])
 545  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 546 ])
 547
 548 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 549 # There is a very specific comment in /usr/include/curses.h explaining that
 550 # termcap routines built into libcurses must not be used.
 551 #
 552 # The symptoms we observed so far is GDB unexpectedly changing
 553 # the terminal settings when tgetent is called - this is particularly
 554 # visible as the output is missing carriage returns, and so rapidly
 555 # becomes very hard to read.
 556 #
 557 # The readline configure script has already decided that libtermcap
 558 # was enough for its purposes, and so decided to build readline using
 559 # libtermcap.  Since the TUI mode requires curses, building GDB with
 560 # TUI enabled results in both libraries to be used at the same time,
 561 # which is not allowed.  This basically means that GDB with TUI is
 562 # broken on alpha-osf.
 563
 564 case $host_os in
 565   osf* )
 566     if test x"$enable_tui" = xyes; then
 567       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 568     fi
 569     if test x"$enable_tui" = xauto; then
 570       enable_tui=no
 571     fi
 572     ;;
 573 esac
 574
 575 # For the TUI, we need enhanced curses functionality.
 576 if test x"$enable_tui" != xno; then
 577   prefer_curses=yes
 578 fi
 579
 580 curses_found=no
 581 if test x"$prefer_curses" = xyes; then
 582   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 583   # curses library because the latter might not provide all the
 584   # functionality we need.  However, this leads to problems on systems
 585   # where the linker searches /usr/local/lib, but the compiler doesn't
 586   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 587   # default installation of ncurses on alpha*-dec-osf* will lead to such
 588   # a situation.
 589   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 590
 591   if test "$ac_cv_search_waddstr" != no; then
 592     curses_found=yes
 593   fi
 594 fi
 595
 596 # Check whether we should enable the TUI, but only do so if we really
 597 # can.
 598 if test x"$enable_tui" != xno; then
 599   if test -d $srcdir/tui; then
 600     if test "$curses_found" != no; then
 601       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 602       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 603       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 604       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 605     else
 606       if test x"$enable_tui" = xyes; then
 607         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 608       else
 609         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 610       fi
 611     fi
 612   fi
 613 fi
 614
 615 # Since GDB uses Readline, we need termcap functionality.  In many
 616 # cases this will be provided by the curses library, but some systems
 617 # have a seperate termcap library, or no curses library at all.
 618
 619 case $host_os in
 620   cygwin*)
 621     if test -d $srcdir/libtermcap; then
 622       LIBS="../libtermcap/libtermcap.a $LIBS"
 623       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 624     fi ;;
 625   go32* | *djgpp*)
 626     ac_cv_search_tgetent="none required"
 627     ;;
 628   *mingw32*)
 629     ac_cv_search_tgetent="none required"
 630     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 631     ;;
 632 esac
 633
 634 # These are the libraries checked by Readline.
 635 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 636
 637 if test "$ac_cv_search_tgetent" = no; then
 638   AC_MSG_ERROR([no termcap library found])
 639 fi
 640
 641 AC_ARG_WITH([system-readline],
 642   [AS_HELP_STRING([--with-system-readline],
 643                   [use installed readline library])])
 644
 645 if test "$with_system_readline" = yes; then
 646   READLINE=-lreadline
 647   READLINE_DEPS=
 648   READLINE_CFLAGS=
 649   READLINE_TEXI_INCFLAG=
 650 else
 651   READLINE='$(READLINE_DIR)/libreadline.a'
 652   READLINE_DEPS='$(READLINE)'
 653   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 654   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 655 fi
 656 AC_SUBST(READLINE)
 657 AC_SUBST(READLINE_DEPS)
 658 AC_SUBST(READLINE_CFLAGS)
 659 AC_SUBST(READLINE_TEXI_INCFLAG)
 660
 661 # Generate jit-reader.h
 662
 663 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 664 TARGET_PTR=
 665
 666 AC_CHECK_SIZEOF(unsigned long long)
 667 AC_CHECK_SIZEOF(unsigned long)
 668 AC_CHECK_SIZEOF(unsigned __int128)
 669
 670 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 671   TARGET_PTR="unsigned long"
 672 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 673   TARGET_PTR="unsigned long long"
 674 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 675   TARGET_PTR="unsigned __int128"
 676 else
 677   TARGET_PTR="unsigned long"
 678 fi
 679
 680 AC_SUBST(TARGET_PTR)
 681 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 682
 683 AC_SEARCH_LIBS(dlopen, dl)
 684
 685 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 686                 [directory to load the JIT readers from],
 687                 [${libdir}/gdb])
 688
 689 AC_ARG_WITH(expat,
 690   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 691   [], [with_expat=auto])
 692 AC_MSG_CHECKING([whether to use expat])
 693 AC_MSG_RESULT([$with_expat])
 694
 695 if test "${with_expat}" = no; then
 696   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 697   HAVE_LIBEXPAT=no
 698 else
 699   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 700                         [XML_Parser p = XML_ParserCreate (0);])
 701   if test "$HAVE_LIBEXPAT" != yes; then
 702     if test "$with_expat" = yes; then
 703       AC_MSG_ERROR([expat is missing or unusable])
 704     else
 705       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 706     fi
 707   else
 708     save_LIBS=$LIBS
 709     LIBS="$LIBS $LIBEXPAT"
 710     AC_CHECK_FUNCS(XML_StopParser)
 711     LIBS=$save_LIBS
 712   fi
 713 fi
 714
 715 dnl Utility to simplify finding libpython.
 716 dnl $1 = pythonX.Y
 717 dnl $2 = the shell variable to assign the result to
 718 dnl      If libpython is found we store $version here.
 719 dnl $3 = additional flags to add to CPPFLAGS
 720 dnl $4 = additional flags to add to LIBS
 721
 722 AC_DEFUN([AC_TRY_LIBPYTHON],
 723 [
 724   version=$1
 725   define([have_libpython_var],$2)
 726   new_CPPFLAGS=$3
 727   new_LIBS=$4
 728   AC_MSG_CHECKING([for ${version}])
 729   save_CPPFLAGS=$CPPFLAGS
 730   save_LIBS=$LIBS
 731   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 732   LIBS="$LIBS $new_LIBS"
 733   found_usable_python=no
 734   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 735                                  [[Py_Initialize ();]]),
 736                  [have_libpython_var=${version}
 737                   found_usable_python=yes
 738                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 739                   PYTHON_LIBS=$new_LIBS])
 740   CPPFLAGS=$save_CPPFLAGS
 741   LIBS=$save_LIBS
 742   AC_MSG_RESULT([${found_usable_python}])
 743 ])
 744
 745 dnl There are several different values for --with-python:
 746 dnl
 747 dnl no -   Don't include python support.
 748 dnl yes -  Include python support, error if it's missing.
 749 dnl        If we find python in $PATH, use it to fetch configure options,
 750 dnl        otherwise assume the compiler can find it with no help from us.
 751 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 752 dnl auto - Same as "yes", but if python is missing from the system,
 753 dnl        fall back to "no".
 754 dnl /path/to/python/exec-prefix -
 755 dnl        Use the python located in this directory.
 756 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 757 dnl        the compilation parameters.  Otherwise use
 758 dnl        -I/path/to/python/exec-prefix/include,
 759 dnl        -L/path/to/python/exec-prefix/lib.
 760 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 761 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 762 dnl        but is deprecated.
 763 dnl /path/to/python/executable -
 764 dnl        Run python-config.py with this version of python to fetch the
 765 dnl        compilation parameters.
 766 dnl        NOTE: This needn't be the real python executable.
 767 dnl        In a cross-compilation scenario (build != host), this could be
 768 dnl        a shell script that provides what python-config.py provides for
 769 dnl        --ldflags, --includes, --exec-prefix.
 770 dnl python-executable -
 771 dnl        Find python-executable in $PATH, and then handle the same as
 772 dnl        /path/to/python/executable.
 773 dnl
 774 dnl If a python program is specified, it is used to run python-config.py and
 775 dnl is passed --ldflags, --includes, --exec-prefix.
 776
 777 AC_ARG_WITH(python,
 778   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 779   [], [with_python=auto])
 780 AC_MSG_CHECKING([whether to use python])
 781 AC_MSG_RESULT([$with_python])
 782
 783 if test "${with_python}" = no; then
 784   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 785   have_libpython=no
 786 else
 787   case "${with_python}" in
 788   [[\\/]]* | ?:[[\\/]]*)
 789     if test -d ${with_python}; then
 790       # Assume the python binary is ${with_python}/bin/python.
 791       python_prog="${with_python}/bin/python"
 792       python_prefix=
 793       # If python does not exit ${with_python}/bin, then try in
 794       # ${with_python}.  On Windows/MinGW, this is where the Python
 795       # executable is.
 796       if test ! -x "${python_prog}"; then
 797         python_prog="${with_python}/python"
 798         python_prefix=
 799       fi
 800       if test ! -x "${python_prog}"; then
 801         # Fall back to gdb 7.0/7.1 behaviour.
 802         python_prog=missing
 803         python_prefix=${with_python}
 804       fi
 805     elif test -x "${with_python}"; then
 806       # While we can't run python compiled for $host (unless host == build),
 807       # the user could write a script that provides the needed information,
 808       # so we support that.
 809       python_prog=${with_python}
 810       python_prefix=
 811     else
 812       AC_ERROR(invalid value for --with-python)
 813     fi
 814     ;;
 815   */*)
 816     # Disallow --with-python=foo/bar.
 817     AC_ERROR(invalid value for --with-python)
 818     ;;
 819   *)
 820     # The user has either specified auto, yes, or the name of the python
 821     # program assumed to be in $PATH.
 822     python_prefix=
 823     case "${with_python}" in
 824     yes | auto)
 825       if test ${build} = ${host}; then
 826         AC_PATH_PROG(python_prog_path, python, missing)
 827         if test "${python_prog_path}" = missing; then
 828           python_prog=missing
 829         else
 830           python_prog=${python_prog_path}
 831         fi
 832       else
 833         # Not much we can do except assume the cross-compiler will find the
 834         # right files.
 835         python_prog=missing
 836       fi
 837       ;;
 838     *)
 839       # While we can't run python compiled for $host (unless host == build),
 840       # the user could write a script that provides the needed information,
 841       # so we support that.
 842       python_prog="${with_python}"
 843       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 844       if test "${python_prog_path}" = missing; then
 845         AC_ERROR(unable to find python program ${python_prog})
 846       fi
 847       ;;
 848     esac
 849   esac
 850
 851   if test "${python_prog}" != missing; then
 852     # We have a python program to use, but it may be too old.
 853     # Don't flag an error for --with-python=auto (the default).
 854     have_python_config=yes
 855     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 856     if test $? != 0; then
 857       have_python_config=failed
 858       if test "${with_python}" != auto; then
 859         AC_ERROR(failure running python-config --includes)
 860       fi
 861     fi
 862     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 863     if test $? != 0; then
 864       have_python_config=failed
 865       if test "${with_python}" != auto; then
 866         AC_ERROR(failure running python-config --ldflags)
 867       fi
 868     fi
 869     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 870     if test $? != 0; then
 871       have_python_config=failed
 872       if test "${with_python}" != auto; then
 873         AC_ERROR(failure running python-config --exec-prefix)
 874       fi
 875     fi
 876   else
 877     # We do not have a python executable we can use to determine where
 878     # to find the Python headers and libs.  We cannot guess the include
 879     # path from the python_prefix either, because that include path
 880     # depends on the Python version.  So, there is nothing much we can
 881     # do except assume that the compiler will be able to find those files.
 882     python_includes=
 883     python_libs=
 884     have_python_config=no
 885   fi
 886
 887   # If we have python-config, only try the configuration it provides.
 888   # Otherwise fallback on the old way of trying different versions of
 889   # python in turn.
 890
 891   have_libpython=no
 892   if test "${have_python_config}" = yes; then
 893     # Determine the Python version by extracting "-lpython<version>"
 894     # part of the python_libs. <version> is usually X.Y with X and Y
 895     # being decimal numbers, but can also be XY (seen on Windows).
 896     #
 897     # The extraction is performed using sed with a regular expression.
 898     # Initially, the regexp used was using the '?' quantifier to make
 899     # the dot in the version number optional.  Unfortunately, this
 900     # does not work with non-GNU versions of sed because, because of
 901     # what looks like a limitation (the '?' quantifier does not work
 902     # with back-references).  We work around this limitation by using
 903     # the '*' quantifier instead.  It means that, in theory, we might
 904     # match unexpected version strings such as "-lpython2..7", but
 905     # this seems unlikely in practice.  And even if that happens,
 906     # an error will be triggered later on, when checking that version
 907     # number.
 908     python_version=`echo " ${python_libs} " \
 909                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 910     case "${python_version}" in
 911     python*)
 912       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 913                        ${python_includes}, ${python_libs})
 914       ;;
 915     *)
 916       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 917       ;;
 918     esac
 919   elif test "${have_python_config}" != failed; then
 920     if test "${have_libpython}" = no; then
 921       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 922                        ${python_includes}, "${python_libs} -lpython2.7")
 923     fi
 924     if test "${have_libpython}" = no; then
 925       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 926                        ${python_includes}, "${python_libs} -lpython2.6")
 927     fi
 928     if test ${have_libpython} = no; then
 929       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 930                        ${python_includes}, "${python_libs} -lpython2.5")
 931     fi
 932     if test ${have_libpython} = no; then
 933       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 934                        ${python_includes}, "${python_libs} -lpython2.4")
 935     fi
 936   fi
 937   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 938     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 939   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 940     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 941   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 942     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 943   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 944     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 945   fi
 946
 947   if test "${have_libpython}" = no; then
 948     case "${with_python}" in
 949     yes)
 950       AC_MSG_ERROR([python is missing or unusable])
 951       ;;
 952     auto)
 953       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 954       ;;
 955     *)
 956       AC_MSG_ERROR([no usable python found at ${with_python}])
 957       ;;
 958     esac
 959   else
 960     if test -n "${python_prefix}"; then
 961       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 962                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 963       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 964     fi
 965   fi
 966 fi
 967
 968 if test "${have_libpython}" != no; then
 969   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 970   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 971   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 972   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 973   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 974   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 975
 976   # Flags needed to compile Python code (taken from python-config --cflags).
 977   # We cannot call python-config directly because it will output whatever was
 978   # used when compiling the Python interpreter itself, including flags which
 979   # would make the python-related objects be compiled differently from the
 980   # rest of GDB (e.g., -O2 and -fPIC).
 981   if test "${GCC}" = yes; then
 982     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 983   fi
 984
 985   if test "x${tentative_python_cflags}" != x; then
 986     AC_MSG_CHECKING(compiler flags for python code)
 987     for flag in ${tentative_python_cflags}; do
 988       # Check that the compiler accepts it
 989       saved_CFLAGS="$CFLAGS"
 990       CFLAGS="$CFLAGS $flag"
 991       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 992       CFLAGS="$saved_CFLAGS"
 993     done
 994     AC_MSG_RESULT(${PYTHON_CFLAGS})
 995   fi
 996
 997   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
 998   #    #if _SGIAPI
 999   #    #define siginfo __siginfo
1000   #    #endif
1001   # The problem is that including Python causes some XOPEN macros to be
1002   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
1003   # to false.  So, we work around this issue by defining siginfo ourself
1004   # though the command-line.
1005   #
1006   # On x64 Windows, Python's include headers, and pyconfig.h in
1007   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
1008   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
1009   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
1010   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
1011   # The issue was reported to the Python community, but still isn't
1012   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
1013
1014   case "$gdb_host" in
1015     irix*) if test "${GCC}" = yes; then
1016              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
1017            fi
1018            ;;
1019     mingw64)
1020            if test "${GCC}" = yes; then
1021              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1022            fi
1023            ;;
1024   esac
1025
1026   # Note that "python -m threading" cannot be used to check for
1027   # threading support due to a bug in Python 2.7.3
1028   # (http://bugs.python.org/issue15567).
1029   AC_MSG_CHECKING(whether python supports threads)
1030   saved_CPPFLAGS="${CPPFLAGS}"
1031   CPPFLAGS="${PYTHON_CPPFLAGS}"
1032   # Note that the test is reversed so that python_has_threads=yes on
1033   # unexpected failures.
1034   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1035 #include <Python.h>
1036 #ifdef WITH_THREAD
1037 # error
1038 #endif
1039   ]]), [python_has_threads=no], [python_has_threads=yes])
1040   AC_MSG_RESULT(${python_has_threads})
1041   CPPFLAGS="${saved_CPPFLAGS}"
1042 else
1043   # Even if Python support is not compiled in, we need to have these files
1044   # included.
1045   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
1046   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
1047         python/py-prettyprint.c python/py-auto-load.c"
1048 fi
1049 AC_SUBST(PYTHON_CFLAGS)
1050 AC_SUBST(PYTHON_CPPFLAGS)
1051 AC_SUBST(PYTHON_LIBS)
1052
1053 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1054 # but turn it off if Python is enabled with threads, since -lmcheck is
1055 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1056 # and for releases.
1057 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1058    && $development; then
1059   libmcheck_default=yes
1060 else
1061   libmcheck_default=no
1062 fi
1063 GDB_AC_LIBMCHECK(${libmcheck_default})
1064
1065 if test "$ENABLE_LIBMCHECK" = "yes" \
1066         -a "${have_libpython}" != "no" \
1067         -a "${python_has_threads}" = "yes" ; then
1068   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1069 fi
1070
1071 # ------------------------- #
1072 # Checks for header files.  #
1073 # ------------------------- #
1074
1075 AC_HEADER_STDC
1076 # elf_hp.h is for HP/UX 64-bit shared library support.
1077 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1078                   thread_db.h \
1079                   sys/fault.h \
1080                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1081                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1082                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1083                   termios.h termio.h \
1084                   sgtty.h elf_hp.h \
1085                   dlfcn.h])
1086 AC_CHECK_HEADERS(sys/proc.h, [], [],
1087 [#if HAVE_SYS_PARAM_H
1088 # include <sys/param.h>
1089 #endif
1090 ])
1091 AC_CHECK_HEADERS(sys/user.h, [], [],
1092 [#if HAVE_SYS_PARAM_H
1093 # include <sys/param.h>
1094 #endif
1095 ])
1096
1097 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1098 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1099 # think that we don't have <curses.h> if we're using GCC.
1100 case $host_os in
1101   solaris2.[[789]])
1102     if test "$GCC" = yes; then
1103       AC_DEFINE(_MSE_INT_H, 1,
1104         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1105    Solaris 2.[789] when using GCC. ])
1106     fi ;;
1107 esac
1108 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1109 AC_CHECK_HEADERS(term.h, [], [],
1110 [#if HAVE_CURSES_H
1111 # include <curses.h>
1112 #endif
1113 ])
1114
1115 # ------------------------- #
1116 # Checks for declarations.  #
1117 # ------------------------- #
1118
1119 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1120 AM_LC_MESSAGES
1121
1122 # ----------------------- #
1123 # Checks for structures.  #
1124 # ----------------------- #
1125
1126 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1127
1128 # ------------------ #
1129 # Checks for types.  #
1130 # ------------------ #
1131
1132 AC_TYPE_SIGNAL
1133 AC_CHECK_TYPES(socklen_t, [], [],
1134 [#include <sys/types.h>
1135 #include <sys/socket.h>
1136 ])
1137
1138 # ------------------------------------- #
1139 # Checks for compiler characteristics.  #
1140 # ------------------------------------- #
1141
1142 AC_C_CONST
1143 AC_C_INLINE
1144 AC_C_BIGENDIAN
1145
1146 # ------------------------------ #
1147 # Checks for library functions.  #
1148 # ------------------------------ #
1149
1150 AC_FUNC_ALLOCA
1151 AC_FUNC_MMAP
1152 AC_FUNC_VFORK
1153 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid getgid \
1154                 pipe poll pread pread64 pwrite readlink resize_term \
1155                 sbrk setpgid setpgrp setsid \
1156                 sigaction sigprocmask sigsetmask socketpair \
1157                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1158                 setrlimit getrlimit posix_madvise waitpid lstat \
1159                 ptrace64])
1160 AM_LANGINFO_CODESET
1161 GDB_AC_COMMON
1162
1163 # Check the return and argument types of ptrace.  No canned test for
1164 # this, so roll our own.
1165 gdb_ptrace_headers='
1166 #include <sys/types.h>
1167 #if HAVE_SYS_PTRACE_H
1168 # include <sys/ptrace.h>
1169 #endif
1170 #if HAVE_UNISTD_H
1171 # include <unistd.h>
1172 #endif
1173 '
1174 # There is no point in checking if we don't have a prototype.
1175 AC_CHECK_DECLS(ptrace, [], [
1176   : ${gdb_cv_func_ptrace_ret='int'}
1177   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1178 ], $gdb_ptrace_headers)
1179 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1180 # empty argument list, so check for that explicitly.
1181 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1182   AC_TRY_COMPILE($gdb_ptrace_headers,
1183     [extern long ptrace (enum __ptrace_request, ...);],
1184     gdb_cv_func_ptrace_ret='long',
1185     AC_TRY_COMPILE($gdb_ptrace_headers,
1186       [extern int ptrace ();],
1187       gdb_cv_func_ptrace_ret='int',
1188       gdb_cv_func_ptrace_ret='long')))
1189 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1190   [Define as the return type of ptrace.])
1191 # Check argument types.
1192 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1193   AC_TRY_COMPILE($gdb_ptrace_headers,
1194     [extern long ptrace (enum __ptrace_request, ...);],
1195     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1196 for gdb_arg1 in 'int' 'long'; do
1197  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1198   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1199    for gdb_arg4 in 'int' 'long' 'void *'; do
1200      AC_TRY_COMPILE($gdb_ptrace_headers, [
1201 extern $gdb_cv_func_ptrace_ret
1202   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1203 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1204     break 4;])
1205     for gdb_arg5 in 'int *' 'int' 'long'; do
1206      AC_TRY_COMPILE($gdb_ptrace_headers, [
1207 extern $gdb_cv_func_ptrace_ret
1208   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1209 ], [
1210 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1211     break 5;])
1212     done
1213    done
1214   done
1215  done
1216 done
1217 # Provide a safe default value.
1218 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1219 ])])
1220 ac_save_IFS=$IFS; IFS=','
1221 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1222 IFS=$ac_save_IFS
1223 shift
1224 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1225   [Define to the type of arg 3 for ptrace.])
1226 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG4, $[4],
1227   [Define to the type of arg 4 for ptrace.])
1228 if test -n "$[5]"; then
1229   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1230     [Define to the type of arg 5 for ptrace.])
1231 fi
1232
1233 dnl AC_FUNC_SETPGRP does not work when cross compiling
1234 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1235 if test "$cross_compiling" = no; then
1236   AC_FUNC_SETPGRP
1237 else
1238   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1239     [AC_TRY_COMPILE([
1240 #include <unistd.h>
1241 ], [
1242   if (setpgrp(1,1) == -1)
1243     exit (0);
1244   else
1245     exit (1);
1246 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1247 if test $ac_cv_func_setpgrp_void = yes; then
1248   AC_DEFINE(SETPGRP_VOID, 1)
1249 fi
1250 fi
1251
1252 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1253 # since sigsetjmp might only be defined as a macro.
1254 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1255 [AC_TRY_COMPILE([
1256 #include <setjmp.h>
1257 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1258 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1259 if test $gdb_cv_func_sigsetjmp = yes; then
1260   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1261 fi
1262
1263 # Assume we'll default to using the included libiberty regex.
1264 gdb_use_included_regex=yes
1265
1266 # However, if the system regex is GNU regex, then default to *not*
1267 # using the included regex.
1268 AC_CACHE_CHECK(
1269   [for GNU regex],
1270   [gdb_cv_have_gnu_regex],
1271   [AC_TRY_COMPILE(
1272     [#include <gnu-versions.h>],
1273     [#define REGEX_INTERFACE_VERSION 1
1274 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1275 # error "Version mismatch"
1276 #endif],
1277     gdb_cv_have_gnu_regex=yes,
1278     gdb_cv_have_gnu_regex=no)])
1279 if test $gdb_cv_have_gnu_regex = yes; then
1280   gdb_use_included_regex=no
1281 fi
1282
1283 AC_ARG_WITH(included-regex,
1284   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1285   gdb_with_regex=$withval,
1286   gdb_with_regex=$gdb_use_included_regex)
1287 if test "$gdb_with_regex" = yes; then
1288   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1289     [Define to 1 if the regex included in libiberty should be used.])
1290 fi
1291
1292 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1293 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1294 [#include <sys/param.h>
1295 #include <sys/proc.h>
1296 ])
1297
1298 # See if <sys/lwp.h> defines `struct lwp`.
1299 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1300 [AC_TRY_COMPILE([#include <sys/param.h>
1301 #include <sys/lwp.h>], [struct lwp l;],
1302 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1303 if test $gdb_cv_struct_lwp = yes; then
1304   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1305             [Define to 1 if your system has struct lwp.])
1306 fi
1307
1308 # See if <machine/reg.h> degines `struct reg'.
1309 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1310 [AC_TRY_COMPILE([#include <sys/types.h>
1311 #include <machine/reg.h>], [struct reg r;],
1312 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1313 if test $gdb_cv_struct_reg = yes; then
1314   AC_DEFINE(HAVE_STRUCT_REG, 1,
1315             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1316 fi
1317
1318 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1319 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1320 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1321                  [#include <machine/reg.h>])
1322
1323 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1324 # Older amd64 Linux's don't have the fs_base and gs_base members of
1325 # `struct user_regs_struct'.
1326 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1327                  [], [], [#include <sys/user.h>])
1328
1329 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1330 AC_MSG_CHECKING(for PTRACE_GETREGS)
1331 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1332 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1333                 [PTRACE_GETREGS;],
1334                 [gdb_cv_have_ptrace_getregs=yes],
1335                 [gdb_cv_have_ptrace_getregs=no])])
1336 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1337 if test $gdb_cv_have_ptrace_getregs = yes; then
1338   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1339   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1340 fi
1341
1342 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1343 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1344 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1345 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1346                 [PTRACE_GETFPXREGS;],
1347                 [gdb_cv_have_ptrace_getfpxregs=yes],
1348                 [gdb_cv_have_ptrace_getfpxregs=no])])
1349 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1350 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1351   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1352   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1353 fi
1354
1355 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1356 AC_MSG_CHECKING(for PT_GETDBREGS)
1357 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1358 [AC_TRY_COMPILE([#include <sys/types.h>
1359 #include <sys/ptrace.h>],
1360                 [PT_GETDBREGS;],
1361                 [gdb_cv_have_pt_getdbregs=yes],
1362                 [gdb_cv_have_pt_getdbregs=no])])
1363 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1364 if test $gdb_cv_have_pt_getdbregs = yes; then
1365   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1366   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1367 fi
1368
1369 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1370 AC_MSG_CHECKING(for PT_GETXMMREGS)
1371 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1372 [AC_TRY_COMPILE([#include <sys/types.h>
1373 #include <sys/ptrace.h>],
1374                 [PT_GETXMMREGS;],
1375                 [gdb_cv_have_pt_getxmmregs=yes],
1376                 [gdb_cv_have_pt_getxmmregs=no])])
1377 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1378 if test $gdb_cv_have_pt_getxmmregs = yes; then
1379   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1380   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1381 fi
1382
1383 # Detect which type of /proc is in use, such as for Solaris.
1384
1385 if test "${target}" = "${host}"; then
1386   case "${host}" in
1387   *-*-sysv4.2* | *-*-sysv5* )
1388       AC_DEFINE(NEW_PROC_API, 1,
1389       [Define if you want to use new multi-fd /proc interface.])
1390       ;;
1391   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1392       AC_DEFINE(NEW_PROC_API, 1,
1393       [Define if you want to use new multi-fd /proc interface.])
1394       ;;
1395   mips-sgi-irix5*)
1396       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1397       AC_DEFINE([_KMEMUSER], 1,
1398       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1399        around a <sys/proc.h> problem on IRIX 5.])
1400       ;;
1401   esac
1402 fi
1403
1404 if test "$ac_cv_header_sys_procfs_h" = yes; then
1405   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1406   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1407   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1408   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1409   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1410   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1411   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1412   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1413   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1414   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1415   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1416
1417
1418   dnl Check for broken prfpregset_t type
1419
1420   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1421   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1422   dnl instead of the struct itself).  We detect this here, and work
1423   dnl around it in gdb_proc_service.h.
1424
1425   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1426     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1427     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1428       [AC_TRY_RUN([#include <sys/procfs.h>
1429        int main ()
1430        {
1431          if (sizeof (prfpregset_t) == sizeof (void *))
1432            return 1;
1433          return 0;
1434        }],
1435        gdb_cv_prfpregset_t_broken=no,
1436        gdb_cv_prfpregset_t_broken=yes,
1437        gdb_cv_prfpregset_t_broken=yes)])
1438     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1439     if test $gdb_cv_prfpregset_t_broken = yes; then
1440       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1441       [Define if the prfpregset_t type is broken.])
1442     fi
1443   fi
1444 fi
1445
1446 # Check if the compiler supports the `long long' type.
1447
1448 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1449                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1450 [[extern long long foo;]],
1451 [[switch (foo & 2) { case 0: return 1; }]])],
1452                                   gdb_cv_c_long_long=yes,
1453                                   gdb_cv_c_long_long=no)])
1454 if test $gdb_cv_c_long_long != yes; then
1455   # libdecnumber requires long long.
1456   AC_MSG_ERROR([Compiler must support long long for GDB.])
1457 fi
1458
1459 # Check if the compiler and runtime support printing long longs.
1460
1461 AC_CACHE_CHECK([for long long support in printf],
1462                gdb_cv_printf_has_long_long,
1463                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1464 [[char buf[32];
1465   long long l = 0;
1466   l = (l << 16) + 0x0123;
1467   l = (l << 16) + 0x4567;
1468   l = (l << 16) + 0x89ab;
1469   l = (l << 16) + 0xcdef;
1470   sprintf (buf, "0x%016llx", l);
1471   return (strcmp ("0x0123456789abcdef", buf));]])],
1472                               gdb_cv_printf_has_long_long=yes,
1473                               gdb_cv_printf_has_long_long=no,
1474                               gdb_cv_printf_has_long_long=no)])
1475 if test $gdb_cv_printf_has_long_long = yes; then
1476   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1477             [Define to 1 if the "%ll" format works to print long longs.])
1478 fi
1479
1480 # Check if the compiler and runtime support printing decfloats.
1481
1482 AC_CACHE_CHECK([for decfloat support in printf],
1483                gdb_cv_printf_has_decfloat,
1484                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1485 [[char buf[64];
1486   _Decimal32 d32 = 1.2345df;
1487   _Decimal64 d64 = 1.2345dd;
1488   _Decimal128 d128 = 1.2345dl;
1489   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1490   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1491                               gdb_cv_printf_has_decfloat=yes,
1492                               gdb_cv_printf_has_decfloat=no,
1493                               gdb_cv_printf_has_decfloat=no)])
1494 if test $gdb_cv_printf_has_decfloat = yes; then
1495   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1496             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1497 fi
1498
1499 # Check if the compiler supports the `long double' type.  We can't use
1500 # AC_C_LONG_DOUBLE because that one does additional checks on the
1501 # constants defined in <float.h> that fail on some systems,
1502 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1503
1504 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1505                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1506                                   gdb_cv_c_long_double=yes,
1507                                   gdb_cv_c_long_double=no)])
1508 if test $gdb_cv_c_long_double = yes; then
1509   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1510            [Define to 1 if the compiler supports long double.])
1511 fi
1512
1513 # Check if the compiler and runtime support printing long doubles.
1514
1515 AC_CACHE_CHECK([for long double support in printf],
1516                gdb_cv_printf_has_long_double,
1517                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1518 [[char buf[16];
1519   long double f = 3.141592653;
1520   sprintf (buf, "%Lg", f);
1521   return (strncmp ("3.14159", buf, 7));]])],
1522                               gdb_cv_printf_has_long_double=yes,
1523                               gdb_cv_printf_has_long_double=no,
1524                               gdb_cv_printf_has_long_double=no)])
1525 if test $gdb_cv_printf_has_long_double = yes; then
1526   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1527             [Define to 1 if the "%Lg" format works to print long doubles.])
1528 fi
1529
1530 # Check if the compiler and runtime support scanning long doubles.
1531
1532 AC_CACHE_CHECK([for long double support in scanf],
1533                gdb_cv_scanf_has_long_double,
1534                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1535 [[#include <stdio.h>]],
1536 [[char *buf = "3.141592653";
1537   long double f = 0;
1538   sscanf (buf, "%Lg", &f);
1539   return !(f > 3.14159 && f < 3.14160);]])],
1540                               gdb_cv_scanf_has_long_double=yes,
1541                               gdb_cv_scanf_has_long_double=no,
1542                               gdb_cv_scanf_has_long_double=no)])
1543 if test $gdb_cv_scanf_has_long_double = yes; then
1544   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1545             [Define to 1 if the "%Lg" format works to scan long doubles.])
1546 fi
1547
1548 case ${host_os} in
1549 aix*)
1550   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1551     SAVE_LDFLAGS=$LDFLAGS
1552
1553     case $GCC in
1554     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1555     *) gdb_cv_bigtoc=-bbigtoc ;;
1556     esac
1557
1558     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1559     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1560     LDFLAGS="${SAVE_LDFLAGS}"
1561   ])
1562   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1563   ;;
1564 esac
1565
1566 AC_MSG_CHECKING(for the dynamic export flag)
1567 dynamic_list=false
1568 if test "${gdb_native}" = yes; then
1569    # The dynamically loaded libthread_db needs access to symbols in the gdb
1570    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1571    # may not be supported there.
1572    old_LDFLAGS="$LDFLAGS"
1573    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1574    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1575    LDFLAGS="$LDFLAGS $RDYNAMIC"
1576    if test "${have_libpython}" = no; then
1577      AC_TRY_LINK([], [], [dynamic_list=true])
1578    else
1579      # Workaround http://bugs.python.org/issue4434 where static
1580      # libpythonX.Y.a would get its symbols required for
1581      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1582      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1583      old_CFLAGS="$CFLAGS"
1584      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1585      old_LIBS="$LIBS"
1586      LIBS="$LIBS $PYTHON_LIBS"
1587      AC_RUN_IFELSE(
1588        AC_LANG_PROGRAM(
1589          [#include "]${have_libpython}[/Python.h"],
1590          [int err;
1591           Py_Initialize ();
1592           err = PyRun_SimpleString ("import itertools\n");
1593           Py_Finalize ();
1594           return err == 0 ? 0 : 1;]),
1595        [dynamic_list=true], [], [true])
1596      LIBS="$old_LIBS"
1597      CFLAGS="$old_CFLAGS"
1598    fi
1599    LDFLAGS="$old_LDFLAGS"
1600 fi
1601 if $dynamic_list; then
1602   found="-Wl,--dynamic-list"
1603   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1604 else
1605   found="-rdynamic"
1606   RDYNAMIC="-rdynamic"
1607 fi
1608 AC_SUBST(RDYNAMIC)
1609 AC_MSG_RESULT($found)
1610
1611 dnl For certain native configurations, we need to check whether thread
1612 dnl support can be built in or not.
1613 dnl
1614 dnl Note that we only want this if we are both native (host == target),
1615 dnl and not doing a canadian cross build (build == host).
1616
1617 if test ${build} = ${host} -a ${host} = ${target} ; then
1618    case ${host_os} in
1619    solaris*)
1620       # See if thread_db library is around for Solaris thread debugging.
1621       # Note that we must explicitly test for version 1 of the library
1622       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1623       # the same API.
1624       AC_MSG_CHECKING(for Solaris thread debugging library)
1625       if test -f /usr/lib/libthread_db.so.1 ; then
1626          AC_MSG_RESULT(yes)
1627          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1628          [Define if using Solaris thread debugging.])
1629          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1630          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1631          AC_CHECK_LIB(dl, dlopen)
1632          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1633          # Sun randomly tweaked the prototypes in <proc_service.h>
1634          # at one point.
1635          AC_MSG_CHECKING(if <proc_service.h> is old)
1636          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1637             AC_TRY_COMPILE([
1638                 #include <proc_service.h>
1639                 ps_err_e ps_pdwrite
1640                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1641             ],, gdb_cv_proc_service_is_old=no,
1642                 gdb_cv_proc_service_is_old=yes)
1643          ])
1644          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1645          if test $gdb_cv_proc_service_is_old = yes; then
1646             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1647             [Define if <proc_service.h> on solaris uses int instead of
1648              size_t, and assorted other type changes.])
1649          fi
1650       else
1651          AC_MSG_RESULT(no)
1652       fi
1653       ;;
1654    aix*)
1655       AC_MSG_CHECKING(for AiX thread debugging library)
1656       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1657                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1658                                    [#ifndef PTHDB_VERSION_3
1659                                     #error
1660                                     #endif],
1661                                    gdb_cv_have_aix_thread_debug=yes,
1662                                    gdb_cv_have_aix_thread_debug=no)])
1663       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1664       if test $gdb_cv_have_aix_thread_debug = yes; then
1665          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1666          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1667          LIBS="$LIBS -lpthdebug"
1668
1669          # Older versions of AIX do not provide the declaration for
1670          # the getthrds function (it appears that it was introduced
1671          # with AIX 6.x).
1672          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1673       fi
1674       ;;
1675    esac
1676    AC_SUBST(CONFIG_LDFLAGS)
1677 fi
1678
1679 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1680 dnl other error codes.
1681 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1682    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1683                   gdb_cv_thread_db_h_has_td_notalloc,
1684      AC_TRY_COMPILE(
1685        [#include <thread_db.h>],
1686        [int i = TD_NOTALLOC;],
1687        gdb_cv_thread_db_h_has_td_notalloc=yes,
1688        gdb_cv_thread_db_h_has_td_notalloc=no
1689      )
1690    )
1691    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1692                   gdb_cv_thread_db_h_has_td_version,
1693      AC_TRY_COMPILE(
1694        [#include <thread_db.h>],
1695        [int i = TD_VERSION;],
1696        gdb_cv_thread_db_h_has_td_version=yes,
1697        gdb_cv_thread_db_h_has_td_version=no
1698      )
1699    )
1700    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1701                   gdb_cv_thread_db_h_has_td_notls,
1702      AC_TRY_COMPILE(
1703        [#include <thread_db.h>],
1704        [int i = TD_NOTLS;],
1705        gdb_cv_thread_db_h_has_td_notls=yes,
1706        gdb_cv_thread_db_h_has_td_notls=no
1707      )
1708    )
1709 fi
1710 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1711   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1712             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1713 fi
1714 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1715   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1716             [Define if <thread_db.h> has the TD_VERSION error code.])
1717 fi
1718 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1719   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1720             [Define if <thread_db.h> has the TD_NOTLS error code.])
1721 fi
1722
1723 dnl See if we have a sys/syscall header file that has __NR_tkill.
1724 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1725    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1726                   gdb_cv_sys_syscall_h_has_tkill,
1727      AC_TRY_COMPILE(
1728        [#include <sys/syscall.h>],
1729        [int i = __NR_tkill;],
1730        gdb_cv_sys_syscall_h_has_tkill=yes,
1731        gdb_cv_sys_syscall_h_has_tkill=no
1732      )
1733    )
1734 fi
1735 dnl See if we can issue tkill syscall.
1736 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes"; then
1737   AC_CHECK_FUNC(syscall,
1738     AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1739   )
1740 fi
1741
1742 dnl Check if we can disable the virtual address space randomization.
1743 dnl The functionality of setarch -R.
1744 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1745 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1746 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1747 #       define ADDR_NO_RANDOMIZE 0x0040000
1748 #      endif
1749        /* Test the flag could be set and stays set.  */
1750        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1751        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1752            return 1])])
1753 AC_RUN_IFELSE([PERSONALITY_TEST],
1754               [have_personality=true],
1755               [have_personality=false],
1756               [AC_LINK_IFELSE([PERSONALITY_TEST],
1757                               [have_personality=true],
1758                               [have_personality=false])])
1759 if $have_personality
1760 then
1761     AC_DEFINE([HAVE_PERSONALITY], 1,
1762               [Define if you support the personality syscall.])
1763 fi
1764
1765 dnl Set the host's .gdbinit filename.
1766 case $host_os in
1767   go32* | *djgpp*)
1768     gdbinit=gdb.ini
1769     ;;
1770   *)
1771     gdbinit=.gdbinit
1772     ;;
1773 esac
1774 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1775
1776 dnl Handle optional features that can be enabled.
1777
1778 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1779 # except that the argument to --with-sysroot is optional.
1780 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1781 if test "x$with_sysroot" = xyes; then
1782   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1783 fi
1784 AC_ARG_WITH(sysroot,
1785   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1786                  [search for usr/lib et al within DIR]),
1787   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1788 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1789               [search for usr/lib et al within DIR])
1790 AC_SUBST(TARGET_SYSTEM_ROOT)
1791 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1792
1793 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1794     [automatically load a system-wide gdbinit file],
1795     [])
1796
1797 AC_ARG_ENABLE(werror,
1798   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1799   [case "${enableval}" in
1800      yes | y) ERROR_ON_WARNING="yes" ;;
1801      no | n)  ERROR_ON_WARNING="no" ;;
1802      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1803    esac])
1804
1805 # Enable -Werror by default when using gcc.  Turn it off for releases.
1806 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
1807     ERROR_ON_WARNING=yes
1808 fi
1809
1810 WERROR_CFLAGS=""
1811 if test "${ERROR_ON_WARNING}" = yes ; then
1812     WERROR_CFLAGS="-Werror"
1813 fi
1814
1815 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1816 -Wpointer-sign \
1817 -Wno-unused -Wunused-value -Wunused-function \
1818 -Wno-switch -Wno-char-subscripts -Wmissing-prototypes \
1819 -Wdeclaration-after-statement -Wempty-body -Wmissing-parameter-type \
1820 -Wold-style-declaration -Wold-style-definition"
1821
1822 # Enable -Wno-format by default when using gcc on mingw since many
1823 # GCC versions complain about %I64.
1824 case "${host}" in
1825   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1826   *) build_warnings="$build_warnings -Wformat-nonliteral" ;;
1827 esac
1828
1829 AC_ARG_ENABLE(build-warnings,
1830 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1831 [case "${enableval}" in
1832   yes)  ;;
1833   no)   build_warnings="-w";;
1834   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1835         build_warnings="${build_warnings} ${t}";;
1836   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1837         build_warnings="${t} ${build_warnings}";;
1838   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1839 esac
1840 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1841   echo "Setting compiler warning flags = $build_warnings" 6>&1
1842 fi])dnl
1843 AC_ARG_ENABLE(gdb-build-warnings,
1844 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1845 [case "${enableval}" in
1846   yes)  ;;
1847   no)   build_warnings="-w";;
1848   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1849         build_warnings="${build_warnings} ${t}";;
1850   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1851         build_warnings="${t} ${build_warnings}";;
1852   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1853 esac
1854 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1855   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1856 fi])dnl
1857 WARN_CFLAGS=""
1858 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1859 then
1860     AC_MSG_CHECKING(compiler warning flags)
1861     # Separate out the -Werror flag as some files just cannot be
1862     # compiled with it enabled.
1863     for w in ${build_warnings}; do
1864         case $w in
1865         -Werr*) WERROR_CFLAGS=-Werror ;;
1866         *) # Check that GCC accepts it
1867             saved_CFLAGS="$CFLAGS"
1868             CFLAGS="$CFLAGS $w"
1869             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1870             CFLAGS="$saved_CFLAGS"
1871         esac
1872     done
1873     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1874 fi
1875 AC_SUBST(WARN_CFLAGS)
1876 AC_SUBST(WERROR_CFLAGS)
1877
1878 # In the Cygwin environment, we need some additional flags.
1879 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1880 [AC_EGREP_CPP(^lose$, [
1881 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1882 lose
1883 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1884
1885
1886 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1887 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1888 case ${host} in
1889   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1890   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1891   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1892 esac
1893 AC_SUBST(SER_HARDWIRE)
1894
1895 # libreadline needs libuser32.a in a cygwin environment
1896 WIN32LIBS=
1897 if test x$gdb_cv_os_cygwin = xyes; then
1898     WIN32LIBS="-luser32"
1899     case "${target}" in
1900         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1901         ;;
1902     esac
1903 fi
1904
1905 # The ser-tcp.c module requires sockets.
1906 case ${host} in
1907   *mingw32*)
1908     AC_DEFINE(USE_WIN32API, 1,
1909               [Define if we should use the Windows API, instead of the
1910                POSIX API.  On Windows, we use the Windows API when
1911                building for MinGW, but the POSIX API when building
1912                for Cygwin.])
1913     WIN32LIBS="$WIN32LIBS -lws2_32"
1914     ;;
1915 esac
1916 AC_SUBST(WIN32LIBS)
1917
1918 # Add ELF support to GDB, but only if BFD includes ELF support.
1919 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1920                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1921 if test $gdb_cv_var_elf = yes; then
1922   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o"
1923   AC_DEFINE(HAVE_ELF, 1,
1924             [Define if ELF support should be included.])
1925   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1926   if test "$plugins" = "yes"; then
1927     AC_SEARCH_LIBS(dlopen, dl)
1928   fi
1929 fi
1930
1931 # Add macho support to GDB, but only if BFD includes it.
1932 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1933                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1934 if test $gdb_cv_var_macho = yes; then
1935   CONFIG_OBS="$CONFIG_OBS machoread.o"
1936 fi
1937
1938 # Add SOM support to GDB, but only if BFD includes it.
1939 GDB_AC_CHECK_BFD([for SOM support in BFD], gdb_cv_var_som,
1940                  [bfd_som_attach_aux_hdr (NULL, 0, NULL)], som.h)
1941 if test $gdb_cv_var_som = yes; then
1942   CONFIG_OBS="$CONFIG_OBS somread.o"
1943 fi
1944
1945 # Add any host-specific objects to GDB.
1946 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1947
1948 # If building on ELF, look for lzma support for embedded compressed debug info.
1949 if test $gdb_cv_var_elf = yes; then
1950   AC_ARG_WITH(lzma,
1951     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1952     [], [with_lzma=auto])
1953   AC_MSG_CHECKING([whether to use lzma])
1954   AC_MSG_RESULT([$with_lzma])
1955
1956   if test "${with_lzma}" != no; then
1957     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1958                           [lzma_index_iter iter;
1959                            lzma_index_iter_init (&iter, 0);
1960                            lzma_mf_is_supported (LZMA_MF_HC3);])
1961     if test "$HAVE_LIBLZMA" != yes; then
1962       if test "$with_lzma" = yes; then
1963         AC_MSG_ERROR([missing liblzma for --with-lzma])
1964       fi
1965     fi
1966   fi
1967 fi
1968
1969 LIBGUI="../libgui/src/libgui.a"
1970 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1971 AC_SUBST(LIBGUI)
1972 AC_SUBST(GUI_CFLAGS_X)
1973
1974 WIN32LDAPP=
1975 AC_SUBST(WIN32LIBS)
1976 AC_SUBST(WIN32LDAPP)
1977
1978 case "${host}" in
1979 *-*-cygwin* | *-*-mingw* )
1980     configdir="win"
1981     ;;
1982 *)
1983     configdir="unix"
1984     ;;
1985 esac
1986
1987 GDBTKLIBS=
1988 if test "${enable_gdbtk}" = "yes"; then
1989
1990     # Gdbtk must have an absolute path to srcdir in order to run
1991     # properly when not installed.
1992     here=`pwd`
1993     cd ${srcdir}
1994     GDBTK_SRC_DIR=`pwd`
1995     cd $here
1996
1997     SC_PATH_TCLCONFIG
1998
1999     # If $no_tk is nonempty, then we can't do Tk, and there is no
2000     # point to doing Tcl.
2001     SC_PATH_TKCONFIG
2002
2003     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2004         SC_LOAD_TCLCONFIG
2005
2006         # Check for in-tree tcl
2007         here=`pwd`
2008         cd ${srcdir}/..
2009         topdir=`pwd`
2010         cd ${here}
2011
2012         intree="no"
2013         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2014           intree="yes"
2015         fi
2016
2017         # Find Tcl private headers
2018         if test x"${intree}" = xno; then
2019           CY_AC_TCL_PRIVATE_HEADERS
2020           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2021           TCL_LIBRARY="${TCL_LIB_SPEC}"
2022           TCL_DEPS=""
2023         else
2024           # If building tcl in the same src tree, private headers
2025           # are not needed, but we need to be sure to use the right
2026           # headers library
2027           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2028           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2029           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2030         fi
2031         AC_SUBST(TCL_INCLUDE)
2032         AC_SUBST(TCL_LIBRARY)
2033         AC_SUBST(TCL_DEPS)
2034
2035         SC_LOAD_TKCONFIG
2036
2037         # Check for in-tree Tk
2038         intree="no"
2039         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2040           intree="yes"
2041         fi
2042
2043         # Find Tk private headers
2044         if test x"${intree}" = xno; then
2045           CY_AC_TK_PRIVATE_HEADERS
2046           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2047           TK_LIBRARY=${TK_LIB_SPEC}
2048           TK_DEPS=""
2049         else
2050           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2051           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2052           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2053         fi
2054         AC_SUBST(TK_INCLUDE)
2055         AC_SUBST(TK_LIBRARY)
2056         AC_SUBST(TK_DEPS)
2057         AC_SUBST(TK_XINCLUDES)
2058
2059         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2060
2061         # Include some libraries that Tcl and Tk want.
2062         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2063         # Yes, the ordering seems wrong here.  But it isn't.
2064         # TK_LIBS is the list of libraries that need to be linked
2065         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2066         # were in LIBS then any link tests after this point would
2067         # try to include things like `$(LIBGUI)', which wouldn't work.
2068         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2069
2070         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2071         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2072         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2073         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2074         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2075         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2076         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2077
2078         if test x$gdb_cv_os_cygwin = xyes; then
2079           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2080           WIN32LDAPP="-Wl,--subsystem,console"
2081           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2082         fi
2083
2084         AC_CONFIG_SUBDIRS(gdbtk)
2085     fi
2086 fi
2087
2088 AC_SUBST(X_CFLAGS)
2089 AC_SUBST(X_LDFLAGS)
2090 AC_SUBST(X_LIBS)
2091 AC_SUBST(GDBTKLIBS)
2092 AC_SUBST(GDBTK_CFLAGS)
2093 AC_SUBST(GDBTK_SRC_DIR)
2094
2095 AC_PATH_X
2096
2097 # Unlike the sim directory, whether a simulator is linked is controlled by
2098 # presence of a gdb_sim definition in the target configure.tgt entry.
2099 # This code just checks for a few cases where we'd like to ignore those
2100 # definitions, even when they're present in the '.mt' file.  These cases
2101 # are when --disable-sim is specified, or if the simulator directory is
2102 # not part of the source tree.
2103 #
2104 AC_ARG_ENABLE(sim,
2105 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2106 [echo "enable_sim = $enable_sim";
2107  echo "enableval = ${enableval}";
2108  case "${enableval}" in
2109   yes) ignore_sim=false ;;
2110   no)  ignore_sim=true ;;
2111   *)   ignore_sim=false ;;
2112  esac],
2113 [ignore_sim=false])
2114
2115 if test ! -d "${srcdir}/../sim"; then
2116   ignore_sim=true
2117 fi
2118
2119 SIM=
2120 SIM_OBS=
2121 if test "${ignore_sim}" = "false"; then
2122   if test x"${gdb_sim}" != x ; then
2123     SIM="${gdb_sim}"
2124     SIM_OBS="remote-sim.o"
2125     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2126   fi
2127 fi
2128 AC_SUBST(SIM)
2129 AC_SUBST(SIM_OBS)
2130
2131 AC_SUBST(ENABLE_CFLAGS)
2132 AC_SUBST(PROFILE_CFLAGS)
2133
2134 AC_SUBST(CONFIG_OBS)
2135 AC_SUBST(CONFIG_DEPS)
2136 AC_SUBST(CONFIG_SRCS)
2137 AC_SUBST(CONFIG_ALL)
2138 AC_SUBST(CONFIG_CLEAN)
2139 AC_SUBST(CONFIG_INSTALL)
2140 AC_SUBST(CONFIG_UNINSTALL)
2141
2142 # List of host floatformats.
2143 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2144 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2145 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2146
2147 # target_subdir is used by the testsuite to find the target libraries.
2148 target_subdir=
2149 if test "${host}" != "${target}"; then
2150     target_subdir="${target_alias}/"
2151 fi
2152 AC_SUBST(target_subdir)
2153
2154 frags=
2155 if test "${gdb_native}" = "yes"; then
2156   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2157   if test ! -f ${host_makefile_frag}; then
2158     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2159   fi
2160   frags="$frags $host_makefile_frag"
2161 else
2162   host_makefile_frag=/dev/null
2163 fi
2164
2165 AC_SUBST_FILE(host_makefile_frag)
2166 AC_SUBST(frags)
2167
2168 changequote(,)dnl
2169 if test "${gdb_native}" = "yes"; then
2170 # We pick this up from the host configuration file (.mh) because we
2171 # do not have a native configuration Makefile fragment.
2172 nativefile=`sed -n '
2173 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2174 ' ${host_makefile_frag}`
2175 fi
2176 changequote([,])
2177
2178 if test x"${gdb_osabi}" != x ; then
2179     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2180                        [Define to the default OS ABI for this configuration.])
2181 fi
2182
2183 # Enable multi-ice-gdb-server.
2184 AC_ARG_ENABLE(multi-ice,
2185 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2186   [case $enableval in
2187     yes | no)
2188       ;;
2189     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2190   esac])
2191 if test "x$enable_multi_ice" = xyes; then
2192    AC_CONFIG_SUBDIRS(multi-ice)
2193 fi
2194
2195 AC_ARG_ENABLE(gdbserver,
2196 AS_HELP_STRING([--enable-gdbserver],
2197                [automatically build gdbserver (yes/no/auto, default is auto)]),
2198 [case "${enableval}" in
2199   yes| no|auto) ;;
2200   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2201 esac],[enable_gdbserver=auto])
2202
2203 # We only build gdbserver automatically in a native configuration, and
2204 # only if the user did not explicitly disable its build.
2205 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2206   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2207   if test "x$build_gdbserver" = xyes; then
2208     AC_MSG_RESULT(yes)
2209     AC_CONFIG_SUBDIRS(gdbserver)
2210     gdbserver_build_enabled=yes
2211   else
2212     AC_MSG_RESULT(no)
2213   fi
2214 fi
2215
2216 # If the user explicitly request the gdbserver to be built, verify that
2217 # we were in fact able to enable it.
2218 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2219   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2220 fi
2221
2222 # Check for babeltrace and babeltrace-ctf
2223 AC_ARG_WITH(babeltrace,
2224   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2225   [], [with_babeltrace=auto])
2226 AC_MSG_CHECKING([whether to use babeltrace])
2227 AC_MSG_RESULT([$with_babeltrace])
2228
2229 if test "x$with_babeltrace" = "xno"; then
2230   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2231 else
2232   # Append -Werror to CFLAGS so that configure can catch the warning
2233   # "assignment from incompatible pointer type", which is related to
2234   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2235   # in GDB, while babeltrace 1.0.3 is broken.
2236   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2237   # safe to save and restore CFLAGS here.
2238   saved_CFLAGS=$CFLAGS
2239   CFLAGS="$CFLAGS -Werror"
2240   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2241                         [#include <babeltrace/babeltrace.h>
2242                          #include <babeltrace/ctf/events.h>
2243                          #include <babeltrace/ctf/iterator.h>],
2244                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2245                         struct bt_ctf_event *event = NULL;
2246                         const struct bt_definition *scope;
2247
2248                         scope = bt_ctf_get_top_level_scope (event,
2249                                                            BT_STREAM_EVENT_HEADER);
2250                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2251                         ])
2252   CFLAGS=$saved_CFLAGS
2253
2254   if test "$HAVE_LIBBABELTRACE" != yes; then
2255      if test "$with_babeltrace" = yes; then
2256        AC_MSG_ERROR([babeltrace is missing or unusable])
2257      else
2258        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2259      fi
2260   fi
2261 fi
2262
2263 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2264 # to an empty version.
2265
2266 files=
2267 links=
2268
2269 rm -f nm.h
2270 if test "${nativefile}" != ""; then
2271     case "${nativefile}" in
2272       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2273       * ) GDB_NM_FILE="${nativefile}"
2274     esac
2275     files="${files} ${GDB_NM_FILE}"
2276     links="${links} nm.h"
2277     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2278 fi
2279 AC_SUBST(GDB_NM_FILE)
2280
2281 AC_LINK_FILES($files, $links)
2282
2283 dnl Check for exe extension set on certain hosts (e.g. Win32)
2284 AC_EXEEXT
2285
2286 dnl  Detect the character set used by this host.
2287 dnl  At the moment, we just assume it's UTF-8.
2288 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2289           [Define to be a string naming the default host character set.])
2290
2291 # Undo the $ec_script escaping suitable for Makefile.
2292 transform=`echo "$program_transform_name" | sed -e 's/[\\$][\\$]/\\$/g'`
2293 GDB_TRANSFORM_NAME=`echo gdb | sed -e "$transform"`
2294 if test "x$GDB_TRANSFORM_NAME" = x; then
2295   GDB_TRANSFORM_NAME=gdb
2296 fi
2297 AC_SUBST(GDB_TRANSFORM_NAME)
2298 GCORE_TRANSFORM_NAME=`echo gcore | sed -e "$transform"`
2299 if test "x$GCORE_TRANSFORM_NAME" = x; then
2300   GCORE_TRANSFORM_NAME=gcore
2301 fi
2302 AC_SUBST(GCORE_TRANSFORM_NAME)
2303 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2304
2305 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2306 [
2307 case x$CONFIG_HEADERS in
2308 xconfig.h:config.in)
2309 echo > stamp-h ;;
2310 esac
2311 ])
2312
2313 exit 0