gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2019 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_INIT(main.c)
  22 AC_CONFIG_HEADER(config.h:config.in)
  23 AM_MAINTAINER_MODE
  24
  25 # Set the 'development' global.
  26 . $srcdir/../bfd/development.sh
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30
  31 AC_USE_SYSTEM_EXTENSIONS
  32 ACX_LARGEFILE
  33 AM_PROG_CC_STDC
  34 AM_PROG_INSTALL_STRIP
  35
  36 AC_CONFIG_AUX_DIR(..)
  37 AC_CANONICAL_SYSTEM
  38 AC_ARG_PROGRAM
  39
  40 # We require a C++11 compiler.  Check if one is available, and if
  41 # necessary, set CXX_DIALECT to some -std=xxx switch.
  42 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  43
  44 # Dependency checking.
  45 ZW_CREATE_DEPDIR
  46 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  47
  48 gnulib_extra_configure_args=
  49 # If large-file support is disabled, make sure gnulib does the same.
  50 if test "$enable_largefile" = no; then
  51 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  52 fi
  53
  54 # Configure gnulib.  We need to build gnulib under some other
  55 # directory not "gnulib", to avoid the problem of both GDB and
  56 # GDBserver wanting to build it in the same directory, when building
  57 # in the source dir.
  58 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"],
  59                   ["$gnulib_extra_configure_args"])
  60
  61 dnl List of object files and targets accumulated by configure.
  62
  63 CONFIG_OBS=
  64 CONFIG_DEPS=
  65 CONFIG_SRCS=
  66 ENABLE_CFLAGS=
  67
  68 CONFIG_ALL=
  69 CONFIG_CLEAN=
  70 CONFIG_INSTALL=
  71 CONFIG_UNINSTALL=
  72
  73 dnl Set up for gettext.
  74 ZW_GNU_GETTEXT_SISTER_DIR
  75
  76 localedir='${datadir}/locale'
  77 AC_SUBST(localedir)
  78
  79 if test x"$USE_NLS" = xyes; then
  80    CONFIG_ALL="$CONFIG_ALL all-po"
  81    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  82    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  83    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  84 fi
  85
  86 GNULIB=build-gnulib/import
  87
  88 # For Makefile dependencies.
  89 GNULIB_STDINT_H=
  90 if test x"$STDINT_H" != x; then
  91   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  92 fi
  93 AC_SUBST(GNULIB_STDINT_H)
  94
  95 PACKAGE=gdb
  96 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  97 AC_SUBST(PACKAGE)
  98
  99 # We never need to detect it in this sub-configure.
 100 # But preserve it for config.status --recheck.
 101 AC_ARG_VAR(MAKEINFO,
 102   [Parent configure detects if it is of sufficient version.])
 103 AC_ARG_VAR(MAKEINFOFLAGS,
 104   [Parameters for MAKEINFO.])
 105
 106 MAKEINFO_EXTRA_FLAGS=""
 107 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 108   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 109   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 110     gdb_cv_have_makeinfo_click=yes
 111   else
 112     gdb_cv_have_makeinfo_click=no
 113   fi])
 114 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 115   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 116 fi
 117 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 118
 119 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 120     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 121     [${libdir}/debug])
 122
 123 # We can't pass paths as command line arguments.
 124 # Mingw32 tries to be clever and will convert the paths for us.
 125 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 126 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 127 # This breaks GDB's relocatable path conversions since paths passed in
 128 # config.h would not get so translated, the path prefixes no longer match.
 129 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 130
 131 # GDB's datadir relocation
 132
 133 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 134     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 135     [${datadir}/gdb])
 136
 137 AC_ARG_WITH(relocated-sources,
 138 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 139 [reloc_srcdir="${withval}"
 140  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 141               [Relocated directory for source files. ])
 142 ])
 143
 144 AC_MSG_CHECKING([for default auto-load directory])
 145 AC_ARG_WITH(auto-load-dir,
 146 AS_HELP_STRING([--with-auto-load-dir=PATH],
 147   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 148   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 149 escape_dir=`echo $with_auto_load_dir | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 150 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 151               [Directories from which to load auto-loaded scripts.])
 152 AC_MSG_RESULT([$with_auto_load_dir])
 153
 154 AC_MSG_CHECKING([for default auto-load safe-path])
 155 AC_ARG_WITH(auto-load-safe-path,
 156 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 157   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 158 AS_HELP_STRING([--without-auto-load-safe-path],
 159                [do not restrict auto-loaded files locations]),
 160     [if test "$with_auto_load_safe_path" = "no"; then
 161      with_auto_load_safe_path="/"
 162      fi],
 163 [with_auto_load_safe_path="$with_auto_load_dir"])
 164 escape_dir=`echo $with_auto_load_safe_path | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 165 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 166               [Directories safe to hold auto-loaded files.])
 167 AC_MSG_RESULT([$with_auto_load_safe_path])
 168
 169 AC_CONFIG_SUBDIRS(testsuite)
 170
 171 # Check whether to support alternative target configurations
 172 AC_ARG_ENABLE(targets,
 173 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 174 [case "${enableval}" in
 175   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 176             ;;
 177   no)       enable_targets= ;;
 178   *)        enable_targets=$enableval ;;
 179 esac])
 180
 181 # Check whether to enable 64-bit support on 32-bit hosts
 182 AC_ARG_ENABLE(64-bit-bfd,
 183 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 184 [case "${enableval}" in
 185   yes)  want64=true  ;;
 186   no)   want64=false ;;
 187   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 188 esac],[want64=false])dnl
 189
 190 # Provide defaults for some variables set by the per-host and per-target
 191 # configuration.
 192 gdb_host_obs=posix-hdep.o
 193
 194 if test "${target}" = "${host}"; then
 195   gdb_native=yes
 196 else
 197   gdb_native=no
 198 fi
 199
 200 . $srcdir/configure.host
 201
 202 # Add in the common host objects.
 203 . $srcdir/common/common.host
 204 gdb_host_obs="$gdb_host_obs $common_host_obs"
 205
 206 # Accumulate some settings from configure.tgt over all enabled targets
 207
 208 TARGET_OBS=
 209 all_targets=
 210 HAVE_NATIVE_GCORE_TARGET=
 211
 212 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 213 do
 214   if test "$targ_alias" = "all"; then
 215     all_targets=true
 216   else
 217     # Canonicalize the secondary target names.
 218     result=`$ac_config_sub $targ_alias 2>/dev/null`
 219     if test -n "$result"; then
 220         targ=$result
 221     else
 222         targ=$targ_alias
 223     fi
 224
 225     . ${srcdir}/configure.tgt
 226
 227     AS_IF([test -z "${gdb_target_obs}"],
 228       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 229
 230     # Target-specific object files
 231     for i in ${gdb_target_obs}; do
 232         case " $TARGET_OBS " in
 233         *" ${i} "*) ;;
 234         *)
 235           TARGET_OBS="$TARGET_OBS ${i}"
 236           ;;
 237         esac
 238     done
 239
 240     # Check whether this target needs 64-bit CORE_ADDR
 241     if test x${want64} = xfalse; then
 242       . ${srcdir}/../bfd/config.bfd
 243     fi
 244
 245     # Check whether this target is native and supports gcore.
 246     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 247        && $gdb_have_gcore; then
 248       HAVE_NATIVE_GCORE_TARGET=1
 249     fi
 250   fi
 251 done
 252
 253 if test x${all_targets} = xtrue; then
 254
 255   # We want all 64-bit targets if we either:
 256   #  - run on a 64-bit host  or
 257   #  - already require 64-bit support for some other target  or
 258   #  - the --enable-64-bit-bfd option was supplied
 259   # Otherwise we only support all 32-bit targets.
 260   #
 261   # NOTE: This test must be in sync with the corresponding
 262   #       tests in BFD!
 263
 264   if test x${want64} = xfalse; then
 265     AC_CHECK_SIZEOF(long)
 266     if test "x${ac_cv_sizeof_long}" = "x8"; then
 267       want64=true
 268     fi
 269   fi
 270   if test x${want64} = xtrue; then
 271     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 272   else
 273     TARGET_OBS='$(ALL_TARGET_OBS)'
 274   fi
 275 fi
 276
 277 AC_SUBST(TARGET_OBS)
 278 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 279
 280 # For other settings, only the main target counts.
 281 gdb_sim=
 282 gdb_osabi=
 283 build_gdbserver=
 284 targ=$target; . ${srcdir}/configure.tgt
 285
 286 # Fetch the default architecture and default target vector from BFD.
 287 targ=$target; . $srcdir/../bfd/config.bfd
 288
 289 # We only want the first architecture, so strip off the others if
 290 # there is more than one.
 291 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 292
 293 if test "x$targ_archs" != x; then
 294   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 295     [Define to BFD's default architecture. ])
 296 fi
 297 if test "x$targ_defvec" != x; then
 298   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 299     [Define to BFD's default target vector. ])
 300 fi
 301
 302 # Enable MI.
 303 AC_ARG_ENABLE(gdbmi,
 304 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 305   [case $enableval in
 306     yes | no)
 307       ;;
 308     *)
 309       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 310   esac],
 311   [enable_gdbmi=yes])
 312 if test x"$enable_gdbmi" = xyes; then
 313   if test -d $srcdir/mi; then
 314     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 315     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 316     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 317     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 318   fi
 319 fi
 320
 321 # Enable TUI.
 322 AC_ARG_ENABLE(tui,
 323 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 324   [case $enableval in
 325     yes | no | auto)
 326       ;;
 327     *)
 328       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 329   esac],enable_tui=auto)
 330
 331 # Enable gdbtk.
 332 AC_ARG_ENABLE(gdbtk,
 333 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 334   [case $enableval in
 335     yes | no)
 336       ;;
 337     *)
 338       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 339   esac],
 340   [if test -d $srcdir/gdbtk; then
 341     enable_gdbtk=yes
 342   else
 343     enable_gdbtk=no
 344   fi])
 345 # We unconditionally disable gdbtk tests on selected platforms.
 346 case $host_os in
 347   go32* | windows*)
 348     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 349     enable_gdbtk=no ;;
 350 esac
 351
 352 # Libunwind support for ia64.
 353
 354 AC_ARG_WITH(libunwind-ia64,
 355 AS_HELP_STRING([--with-libunwind-ia64],
 356                [use libunwind frame unwinding for ia64 targets]),,
 357             [with_libunwind_ia64=auto])
 358
 359 # Backward compatibility option.
 360 if test "${with_libunwind+set}" = set; then
 361   if test x"$with_libunwind_ia64" != xauto; then
 362     AC_MSG_ERROR(
 363       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 364   fi
 365   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 366   with_libunwind_ia64="$with_libunwind"
 367 fi
 368
 369 case "$with_libunwind_ia64" in
 370   yes | no)
 371     ;;
 372   auto)
 373     AC_CHECK_HEADERS(libunwind-ia64.h)
 374     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 375     ;;
 376   *)
 377     AC_MSG_ERROR(
 378       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 379     ;;
 380 esac
 381
 382 if test x"$with_libunwind_ia64" = xyes; then
 383   AC_CHECK_HEADERS(libunwind-ia64.h)
 384   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 385     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 386   fi
 387   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 388   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 389   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 390 fi
 391
 392 opt_curses=no
 393 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 394
 395 prefer_curses=no
 396 if test "$opt_curses" = "yes"; then
 397   prefer_curses=yes
 398 fi
 399
 400 # Profiling support.
 401 AC_ARG_ENABLE(profiling,
 402 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 403   [case $enableval in
 404     yes | no)
 405       ;;
 406     *)
 407       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 408   esac],
 409  [enable_profiling=no])
 410
 411 AC_CHECK_FUNCS(monstartup _mcleanup)
 412 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 413 [AC_TRY_LINK(
 414 [#include <stdlib.h>
 415 extern char _etext;
 416 ],
 417 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 418 if test $ac_cv_var__etext = yes; then
 419   AC_DEFINE(HAVE__ETEXT, 1,
 420             [Define to 1 if your system has the _etext variable. ])
 421 fi
 422 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 423 [AC_TRY_LINK(
 424 [#include <stdlib.h>
 425 extern char etext;
 426 ],
 427 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 428 if test $ac_cv_var_etext = yes; then
 429   AC_DEFINE(HAVE_ETEXT, 1,
 430             [Define to 1 if your system has the etext variable. ])
 431 fi
 432 if test "$enable_profiling" = yes ; then
 433   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 434     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 435   fi
 436   PROFILE_CFLAGS=-pg
 437   OLD_CFLAGS="$CFLAGS"
 438   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 439
 440   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 441     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 442      ac_cv_cc_supports_pg=no)])
 443
 444   if test $ac_cv_cc_supports_pg = no; then
 445     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 446   fi
 447
 448   CFLAGS="$OLD_CFLAGS"
 449 fi
 450
 451 CODESIGN_CERT=
 452 AC_ARG_ENABLE([codesign],
 453   AS_HELP_STRING([--enable-codesign=CERT],
 454                  [sign gdb with 'codesign -s CERT']),
 455   [CODESIGN_CERT=$enableval])
 456 AC_SUBST([CODESIGN_CERT])
 457
 458 ACX_PKGVERSION([GDB])
 459 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 460 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 461 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 462
 463 # --------------------- #
 464 # Checks for programs.  #
 465 # --------------------- #
 466
 467 AC_PROG_AWK
 468 AC_PROG_INSTALL
 469 AC_PROG_LN_S
 470 AC_PROG_RANLIB
 471 AC_PROG_YACC
 472
 473 AC_CHECK_TOOL(AR, ar)
 474 AC_CHECK_TOOL(DLLTOOL, dlltool)
 475 AC_CHECK_TOOL(WINDRES, windres)
 476
 477 case $host_os in
 478   gnu*)
 479     # Needed for GNU Hurd hosts.
 480     AC_CHECK_TOOL(MIG, mig)
 481     if test x"$MIG" = x; then
 482       AC_MSG_ERROR([MIG not found but required for $host hosts])
 483     fi
 484     ;;
 485 esac
 486
 487 # ---------------------- #
 488 # Checks for libraries.  #
 489 # ---------------------- #
 490
 491 # We might need to link with -lm; most simulators need it.
 492 AC_CHECK_LIB(m, main)
 493
 494 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 495 AC_SEARCH_LIBS(gethostbyname, nsl)
 496
 497 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 498 AC_SEARCH_LIBS(socketpair, socket)
 499
 500 # Link in zlib if we can.  This allows us to read compressed debug sections.
 501 AM_ZLIB
 502
 503 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 504 # On GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd.
 505 AC_SEARCH_LIBS(kinfo_getvmmap, util util-freebsd,
 506   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 507             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 508
 509 # fbsd-nat.c can also use kinfo_getfile.
 510 AC_SEARCH_LIBS(kinfo_getfile, util util-freebsd,
 511   [AC_DEFINE(HAVE_KINFO_GETFILE, 1,
 512             [Define to 1 if your system has the kinfo_getfile function. ])])
 513
 514 AM_ICONV
 515
 516 # GDB may fork/exec the iconv program to get the list of supported character
 517 # sets.  Allow the user to specify where to find it.
 518 # There are several factors affecting the choice of option name:
 519 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 520 #   the build-time location of libiconv files.
 521 # - The program we need to find is iconv, which comes with glibc.  The user
 522 #   doesn't necessarily have libiconv installed.  Therefore naming this
 523 #   --with-libiconv-foo feels wrong.
 524 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 525 #   defined to work on directories not files (though it really doesn't know
 526 #   the difference).
 527 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 528 #   with --with-libiconv-prefix.
 529 # Putting these together is why the option name is --with-iconv-bin.
 530
 531 AC_ARG_WITH(iconv-bin,
 532 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 533 [iconv_bin="${withval}"
 534  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 535                     [Path of directory of iconv program.])
 536  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 537 ])
 538
 539 # For the TUI, we need enhanced curses functionality.
 540 if test x"$enable_tui" != xno; then
 541   prefer_curses=yes
 542 fi
 543
 544 curses_found=no
 545 if test x"$prefer_curses" = xyes; then
 546   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 547   # curses library because the latter might not provide all the
 548   # functionality we need.  However, this leads to problems on systems
 549   # where the linker searches /usr/local/lib, but the compiler doesn't
 550   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 551   # default installation of ncurses on alpha*-dec-osf* will lead to such
 552   # a situation.
 553   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 554
 555   if test "$ac_cv_search_waddstr" != no; then
 556     curses_found=yes
 557   fi
 558 fi
 559
 560 # Check whether we should enable the TUI, but only do so if we really
 561 # can.
 562 if test x"$enable_tui" != xno; then
 563   if test -d $srcdir/tui; then
 564     if test "$curses_found" != no; then
 565       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 566       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 567       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 568       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 569     else
 570       if test x"$enable_tui" = xyes; then
 571         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 572       else
 573         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 574       fi
 575     fi
 576   fi
 577 fi
 578
 579 # Since GDB uses Readline, we need termcap functionality.  In many
 580 # cases this will be provided by the curses library, but some systems
 581 # have a separate termcap library, or no curses library at all.
 582
 583 case $host_os in
 584   cygwin*)
 585     if test -d $srcdir/libtermcap; then
 586       LIBS="../libtermcap/libtermcap.a $LIBS"
 587       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 588     fi ;;
 589   go32* | *djgpp*)
 590     ac_cv_search_tgetent="none required"
 591     ;;
 592 esac
 593
 594 # These are the libraries checked by Readline.
 595 AC_SEARCH_LIBS(tgetent, [termcap tinfow tinfo curses ncursesw ncurses])
 596
 597 if test "$ac_cv_search_tgetent" = no; then
 598   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 599 fi
 600
 601 AC_ARG_WITH([system-readline],
 602   [AS_HELP_STRING([--with-system-readline],
 603                   [use installed readline library])])
 604
 605 if test "$with_system_readline" = yes; then
 606   READLINE=-lreadline
 607   READLINE_DEPS=
 608   READLINE_CFLAGS=
 609   READLINE_TEXI_INCFLAG=
 610 else
 611   READLINE='$(READLINE_DIR)/libreadline.a'
 612   READLINE_DEPS='$(READLINE)'
 613   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 614   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 615 fi
 616 AC_SUBST(READLINE)
 617 AC_SUBST(READLINE_DEPS)
 618 AC_SUBST(READLINE_CFLAGS)
 619 AC_SUBST(READLINE_TEXI_INCFLAG)
 620
 621 # Generate jit-reader.h
 622
 623 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 624 TARGET_PTR=
 625
 626 AC_CHECK_SIZEOF(unsigned long long)
 627 AC_CHECK_SIZEOF(unsigned long)
 628 AC_CHECK_SIZEOF(unsigned __int128)
 629
 630 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 631   TARGET_PTR="unsigned long"
 632 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 633   TARGET_PTR="unsigned long long"
 634 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 635   TARGET_PTR="unsigned __int128"
 636 else
 637   TARGET_PTR="unsigned long"
 638 fi
 639
 640 AC_SUBST(TARGET_PTR)
 641 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 642
 643 AC_SEARCH_LIBS(dlopen, dl)
 644
 645 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 646                 [directory to load the JIT readers from],
 647                 [${libdir}/gdb])
 648
 649 AC_ARG_WITH(expat,
 650   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 651   [], [with_expat=auto])
 652 AC_MSG_CHECKING([whether to use expat])
 653 AC_MSG_RESULT([$with_expat])
 654
 655 if test "${with_expat}" = no; then
 656   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 657   HAVE_LIBEXPAT=no
 658 else
 659   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 660                         [XML_Parser p = XML_ParserCreate (0);])
 661   if test "$HAVE_LIBEXPAT" != yes; then
 662     if test "$with_expat" = yes; then
 663       AC_MSG_ERROR([expat is missing or unusable])
 664     else
 665       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 666     fi
 667   else
 668     save_LIBS=$LIBS
 669     LIBS="$LIBS $LIBEXPAT"
 670     AC_CHECK_FUNCS(XML_StopParser)
 671     LIBS=$save_LIBS
 672   fi
 673 fi
 674
 675 AC_ARG_WITH(mpfr,
 676   AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]),
 677   [], [with_mpfr=auto])
 678 AC_MSG_CHECKING([whether to use MPFR])
 679 AC_MSG_RESULT([$with_mpfr])
 680
 681 if test "${with_mpfr}" = no; then
 682   AC_MSG_WARN([MPFR support disabled; some features may be unavailable.])
 683   HAVE_LIBMPFR=no
 684 else
 685   AC_LIB_HAVE_LINKFLAGS([mpfr], [gmp], [#include <mpfr.h>],
 686                         [mpfr_exp_t exp; mpfr_t x;
 687                          mpfr_frexp (&exp, x, x, MPFR_RNDN);])
 688   if test "$HAVE_LIBMPFR" != yes; then
 689     if test "$with_mpfr" = yes; then
 690       AC_MSG_ERROR([MPFR is missing or unusable])
 691     else
 692       AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.])
 693     fi
 694   fi
 695 fi
 696
 697 # --------------------- #
 698 # Check for libpython.  #
 699 # --------------------- #
 700
 701 dnl Utility to simplify finding libpython.
 702 dnl $1 = pythonX.Y
 703 dnl $2 = the shell variable to assign the result to
 704 dnl      If libpython is found we store $version here.
 705 dnl $3 = additional flags to add to CPPFLAGS
 706 dnl $4 = additional flags to add to LIBS
 707
 708 AC_DEFUN([AC_TRY_LIBPYTHON],
 709 [
 710   version=$1
 711   define([have_libpython_var],$2)
 712   new_CPPFLAGS=$3
 713   new_LIBS=$4
 714   AC_MSG_CHECKING([for ${version}])
 715   save_CPPFLAGS=$CPPFLAGS
 716   save_LIBS=$LIBS
 717   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 718   LIBS="$new_LIBS $LIBS"
 719   found_usable_python=no
 720   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "Python.h"]],
 721                                  [[Py_Initialize ();]])],
 722                  [have_libpython_var=${version}
 723                   found_usable_python=yes
 724                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 725                   PYTHON_LIBS=$new_LIBS])
 726   CPPFLAGS=$save_CPPFLAGS
 727   LIBS=$save_LIBS
 728   AC_MSG_RESULT([${found_usable_python}])
 729 ])
 730
 731 dnl There are several different values for --with-python:
 732 dnl
 733 dnl no -   Don't include python support.
 734 dnl yes -  Include python support, error if it's missing.
 735 dnl        If we find python in $PATH, use it to fetch configure options,
 736 dnl        otherwise assume the compiler can find it with no help from us.
 737 dnl        Python 2.7 and 2.6 are tried in turn.
 738 dnl auto - Same as "yes", but if python is missing from the system,
 739 dnl        fall back to "no".
 740 dnl /path/to/python/exec-prefix -
 741 dnl        Use the python located in this directory.
 742 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 743 dnl        the compilation parameters.  Otherwise use
 744 dnl        -I/path/to/python/exec-prefix/include,
 745 dnl        -L/path/to/python/exec-prefix/lib.
 746 dnl        Python 2.7 and 2.6 are tried in turn.
 747 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 748 dnl        but is deprecated.
 749 dnl /path/to/python/executable -
 750 dnl        Run python-config.py with this version of python to fetch the
 751 dnl        compilation parameters.
 752 dnl        NOTE: This needn't be the real python executable.
 753 dnl        In a cross-compilation scenario (build != host), this could be
 754 dnl        a shell script that provides what python-config.py provides for
 755 dnl        --ldflags, --includes, --exec-prefix.
 756 dnl python-executable -
 757 dnl        Find python-executable in $PATH, and then handle the same as
 758 dnl        /path/to/python/executable.
 759 dnl
 760 dnl If a python program is specified, it is used to run python-config.py and
 761 dnl is passed --ldflags, --includes, --exec-prefix.
 762
 763 AC_ARG_WITH(python,
 764   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 765   [], [with_python=auto])
 766 AC_MSG_CHECKING([whether to use python])
 767 AC_MSG_RESULT([$with_python])
 768
 769 if test "${with_python}" = no; then
 770   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 771   have_libpython=no
 772 else
 773   case "${with_python}" in
 774   [[\\/]]* | ?:[[\\/]]*)
 775     if test -d ${with_python}; then
 776       # Assume the python binary is ${with_python}/bin/python.
 777       python_prog="${with_python}/bin/python"
 778       python_prefix=
 779       # If python does not exit ${with_python}/bin, then try in
 780       # ${with_python}.  On Windows/MinGW, this is where the Python
 781       # executable is.
 782       if test ! -x "${python_prog}"; then
 783         python_prog="${with_python}/python"
 784         python_prefix=
 785       fi
 786       if test ! -x "${python_prog}"; then
 787         # Fall back to gdb 7.0/7.1 behaviour.
 788         python_prog=missing
 789         python_prefix=${with_python}
 790       fi
 791     elif test -x "${with_python}"; then
 792       # While we can't run python compiled for $host (unless host == build),
 793       # the user could write a script that provides the needed information,
 794       # so we support that.
 795       python_prog=${with_python}
 796       python_prefix=
 797     else
 798       AC_ERROR(invalid value for --with-python)
 799     fi
 800     ;;
 801   */*)
 802     # Disallow --with-python=foo/bar.
 803     AC_ERROR(invalid value for --with-python)
 804     ;;
 805   *)
 806     # The user has either specified auto, yes, or the name of the python
 807     # program assumed to be in $PATH.
 808     python_prefix=
 809     case "${with_python}" in
 810     yes | auto)
 811       if test ${build} = ${host}; then
 812         AC_PATH_PROG(python_prog_path, python, missing)
 813         if test "${python_prog_path}" = missing; then
 814           python_prog=missing
 815         else
 816           python_prog=${python_prog_path}
 817         fi
 818       else
 819         # Not much we can do except assume the cross-compiler will find the
 820         # right files.
 821         python_prog=missing
 822       fi
 823       ;;
 824     *)
 825       # While we can't run python compiled for $host (unless host == build),
 826       # the user could write a script that provides the needed information,
 827       # so we support that.
 828       python_prog="${with_python}"
 829       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 830       if test "${python_prog_path}" = missing; then
 831         AC_ERROR(unable to find python program ${python_prog})
 832       fi
 833       ;;
 834     esac
 835   esac
 836
 837   if test "${python_prog}" != missing; then
 838     # We have a python program to use, but it may be too old.
 839     # Don't flag an error for --with-python=auto (the default).
 840     have_python_config=yes
 841     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 842     if test $? != 0; then
 843       have_python_config=failed
 844       if test "${with_python}" != auto; then
 845         AC_ERROR(failure running python-config --includes)
 846       fi
 847     fi
 848     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 849     if test $? != 0; then
 850       have_python_config=failed
 851       if test "${with_python}" != auto; then
 852         AC_ERROR(failure running python-config --ldflags)
 853       fi
 854     fi
 855     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 856     if test $? != 0; then
 857       have_python_config=failed
 858       if test "${with_python}" != auto; then
 859         AC_ERROR(failure running python-config --exec-prefix)
 860       fi
 861     fi
 862   else
 863     # We do not have a python executable we can use to determine where
 864     # to find the Python headers and libs.  We cannot guess the include
 865     # path from the python_prefix either, because that include path
 866     # depends on the Python version.  So, there is nothing much we can
 867     # do except assume that the compiler will be able to find those files.
 868     python_includes=
 869     python_libs=
 870     have_python_config=no
 871   fi
 872
 873   # If we have python-config, only try the configuration it provides.
 874   # Otherwise fallback on the old way of trying different versions of
 875   # python in turn.
 876
 877   have_libpython=no
 878   if test "${have_python_config}" = yes; then
 879     # Determine the Python version by extracting "-lpython<version>"
 880     # part of the python_libs. <version> is usually X.Y with X and Y
 881     # being decimal numbers, but can also be XY (seen on Windows).
 882     #
 883     # The extraction is performed using sed with a regular expression.
 884     # Initially, the regexp used was using the '?' quantifier to make
 885     # the dot in the version number optional.  Unfortunately, this
 886     # does not work with non-GNU versions of sed because, because of
 887     # what looks like a limitation (the '?' quantifier does not work
 888     # with back-references).  We work around this limitation by using
 889     # the '*' quantifier instead.  It means that, in theory, we might
 890     # match unexpected version strings such as "-lpython2..7", but
 891     # this seems unlikely in practice.  And even if that happens,
 892     # an error will be triggered later on, when checking that version
 893     # number.
 894     python_version=`echo " ${python_libs} " \
 895                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 896     case "${python_version}" in
 897     python*)
 898       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 899                        ${python_includes}, ${python_libs})
 900       ;;
 901     *)
 902       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 903       ;;
 904     esac
 905   elif test "${have_python_config}" != failed; then
 906     if test "${have_libpython}" = no; then
 907       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 908                        ${python_includes}, "-lpython2.7 ${python_libs}")
 909     fi
 910     if test "${have_libpython}" = no; then
 911       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 912                        ${python_includes}, "-lpython2.6 ${python_libs}")
 913     fi
 914   fi
 915   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 916     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 917   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 918     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 919   fi
 920
 921   if test "${have_libpython}" = no; then
 922     case "${with_python}" in
 923     yes)
 924       AC_MSG_ERROR([python is missing or unusable])
 925       ;;
 926     auto)
 927       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 928       ;;
 929     *)
 930       AC_MSG_ERROR([no usable python found at ${with_python}])
 931       ;;
 932     esac
 933   else
 934     if test -n "${python_prefix}"; then
 935       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 936                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 937       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 938     fi
 939   fi
 940 fi
 941
 942 if test "${have_libpython}" != no; then
 943   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 944   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 945   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 946   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 947   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 948   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 949
 950   # Flags needed to compile Python code (taken from python-config --cflags).
 951   # We cannot call python-config directly because it will output whatever was
 952   # used when compiling the Python interpreter itself, including flags which
 953   # would make the python-related objects be compiled differently from the
 954   # rest of GDB (e.g., -O2 and -fPIC).
 955   if test "${GCC}" = yes; then
 956     tentative_python_cflags="-fno-strict-aliasing -fwrapv"
 957     # Python headers recommend -DNDEBUG, but it's unclear if that just
 958     # refers to building Python itself.  In release mode, though, it
 959     # doesn't hurt for the Python code in gdb to follow.
 960     $development || tentative_python_cflags="$tentative_python_cflags -DNDEBUG"
 961   fi
 962
 963   if test "x${tentative_python_cflags}" != x; then
 964     AC_MSG_CHECKING(compiler flags for python code)
 965     for flag in ${tentative_python_cflags}; do
 966       # Check that the compiler accepts it
 967       saved_CFLAGS="$CFLAGS"
 968       CFLAGS="$CFLAGS $flag"
 969       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 970       CFLAGS="$saved_CFLAGS"
 971     done
 972     AC_MSG_RESULT(${PYTHON_CFLAGS})
 973   fi
 974
 975   # On x64 Windows, Python's include headers, and pyconfig.h in
 976   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 977   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 978   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 979   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 980   # The issue was reported to the Python community, but still isn't
 981   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 982
 983   case "$gdb_host" in
 984     mingw64)
 985            if test "${GCC}" = yes; then
 986              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
 987            fi
 988            ;;
 989   esac
 990
 991   # Note that "python -m threading" cannot be used to check for
 992   # threading support due to a bug in Python 2.7.3
 993   # (http://bugs.python.org/issue15567).
 994   AC_MSG_CHECKING(whether python supports threads)
 995   saved_CPPFLAGS="${CPPFLAGS}"
 996   CPPFLAGS="${PYTHON_CPPFLAGS}"
 997   # Note that the test is reversed so that python_has_threads=yes on
 998   # unexpected failures.
 999   AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
1000 #include <Python.h>
1001 #ifdef WITH_THREAD
1002 # error
1003 #endif
1004   ]])], [python_has_threads=no], [python_has_threads=yes])
1005   AC_MSG_RESULT(${python_has_threads})
1006   CPPFLAGS="${saved_CPPFLAGS}"
1007 else
1008   # Even if Python support is not compiled in, we need to have this file
1009   # included so that the "python" command, et.al., still exists.
1010   CONFIG_OBS="$CONFIG_OBS python/python.o"
1011   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1012 fi
1013
1014 # Work around Python http://bugs.python.org/issue10112.  See also
1015 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
1016 # no effect.  Note that the only test after this that uses Python is
1017 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
1018 # run without -export-dynamic too.
1019 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
1020
1021 AC_SUBST(PYTHON_CFLAGS)
1022 AC_SUBST(PYTHON_CPPFLAGS)
1023 AC_SUBST(PYTHON_LIBS)
1024 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1025
1026 # -------------------- #
1027 # Check for libguile.  #
1028 # -------------------- #
1029
1030 dnl Utility to simplify finding libguile.
1031 dnl $1 = pkg-config-program
1032 dnl $2 = space-separate list of guile versions to try
1033 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1034 dnl $4 = the shell variable to assign the result to
1035 dnl      If libguile is found we store "yes" here.
1036
1037 AC_DEFUN([AC_TRY_LIBGUILE],
1038 [
1039   pkg_config=$1
1040   guile_version_list=$2
1041   flag_errors=$3
1042   define([have_libguile_var],$4)
1043   found_usable_guile=checking
1044   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1045   for guile_version in ${guile_version_list}; do
1046     ${pkg_config} --exists ${guile_version} 2>/dev/null
1047     if test $? != 0; then
1048       continue
1049     fi
1050     dnl pkg-config says the package exists, so if we get an error now,
1051     dnl that's bad.
1052     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1053     if test $? != 0; then
1054       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1055     fi
1056     new_LIBS=`${pkg_config} --libs ${guile_version}`
1057     if test $? != 0; then
1058       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1059     fi
1060     dnl If we get this far, great.
1061     found_usable_guile=${guile_version}
1062     break
1063   done
1064   if test "${found_usable_guile}" = "checking"; then
1065     if test "${flag_errors}" = "yes"; then
1066       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1067     else
1068       found_usable_guile=no
1069     fi
1070   fi
1071   dnl One final sanity check.
1072   dnl The user could have said --with-guile=python-2.7.
1073   if test "${found_usable_guile}" != no; then
1074     save_CPPFLAGS=$CPPFLAGS
1075     save_LIBS=$LIBS
1076     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1077     LIBS="$LIBS $new_LIBS"
1078     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "libguile.h"]],
1079                                    [[scm_init_guile ();]])],
1080                    [have_libguile_var=yes
1081                     GUILE_CPPFLAGS=$new_CPPFLAGS
1082                     GUILE_LIBS=$new_LIBS],
1083                    [found_usable_guile=no])
1084     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1085     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1086       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1087                 [Define if Guile supports manual finalization.])
1088     )
1089     CPPFLAGS=$save_CPPFLAGS
1090     LIBS=$save_LIBS
1091     if test "${found_usable_guile}" = no; then
1092       if test "${flag_errors}" = yes; then
1093         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1094       fi
1095     fi
1096   fi
1097   AC_MSG_RESULT([${found_usable_guile}])
1098 ])
1099
1100 dnl There are several different values for --with-guile:
1101 dnl
1102 dnl no -   Don't include guile support.
1103 dnl yes -  Include guile support, error if it's missing.
1104 dnl        The pkg-config program must be in $PATH.
1105 dnl auto - Same as "yes", but if guile is missing from the system,
1106 dnl        fall back to "no".
1107 dnl guile-version [guile-version-choice-2 ...] -
1108 dnl        A space-separated list of guile package versions to try.
1109 dnl        These are passed to pkg-config as-is.
1110 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1111 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1112 dnl /path/to/pkg-config -
1113 dnl        Use this pkg-config program.
1114 dnl        NOTE: This needn't be the "real" pkg-config program.
1115 dnl        It could be a shell script.  It is invoked as:
1116 dnl        pkg-config --exists $version
1117 dnl        pkg-config --cflags $version
1118 dnl        pkg-config --libs $version
1119 dnl        pkg-config --variable guild $version
1120 dnl        The script will be called with $version having each value in
1121 dnl        $try_guile_versions until --exists indicates success.
1122
1123 AC_ARG_WITH(guile,
1124   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1125   [], [with_guile=auto])
1126 AC_MSG_CHECKING([whether to use guile])
1127 AC_MSG_RESULT([$with_guile])
1128
1129 dnl We check guile with pkg-config.
1130 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1131
1132 try_guile_versions="guile-2.0"
1133 have_libguile=no
1134 case "${with_guile}" in
1135 no)
1136   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1137   ;;
1138 auto)
1139   if test "${pkg_config_prog_path}" = "missing"; then
1140     AC_MSG_WARN([pkg-config not found, guile support disabled])
1141   else
1142     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1143   fi
1144   ;;
1145 yes)
1146   if test "${pkg_config_prog_path}" = "missing"; then
1147     AC_MSG_ERROR([pkg-config not found])
1148   fi
1149   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1150   ;;
1151 [[\\/]]* | ?:[[\\/]]*)
1152   if test -x "${with_guile}"; then
1153     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1154   else
1155     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1156   fi
1157   ;;
1158 "" | */*)
1159   # Disallow --with=guile="" and --with-guile=foo/bar.
1160   AC_MSG_ERROR([invalid value for --with-guile])
1161   ;;
1162 *)
1163   # A space separate list of guile versions to try, in order.
1164   if test "${pkg_config_prog_path}" = "missing"; then
1165     AC_MSG_ERROR([pkg-config not found])
1166   fi
1167   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1168   ;;
1169 esac
1170
1171 if test "${have_libguile}" != no; then
1172   dnl Get the name of the 'guild' program.
1173   case "${with_guile}" in
1174   [[\\/]]* | ?:[[\\/]]*)
1175     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1176     ;;
1177   *)
1178     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1179     ;;
1180   esac
1181
1182   dnl Make sure guild can handle this host.
1183   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1184   dnl If not, disable guile support.
1185   if test "$ac_cv_guild_ok" = no; then
1186     have_libguile=no
1187     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1188   fi
1189 fi
1190
1191 if test "${have_libguile}" != no; then
1192   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1193   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1194   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1195   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1196   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1197   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1198
1199   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1200   save_LIBS="$LIBS"
1201   save_CPPFLAGS="$CPPFLAGS"
1202   LIBS="$GUILE_LIBS"
1203   CPPFLAGS="$GUILE_CPPFLAGS"
1204   AC_CHECK_FUNCS([scm_new_smob])
1205   LIBS="$save_LIBS"
1206   CPPFLAGS="$save_CPPFLAGS"
1207 else
1208   # Even if Guile support is not compiled in, we need to have these files
1209   # included.
1210   CONFIG_OBS="$CONFIG_OBS guile/guile.o"
1211   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1212 fi
1213 AC_SUBST(GUILE_CPPFLAGS)
1214 AC_SUBST(GUILE_LIBS)
1215 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1216
1217 # ---------------------------- #
1218 # Check for source highlight.  #
1219 # ---------------------------- #
1220
1221 SRCHIGH_LIBS=
1222 SRCHIGH_CFLAGS=
1223
1224 AC_ARG_ENABLE(source-highlight,
1225   AS_HELP_STRING([--enable-source-highlight],
1226     [enable source-highlight for source listings]),
1227   [case "${enableval}" in
1228   yes)  enable_source_highlight=yes ;;
1229   no)   enable_source_highlight=no  ;;
1230   *)    AC_MSG_ERROR(bad value ${enableval} for source-highlight option) ;;
1231 esac],
1232 [enable_source_highlight=auto])
1233
1234 if test "${enable_source_highlight}" != "no"; then
1235   AC_MSG_CHECKING([for the source-highlight library])
1236   if test "${pkg_config_prog_path}" = "missing"; then
1237     AC_MSG_RESULT([no - pkg-config not found])
1238     if test "${enable_source_highlight}" = "yes"; then
1239       AC_MSG_ERROR([pkg-config was not found in your system])
1240     fi
1241   else
1242     if ${pkg_config_prog_path} --exists source-highlight; then
1243       SRCHIGH_CFLAGS=`${pkg_config_prog_path} --cflags source-highlight`
1244       SRCHIGH_LIBS=`${pkg_config_prog_path} --libs source-highlight`
1245       AC_DEFINE([HAVE_SOURCE_HIGHLIGHT], 1,
1246                 [Define to 1 if the source-highlight library is available])
1247       AC_MSG_RESULT([yes])
1248     else
1249       AC_MSG_RESULT([no])
1250       if test "${enable_source_highlight}" = "yes"; then
1251         AC_MSG_ERROR([source-highlight was not found in your system])
1252       fi
1253     fi
1254   fi
1255 fi
1256 AC_SUBST(SRCHIGH_LIBS)
1257 AC_SUBST(SRCHIGH_CFLAGS)
1258
1259 # --------------------- #
1260 # Check for libmcheck.  #
1261 # --------------------- #
1262
1263 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1264 # but turn it off if Python is enabled with threads, since -lmcheck is
1265 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1266 # and for releases.
1267 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1268    && $development; then
1269   libmcheck_default=yes
1270 else
1271   libmcheck_default=no
1272 fi
1273 GDB_AC_LIBMCHECK(${libmcheck_default})
1274
1275 if test "$ENABLE_LIBMCHECK" = "yes" \
1276         -a "${have_libpython}" != "no" \
1277         -a "${python_has_threads}" = "yes" ; then
1278   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1279 fi
1280
1281 AC_ARG_WITH(intel_pt,
1282   AS_HELP_STRING([--with-intel-pt], [include Intel Processor Trace support (auto/yes/no)]),
1283   [], [with_intel_pt=auto])
1284 AC_MSG_CHECKING([whether to use intel pt])
1285 AC_MSG_RESULT([$with_intel_pt])
1286
1287 if test "${with_intel_pt}" = no; then
1288   AC_MSG_WARN([Intel Processor Trace support disabled; some features may be unavailable.])
1289   HAVE_LIBIPT=no
1290 else
1291   AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
1292 #include <linux/perf_event.h>
1293 #ifndef PERF_ATTR_SIZE_VER5
1294 # error
1295 #endif
1296   ]])], [perf_event=yes], [perf_event=no])
1297   if test "$perf_event" != yes; then
1298     if test "$with_intel_pt" = yes; then
1299       AC_MSG_ERROR([linux/perf_event.h missing or too old])
1300     else
1301       AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
1302     fi
1303   fi
1304
1305   AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
1306   if test "$HAVE_LIBIPT" != yes; then
1307     if test "$with_intel_pt" = yes; then
1308       AC_MSG_ERROR([libipt is missing or unusable])
1309     else
1310       AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
1311     fi
1312   else
1313     save_LIBS=$LIBS
1314     LIBS="$LIBS $LIBIPT"
1315     AC_CHECK_FUNCS(pt_insn_event)
1316     AC_CHECK_MEMBERS([struct pt_insn.enabled, struct pt_insn.resynced], [], [],
1317                      [#include <intel-pt.h>])
1318     LIBS=$save_LIBS
1319   fi
1320 fi
1321
1322 # ------------------------- #
1323 # Checks for header files.  #
1324 # ------------------------- #
1325
1326 AC_HEADER_STDC
1327 # elf_hp.h is for HP/UX 64-bit shared library support.
1328 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1329                   thread_db.h linux/elf.h \
1330                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1331                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1332                   sys/reg.h sys/debugreg.h sys/select.h \
1333                   termios.h elf_hp.h \
1334                   dlfcn.h])
1335 AC_CHECK_HEADERS(sys/user.h, [], [],
1336 [#if HAVE_SYS_PARAM_H
1337 # include <sys/param.h>
1338 #endif
1339 ])
1340
1341 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1342 AC_CHECK_HEADERS(term.h, [], [],
1343 [#if HAVE_CURSES_H
1344 # include <curses.h>
1345 #endif
1346 ])
1347
1348 # ------------------------- #
1349 # Checks for declarations.  #
1350 # ------------------------- #
1351
1352 libiberty_INIT
1353
1354 AC_CHECK_DECLS([snprintf])
1355 AM_LC_MESSAGES
1356
1357 # ----------------------- #
1358 # Checks for structures.  #
1359 # ----------------------- #
1360
1361 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1362
1363 # ------------------ #
1364 # Checks for types.  #
1365 # ------------------ #
1366
1367 AC_CHECK_TYPES(socklen_t, [], [],
1368 [#include <sys/types.h>
1369 #include <sys/socket.h>
1370 ])
1371
1372 # ------------------------------------- #
1373 # Checks for compiler characteristics.  #
1374 # ------------------------------------- #
1375
1376 AC_C_CONST
1377 AC_C_INLINE
1378 AC_C_BIGENDIAN
1379
1380 # ------------------------------ #
1381 # Checks for library functions.  #
1382 # ------------------------------ #
1383
1384 AC_FUNC_MMAP
1385 AC_FUNC_VFORK
1386 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1387                 pipe poll pread pread64 pwrite resize_term \
1388                 sbrk getpgid setpgid setpgrp setsid \
1389                 sigaction sigprocmask sigsetmask socketpair \
1390                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1391                 setrlimit getrlimit posix_madvise waitpid \
1392                 ptrace64 sigaltstack setns use_default_colors])
1393 AM_LANGINFO_CODESET
1394 GDB_AC_COMMON
1395
1396 # Check the return and argument types of ptrace.
1397 GDB_AC_PTRACE
1398
1399 dnl AC_FUNC_SETPGRP does not work when cross compiling
1400 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1401 if test "$cross_compiling" = no; then
1402   AC_FUNC_SETPGRP
1403 else
1404   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1405     [AC_TRY_COMPILE([
1406 #include <unistd.h>
1407 ], [
1408   if (setpgrp(1,1) == -1)
1409     exit (0);
1410   else
1411     exit (1);
1412 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1413 if test $ac_cv_func_setpgrp_void = yes; then
1414   AC_DEFINE(SETPGRP_VOID, 1)
1415 fi
1416 fi
1417
1418 # Assume we'll default to using the included libiberty regex.
1419 gdb_use_included_regex=yes
1420
1421 # However, if the system regex is GNU regex, then default to *not*
1422 # using the included regex.
1423 AC_CACHE_CHECK(
1424   [for GNU regex],
1425   [gdb_cv_have_gnu_regex],
1426   [AC_TRY_COMPILE(
1427     [#include <gnu-versions.h>],
1428     [#define REGEX_INTERFACE_VERSION 1
1429 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1430 # error "Version mismatch"
1431 #endif],
1432     gdb_cv_have_gnu_regex=yes,
1433     gdb_cv_have_gnu_regex=no)])
1434 if test $gdb_cv_have_gnu_regex = yes; then
1435   gdb_use_included_regex=no
1436 fi
1437
1438 AC_ARG_WITH(included-regex,
1439   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1440   gdb_with_regex=$withval,
1441   gdb_with_regex=$gdb_use_included_regex)
1442 if test "$gdb_with_regex" = yes; then
1443   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1444     [Define to 1 if the regex included in libiberty should be used.])
1445 fi
1446
1447 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1448 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1449 [#include <sys/param.h>
1450 #include <sys/proc.h>
1451 ])
1452
1453 # See if <sys/lwp.h> defines `struct lwp`.
1454 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1455 [AC_TRY_COMPILE([#include <sys/param.h>
1456 #define _KMEMUSER
1457 #include <sys/lwp.h>], [struct lwp l;],
1458 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1459 if test $gdb_cv_struct_lwp = yes; then
1460   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1461             [Define to 1 if your system has struct lwp.])
1462 fi
1463
1464 # See if <machine/reg.h> degines `struct reg'.
1465 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1466 [AC_TRY_COMPILE([#include <sys/types.h>
1467 #include <machine/reg.h>], [struct reg r;],
1468 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1469 if test $gdb_cv_struct_reg = yes; then
1470   AC_DEFINE(HAVE_STRUCT_REG, 1,
1471             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1472 fi
1473
1474 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1475 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1476 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1477                  [#include <sys/types.h>
1478 #include <machine/reg.h>])
1479
1480 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1481 # Older amd64 Linux's don't have the fs_base and gs_base members of
1482 # `struct user_regs_struct'.
1483 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1484      [], [], [#include <sys/types.h>
1485 #include <sys/user.h>])
1486
1487 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1488 AC_MSG_CHECKING(for PTRACE_GETREGS)
1489 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1490 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1491                 [PTRACE_GETREGS;],
1492                 [gdb_cv_have_ptrace_getregs=yes],
1493                 [gdb_cv_have_ptrace_getregs=no])])
1494 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1495 if test $gdb_cv_have_ptrace_getregs = yes; then
1496   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1497   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1498 fi
1499
1500 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1501 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1502 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1503 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1504                 [PTRACE_GETFPXREGS;],
1505                 [gdb_cv_have_ptrace_getfpxregs=yes],
1506                 [gdb_cv_have_ptrace_getfpxregs=no])])
1507 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1508 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1509   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1510   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1511 fi
1512
1513 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1514 AC_MSG_CHECKING(for PT_GETDBREGS)
1515 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1516 [AC_TRY_COMPILE([#include <sys/types.h>
1517 #include <sys/ptrace.h>],
1518                 [PT_GETDBREGS;],
1519                 [gdb_cv_have_pt_getdbregs=yes],
1520                 [gdb_cv_have_pt_getdbregs=no])])
1521 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1522 if test $gdb_cv_have_pt_getdbregs = yes; then
1523   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1524   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1525 fi
1526
1527 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1528 AC_MSG_CHECKING(for PT_GETXMMREGS)
1529 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1530 [AC_TRY_COMPILE([#include <sys/types.h>
1531 #include <sys/ptrace.h>],
1532                 [PT_GETXMMREGS;],
1533                 [gdb_cv_have_pt_getxmmregs=yes],
1534                 [gdb_cv_have_pt_getxmmregs=no])])
1535 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1536 if test $gdb_cv_have_pt_getxmmregs = yes; then
1537   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1538   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1539 fi
1540
1541 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1542 # Older FreeBSD versions don't have the pl_tdname member of
1543 # `struct ptrace_lwpinfo'.
1544 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1545                  [#include <sys/ptrace.h>])
1546
1547 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1548 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1549 # FreeBSD 10.3.
1550 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1551                  [#include <sys/ptrace.h>])
1552
1553 if test "$ac_cv_header_sys_procfs_h" = yes; then
1554   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1555   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1556   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1557   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1558   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1559   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1560   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1561   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
1562 fi
1563
1564 # Check if the compiler supports the `long long' type.
1565
1566 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1567                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1568 [[extern long long foo;]],
1569 [[switch (foo & 2) { case 0: return 1; }]])],
1570                                   gdb_cv_c_long_long=yes,
1571                                   gdb_cv_c_long_long=no)])
1572 if test $gdb_cv_c_long_long != yes; then
1573   # libdecnumber requires long long.
1574   AC_MSG_ERROR([Compiler must support long long for GDB.])
1575 fi
1576
1577 # Check if the compiler and runtime support printing long longs.
1578
1579 AC_CACHE_CHECK([for long long support in printf],
1580                gdb_cv_printf_has_long_long,
1581                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1582 [[char buf[32];
1583   long long l = 0;
1584   l = (l << 16) + 0x0123;
1585   l = (l << 16) + 0x4567;
1586   l = (l << 16) + 0x89ab;
1587   l = (l << 16) + 0xcdef;
1588   sprintf (buf, "0x%016llx", l);
1589   return (strcmp ("0x0123456789abcdef", buf));]])],
1590                               gdb_cv_printf_has_long_long=yes,
1591                               gdb_cv_printf_has_long_long=no,
1592                               gdb_cv_printf_has_long_long=no)])
1593 if test $gdb_cv_printf_has_long_long = yes; then
1594   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1595             [Define to 1 if the "%ll" format works to print long longs.])
1596 fi
1597
1598 # Check if the compiler and runtime support printing decfloats.
1599
1600 AC_CACHE_CHECK([for decfloat support in printf],
1601                gdb_cv_printf_has_decfloat,
1602                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1603 [[char buf[64];
1604   _Decimal32 d32 = 1.2345df;
1605   _Decimal64 d64 = 1.2345dd;
1606   _Decimal128 d128 = 1.2345dl;
1607   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1608   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1609                               gdb_cv_printf_has_decfloat=yes,
1610                               gdb_cv_printf_has_decfloat=no,
1611                               gdb_cv_printf_has_decfloat=no)])
1612 if test $gdb_cv_printf_has_decfloat = yes; then
1613   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1614             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1615 fi
1616
1617 # Check if the compiler supports the `long double' type.  We can't use
1618 # AC_C_LONG_DOUBLE because that one does additional checks on the
1619 # constants defined in <float.h> that fail on some systems,
1620 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1621
1622 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1623                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1624                                   gdb_cv_c_long_double=yes,
1625                                   gdb_cv_c_long_double=no)])
1626 if test $gdb_cv_c_long_double = yes; then
1627   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1628            [Define to 1 if the compiler supports long double.])
1629 fi
1630
1631 # Check if the compiler and runtime support printing long doubles.
1632
1633 AC_CACHE_CHECK([for long double support in printf],
1634                gdb_cv_printf_has_long_double,
1635                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1636 [[char buf[16];
1637   long double f = 3.141592653;
1638   sprintf (buf, "%Lg", f);
1639   return (strncmp ("3.14159", buf, 7));]])],
1640                               gdb_cv_printf_has_long_double=yes,
1641                               gdb_cv_printf_has_long_double=no,
1642                               gdb_cv_printf_has_long_double=no)])
1643 if test $gdb_cv_printf_has_long_double = yes; then
1644   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1645             [Define to 1 if the "%Lg" format works to print long doubles.])
1646 fi
1647
1648 # Check if the compiler and runtime support scanning long doubles.
1649
1650 AC_CACHE_CHECK([for long double support in scanf],
1651                gdb_cv_scanf_has_long_double,
1652                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1653 [[#include <stdio.h>]],
1654 [[char *buf = "3.141592653";
1655   long double f = 0;
1656   sscanf (buf, "%Lg", &f);
1657   return !(f > 3.14159 && f < 3.14160);]])],
1658                               gdb_cv_scanf_has_long_double=yes,
1659                               gdb_cv_scanf_has_long_double=no,
1660                               gdb_cv_scanf_has_long_double=no)])
1661 if test $gdb_cv_scanf_has_long_double = yes; then
1662   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1663             [Define to 1 if the "%Lg" format works to scan long doubles.])
1664 fi
1665
1666 case ${host_os} in
1667 aix*)
1668   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1669     SAVE_LDFLAGS=$LDFLAGS
1670
1671     case $GCC in
1672     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1673     *) gdb_cv_bigtoc=-bbigtoc ;;
1674     esac
1675
1676     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1677     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1678     LDFLAGS="${SAVE_LDFLAGS}"
1679   ])
1680   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1681   ;;
1682 esac
1683
1684 AC_MSG_CHECKING(for the dynamic export flag)
1685 dynamic_list=false
1686 if test "${gdb_native}" = yes; then
1687    # The dynamically loaded libthread_db needs access to symbols in the gdb
1688    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1689    # may not be supported there.
1690    old_LDFLAGS="$LDFLAGS"
1691    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1692    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1693    LDFLAGS="$LDFLAGS $RDYNAMIC"
1694    if test "${have_libpython}" = no; then
1695      AC_TRY_LINK([], [], [dynamic_list=true])
1696    else
1697      # Workaround http://bugs.python.org/issue4434 where static
1698      # libpythonX.Y.a would get its symbols required for
1699      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1700      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1701
1702      # Note the workaround for Python
1703      # http://bugs.python.org/issue10112 earlier has removed
1704      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1705      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1706      # always pass.
1707      old_CFLAGS="$CFLAGS"
1708      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1709      old_LIBS="$LIBS"
1710      LIBS="$LIBS $PYTHON_LIBS"
1711      old_CPPFLAGS="$CPPFLAGS"
1712      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1713      AC_RUN_IFELSE(
1714        [AC_LANG_PROGRAM(
1715          [#include "Python.h"],
1716          [int err;
1717           Py_Initialize ();
1718           err = PyRun_SimpleString ("import itertools\n");
1719           Py_Finalize ();
1720           return err == 0 ? 0 : 1;])],
1721        [dynamic_list=true], [], [true])
1722      LIBS="$old_LIBS"
1723      CFLAGS="$old_CFLAGS"
1724      CPPFLAGS="$old_CPPFLAGS"
1725    fi
1726    LDFLAGS="$old_LDFLAGS"
1727 fi
1728 if $dynamic_list; then
1729   found="-Wl,--dynamic-list"
1730   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1731 else
1732   found="-rdynamic"
1733   RDYNAMIC="-rdynamic"
1734 fi
1735 AC_SUBST(RDYNAMIC)
1736 AC_MSG_RESULT($found)
1737
1738 dnl For certain native configurations, we need to check whether thread
1739 dnl support can be built in or not.
1740 dnl
1741 dnl Note that we only want this if we are both native (host == target),
1742 dnl and not doing a canadian cross build (build == host).
1743
1744 if test ${build} = ${host} -a ${host} = ${target} ; then
1745    case ${host_os} in
1746    aix*)
1747       AC_MSG_CHECKING(for AiX thread debugging library)
1748       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1749                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1750                                    [#ifndef PTHDB_VERSION_3
1751                                     #error
1752                                     #endif],
1753                                    gdb_cv_have_aix_thread_debug=yes,
1754                                    gdb_cv_have_aix_thread_debug=no)])
1755       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1756       if test $gdb_cv_have_aix_thread_debug = yes; then
1757          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1758          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1759          LIBS="$LIBS -lpthdebug"
1760
1761          # Older versions of AIX do not provide the declaration for
1762          # the getthrds function (it appears that it was introduced
1763          # with AIX 6.x).
1764          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1765       fi
1766       ;;
1767    esac
1768    AC_SUBST(CONFIG_LDFLAGS)
1769 fi
1770
1771 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1772 dnl other error codes.
1773 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1774    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1775                   gdb_cv_thread_db_h_has_td_notalloc,
1776      AC_TRY_COMPILE(
1777        [#include <thread_db.h>],
1778        [int i = TD_NOTALLOC;],
1779        gdb_cv_thread_db_h_has_td_notalloc=yes,
1780        gdb_cv_thread_db_h_has_td_notalloc=no
1781      )
1782    )
1783    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1784                   gdb_cv_thread_db_h_has_td_version,
1785      AC_TRY_COMPILE(
1786        [#include <thread_db.h>],
1787        [int i = TD_VERSION;],
1788        gdb_cv_thread_db_h_has_td_version=yes,
1789        gdb_cv_thread_db_h_has_td_version=no
1790      )
1791    )
1792    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1793                   gdb_cv_thread_db_h_has_td_notls,
1794      AC_TRY_COMPILE(
1795        [#include <thread_db.h>],
1796        [int i = TD_NOTLS;],
1797        gdb_cv_thread_db_h_has_td_notls=yes,
1798        gdb_cv_thread_db_h_has_td_notls=no
1799      )
1800    )
1801 fi
1802 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1803   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1804             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1805 fi
1806 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1807   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1808             [Define if <thread_db.h> has the TD_VERSION error code.])
1809 fi
1810 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1811   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1812             [Define if <thread_db.h> has the TD_NOTLS error code.])
1813 fi
1814
1815 dnl Check if we can disable the virtual address space randomization.
1816 dnl The functionality of setarch -R.
1817 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1818 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1819 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1820 #       define ADDR_NO_RANDOMIZE 0x0040000
1821 #      endif
1822        /* Test the flag could be set and stays set.  */
1823        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1824        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1825            return 1])])
1826 AC_RUN_IFELSE([PERSONALITY_TEST],
1827               [have_personality=true],
1828               [have_personality=false],
1829               [AC_LINK_IFELSE([PERSONALITY_TEST],
1830                               [have_personality=true],
1831                               [have_personality=false])])
1832 if $have_personality
1833 then
1834     AC_DEFINE([HAVE_PERSONALITY], 1,
1835               [Define if you support the personality syscall.])
1836 fi
1837
1838 dnl Set the host's .gdbinit filename.
1839 case $host_os in
1840   go32* | *djgpp*)
1841     gdbinit=gdb.ini
1842     ;;
1843   *)
1844     gdbinit=.gdbinit
1845     ;;
1846 esac
1847 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1848
1849 dnl Handle optional features that can be enabled.
1850
1851 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1852 # except that the argument to --with-sysroot is optional.
1853 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1854 if test "x$with_sysroot" = xyes; then
1855   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1856 fi
1857 AC_ARG_WITH(sysroot,
1858   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1859                  [search for usr/lib et al within DIR]),
1860   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1861 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1862               [search for usr/lib et al within DIR])
1863 AC_SUBST(TARGET_SYSTEM_ROOT)
1864 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1865
1866 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1867     [automatically load a system-wide gdbinit file],
1868     [])
1869
1870 AM_GDB_WARNINGS
1871 AM_GDB_UBSAN
1872
1873 # In the Cygwin environment, we need some additional flags.
1874 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1875 [AC_EGREP_CPP(^lose$, [
1876 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1877 lose
1878 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1879
1880
1881 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1882 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1883 case ${host} in
1884   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1885   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1886   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1887   *) SER_HARDWIRE="$SER_HARDWIRE ser-uds.o" ;;
1888 esac
1889 AC_SUBST(SER_HARDWIRE)
1890
1891 # libreadline needs libuser32.a in a cygwin environment
1892 WIN32LIBS=
1893 if test x$gdb_cv_os_cygwin = xyes; then
1894     WIN32LIBS="-luser32"
1895     case "${target}" in
1896         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1897         ;;
1898     esac
1899 fi
1900
1901 # The ser-tcp.c module requires sockets.
1902 case ${host} in
1903   *mingw32*)
1904     AC_DEFINE(USE_WIN32API, 1,
1905               [Define if we should use the Windows API, instead of the
1906                POSIX API.  On Windows, we use the Windows API when
1907                building for MinGW, but the POSIX API when building
1908                for Cygwin.])
1909     WIN32LIBS="$WIN32LIBS -lws2_32"
1910     ;;
1911 esac
1912 AC_SUBST(WIN32LIBS)
1913
1914 # Add ELF support to GDB, but only if BFD includes ELF support.
1915 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1916                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1917 if test $gdb_cv_var_elf = yes; then
1918   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1919   AC_DEFINE(HAVE_ELF, 1,
1920             [Define if ELF support should be included.])
1921   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1922   if test "$plugins" = "yes"; then
1923     AC_SEARCH_LIBS(dlopen, dl)
1924   fi
1925 fi
1926
1927 # Add macho support to GDB, but only if BFD includes it.
1928 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1929                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1930 if test $gdb_cv_var_macho = yes; then
1931   CONFIG_OBS="$CONFIG_OBS machoread.o"
1932 fi
1933
1934 # Add any host-specific objects to GDB.
1935 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1936
1937 # If building on ELF, look for lzma support for embedded compressed debug info.
1938 if test $gdb_cv_var_elf = yes; then
1939   AC_ARG_WITH(lzma,
1940     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1941     [], [with_lzma=auto])
1942   AC_MSG_CHECKING([whether to use lzma])
1943   AC_MSG_RESULT([$with_lzma])
1944
1945   if test "${with_lzma}" != no; then
1946     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1947                           [lzma_index_iter iter;
1948                            lzma_index_iter_init (&iter, 0);
1949                            lzma_mf_is_supported (LZMA_MF_HC3);])
1950     if test "$HAVE_LIBLZMA" != yes; then
1951       if test "$with_lzma" = yes; then
1952         AC_MSG_ERROR([missing liblzma for --with-lzma])
1953       fi
1954     fi
1955   fi
1956 fi
1957
1958 LIBGUI="../libgui/src/libgui.a"
1959 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1960 AC_SUBST(LIBGUI)
1961 AC_SUBST(GUI_CFLAGS_X)
1962
1963 WIN32LDAPP=
1964 AC_SUBST(WIN32LIBS)
1965 AC_SUBST(WIN32LDAPP)
1966
1967 case "${host}" in
1968 *-*-cygwin* | *-*-mingw* )
1969     configdir="win"
1970     ;;
1971 *)
1972     configdir="unix"
1973     ;;
1974 esac
1975
1976 GDBTKLIBS=
1977 if test "${enable_gdbtk}" = "yes"; then
1978
1979     # Gdbtk must have an absolute path to srcdir in order to run
1980     # properly when not installed.
1981     here=`pwd`
1982     cd ${srcdir}
1983     GDBTK_SRC_DIR=`pwd`
1984     cd $here
1985
1986     SC_PATH_TCLCONFIG
1987
1988     # If $no_tk is nonempty, then we can't do Tk, and there is no
1989     # point to doing Tcl.
1990     SC_PATH_TKCONFIG
1991
1992     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1993         SC_LOAD_TCLCONFIG
1994
1995         # Check for in-tree tcl
1996         here=`pwd`
1997         cd ${srcdir}/..
1998         topdir=`pwd`
1999         cd ${here}
2000
2001         intree="no"
2002         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2003           intree="yes"
2004         fi
2005
2006         # Find Tcl private headers
2007         if test x"${intree}" = xno; then
2008           CY_AC_TCL_PRIVATE_HEADERS
2009           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2010           TCL_LIBRARY="${TCL_LIB_SPEC}"
2011           TCL_DEPS=""
2012         else
2013           # If building tcl in the same src tree, private headers
2014           # are not needed, but we need to be sure to use the right
2015           # headers library
2016           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2017           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2018           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2019         fi
2020         AC_SUBST(TCL_INCLUDE)
2021         AC_SUBST(TCL_LIBRARY)
2022         AC_SUBST(TCL_DEPS)
2023
2024         SC_LOAD_TKCONFIG
2025
2026         # Check for in-tree Tk
2027         intree="no"
2028         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2029           intree="yes"
2030         fi
2031
2032         # Find Tk private headers
2033         if test x"${intree}" = xno; then
2034           CY_AC_TK_PRIVATE_HEADERS
2035           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2036           TK_LIBRARY=${TK_LIB_SPEC}
2037           TK_DEPS=""
2038         else
2039           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2040           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2041           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2042         fi
2043         AC_SUBST(TK_INCLUDE)
2044         AC_SUBST(TK_LIBRARY)
2045         AC_SUBST(TK_DEPS)
2046         AC_SUBST(TK_XINCLUDES)
2047
2048         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2049
2050         # Include some libraries that Tcl and Tk want.
2051         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2052         # Yes, the ordering seems wrong here.  But it isn't.
2053         # TK_LIBS is the list of libraries that need to be linked
2054         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2055         # were in LIBS then any link tests after this point would
2056         # try to include things like `$(LIBGUI)', which wouldn't work.
2057         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2058
2059         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2060         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2061         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2062         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2063         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2064         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2065         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2066
2067         if test x$gdb_cv_os_cygwin = xyes; then
2068           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2069           WIN32LDAPP="-Wl,--subsystem,console"
2070           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2071         fi
2072
2073         AC_CONFIG_SUBDIRS(gdbtk)
2074     fi
2075 fi
2076
2077 AC_SUBST(X_CFLAGS)
2078 AC_SUBST(X_LDFLAGS)
2079 AC_SUBST(X_LIBS)
2080 AC_SUBST(GDBTKLIBS)
2081 AC_SUBST(GDBTK_CFLAGS)
2082 AC_SUBST(GDBTK_SRC_DIR)
2083
2084 AC_PATH_X
2085
2086 # Unlike the sim directory, whether a simulator is linked is controlled by
2087 # presence of a gdb_sim definition in the target configure.tgt entry.
2088 # This code just checks for a few cases where we'd like to ignore those
2089 # definitions, even when they're present in the '.mt' file.  These cases
2090 # are when --disable-sim is specified, or if the simulator directory is
2091 # not part of the source tree.
2092 #
2093 AC_ARG_ENABLE(sim,
2094 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2095 [echo "enable_sim = $enable_sim";
2096  echo "enableval = ${enableval}";
2097  case "${enableval}" in
2098   yes) ignore_sim=false ;;
2099   no)  ignore_sim=true ;;
2100   *)   ignore_sim=false ;;
2101  esac],
2102 [ignore_sim=false])
2103
2104 if test ! -d "${srcdir}/../sim"; then
2105   ignore_sim=true
2106 fi
2107
2108 SIM=
2109 SIM_OBS=
2110 if test "${ignore_sim}" = "false"; then
2111   if test x"${gdb_sim}" != x ; then
2112     SIM="${gdb_sim}"
2113     SIM_OBS="remote-sim.o"
2114     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2115
2116     # Some tdep code should only be compiled in when the ppc sim is
2117     # built.  PR sim/13418.
2118     case $target in
2119       powerpc*-*-*)
2120         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2121         ;;
2122     esac
2123   fi
2124 fi
2125 AC_SUBST(SIM)
2126 AC_SUBST(SIM_OBS)
2127
2128 AC_SUBST(ENABLE_CFLAGS)
2129 AC_SUBST(PROFILE_CFLAGS)
2130
2131 AC_SUBST(CONFIG_OBS)
2132 AC_SUBST(CONFIG_DEPS)
2133 AC_SUBST(CONFIG_SRCS)
2134 AC_SUBST(CONFIG_ALL)
2135 AC_SUBST(CONFIG_CLEAN)
2136 AC_SUBST(CONFIG_INSTALL)
2137 AC_SUBST(CONFIG_UNINSTALL)
2138
2139 # List of host floatformats.
2140 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2141 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2142 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2143
2144 # target_subdir is used by the testsuite to find the target libraries.
2145 target_subdir=
2146 if test "${host}" != "${target}"; then
2147     target_subdir="${target_alias}/"
2148 fi
2149 AC_SUBST(target_subdir)
2150
2151 # Import nat definitions.
2152 nat_makefile_frag=/dev/null
2153 if test "${gdb_native}" = "yes"; then
2154   . ${srcdir}/configure.nat
2155   nativefile=$NAT_FILE
2156 fi
2157
2158 AC_SUBST(NAT_FILE)
2159 AC_SUBST(NATDEPFILES)
2160 AC_SUBST(NAT_CDEPS)
2161 AC_SUBST(LOADLIBES)
2162 AC_SUBST(MH_CFLAGS)
2163 AC_SUBST(XM_CLIBS)
2164 AC_SUBST(NAT_GENERATED_FILES)
2165 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2166 AC_SUBST_FILE(nat_makefile_frag)
2167
2168 if test x"${gdb_osabi}" != x ; then
2169     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2170                        [Define to the default OS ABI for this configuration.])
2171 fi
2172
2173 AC_ARG_ENABLE(gdbserver,
2174 AS_HELP_STRING([--enable-gdbserver],
2175                [automatically build gdbserver (yes/no/auto, default is auto)]),
2176 [case "${enableval}" in
2177   yes| no|auto) ;;
2178   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2179 esac],[enable_gdbserver=auto])
2180
2181 # We only build gdbserver automatically in a native configuration, and
2182 # only if the user did not explicitly disable its build.
2183 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2184   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2185   if test "x$build_gdbserver" = xyes; then
2186     AC_MSG_RESULT(yes)
2187     AC_CONFIG_SUBDIRS(gdbserver)
2188     gdbserver_build_enabled=yes
2189   else
2190     AC_MSG_RESULT(no)
2191   fi
2192 fi
2193
2194 # If the user explicitly request the gdbserver to be built, verify that
2195 # we were in fact able to enable it.
2196 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2197   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2198 fi
2199
2200 # Check for babeltrace and babeltrace-ctf
2201 AC_ARG_WITH(babeltrace,
2202   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2203   [], [with_babeltrace=auto])
2204 AC_MSG_CHECKING([whether to use babeltrace])
2205 AC_MSG_RESULT([$with_babeltrace])
2206
2207 if test "x$with_babeltrace" = "xno"; then
2208   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2209 else
2210   # Append -Werror to CFLAGS so that configure can catch the warning
2211   # "assignment from incompatible pointer type", which is related to
2212   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2213   # in GDB, while babeltrace 1.0.3 is broken.
2214   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2215   # safe to save and restore CFLAGS here.
2216   saved_CFLAGS=$CFLAGS
2217   CFLAGS="$CFLAGS -Werror"
2218   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2219                         [#include <babeltrace/babeltrace.h>
2220                          #include <babeltrace/ctf/events.h>
2221                          #include <babeltrace/ctf/iterator.h>],
2222                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2223                         struct bt_ctf_event *event = NULL;
2224                         const struct bt_definition *scope;
2225
2226                         pos->type = BT_SEEK_BEGIN;
2227                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2228                         scope = bt_ctf_get_top_level_scope (event,
2229                                                            BT_STREAM_EVENT_HEADER);
2230                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2231                         ])
2232   CFLAGS=$saved_CFLAGS
2233
2234   if test "$HAVE_LIBBABELTRACE" != yes; then
2235      if test "$with_babeltrace" = yes; then
2236        AC_MSG_ERROR([babeltrace is missing or unusable])
2237      else
2238        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2239      fi
2240   fi
2241 fi
2242
2243 # If nativefile (NAT_FILE) is not set in configure.nat, we link to an
2244 # empty version.
2245
2246 files=
2247 links=
2248
2249 rm -f nm.h
2250 if test "${nativefile}" != ""; then
2251     case "${nativefile}" in
2252       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2253       * ) GDB_NM_FILE="${nativefile}"
2254     esac
2255     files="${files} ${GDB_NM_FILE}"
2256     links="${links} nm.h"
2257     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2258 fi
2259 AC_SUBST(GDB_NM_FILE)
2260
2261 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2262 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2263 if test "x$USE_MAINTAINER_MODE" = xyes; then
2264   if test "${XSLTPROC}" = missing; then
2265     AC_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2266   fi
2267 fi
2268 AC_SUBST(XSLTPROC)
2269
2270 AC_LINK_FILES($files, $links)
2271
2272 dnl Check for exe extension set on certain hosts (e.g. Win32)
2273 AC_EXEEXT
2274
2275 dnl  Detect the character set used by this host.
2276 dnl  At the moment, we just assume it's UTF-8.
2277 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2278           [Define to be a string naming the default host character set.])
2279
2280 GDB_AC_SELFTEST([
2281   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_UNITTESTS_OBS) common/selftest.o selftest-arch.o"
2282   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_UNITTESTS_SRCS) common/selftest.c selftest-arch.c"
2283 ])
2284
2285 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2286 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2287 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2288 AC_CONFIG_FILES([Makefile gdb-gdb.gdb gdb-gdb.py doc/Makefile data-directory/Makefile],
2289 [
2290 case x$CONFIG_HEADERS in
2291 xconfig.h:config.in)
2292 echo > stamp-h ;;
2293 esac
2294 ])
2295
2296 AC_OUTPUT