gdb/c-exp.y

   1 /* YACC parser for C expressions, for GDB.
   2    Copyright (C) 1986-2013 Free Software Foundation, Inc.
   3
   4    This file is part of GDB.
   5
   6    This program is free software; you can redistribute it and/or modify
   7    it under the terms of the GNU General Public License as published by
   8    the Free Software Foundation; either version 3 of the License, or
   9    (at your option) any later version.
  10
  11    This program is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14    GNU General Public License for more details.
  15
  16    You should have received a copy of the GNU General Public License
  17    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  18
  19 /* Parse a C expression from text in a string,
  20    and return the result as a  struct expression  pointer.
  21    That structure contains arithmetic operations in reverse polish,
  22    with constants represented by operations that are followed by special data.
  23    See expression.h for the details of the format.
  24    What is important here is that it can be built up sequentially
  25    during the process of parsing; the lower levels of the tree always
  26    come first in the result.
  27
  28    Note that malloc's and realloc's in this file are transformed to
  29    xmalloc and xrealloc respectively by the same sed command in the
  30    makefile that remaps any other malloc/realloc inserted by the parser
  31    generator.  Doing this with #defines and trying to control the interaction
  32    with include files (<malloc.h> and <stdlib.h> for example) just became
  33    too messy, particularly when such includes can be inserted at random
  34    times by the parser generator.  */
  35
  36 %{
  37
  38 #include "defs.h"
  39 #include "gdb_string.h"
  40 #include <ctype.h>
  41 #include "expression.h"
  42 #include "value.h"
  43 #include "parser-defs.h"
  44 #include "language.h"
  45 #include "c-lang.h"
  46 #include "bfd.h" /* Required by objfiles.h.  */
  47 #include "symfile.h" /* Required by objfiles.h.  */
  48 #include "objfiles.h" /* For have_full_symbols and have_partial_symbols */
  49 #include "charset.h"
  50 #include "block.h"
  51 #include "cp-support.h"
  52 #include "dfp.h"
  53 #include "gdb_assert.h"
  54 #include "macroscope.h"
  55 #include "objc-lang.h"
  56 #include "typeprint.h"
  57 #include "cp-abi.h"
  58
  59 #define parse_type builtin_type (parse_gdbarch)
  60
  61 /* Remap normal yacc parser interface names (yyparse, yylex, yyerror, etc),
  62    as well as gratuitiously global symbol names, so we can have multiple
  63    yacc generated parsers in gdb.  Note that these are only the variables
  64    produced by yacc.  If other parser generators (bison, byacc, etc) produce
  65    additional global names that conflict at link time, then those parser
  66    generators need to be fixed instead of adding those names to this list. */
  67
  68 #define yymaxdepth c_maxdepth
  69 #define yyparse c_parse_internal
  70 #define yylex   c_lex
  71 #define yyerror c_error
  72 #define yylval  c_lval
  73 #define yychar  c_char
  74 #define yydebug c_debug
  75 #define yypact  c_pact
  76 #define yyr1    c_r1
  77 #define yyr2    c_r2
  78 #define yydef   c_def
  79 #define yychk   c_chk
  80 #define yypgo   c_pgo
  81 #define yyact   c_act
  82 #define yyexca  c_exca
  83 #define yyerrflag c_errflag
  84 #define yynerrs c_nerrs
  85 #define yyps    c_ps
  86 #define yypv    c_pv
  87 #define yys     c_s
  88 #define yy_yys  c_yys
  89 #define yystate c_state
  90 #define yytmp   c_tmp
  91 #define yyv     c_v
  92 #define yy_yyv  c_yyv
  93 #define yyval   c_val
  94 #define yylloc  c_lloc
  95 #define yyreds  c_reds          /* With YYDEBUG defined */
  96 #define yytoks  c_toks          /* With YYDEBUG defined */
  97 #define yyname  c_name          /* With YYDEBUG defined */
  98 #define yyrule  c_rule          /* With YYDEBUG defined */
  99 #define yylhs   c_yylhs
 100 #define yylen   c_yylen
 101 #define yydefred c_yydefred
 102 #define yydgoto c_yydgoto
 103 #define yysindex c_yysindex
 104 #define yyrindex c_yyrindex
 105 #define yygindex c_yygindex
 106 #define yytable  c_yytable
 107 #define yycheck  c_yycheck
 108 #define yyss    c_yyss
 109 #define yysslim c_yysslim
 110 #define yyssp   c_yyssp
 111 #define yystacksize c_yystacksize
 112 #define yyvs    c_yyvs
 113 #define yyvsp   c_yyvsp
 114
 115 #ifndef YYDEBUG
 116 #define YYDEBUG 1               /* Default to yydebug support */
 117 #endif
 118
 119 #define YYFPRINTF parser_fprintf
 120
 121 int yyparse (void);
 122
 123 static int yylex (void);
 124
 125 void yyerror (char *);
 126
 127 %}
 128
 129 /* Although the yacc "value" of an expression is not used,
 130    since the result is stored in the structure being created,
 131    other node types do have values.  */
 132
 133 %union
 134   {
 135     LONGEST lval;
 136     struct {
 137       LONGEST val;
 138       struct type *type;
 139     } typed_val_int;
 140     struct {
 141       DOUBLEST dval;
 142       struct type *type;
 143     } typed_val_float;
 144     struct {
 145       gdb_byte val[16];
 146       struct type *type;
 147     } typed_val_decfloat;
 148     struct type *tval;
 149     struct stoken sval;
 150     struct typed_stoken tsval;
 151     struct ttype tsym;
 152     struct symtoken ssym;
 153     int voidval;
 154     struct block *bval;
 155     enum exp_opcode opcode;
 156
 157     struct stoken_vector svec;
 158     VEC (type_ptr) *tvec;
 159
 160     struct type_stack *type_stack;
 161
 162     struct objc_class_str class;
 163   }
 164
 165 %{
 166 /* YYSTYPE gets defined by %union */
 167 static int parse_number (const char *, int, int, YYSTYPE *);
 168 static struct stoken operator_stoken (const char *);
 169 static void check_parameter_typelist (VEC (type_ptr) *);
 170 static void write_destructor_name (struct stoken);
 171
 172 static void c_print_token (FILE *file, int type, YYSTYPE value);
 173 #define YYPRINT(FILE, TYPE, VALUE) c_print_token (FILE, TYPE, VALUE)
 174 %}
 175
 176 %type <voidval> exp exp1 type_exp start variable qualified_name lcurly
 177 %type <lval> rcurly
 178 %type <tval> type typebase
 179 %type <tvec> nonempty_typelist func_mod parameter_typelist
 180 /* %type <bval> block */
 181
 182 /* Fancy type parsing.  */
 183 %type <tval> ptype
 184 %type <lval> array_mod
 185 %type <tval> conversion_type_id
 186
 187 %type <type_stack> ptr_operator_ts abs_decl direct_abs_decl
 188
 189 %token <typed_val_int> INT
 190 %token <typed_val_float> FLOAT
 191 %token <typed_val_decfloat> DECFLOAT
 192
 193 /* Both NAME and TYPENAME tokens represent symbols in the input,
 194    and both convey their data as strings.
 195    But a TYPENAME is a string that happens to be defined as a typedef
 196    or builtin type name (such as int or char)
 197    and a NAME is any other symbol.
 198    Contexts where this distinction is not important can use the
 199    nonterminal "name", which matches either NAME or TYPENAME.  */
 200
 201 %token <tsval> STRING
 202 %token <sval> NSSTRING          /* ObjC Foundation "NSString" literal */
 203 %token SELECTOR                 /* ObjC "@selector" pseudo-operator   */
 204 %token <tsval> CHAR
 205 %token <ssym> NAME /* BLOCKNAME defined below to give it higher precedence. */
 206 %token <ssym> UNKNOWN_CPP_NAME
 207 %token <voidval> COMPLETE
 208 %token <tsym> TYPENAME
 209 %token <class> CLASSNAME        /* ObjC Class name */
 210 %type <sval> name
 211 %type <svec> string_exp
 212 %type <ssym> name_not_typename
 213 %type <tsym> typename
 214
 215  /* This is like a '[' token, but is only generated when parsing
 216     Objective C.  This lets us reuse the same parser without
 217     erroneously parsing ObjC-specific expressions in C.  */
 218 %token OBJC_LBRAC
 219
 220 /* A NAME_OR_INT is a symbol which is not known in the symbol table,
 221    but which would parse as a valid number in the current input radix.
 222    E.g. "c" when input_radix==16.  Depending on the parse, it will be
 223    turned into a name or into a number.  */
 224
 225 %token <ssym> NAME_OR_INT
 226
 227 %token OPERATOR
 228 %token STRUCT CLASS UNION ENUM SIZEOF UNSIGNED COLONCOLON
 229 %token TEMPLATE
 230 %token ERROR
 231 %token NEW DELETE
 232 %type <sval> operator
 233 %token REINTERPRET_CAST DYNAMIC_CAST STATIC_CAST CONST_CAST
 234 %token ENTRY
 235 %token TYPEOF
 236 %token DECLTYPE
 237 %token TYPEID
 238
 239 /* Special type cases, put in to allow the parser to distinguish different
 240    legal basetypes.  */
 241 %token SIGNED_KEYWORD LONG SHORT INT_KEYWORD CONST_KEYWORD VOLATILE_KEYWORD DOUBLE_KEYWORD
 242
 243 %token <sval> VARIABLE
 244
 245 %token <opcode> ASSIGN_MODIFY
 246
 247 /* C++ */
 248 %token TRUEKEYWORD
 249 %token FALSEKEYWORD
 250
 251
 252 %left ','
 253 %left ABOVE_COMMA
 254 %right '=' ASSIGN_MODIFY
 255 %right '?'
 256 %left OROR
 257 %left ANDAND
 258 %left '|'
 259 %left '^'
 260 %left '&'
 261 %left EQUAL NOTEQUAL
 262 %left '<' '>' LEQ GEQ
 263 %left LSH RSH
 264 %left '@'
 265 %left '+' '-'
 266 %left '*' '/' '%'
 267 %right UNARY INCREMENT DECREMENT
 268 %right ARROW ARROW_STAR '.' DOT_STAR '[' OBJC_LBRAC '('
 269 %token <ssym> BLOCKNAME
 270 %token <bval> FILENAME
 271 %type <bval> block
 272 %left COLONCOLON
 273
 274 %token DOTDOTDOT
 275
 276 \f
 277 %%
 278
 279 start   :       exp1
 280         |       type_exp
 281         ;
 282
 283 type_exp:       type
 284                         { write_exp_elt_opcode(OP_TYPE);
 285                           write_exp_elt_type($1);
 286                           write_exp_elt_opcode(OP_TYPE);}
 287         |       TYPEOF '(' exp ')'
 288                         {
 289                           write_exp_elt_opcode (OP_TYPEOF);
 290                         }
 291         |       TYPEOF '(' type ')'
 292                         {
 293                           write_exp_elt_opcode (OP_TYPE);
 294                           write_exp_elt_type ($3);
 295                           write_exp_elt_opcode (OP_TYPE);
 296                         }
 297         |       DECLTYPE '(' exp ')'
 298                         {
 299                           write_exp_elt_opcode (OP_DECLTYPE);
 300                         }
 301         ;
 302
 303 /* Expressions, including the comma operator.  */
 304 exp1    :       exp
 305         |       exp1 ',' exp
 306                         { write_exp_elt_opcode (BINOP_COMMA); }
 307         ;
 308
 309 /* Expressions, not including the comma operator.  */
 310 exp     :       '*' exp    %prec UNARY
 311                         { write_exp_elt_opcode (UNOP_IND); }
 312         ;
 313
 314 exp     :       '&' exp    %prec UNARY
 315                         { write_exp_elt_opcode (UNOP_ADDR); }
 316         ;
 317
 318 exp     :       '-' exp    %prec UNARY
 319                         { write_exp_elt_opcode (UNOP_NEG); }
 320         ;
 321
 322 exp     :       '+' exp    %prec UNARY
 323                         { write_exp_elt_opcode (UNOP_PLUS); }
 324         ;
 325
 326 exp     :       '!' exp    %prec UNARY
 327                         { write_exp_elt_opcode (UNOP_LOGICAL_NOT); }
 328         ;
 329
 330 exp     :       '~' exp    %prec UNARY
 331                         { write_exp_elt_opcode (UNOP_COMPLEMENT); }
 332         ;
 333
 334 exp     :       INCREMENT exp    %prec UNARY
 335                         { write_exp_elt_opcode (UNOP_PREINCREMENT); }
 336         ;
 337
 338 exp     :       DECREMENT exp    %prec UNARY
 339                         { write_exp_elt_opcode (UNOP_PREDECREMENT); }
 340         ;
 341
 342 exp     :       exp INCREMENT    %prec UNARY
 343                         { write_exp_elt_opcode (UNOP_POSTINCREMENT); }
 344         ;
 345
 346 exp     :       exp DECREMENT    %prec UNARY
 347                         { write_exp_elt_opcode (UNOP_POSTDECREMENT); }
 348         ;
 349
 350 exp     :       TYPEID '(' exp ')' %prec UNARY
 351                         { write_exp_elt_opcode (OP_TYPEID); }
 352         ;
 353
 354 exp     :       TYPEID '(' type_exp ')' %prec UNARY
 355                         { write_exp_elt_opcode (OP_TYPEID); }
 356         ;
 357
 358 exp     :       SIZEOF exp       %prec UNARY
 359                         { write_exp_elt_opcode (UNOP_SIZEOF); }
 360         ;
 361
 362 exp     :       exp ARROW name
 363                         { write_exp_elt_opcode (STRUCTOP_PTR);
 364                           write_exp_string ($3);
 365                           write_exp_elt_opcode (STRUCTOP_PTR); }
 366         ;
 367
 368 exp     :       exp ARROW name COMPLETE
 369                         { mark_struct_expression ();
 370                           write_exp_elt_opcode (STRUCTOP_PTR);
 371                           write_exp_string ($3);
 372                           write_exp_elt_opcode (STRUCTOP_PTR); }
 373         ;
 374
 375 exp     :       exp ARROW COMPLETE
 376                         { struct stoken s;
 377                           mark_struct_expression ();
 378                           write_exp_elt_opcode (STRUCTOP_PTR);
 379                           s.ptr = "";
 380                           s.length = 0;
 381                           write_exp_string (s);
 382                           write_exp_elt_opcode (STRUCTOP_PTR); }
 383         ;
 384
 385 exp     :       exp ARROW '~' name
 386                         { write_exp_elt_opcode (STRUCTOP_PTR);
 387                           write_destructor_name ($4);
 388                           write_exp_elt_opcode (STRUCTOP_PTR); }
 389         ;
 390
 391 exp     :       exp ARROW '~' name COMPLETE
 392                         { mark_struct_expression ();
 393                           write_exp_elt_opcode (STRUCTOP_PTR);
 394                           write_destructor_name ($4);
 395                           write_exp_elt_opcode (STRUCTOP_PTR); }
 396         ;
 397
 398 exp     :       exp ARROW qualified_name
 399                         { /* exp->type::name becomes exp->*(&type::name) */
 400                           /* Note: this doesn't work if name is a
 401                              static member!  FIXME */
 402                           write_exp_elt_opcode (UNOP_ADDR);
 403                           write_exp_elt_opcode (STRUCTOP_MPTR); }
 404         ;
 405
 406 exp     :       exp ARROW_STAR exp
 407                         { write_exp_elt_opcode (STRUCTOP_MPTR); }
 408         ;
 409
 410 exp     :       exp '.' name
 411                         { write_exp_elt_opcode (STRUCTOP_STRUCT);
 412                           write_exp_string ($3);
 413                           write_exp_elt_opcode (STRUCTOP_STRUCT); }
 414         ;
 415
 416 exp     :       exp '.' name COMPLETE
 417                         { mark_struct_expression ();
 418                           write_exp_elt_opcode (STRUCTOP_STRUCT);
 419                           write_exp_string ($3);
 420                           write_exp_elt_opcode (STRUCTOP_STRUCT); }
 421         ;
 422
 423 exp     :       exp '.' COMPLETE
 424                         { struct stoken s;
 425                           mark_struct_expression ();
 426                           write_exp_elt_opcode (STRUCTOP_STRUCT);
 427                           s.ptr = "";
 428                           s.length = 0;
 429                           write_exp_string (s);
 430                           write_exp_elt_opcode (STRUCTOP_STRUCT); }
 431         ;
 432
 433 exp     :       exp '.' '~' name
 434                         { write_exp_elt_opcode (STRUCTOP_STRUCT);
 435                           write_destructor_name ($4);
 436                           write_exp_elt_opcode (STRUCTOP_STRUCT); }
 437         ;
 438
 439 exp     :       exp '.' '~' name COMPLETE
 440                         { mark_struct_expression ();
 441                           write_exp_elt_opcode (STRUCTOP_STRUCT);
 442                           write_destructor_name ($4);
 443                           write_exp_elt_opcode (STRUCTOP_STRUCT); }
 444         ;
 445
 446 exp     :       exp '.' qualified_name
 447                         { /* exp.type::name becomes exp.*(&type::name) */
 448                           /* Note: this doesn't work if name is a
 449                              static member!  FIXME */
 450                           write_exp_elt_opcode (UNOP_ADDR);
 451                           write_exp_elt_opcode (STRUCTOP_MEMBER); }
 452         ;
 453
 454 exp     :       exp DOT_STAR exp
 455                         { write_exp_elt_opcode (STRUCTOP_MEMBER); }
 456         ;
 457
 458 exp     :       exp '[' exp1 ']'
 459                         { write_exp_elt_opcode (BINOP_SUBSCRIPT); }
 460         ;
 461
 462 exp     :       exp OBJC_LBRAC exp1 ']'
 463                         { write_exp_elt_opcode (BINOP_SUBSCRIPT); }
 464         ;
 465
 466 /*
 467  * The rules below parse ObjC message calls of the form:
 468  *      '[' target selector {':' argument}* ']'
 469  */
 470
 471 exp     :       OBJC_LBRAC TYPENAME
 472                         {
 473                           CORE_ADDR class;
 474
 475                           class = lookup_objc_class (parse_gdbarch,
 476                                                      copy_name ($2.stoken));
 477                           if (class == 0)
 478                             error (_("%s is not an ObjC Class"),
 479                                    copy_name ($2.stoken));
 480                           write_exp_elt_opcode (OP_LONG);
 481                           write_exp_elt_type (parse_type->builtin_int);
 482                           write_exp_elt_longcst ((LONGEST) class);
 483                           write_exp_elt_opcode (OP_LONG);
 484                           start_msglist();
 485                         }
 486                 msglist ']'
 487                         { write_exp_elt_opcode (OP_OBJC_MSGCALL);
 488                           end_msglist();
 489                           write_exp_elt_opcode (OP_OBJC_MSGCALL);
 490                         }
 491         ;
 492
 493 exp     :       OBJC_LBRAC CLASSNAME
 494                         {
 495                           write_exp_elt_opcode (OP_LONG);
 496                           write_exp_elt_type (parse_type->builtin_int);
 497                           write_exp_elt_longcst ((LONGEST) $2.class);
 498                           write_exp_elt_opcode (OP_LONG);
 499                           start_msglist();
 500                         }
 501                 msglist ']'
 502                         { write_exp_elt_opcode (OP_OBJC_MSGCALL);
 503                           end_msglist();
 504                           write_exp_elt_opcode (OP_OBJC_MSGCALL);
 505                         }
 506         ;
 507
 508 exp     :       OBJC_LBRAC exp
 509                         { start_msglist(); }
 510                 msglist ']'
 511                         { write_exp_elt_opcode (OP_OBJC_MSGCALL);
 512                           end_msglist();
 513                           write_exp_elt_opcode (OP_OBJC_MSGCALL);
 514                         }
 515         ;
 516
 517 msglist :       name
 518                         { add_msglist(&$1, 0); }
 519         |       msgarglist
 520         ;
 521
 522 msgarglist :    msgarg
 523         |       msgarglist msgarg
 524         ;
 525
 526 msgarg  :       name ':' exp
 527                         { add_msglist(&$1, 1); }
 528         |       ':' exp /* Unnamed arg.  */
 529                         { add_msglist(0, 1);   }
 530         |       ',' exp /* Variable number of args.  */
 531                         { add_msglist(0, 0);   }
 532         ;
 533
 534 exp     :       exp '('
 535                         /* This is to save the value of arglist_len
 536                            being accumulated by an outer function call.  */
 537                         { start_arglist (); }
 538                 arglist ')'     %prec ARROW
 539                         { write_exp_elt_opcode (OP_FUNCALL);
 540                           write_exp_elt_longcst ((LONGEST) end_arglist ());
 541                           write_exp_elt_opcode (OP_FUNCALL); }
 542         ;
 543
 544 exp     :       UNKNOWN_CPP_NAME '('
 545                         {
 546                           /* This could potentially be a an argument defined
 547                              lookup function (Koenig).  */
 548                           write_exp_elt_opcode (OP_ADL_FUNC);
 549                           write_exp_elt_block (expression_context_block);
 550                           write_exp_elt_sym (NULL); /* Placeholder.  */
 551                           write_exp_string ($1.stoken);
 552                           write_exp_elt_opcode (OP_ADL_FUNC);
 553
 554                         /* This is to save the value of arglist_len
 555                            being accumulated by an outer function call.  */
 556
 557                           start_arglist ();
 558                         }
 559                 arglist ')'     %prec ARROW
 560                         {
 561                           write_exp_elt_opcode (OP_FUNCALL);
 562                           write_exp_elt_longcst ((LONGEST) end_arglist ());
 563                           write_exp_elt_opcode (OP_FUNCALL);
 564                         }
 565         ;
 566
 567 lcurly  :       '{'
 568                         { start_arglist (); }
 569         ;
 570
 571 arglist :
 572         ;
 573
 574 arglist :       exp
 575                         { arglist_len = 1; }
 576         ;
 577
 578 arglist :       arglist ',' exp   %prec ABOVE_COMMA
 579                         { arglist_len++; }
 580         ;
 581
 582 exp     :       exp '(' parameter_typelist ')' const_or_volatile
 583                         { int i;
 584                           VEC (type_ptr) *type_list = $3;
 585                           struct type *type_elt;
 586                           LONGEST len = VEC_length (type_ptr, type_list);
 587
 588                           write_exp_elt_opcode (TYPE_INSTANCE);
 589                           write_exp_elt_longcst (len);
 590                           for (i = 0;
 591                                VEC_iterate (type_ptr, type_list, i, type_elt);
 592                                ++i)
 593                             write_exp_elt_type (type_elt);
 594                           write_exp_elt_longcst(len);
 595                           write_exp_elt_opcode (TYPE_INSTANCE);
 596                           VEC_free (type_ptr, type_list);
 597                         }
 598         ;
 599
 600 rcurly  :       '}'
 601                         { $$ = end_arglist () - 1; }
 602         ;
 603 exp     :       lcurly arglist rcurly   %prec ARROW
 604                         { write_exp_elt_opcode (OP_ARRAY);
 605                           write_exp_elt_longcst ((LONGEST) 0);
 606                           write_exp_elt_longcst ((LONGEST) $3);
 607                           write_exp_elt_opcode (OP_ARRAY); }
 608         ;
 609
 610 exp     :       lcurly type_exp rcurly exp  %prec UNARY
 611                         { write_exp_elt_opcode (UNOP_MEMVAL_TYPE); }
 612         ;
 613
 614 exp     :       '(' type_exp ')' exp  %prec UNARY
 615                         { write_exp_elt_opcode (UNOP_CAST_TYPE); }
 616         ;
 617
 618 exp     :       '(' exp1 ')'
 619                         { }
 620         ;
 621
 622 /* Binary operators in order of decreasing precedence.  */
 623
 624 exp     :       exp '@' exp
 625                         { write_exp_elt_opcode (BINOP_REPEAT); }
 626         ;
 627
 628 exp     :       exp '*' exp
 629                         { write_exp_elt_opcode (BINOP_MUL); }
 630         ;
 631
 632 exp     :       exp '/' exp
 633                         { write_exp_elt_opcode (BINOP_DIV); }
 634         ;
 635
 636 exp     :       exp '%' exp
 637                         { write_exp_elt_opcode (BINOP_REM); }
 638         ;
 639
 640 exp     :       exp '+' exp
 641                         { write_exp_elt_opcode (BINOP_ADD); }
 642         ;
 643
 644 exp     :       exp '-' exp
 645                         { write_exp_elt_opcode (BINOP_SUB); }
 646         ;
 647
 648 exp     :       exp LSH exp
 649                         { write_exp_elt_opcode (BINOP_LSH); }
 650         ;
 651
 652 exp     :       exp RSH exp
 653                         { write_exp_elt_opcode (BINOP_RSH); }
 654         ;
 655
 656 exp     :       exp EQUAL exp
 657                         { write_exp_elt_opcode (BINOP_EQUAL); }
 658         ;
 659
 660 exp     :       exp NOTEQUAL exp
 661                         { write_exp_elt_opcode (BINOP_NOTEQUAL); }
 662         ;
 663
 664 exp     :       exp LEQ exp
 665                         { write_exp_elt_opcode (BINOP_LEQ); }
 666         ;
 667
 668 exp     :       exp GEQ exp
 669                         { write_exp_elt_opcode (BINOP_GEQ); }
 670         ;
 671
 672 exp     :       exp '<' exp
 673                         { write_exp_elt_opcode (BINOP_LESS); }
 674         ;
 675
 676 exp     :       exp '>' exp
 677                         { write_exp_elt_opcode (BINOP_GTR); }
 678         ;
 679
 680 exp     :       exp '&' exp
 681                         { write_exp_elt_opcode (BINOP_BITWISE_AND); }
 682         ;
 683
 684 exp     :       exp '^' exp
 685                         { write_exp_elt_opcode (BINOP_BITWISE_XOR); }
 686         ;
 687
 688 exp     :       exp '|' exp
 689                         { write_exp_elt_opcode (BINOP_BITWISE_IOR); }
 690         ;
 691
 692 exp     :       exp ANDAND exp
 693                         { write_exp_elt_opcode (BINOP_LOGICAL_AND); }
 694         ;
 695
 696 exp     :       exp OROR exp
 697                         { write_exp_elt_opcode (BINOP_LOGICAL_OR); }
 698         ;
 699
 700 exp     :       exp '?' exp ':' exp     %prec '?'
 701                         { write_exp_elt_opcode (TERNOP_COND); }
 702         ;
 703
 704 exp     :       exp '=' exp
 705                         { write_exp_elt_opcode (BINOP_ASSIGN); }
 706         ;
 707
 708 exp     :       exp ASSIGN_MODIFY exp
 709                         { write_exp_elt_opcode (BINOP_ASSIGN_MODIFY);
 710                           write_exp_elt_opcode ($2);
 711                           write_exp_elt_opcode (BINOP_ASSIGN_MODIFY); }
 712         ;
 713
 714 exp     :       INT
 715                         { write_exp_elt_opcode (OP_LONG);
 716                           write_exp_elt_type ($1.type);
 717                           write_exp_elt_longcst ((LONGEST)($1.val));
 718                           write_exp_elt_opcode (OP_LONG); }
 719         ;
 720
 721 exp     :       CHAR
 722                         {
 723                           struct stoken_vector vec;
 724                           vec.len = 1;
 725                           vec.tokens = &$1;
 726                           write_exp_string_vector ($1.type, &vec);
 727                         }
 728         ;
 729
 730 exp     :       NAME_OR_INT
 731                         { YYSTYPE val;
 732                           parse_number ($1.stoken.ptr, $1.stoken.length, 0, &val);
 733                           write_exp_elt_opcode (OP_LONG);
 734                           write_exp_elt_type (val.typed_val_int.type);
 735                           write_exp_elt_longcst ((LONGEST)val.typed_val_int.val);
 736                           write_exp_elt_opcode (OP_LONG);
 737                         }
 738         ;
 739
 740
 741 exp     :       FLOAT
 742                         { write_exp_elt_opcode (OP_DOUBLE);
 743                           write_exp_elt_type ($1.type);
 744                           write_exp_elt_dblcst ($1.dval);
 745                           write_exp_elt_opcode (OP_DOUBLE); }
 746         ;
 747
 748 exp     :       DECFLOAT
 749                         { write_exp_elt_opcode (OP_DECFLOAT);
 750                           write_exp_elt_type ($1.type);
 751                           write_exp_elt_decfloatcst ($1.val);
 752                           write_exp_elt_opcode (OP_DECFLOAT); }
 753         ;
 754
 755 exp     :       variable
 756         ;
 757
 758 exp     :       VARIABLE
 759                         {
 760                           write_dollar_variable ($1);
 761                         }
 762         ;
 763
 764 exp     :       SELECTOR '(' name ')'
 765                         {
 766                           write_exp_elt_opcode (OP_OBJC_SELECTOR);
 767                           write_exp_string ($3);
 768                           write_exp_elt_opcode (OP_OBJC_SELECTOR); }
 769         ;
 770
 771 exp     :       SIZEOF '(' type ')'     %prec UNARY
 772                         { write_exp_elt_opcode (OP_LONG);
 773                           write_exp_elt_type (lookup_signed_typename
 774                                               (parse_language, parse_gdbarch,
 775                                                "int"));
 776                           CHECK_TYPEDEF ($3);
 777                           write_exp_elt_longcst ((LONGEST) TYPE_LENGTH ($3));
 778                           write_exp_elt_opcode (OP_LONG); }
 779         ;
 780
 781 exp     :       REINTERPRET_CAST '<' type_exp '>' '(' exp ')' %prec UNARY
 782                         { write_exp_elt_opcode (UNOP_REINTERPRET_CAST); }
 783         ;
 784
 785 exp     :       STATIC_CAST '<' type_exp '>' '(' exp ')' %prec UNARY
 786                         { write_exp_elt_opcode (UNOP_CAST_TYPE); }
 787         ;
 788
 789 exp     :       DYNAMIC_CAST '<' type_exp '>' '(' exp ')' %prec UNARY
 790                         { write_exp_elt_opcode (UNOP_DYNAMIC_CAST); }
 791         ;
 792
 793 exp     :       CONST_CAST '<' type_exp '>' '(' exp ')' %prec UNARY
 794                         { /* We could do more error checking here, but
 795                              it doesn't seem worthwhile.  */
 796                           write_exp_elt_opcode (UNOP_CAST_TYPE); }
 797         ;
 798
 799 string_exp:
 800                 STRING
 801                         {
 802                           /* We copy the string here, and not in the
 803                              lexer, to guarantee that we do not leak a
 804                              string.  Note that we follow the
 805                              NUL-termination convention of the
 806                              lexer.  */
 807                           struct typed_stoken *vec = XNEW (struct typed_stoken);
 808                           $$.len = 1;
 809                           $$.tokens = vec;
 810
 811                           vec->type = $1.type;
 812                           vec->length = $1.length;
 813                           vec->ptr = malloc ($1.length + 1);
 814                           memcpy (vec->ptr, $1.ptr, $1.length + 1);
 815                         }
 816
 817         |       string_exp STRING
 818                         {
 819                           /* Note that we NUL-terminate here, but just
 820                              for convenience.  */
 821                           char *p;
 822                           ++$$.len;
 823                           $$.tokens = realloc ($$.tokens,
 824                                                $$.len * sizeof (struct typed_stoken));
 825
 826                           p = malloc ($2.length + 1);
 827                           memcpy (p, $2.ptr, $2.length + 1);
 828
 829                           $$.tokens[$$.len - 1].type = $2.type;
 830                           $$.tokens[$$.len - 1].length = $2.length;
 831                           $$.tokens[$$.len - 1].ptr = p;
 832                         }
 833                 ;
 834
 835 exp     :       string_exp
 836                         {
 837                           int i;
 838                           enum c_string_type type = C_STRING;
 839
 840                           for (i = 0; i < $1.len; ++i)
 841                             {
 842                               switch ($1.tokens[i].type)
 843                                 {
 844                                 case C_STRING:
 845                                   break;
 846                                 case C_WIDE_STRING:
 847                                 case C_STRING_16:
 848                                 case C_STRING_32:
 849                                   if (type != C_STRING
 850                                       && type != $1.tokens[i].type)
 851                                     error (_("Undefined string concatenation."));
 852                                   type = $1.tokens[i].type;
 853                                   break;
 854                                 default:
 855                                   /* internal error */
 856                                   internal_error (__FILE__, __LINE__,
 857                                                   "unrecognized type in string concatenation");
 858                                 }
 859                             }
 860
 861                           write_exp_string_vector (type, &$1);
 862                           for (i = 0; i < $1.len; ++i)
 863                             free ($1.tokens[i].ptr);
 864                           free ($1.tokens);
 865                         }
 866         ;
 867
 868 exp     :       NSSTRING        /* ObjC NextStep NSString constant
 869                                  * of the form '@' '"' string '"'.
 870                                  */
 871                         { write_exp_elt_opcode (OP_OBJC_NSSTRING);
 872                           write_exp_string ($1);
 873                           write_exp_elt_opcode (OP_OBJC_NSSTRING); }
 874         ;
 875
 876 /* C++.  */
 877 exp     :       TRUEKEYWORD
 878                         { write_exp_elt_opcode (OP_LONG);
 879                           write_exp_elt_type (parse_type->builtin_bool);
 880                           write_exp_elt_longcst ((LONGEST) 1);
 881                           write_exp_elt_opcode (OP_LONG); }
 882         ;
 883
 884 exp     :       FALSEKEYWORD
 885                         { write_exp_elt_opcode (OP_LONG);
 886                           write_exp_elt_type (parse_type->builtin_bool);
 887                           write_exp_elt_longcst ((LONGEST) 0);
 888                           write_exp_elt_opcode (OP_LONG); }
 889         ;
 890
 891 /* end of C++.  */
 892
 893 block   :       BLOCKNAME
 894                         {
 895                           if ($1.sym)
 896                             $$ = SYMBOL_BLOCK_VALUE ($1.sym);
 897                           else
 898                             error (_("No file or function \"%s\"."),
 899                                    copy_name ($1.stoken));
 900                         }
 901         |       FILENAME
 902                         {
 903                           $$ = $1;
 904                         }
 905         ;
 906
 907 block   :       block COLONCOLON name
 908                         { struct symbol *tem
 909                             = lookup_symbol (copy_name ($3), $1,
 910                                              VAR_DOMAIN, NULL);
 911                           if (!tem || SYMBOL_CLASS (tem) != LOC_BLOCK)
 912                             error (_("No function \"%s\" in specified context."),
 913                                    copy_name ($3));
 914                           $$ = SYMBOL_BLOCK_VALUE (tem); }
 915         ;
 916
 917 variable:       name_not_typename ENTRY
 918                         { struct symbol *sym = $1.sym;
 919
 920                           if (sym == NULL || !SYMBOL_IS_ARGUMENT (sym)
 921                               || !symbol_read_needs_frame (sym))
 922                             error (_("@entry can be used only for function "
 923                                      "parameters, not for \"%s\""),
 924                                    copy_name ($1.stoken));
 925
 926                           write_exp_elt_opcode (OP_VAR_ENTRY_VALUE);
 927                           write_exp_elt_sym (sym);
 928                           write_exp_elt_opcode (OP_VAR_ENTRY_VALUE);
 929                         }
 930         ;
 931
 932 variable:       block COLONCOLON name
 933                         { struct symbol *sym;
 934                           sym = lookup_symbol (copy_name ($3), $1,
 935                                                VAR_DOMAIN, NULL);
 936                           if (sym == 0)
 937                             error (_("No symbol \"%s\" in specified context."),
 938                                    copy_name ($3));
 939                           if (symbol_read_needs_frame (sym))
 940                             {
 941                               if (innermost_block == 0
 942                                   || contained_in (block_found,
 943                                                    innermost_block))
 944                                 innermost_block = block_found;
 945                             }
 946
 947                           write_exp_elt_opcode (OP_VAR_VALUE);
 948                           /* block_found is set by lookup_symbol.  */
 949                           write_exp_elt_block (block_found);
 950                           write_exp_elt_sym (sym);
 951                           write_exp_elt_opcode (OP_VAR_VALUE); }
 952         ;
 953
 954 qualified_name: TYPENAME COLONCOLON name
 955                         {
 956                           struct type *type = $1.type;
 957                           CHECK_TYPEDEF (type);
 958                           if (TYPE_CODE (type) != TYPE_CODE_STRUCT
 959                               && TYPE_CODE (type) != TYPE_CODE_UNION
 960                               && TYPE_CODE (type) != TYPE_CODE_NAMESPACE)
 961                             error (_("`%s' is not defined as an aggregate type."),
 962                                    TYPE_SAFE_NAME (type));
 963
 964                           write_exp_elt_opcode (OP_SCOPE);
 965                           write_exp_elt_type (type);
 966                           write_exp_string ($3);
 967                           write_exp_elt_opcode (OP_SCOPE);
 968                         }
 969         |       TYPENAME COLONCOLON '~' name
 970                         {
 971                           struct type *type = $1.type;
 972                           struct stoken tmp_token;
 973                           char *buf;
 974
 975                           CHECK_TYPEDEF (type);
 976                           if (TYPE_CODE (type) != TYPE_CODE_STRUCT
 977                               && TYPE_CODE (type) != TYPE_CODE_UNION
 978                               && TYPE_CODE (type) != TYPE_CODE_NAMESPACE)
 979                             error (_("`%s' is not defined as an aggregate type."),
 980                                    TYPE_SAFE_NAME (type));
 981                           buf = alloca ($4.length + 2);
 982                           tmp_token.ptr = buf;
 983                           tmp_token.length = $4.length + 1;
 984                           buf[0] = '~';
 985                           memcpy (buf+1, $4.ptr, $4.length);
 986                           buf[tmp_token.length] = 0;
 987
 988                           /* Check for valid destructor name.  */
 989                           destructor_name_p (tmp_token.ptr, $1.type);
 990                           write_exp_elt_opcode (OP_SCOPE);
 991                           write_exp_elt_type (type);
 992                           write_exp_string (tmp_token);
 993                           write_exp_elt_opcode (OP_SCOPE);
 994                         }
 995         |       TYPENAME COLONCOLON name COLONCOLON name
 996                         {
 997                           char *copy = copy_name ($3);
 998                           error (_("No type \"%s\" within class "
 999                                    "or namespace \"%s\"."),
1000                                  copy, TYPE_SAFE_NAME ($1.type));
1001                         }
1002         ;
1003
1004 variable:       qualified_name
1005         |       COLONCOLON name_not_typename
1006                         {
1007                           char *name = copy_name ($2.stoken);
1008                           struct symbol *sym;
1009                           struct bound_minimal_symbol msymbol;
1010
1011                           sym =
1012                             lookup_symbol (name, (const struct block *) NULL,
1013                                            VAR_DOMAIN, NULL);
1014                           if (sym)
1015                             {
1016                               write_exp_elt_opcode (OP_VAR_VALUE);
1017                               write_exp_elt_block (NULL);
1018                               write_exp_elt_sym (sym);
1019                               write_exp_elt_opcode (OP_VAR_VALUE);
1020                               break;
1021                             }
1022
1023                           msymbol = lookup_bound_minimal_symbol (name);
1024                           if (msymbol.minsym != NULL)
1025                             write_exp_msymbol (msymbol);
1026                           else if (!have_full_symbols () && !have_partial_symbols ())
1027                             error (_("No symbol table is loaded.  Use the \"file\" command."));
1028                           else
1029                             error (_("No symbol \"%s\" in current context."), name);
1030                         }
1031         ;
1032
1033 variable:       name_not_typename
1034                         { struct symbol *sym = $1.sym;
1035
1036                           if (sym)
1037                             {
1038                               if (symbol_read_needs_frame (sym))
1039                                 {
1040                                   if (innermost_block == 0
1041                                       || contained_in (block_found,
1042                                                        innermost_block))
1043                                     innermost_block = block_found;
1044                                 }
1045
1046                               write_exp_elt_opcode (OP_VAR_VALUE);
1047                               /* We want to use the selected frame, not
1048                                  another more inner frame which happens to
1049                                  be in the same block.  */
1050                               write_exp_elt_block (NULL);
1051                               write_exp_elt_sym (sym);
1052                               write_exp_elt_opcode (OP_VAR_VALUE);
1053                             }
1054                           else if ($1.is_a_field_of_this)
1055                             {
1056                               /* C++: it hangs off of `this'.  Must
1057                                  not inadvertently convert from a method call
1058                                  to data ref.  */
1059                               if (innermost_block == 0
1060                                   || contained_in (block_found,
1061                                                    innermost_block))
1062                                 innermost_block = block_found;
1063                               write_exp_elt_opcode (OP_THIS);
1064                               write_exp_elt_opcode (OP_THIS);
1065                               write_exp_elt_opcode (STRUCTOP_PTR);
1066                               write_exp_string ($1.stoken);
1067                               write_exp_elt_opcode (STRUCTOP_PTR);
1068                             }
1069                           else
1070                             {
1071                               struct bound_minimal_symbol msymbol;
1072                               char *arg = copy_name ($1.stoken);
1073
1074                               msymbol =
1075                                 lookup_bound_minimal_symbol (arg);
1076                               if (msymbol.minsym != NULL)
1077                                 write_exp_msymbol (msymbol);
1078                               else if (!have_full_symbols () && !have_partial_symbols ())
1079                                 error (_("No symbol table is loaded.  Use the \"file\" command."));
1080                               else
1081                                 error (_("No symbol \"%s\" in current context."),
1082                                        copy_name ($1.stoken));
1083                             }
1084                         }
1085         ;
1086
1087 space_identifier : '@' NAME
1088                 { insert_type_address_space (copy_name ($2.stoken)); }
1089         ;
1090
1091 const_or_volatile: const_or_volatile_noopt
1092         |
1093         ;
1094
1095 cv_with_space_id : const_or_volatile space_identifier const_or_volatile
1096         ;
1097
1098 const_or_volatile_or_space_identifier_noopt: cv_with_space_id
1099         | const_or_volatile_noopt
1100         ;
1101
1102 const_or_volatile_or_space_identifier:
1103                 const_or_volatile_or_space_identifier_noopt
1104         |
1105         ;
1106
1107 ptr_operator:
1108                 ptr_operator '*'
1109                         { insert_type (tp_pointer); }
1110                 const_or_volatile_or_space_identifier
1111         |       '*'
1112                         { insert_type (tp_pointer); }
1113                 const_or_volatile_or_space_identifier
1114         |       '&'
1115                         { insert_type (tp_reference); }
1116         |       '&' ptr_operator
1117                         { insert_type (tp_reference); }
1118         ;
1119
1120 ptr_operator_ts: ptr_operator
1121                         {
1122                           $$ = get_type_stack ();
1123                           /* This cleanup is eventually run by
1124                              c_parse.  */
1125                           make_cleanup (type_stack_cleanup, $$);
1126                         }
1127         ;
1128
1129 abs_decl:       ptr_operator_ts direct_abs_decl
1130                         { $$ = append_type_stack ($2, $1); }
1131         |       ptr_operator_ts
1132         |       direct_abs_decl
1133         ;
1134
1135 direct_abs_decl: '(' abs_decl ')'
1136                         { $$ = $2; }
1137         |       direct_abs_decl array_mod
1138                         {
1139                           push_type_stack ($1);
1140                           push_type_int ($2);
1141                           push_type (tp_array);
1142                           $$ = get_type_stack ();
1143                         }
1144         |       array_mod
1145                         {
1146                           push_type_int ($1);
1147                           push_type (tp_array);
1148                           $$ = get_type_stack ();
1149                         }
1150
1151         |       direct_abs_decl func_mod
1152                         {
1153                           push_type_stack ($1);
1154                           push_typelist ($2);
1155                           $$ = get_type_stack ();
1156                         }
1157         |       func_mod
1158                         {
1159                           push_typelist ($1);
1160                           $$ = get_type_stack ();
1161                         }
1162         ;
1163
1164 array_mod:      '[' ']'
1165                         { $$ = -1; }
1166         |       OBJC_LBRAC ']'
1167                         { $$ = -1; }
1168         |       '[' INT ']'
1169                         { $$ = $2.val; }
1170         |       OBJC_LBRAC INT ']'
1171                         { $$ = $2.val; }
1172         ;
1173
1174 func_mod:       '(' ')'
1175                         { $$ = NULL; }
1176         |       '(' parameter_typelist ')'
1177                         { $$ = $2; }
1178         ;
1179
1180 /* We used to try to recognize pointer to member types here, but
1181    that didn't work (shift/reduce conflicts meant that these rules never
1182    got executed).  The problem is that
1183      int (foo::bar::baz::bizzle)
1184    is a function type but
1185      int (foo::bar::baz::bizzle::*)
1186    is a pointer to member type.  Stroustrup loses again!  */
1187
1188 type    :       ptype
1189         ;
1190
1191 typebase  /* Implements (approximately): (type-qualifier)* type-specifier */
1192         :       TYPENAME
1193                         { $$ = $1.type; }
1194         |       INT_KEYWORD
1195                         { $$ = lookup_signed_typename (parse_language,
1196                                                        parse_gdbarch,
1197                                                        "int"); }
1198         |       LONG
1199                         { $$ = lookup_signed_typename (parse_language,
1200                                                        parse_gdbarch,
1201                                                        "long"); }
1202         |       SHORT
1203                         { $$ = lookup_signed_typename (parse_language,
1204                                                        parse_gdbarch,
1205                                                        "short"); }
1206         |       LONG INT_KEYWORD
1207                         { $$ = lookup_signed_typename (parse_language,
1208                                                        parse_gdbarch,
1209                                                        "long"); }
1210         |       LONG SIGNED_KEYWORD INT_KEYWORD
1211                         { $$ = lookup_signed_typename (parse_language,
1212                                                        parse_gdbarch,
1213                                                        "long"); }
1214         |       LONG SIGNED_KEYWORD
1215                         { $$ = lookup_signed_typename (parse_language,
1216                                                        parse_gdbarch,
1217                                                        "long"); }
1218         |       SIGNED_KEYWORD LONG INT_KEYWORD
1219                         { $$ = lookup_signed_typename (parse_language,
1220                                                        parse_gdbarch,
1221                                                        "long"); }
1222         |       UNSIGNED LONG INT_KEYWORD
1223                         { $$ = lookup_unsigned_typename (parse_language,
1224                                                          parse_gdbarch,
1225                                                          "long"); }
1226         |       LONG UNSIGNED INT_KEYWORD
1227                         { $$ = lookup_unsigned_typename (parse_language,
1228                                                          parse_gdbarch,
1229                                                          "long"); }
1230         |       LONG UNSIGNED
1231                         { $$ = lookup_unsigned_typename (parse_language,
1232                                                          parse_gdbarch,
1233                                                          "long"); }
1234         |       LONG LONG
1235                         { $$ = lookup_signed_typename (parse_language,
1236                                                        parse_gdbarch,
1237                                                        "long long"); }
1238         |       LONG LONG INT_KEYWORD
1239                         { $$ = lookup_signed_typename (parse_language,
1240                                                        parse_gdbarch,
1241                                                        "long long"); }
1242         |       LONG LONG SIGNED_KEYWORD INT_KEYWORD
1243                         { $$ = lookup_signed_typename (parse_language,
1244                                                        parse_gdbarch,
1245                                                        "long long"); }
1246         |       LONG LONG SIGNED_KEYWORD
1247                         { $$ = lookup_signed_typename (parse_language,
1248                                                        parse_gdbarch,
1249                                                        "long long"); }
1250         |       SIGNED_KEYWORD LONG LONG
1251                         { $$ = lookup_signed_typename (parse_language,
1252                                                        parse_gdbarch,
1253                                                        "long long"); }
1254         |       SIGNED_KEYWORD LONG LONG INT_KEYWORD
1255                         { $$ = lookup_signed_typename (parse_language,
1256                                                        parse_gdbarch,
1257                                                        "long long"); }
1258         |       UNSIGNED LONG LONG
1259                         { $$ = lookup_unsigned_typename (parse_language,
1260                                                          parse_gdbarch,
1261                                                          "long long"); }
1262         |       UNSIGNED LONG LONG INT_KEYWORD
1263                         { $$ = lookup_unsigned_typename (parse_language,
1264                                                          parse_gdbarch,
1265                                                          "long long"); }
1266         |       LONG LONG UNSIGNED
1267                         { $$ = lookup_unsigned_typename (parse_language,
1268                                                          parse_gdbarch,
1269                                                          "long long"); }
1270         |       LONG LONG UNSIGNED INT_KEYWORD
1271                         { $$ = lookup_unsigned_typename (parse_language,
1272                                                          parse_gdbarch,
1273                                                          "long long"); }
1274         |       SHORT INT_KEYWORD
1275                         { $$ = lookup_signed_typename (parse_language,
1276                                                        parse_gdbarch,
1277                                                        "short"); }
1278         |       SHORT SIGNED_KEYWORD INT_KEYWORD
1279                         { $$ = lookup_signed_typename (parse_language,
1280                                                        parse_gdbarch,
1281                                                        "short"); }
1282         |       SHORT SIGNED_KEYWORD
1283                         { $$ = lookup_signed_typename (parse_language,
1284                                                        parse_gdbarch,
1285                                                        "short"); }
1286         |       UNSIGNED SHORT INT_KEYWORD
1287                         { $$ = lookup_unsigned_typename (parse_language,
1288                                                          parse_gdbarch,
1289                                                          "short"); }
1290         |       SHORT UNSIGNED
1291                         { $$ = lookup_unsigned_typename (parse_language,
1292                                                          parse_gdbarch,
1293                                                          "short"); }
1294         |       SHORT UNSIGNED INT_KEYWORD
1295                         { $$ = lookup_unsigned_typename (parse_language,
1296                                                          parse_gdbarch,
1297                                                          "short"); }
1298         |       DOUBLE_KEYWORD
1299                         { $$ = lookup_typename (parse_language, parse_gdbarch,
1300                                                 "double", (struct block *) NULL,
1301                                                 0); }
1302         |       LONG DOUBLE_KEYWORD
1303                         { $$ = lookup_typename (parse_language, parse_gdbarch,
1304                                                 "long double",
1305                                                 (struct block *) NULL, 0); }
1306         |       STRUCT name
1307                         { $$ = lookup_struct (copy_name ($2),
1308                                               expression_context_block); }
1309         |       STRUCT COMPLETE
1310                         {
1311                           mark_completion_tag (TYPE_CODE_STRUCT, "", 0);
1312                           $$ = NULL;
1313                         }
1314         |       STRUCT name COMPLETE
1315                         {
1316                           mark_completion_tag (TYPE_CODE_STRUCT, $2.ptr,
1317                                                $2.length);
1318                           $$ = NULL;
1319                         }
1320         |       CLASS name
1321                         { $$ = lookup_struct (copy_name ($2),
1322                                               expression_context_block); }
1323         |       CLASS COMPLETE
1324                         {
1325                           mark_completion_tag (TYPE_CODE_CLASS, "", 0);
1326                           $$ = NULL;
1327                         }
1328         |       CLASS name COMPLETE
1329                         {
1330                           mark_completion_tag (TYPE_CODE_CLASS, $2.ptr,
1331                                                $2.length);
1332                           $$ = NULL;
1333                         }
1334         |       UNION name
1335                         { $$ = lookup_union (copy_name ($2),
1336                                              expression_context_block); }
1337         |       UNION COMPLETE
1338                         {
1339                           mark_completion_tag (TYPE_CODE_UNION, "", 0);
1340                           $$ = NULL;
1341                         }
1342         |       UNION name COMPLETE
1343                         {
1344                           mark_completion_tag (TYPE_CODE_UNION, $2.ptr,
1345                                                $2.length);
1346                           $$ = NULL;
1347                         }
1348         |       ENUM name
1349                         { $$ = lookup_enum (copy_name ($2),
1350                                             expression_context_block); }
1351         |       ENUM COMPLETE
1352                         {
1353                           mark_completion_tag (TYPE_CODE_ENUM, "", 0);
1354                           $$ = NULL;
1355                         }
1356         |       ENUM name COMPLETE
1357                         {
1358                           mark_completion_tag (TYPE_CODE_ENUM, $2.ptr,
1359                                                $2.length);
1360                           $$ = NULL;
1361                         }
1362         |       UNSIGNED typename
1363                         { $$ = lookup_unsigned_typename (parse_language,
1364                                                          parse_gdbarch,
1365                                                          TYPE_NAME($2.type)); }
1366         |       UNSIGNED
1367                         { $$ = lookup_unsigned_typename (parse_language,
1368                                                          parse_gdbarch,
1369                                                          "int"); }
1370         |       SIGNED_KEYWORD typename
1371                         { $$ = lookup_signed_typename (parse_language,
1372                                                        parse_gdbarch,
1373                                                        TYPE_NAME($2.type)); }
1374         |       SIGNED_KEYWORD
1375                         { $$ = lookup_signed_typename (parse_language,
1376                                                        parse_gdbarch,
1377                                                        "int"); }
1378                 /* It appears that this rule for templates is never
1379                    reduced; template recognition happens by lookahead
1380                    in the token processing code in yylex. */
1381         |       TEMPLATE name '<' type '>'
1382                         { $$ = lookup_template_type(copy_name($2), $4,
1383                                                     expression_context_block);
1384                         }
1385         | const_or_volatile_or_space_identifier_noopt typebase
1386                         { $$ = follow_types ($2); }
1387         | typebase const_or_volatile_or_space_identifier_noopt
1388                         { $$ = follow_types ($1); }
1389         ;
1390
1391 typename:       TYPENAME
1392         |       INT_KEYWORD
1393                 {
1394                   $$.stoken.ptr = "int";
1395                   $$.stoken.length = 3;
1396                   $$.type = lookup_signed_typename (parse_language,
1397                                                     parse_gdbarch,
1398                                                     "int");
1399                 }
1400         |       LONG
1401                 {
1402                   $$.stoken.ptr = "long";
1403                   $$.stoken.length = 4;
1404                   $$.type = lookup_signed_typename (parse_language,
1405                                                     parse_gdbarch,
1406                                                     "long");
1407                 }
1408         |       SHORT
1409                 {
1410                   $$.stoken.ptr = "short";
1411                   $$.stoken.length = 5;
1412                   $$.type = lookup_signed_typename (parse_language,
1413                                                     parse_gdbarch,
1414                                                     "short");
1415                 }
1416         ;
1417
1418 parameter_typelist:
1419                 nonempty_typelist
1420                         { check_parameter_typelist ($1); }
1421         |       nonempty_typelist ',' DOTDOTDOT
1422                         {
1423                           VEC_safe_push (type_ptr, $1, NULL);
1424                           check_parameter_typelist ($1);
1425                           $$ = $1;
1426                         }
1427         ;
1428
1429 nonempty_typelist
1430         :       type
1431                 {
1432                   VEC (type_ptr) *typelist = NULL;
1433                   VEC_safe_push (type_ptr, typelist, $1);
1434                   $$ = typelist;
1435                 }
1436         |       nonempty_typelist ',' type
1437                 {
1438                   VEC_safe_push (type_ptr, $1, $3);
1439                   $$ = $1;
1440                 }
1441         ;
1442
1443 ptype   :       typebase
1444         |       ptype abs_decl
1445                 {
1446                   push_type_stack ($2);
1447                   $$ = follow_types ($1);
1448                 }
1449         ;
1450
1451 conversion_type_id: typebase conversion_declarator
1452                 { $$ = follow_types ($1); }
1453         ;
1454
1455 conversion_declarator:  /* Nothing.  */
1456         | ptr_operator conversion_declarator
1457         ;
1458
1459 const_and_volatile:     CONST_KEYWORD VOLATILE_KEYWORD
1460         |               VOLATILE_KEYWORD CONST_KEYWORD
1461         ;
1462
1463 const_or_volatile_noopt:        const_and_volatile
1464                         { insert_type (tp_const);
1465                           insert_type (tp_volatile);
1466                         }
1467         |               CONST_KEYWORD
1468                         { insert_type (tp_const); }
1469         |               VOLATILE_KEYWORD
1470                         { insert_type (tp_volatile); }
1471         ;
1472
1473 operator:       OPERATOR NEW
1474                         { $$ = operator_stoken (" new"); }
1475         |       OPERATOR DELETE
1476                         { $$ = operator_stoken (" delete"); }
1477         |       OPERATOR NEW '[' ']'
1478                         { $$ = operator_stoken (" new[]"); }
1479         |       OPERATOR DELETE '[' ']'
1480                         { $$ = operator_stoken (" delete[]"); }
1481         |       OPERATOR NEW OBJC_LBRAC ']'
1482                         { $$ = operator_stoken (" new[]"); }
1483         |       OPERATOR DELETE OBJC_LBRAC ']'
1484                         { $$ = operator_stoken (" delete[]"); }
1485         |       OPERATOR '+'
1486                         { $$ = operator_stoken ("+"); }
1487         |       OPERATOR '-'
1488                         { $$ = operator_stoken ("-"); }
1489         |       OPERATOR '*'
1490                         { $$ = operator_stoken ("*"); }
1491         |       OPERATOR '/'
1492                         { $$ = operator_stoken ("/"); }
1493         |       OPERATOR '%'
1494                         { $$ = operator_stoken ("%"); }
1495         |       OPERATOR '^'
1496                         { $$ = operator_stoken ("^"); }
1497         |       OPERATOR '&'
1498                         { $$ = operator_stoken ("&"); }
1499         |       OPERATOR '|'
1500                         { $$ = operator_stoken ("|"); }
1501         |       OPERATOR '~'
1502                         { $$ = operator_stoken ("~"); }
1503         |       OPERATOR '!'
1504                         { $$ = operator_stoken ("!"); }
1505         |       OPERATOR '='
1506                         { $$ = operator_stoken ("="); }
1507         |       OPERATOR '<'
1508                         { $$ = operator_stoken ("<"); }
1509         |       OPERATOR '>'
1510                         { $$ = operator_stoken (">"); }
1511         |       OPERATOR ASSIGN_MODIFY
1512                         { const char *op = "unknown";
1513                           switch ($2)
1514                             {
1515                             case BINOP_RSH:
1516                               op = ">>=";
1517                               break;
1518                             case BINOP_LSH:
1519                               op = "<<=";
1520                               break;
1521                             case BINOP_ADD:
1522                               op = "+=";
1523                               break;
1524                             case BINOP_SUB:
1525                               op = "-=";
1526                               break;
1527                             case BINOP_MUL:
1528                               op = "*=";
1529                               break;
1530                             case BINOP_DIV:
1531                               op = "/=";
1532                               break;
1533                             case BINOP_REM:
1534                               op = "%=";
1535                               break;
1536                             case BINOP_BITWISE_IOR:
1537                               op = "|=";
1538                               break;
1539                             case BINOP_BITWISE_AND:
1540                               op = "&=";
1541                               break;
1542                             case BINOP_BITWISE_XOR:
1543                               op = "^=";
1544                               break;
1545                             default:
1546                               break;
1547                             }
1548
1549                           $$ = operator_stoken (op);
1550                         }
1551         |       OPERATOR LSH
1552                         { $$ = operator_stoken ("<<"); }
1553         |       OPERATOR RSH
1554                         { $$ = operator_stoken (">>"); }
1555         |       OPERATOR EQUAL
1556                         { $$ = operator_stoken ("=="); }
1557         |       OPERATOR NOTEQUAL
1558                         { $$ = operator_stoken ("!="); }
1559         |       OPERATOR LEQ
1560                         { $$ = operator_stoken ("<="); }
1561         |       OPERATOR GEQ
1562                         { $$ = operator_stoken (">="); }
1563         |       OPERATOR ANDAND
1564                         { $$ = operator_stoken ("&&"); }
1565         |       OPERATOR OROR
1566                         { $$ = operator_stoken ("||"); }
1567         |       OPERATOR INCREMENT
1568                         { $$ = operator_stoken ("++"); }
1569         |       OPERATOR DECREMENT
1570                         { $$ = operator_stoken ("--"); }
1571         |       OPERATOR ','
1572                         { $$ = operator_stoken (","); }
1573         |       OPERATOR ARROW_STAR
1574                         { $$ = operator_stoken ("->*"); }
1575         |       OPERATOR ARROW
1576                         { $$ = operator_stoken ("->"); }
1577         |       OPERATOR '(' ')'
1578                         { $$ = operator_stoken ("()"); }
1579         |       OPERATOR '[' ']'
1580                         { $$ = operator_stoken ("[]"); }
1581         |       OPERATOR OBJC_LBRAC ']'
1582                         { $$ = operator_stoken ("[]"); }
1583         |       OPERATOR conversion_type_id
1584                         { char *name;
1585                           long length;
1586                           struct ui_file *buf = mem_fileopen ();
1587
1588                           c_print_type ($2, NULL, buf, -1, 0,
1589                                         &type_print_raw_options);
1590                           name = ui_file_xstrdup (buf, &length);
1591                           ui_file_delete (buf);
1592                           $$ = operator_stoken (name);
1593                           free (name);
1594                         }
1595         ;
1596
1597
1598
1599 name    :       NAME { $$ = $1.stoken; }
1600         |       BLOCKNAME { $$ = $1.stoken; }
1601         |       TYPENAME { $$ = $1.stoken; }
1602         |       NAME_OR_INT  { $$ = $1.stoken; }
1603         |       UNKNOWN_CPP_NAME  { $$ = $1.stoken; }
1604         |       operator { $$ = $1; }
1605         ;
1606
1607 name_not_typename :     NAME
1608         |       BLOCKNAME
1609 /* These would be useful if name_not_typename was useful, but it is just
1610    a fake for "variable", so these cause reduce/reduce conflicts because
1611    the parser can't tell whether NAME_OR_INT is a name_not_typename (=variable,
1612    =exp) or just an exp.  If name_not_typename was ever used in an lvalue
1613    context where only a name could occur, this might be useful.
1614         |       NAME_OR_INT
1615  */
1616         |       operator
1617                         {
1618                           struct field_of_this_result is_a_field_of_this;
1619
1620                           $$.stoken = $1;
1621                           $$.sym = lookup_symbol ($1.ptr,
1622                                                   expression_context_block,
1623                                                   VAR_DOMAIN,
1624                                                   &is_a_field_of_this);
1625                           $$.is_a_field_of_this
1626                             = is_a_field_of_this.type != NULL;
1627                         }
1628         |       UNKNOWN_CPP_NAME
1629         ;
1630
1631 %%
1632
1633 /* Like write_exp_string, but prepends a '~'.  */
1634
1635 static void
1636 write_destructor_name (struct stoken token)
1637 {
1638   char *copy = alloca (token.length + 1);
1639
1640   copy[0] = '~';
1641   memcpy (&copy[1], token.ptr, token.length);
1642
1643   token.ptr = copy;
1644   ++token.length;
1645
1646   write_exp_string (token);
1647 }
1648
1649 /* Returns a stoken of the operator name given by OP (which does not
1650    include the string "operator").  */
1651 static struct stoken
1652 operator_stoken (const char *op)
1653 {
1654   static const char *operator_string = "operator";
1655   struct stoken st = { NULL, 0 };
1656   char *buf;
1657
1658   st.length = strlen (operator_string) + strlen (op);
1659   buf = malloc (st.length + 1);
1660   strcpy (buf, operator_string);
1661   strcat (buf, op);
1662   st.ptr = buf;
1663
1664   /* The toplevel (c_parse) will free the memory allocated here.  */
1665   make_cleanup (free, buf);
1666   return st;
1667 };
1668
1669 /* Validate a parameter typelist.  */
1670
1671 static void
1672 check_parameter_typelist (VEC (type_ptr) *params)
1673 {
1674   struct type *type;
1675   int ix;
1676
1677   for (ix = 0; VEC_iterate (type_ptr, params, ix, type); ++ix)
1678     {
1679       if (type != NULL && TYPE_CODE (check_typedef (type)) == TYPE_CODE_VOID)
1680         {
1681           if (ix == 0)
1682             {
1683               if (VEC_length (type_ptr, params) == 1)
1684                 {
1685                   /* Ok.  */
1686                   break;
1687                 }
1688               VEC_free (type_ptr, params);
1689               error (_("parameter types following 'void'"));
1690             }
1691           else
1692             {
1693               VEC_free (type_ptr, params);
1694               error (_("'void' invalid as parameter type"));
1695             }
1696         }
1697     }
1698 }
1699
1700 /* Take care of parsing a number (anything that starts with a digit).
1701    Set yylval and return the token type; update lexptr.
1702    LEN is the number of characters in it.  */
1703
1704 /*** Needs some error checking for the float case ***/
1705
1706 static int
1707 parse_number (const char *buf, int len, int parsed_float, YYSTYPE *putithere)
1708 {
1709   /* FIXME: Shouldn't these be unsigned?  We don't deal with negative values
1710      here, and we do kind of silly things like cast to unsigned.  */
1711   LONGEST n = 0;
1712   LONGEST prevn = 0;
1713   ULONGEST un;
1714
1715   int i = 0;
1716   int c;
1717   int base = input_radix;
1718   int unsigned_p = 0;
1719
1720   /* Number of "L" suffixes encountered.  */
1721   int long_p = 0;
1722
1723   /* We have found a "L" or "U" suffix.  */
1724   int found_suffix = 0;
1725
1726   ULONGEST high_bit;
1727   struct type *signed_type;
1728   struct type *unsigned_type;
1729   char *p;
1730
1731   p = alloca (len);
1732   memcpy (p, buf, len);
1733
1734   if (parsed_float)
1735     {
1736       /* If it ends at "df", "dd" or "dl", take it as type of decimal floating
1737          point.  Return DECFLOAT.  */
1738
1739       if (len >= 2 && p[len - 2] == 'd' && p[len - 1] == 'f')
1740         {
1741           p[len - 2] = '\0';
1742           putithere->typed_val_decfloat.type
1743             = parse_type->builtin_decfloat;
1744           decimal_from_string (putithere->typed_val_decfloat.val, 4,
1745                                gdbarch_byte_order (parse_gdbarch), p);
1746           p[len - 2] = 'd';
1747           return DECFLOAT;
1748         }
1749
1750       if (len >= 2 && p[len - 2] == 'd' && p[len - 1] == 'd')
1751         {
1752           p[len - 2] = '\0';
1753           putithere->typed_val_decfloat.type
1754             = parse_type->builtin_decdouble;
1755           decimal_from_string (putithere->typed_val_decfloat.val, 8,
1756                                gdbarch_byte_order (parse_gdbarch), p);
1757           p[len - 2] = 'd';
1758           return DECFLOAT;
1759         }
1760
1761       if (len >= 2 && p[len - 2] == 'd' && p[len - 1] == 'l')
1762         {
1763           p[len - 2] = '\0';
1764           putithere->typed_val_decfloat.type
1765             = parse_type->builtin_declong;
1766           decimal_from_string (putithere->typed_val_decfloat.val, 16,
1767                                gdbarch_byte_order (parse_gdbarch), p);
1768           p[len - 2] = 'd';
1769           return DECFLOAT;
1770         }
1771
1772       if (! parse_c_float (parse_gdbarch, p, len,
1773                            &putithere->typed_val_float.dval,
1774                            &putithere->typed_val_float.type))
1775         return ERROR;
1776       return FLOAT;
1777     }
1778
1779   /* Handle base-switching prefixes 0x, 0t, 0d, 0 */
1780   if (p[0] == '0')
1781     switch (p[1])
1782       {
1783       case 'x':
1784       case 'X':
1785         if (len >= 3)
1786           {
1787             p += 2;
1788             base = 16;
1789             len -= 2;
1790           }
1791         break;
1792
1793       case 'b':
1794       case 'B':
1795         if (len >= 3)
1796           {
1797             p += 2;
1798             base = 2;
1799             len -= 2;
1800           }
1801         break;
1802
1803       case 't':
1804       case 'T':
1805       case 'd':
1806       case 'D':
1807         if (len >= 3)
1808           {
1809             p += 2;
1810             base = 10;
1811             len -= 2;
1812           }
1813         break;
1814
1815       default:
1816         base = 8;
1817         break;
1818       }
1819
1820   while (len-- > 0)
1821     {
1822       c = *p++;
1823       if (c >= 'A' && c <= 'Z')
1824         c += 'a' - 'A';
1825       if (c != 'l' && c != 'u')
1826         n *= base;
1827       if (c >= '0' && c <= '9')
1828         {
1829           if (found_suffix)
1830             return ERROR;
1831           n += i = c - '0';
1832         }
1833       else
1834         {
1835           if (base > 10 && c >= 'a' && c <= 'f')
1836             {
1837               if (found_suffix)
1838                 return ERROR;
1839               n += i = c - 'a' + 10;
1840             }
1841           else if (c == 'l')
1842             {
1843               ++long_p;
1844               found_suffix = 1;
1845             }
1846           else if (c == 'u')
1847             {
1848               unsigned_p = 1;
1849               found_suffix = 1;
1850             }
1851           else
1852             return ERROR;       /* Char not a digit */
1853         }
1854       if (i >= base)
1855         return ERROR;           /* Invalid digit in this base */
1856
1857       /* Portably test for overflow (only works for nonzero values, so make
1858          a second check for zero).  FIXME: Can't we just make n and prevn
1859          unsigned and avoid this?  */
1860       if (c != 'l' && c != 'u' && (prevn >= n) && n != 0)
1861         unsigned_p = 1;         /* Try something unsigned */
1862
1863       /* Portably test for unsigned overflow.
1864          FIXME: This check is wrong; for example it doesn't find overflow
1865          on 0x123456789 when LONGEST is 32 bits.  */
1866       if (c != 'l' && c != 'u' && n != 0)
1867         {
1868           if ((unsigned_p && (ULONGEST) prevn >= (ULONGEST) n))
1869             error (_("Numeric constant too large."));
1870         }
1871       prevn = n;
1872     }
1873
1874   /* An integer constant is an int, a long, or a long long.  An L
1875      suffix forces it to be long; an LL suffix forces it to be long
1876      long.  If not forced to a larger size, it gets the first type of
1877      the above that it fits in.  To figure out whether it fits, we
1878      shift it right and see whether anything remains.  Note that we
1879      can't shift sizeof (LONGEST) * HOST_CHAR_BIT bits or more in one
1880      operation, because many compilers will warn about such a shift
1881      (which always produces a zero result).  Sometimes gdbarch_int_bit
1882      or gdbarch_long_bit will be that big, sometimes not.  To deal with
1883      the case where it is we just always shift the value more than
1884      once, with fewer bits each time.  */
1885
1886   un = (ULONGEST)n >> 2;
1887   if (long_p == 0
1888       && (un >> (gdbarch_int_bit (parse_gdbarch) - 2)) == 0)
1889     {
1890       high_bit = ((ULONGEST)1) << (gdbarch_int_bit (parse_gdbarch) - 1);
1891
1892       /* A large decimal (not hex or octal) constant (between INT_MAX
1893          and UINT_MAX) is a long or unsigned long, according to ANSI,
1894          never an unsigned int, but this code treats it as unsigned
1895          int.  This probably should be fixed.  GCC gives a warning on
1896          such constants.  */
1897
1898       unsigned_type = parse_type->builtin_unsigned_int;
1899       signed_type = parse_type->builtin_int;
1900     }
1901   else if (long_p <= 1
1902            && (un >> (gdbarch_long_bit (parse_gdbarch) - 2)) == 0)
1903     {
1904       high_bit = ((ULONGEST)1) << (gdbarch_long_bit (parse_gdbarch) - 1);
1905       unsigned_type = parse_type->builtin_unsigned_long;
1906       signed_type = parse_type->builtin_long;
1907     }
1908   else
1909     {
1910       int shift;
1911       if (sizeof (ULONGEST) * HOST_CHAR_BIT
1912           < gdbarch_long_long_bit (parse_gdbarch))
1913         /* A long long does not fit in a LONGEST.  */
1914         shift = (sizeof (ULONGEST) * HOST_CHAR_BIT - 1);
1915       else
1916         shift = (gdbarch_long_long_bit (parse_gdbarch) - 1);
1917       high_bit = (ULONGEST) 1 << shift;
1918       unsigned_type = parse_type->builtin_unsigned_long_long;
1919       signed_type = parse_type->builtin_long_long;
1920     }
1921
1922    putithere->typed_val_int.val = n;
1923
1924    /* If the high bit of the worked out type is set then this number
1925       has to be unsigned. */
1926
1927    if (unsigned_p || (n & high_bit))
1928      {
1929        putithere->typed_val_int.type = unsigned_type;
1930      }
1931    else
1932      {
1933        putithere->typed_val_int.type = signed_type;
1934      }
1935
1936    return INT;
1937 }
1938
1939 /* Temporary obstack used for holding strings.  */
1940 static struct obstack tempbuf;
1941 static int tempbuf_init;
1942
1943 /* Parse a C escape sequence.  The initial backslash of the sequence
1944    is at (*PTR)[-1].  *PTR will be updated to point to just after the
1945    last character of the sequence.  If OUTPUT is not NULL, the
1946    translated form of the escape sequence will be written there.  If
1947    OUTPUT is NULL, no output is written and the call will only affect
1948    *PTR.  If an escape sequence is expressed in target bytes, then the
1949    entire sequence will simply be copied to OUTPUT.  Return 1 if any
1950    character was emitted, 0 otherwise.  */
1951
1952 int
1953 c_parse_escape (const char **ptr, struct obstack *output)
1954 {
1955   const char *tokptr = *ptr;
1956   int result = 1;
1957
1958   /* Some escape sequences undergo character set conversion.  Those we
1959      translate here.  */
1960   switch (*tokptr)
1961     {
1962       /* Hex escapes do not undergo character set conversion, so keep
1963          the escape sequence for later.  */
1964     case 'x':
1965       if (output)
1966         obstack_grow_str (output, "\\x");
1967       ++tokptr;
1968       if (!isxdigit (*tokptr))
1969         error (_("\\x escape without a following hex digit"));
1970       while (isxdigit (*tokptr))
1971         {
1972           if (output)
1973             obstack_1grow (output, *tokptr);
1974           ++tokptr;
1975         }
1976       break;
1977
1978       /* Octal escapes do not undergo character set conversion, so
1979          keep the escape sequence for later.  */
1980     case '0':
1981     case '1':
1982     case '2':
1983     case '3':
1984     case '4':
1985     case '5':
1986     case '6':
1987     case '7':
1988       {
1989         int i;
1990         if (output)
1991           obstack_grow_str (output, "\\");
1992         for (i = 0;
1993              i < 3 && isdigit (*tokptr) && *tokptr != '8' && *tokptr != '9';
1994              ++i)
1995           {
1996             if (output)
1997               obstack_1grow (output, *tokptr);
1998             ++tokptr;
1999           }
2000       }
2001       break;
2002
2003       /* We handle UCNs later.  We could handle them here, but that
2004          would mean a spurious error in the case where the UCN could
2005          be converted to the target charset but not the host
2006          charset.  */
2007     case 'u':
2008     case 'U':
2009       {
2010         char c = *tokptr;
2011         int i, len = c == 'U' ? 8 : 4;
2012         if (output)
2013           {
2014             obstack_1grow (output, '\\');
2015             obstack_1grow (output, *tokptr);
2016           }
2017         ++tokptr;
2018         if (!isxdigit (*tokptr))
2019           error (_("\\%c escape without a following hex digit"), c);
2020         for (i = 0; i < len && isxdigit (*tokptr); ++i)
2021           {
2022             if (output)
2023               obstack_1grow (output, *tokptr);
2024             ++tokptr;
2025           }
2026       }
2027       break;
2028
2029       /* We must pass backslash through so that it does not
2030          cause quoting during the second expansion.  */
2031     case '\\':
2032       if (output)
2033         obstack_grow_str (output, "\\\\");
2034       ++tokptr;
2035       break;
2036
2037       /* Escapes which undergo conversion.  */
2038     case 'a':
2039       if (output)
2040         obstack_1grow (output, '\a');
2041       ++tokptr;
2042       break;
2043     case 'b':
2044       if (output)
2045         obstack_1grow (output, '\b');
2046       ++tokptr;
2047       break;
2048     case 'f':
2049       if (output)
2050         obstack_1grow (output, '\f');
2051       ++tokptr;
2052       break;
2053     case 'n':
2054       if (output)
2055         obstack_1grow (output, '\n');
2056       ++tokptr;
2057       break;
2058     case 'r':
2059       if (output)
2060         obstack_1grow (output, '\r');
2061       ++tokptr;
2062       break;
2063     case 't':
2064       if (output)
2065         obstack_1grow (output, '\t');
2066       ++tokptr;
2067       break;
2068     case 'v':
2069       if (output)
2070         obstack_1grow (output, '\v');
2071       ++tokptr;
2072       break;
2073
2074       /* GCC extension.  */
2075     case 'e':
2076       if (output)
2077         obstack_1grow (output, HOST_ESCAPE_CHAR);
2078       ++tokptr;
2079       break;
2080
2081       /* Backslash-newline expands to nothing at all.  */
2082     case '\n':
2083       ++tokptr;
2084       result = 0;
2085       break;
2086
2087       /* A few escapes just expand to the character itself.  */
2088     case '\'':
2089     case '\"':
2090     case '?':
2091       /* GCC extensions.  */
2092     case '(':
2093     case '{':
2094     case '[':
2095     case '%':
2096       /* Unrecognized escapes turn into the character itself.  */
2097     default:
2098       if (output)
2099         obstack_1grow (output, *tokptr);
2100       ++tokptr;
2101       break;
2102     }
2103   *ptr = tokptr;
2104   return result;
2105 }
2106
2107 /* Parse a string or character literal from TOKPTR.  The string or
2108    character may be wide or unicode.  *OUTPTR is set to just after the
2109    end of the literal in the input string.  The resulting token is
2110    stored in VALUE.  This returns a token value, either STRING or
2111    CHAR, depending on what was parsed.  *HOST_CHARS is set to the
2112    number of host characters in the literal.  */
2113 static int
2114 parse_string_or_char (const char *tokptr, const char **outptr,
2115                       struct typed_stoken *value, int *host_chars)
2116 {
2117   int quote;
2118   enum c_string_type type;
2119   int is_objc = 0;
2120
2121   /* Build the gdb internal form of the input string in tempbuf.  Note
2122      that the buffer is null byte terminated *only* for the
2123      convenience of debugging gdb itself and printing the buffer
2124      contents when the buffer contains no embedded nulls.  Gdb does
2125      not depend upon the buffer being null byte terminated, it uses
2126      the length string instead.  This allows gdb to handle C strings
2127      (as well as strings in other languages) with embedded null
2128      bytes */
2129
2130   if (!tempbuf_init)
2131     tempbuf_init = 1;
2132   else
2133     obstack_free (&tempbuf, NULL);
2134   obstack_init (&tempbuf);
2135
2136   /* Record the string type.  */
2137   if (*tokptr == 'L')
2138     {
2139       type = C_WIDE_STRING;
2140       ++tokptr;
2141     }
2142   else if (*tokptr == 'u')
2143     {
2144       type = C_STRING_16;
2145       ++tokptr;
2146     }
2147   else if (*tokptr == 'U')
2148     {
2149       type = C_STRING_32;
2150       ++tokptr;
2151     }
2152   else if (*tokptr == '@')
2153     {
2154       /* An Objective C string.  */
2155       is_objc = 1;
2156       type = C_STRING;
2157       ++tokptr;
2158     }
2159   else
2160     type = C_STRING;
2161
2162   /* Skip the quote.  */
2163   quote = *tokptr;
2164   if (quote == '\'')
2165     type |= C_CHAR;
2166   ++tokptr;
2167
2168   *host_chars = 0;
2169
2170   while (*tokptr)
2171     {
2172       char c = *tokptr;
2173       if (c == '\\')
2174         {
2175           ++tokptr;
2176           *host_chars += c_parse_escape (&tokptr, &tempbuf);
2177         }
2178       else if (c == quote)
2179         break;
2180       else
2181         {
2182           obstack_1grow (&tempbuf, c);
2183           ++tokptr;
2184           /* FIXME: this does the wrong thing with multi-byte host
2185              characters.  We could use mbrlen here, but that would
2186              make "set host-charset" a bit less useful.  */
2187           ++*host_chars;
2188         }
2189     }
2190
2191   if (*tokptr != quote)
2192     {
2193       if (quote == '"')
2194         error (_("Unterminated string in expression."));
2195       else
2196         error (_("Unmatched single quote."));
2197     }
2198   ++tokptr;
2199
2200   value->type = type;
2201   value->ptr = obstack_base (&tempbuf);
2202   value->length = obstack_object_size (&tempbuf);
2203
2204   *outptr = tokptr;
2205
2206   return quote == '"' ? (is_objc ? NSSTRING : STRING) : CHAR;
2207 }
2208
2209 /* This is used to associate some attributes with a token.  */
2210
2211 enum token_flags
2212 {
2213   /* If this bit is set, the token is C++-only.  */
2214
2215   FLAG_CXX = 1,
2216
2217   /* If this bit is set, the token is conditional: if there is a
2218      symbol of the same name, then the token is a symbol; otherwise,
2219      the token is a keyword.  */
2220
2221   FLAG_SHADOW = 2
2222 };
2223
2224 struct token
2225 {
2226   char *operator;
2227   int token;
2228   enum exp_opcode opcode;
2229   enum token_flags flags;
2230 };
2231
2232 static const struct token tokentab3[] =
2233   {
2234     {">>=", ASSIGN_MODIFY, BINOP_RSH, 0},
2235     {"<<=", ASSIGN_MODIFY, BINOP_LSH, 0},
2236     {"->*", ARROW_STAR, BINOP_END, FLAG_CXX},
2237     {"...", DOTDOTDOT, BINOP_END, 0}
2238   };
2239
2240 static const struct token tokentab2[] =
2241   {
2242     {"+=", ASSIGN_MODIFY, BINOP_ADD, 0},
2243     {"-=", ASSIGN_MODIFY, BINOP_SUB, 0},
2244     {"*=", ASSIGN_MODIFY, BINOP_MUL, 0},
2245     {"/=", ASSIGN_MODIFY, BINOP_DIV, 0},
2246     {"%=", ASSIGN_MODIFY, BINOP_REM, 0},
2247     {"|=", ASSIGN_MODIFY, BINOP_BITWISE_IOR, 0},
2248     {"&=", ASSIGN_MODIFY, BINOP_BITWISE_AND, 0},
2249     {"^=", ASSIGN_MODIFY, BINOP_BITWISE_XOR, 0},
2250     {"++", INCREMENT, BINOP_END, 0},
2251     {"--", DECREMENT, BINOP_END, 0},
2252     {"->", ARROW, BINOP_END, 0},
2253     {"&&", ANDAND, BINOP_END, 0},
2254     {"||", OROR, BINOP_END, 0},
2255     /* "::" is *not* only C++: gdb overrides its meaning in several
2256        different ways, e.g., 'filename'::func, function::variable.  */
2257     {"::", COLONCOLON, BINOP_END, 0},
2258     {"<<", LSH, BINOP_END, 0},
2259     {">>", RSH, BINOP_END, 0},
2260     {"==", EQUAL, BINOP_END, 0},
2261     {"!=", NOTEQUAL, BINOP_END, 0},
2262     {"<=", LEQ, BINOP_END, 0},
2263     {">=", GEQ, BINOP_END, 0},
2264     {".*", DOT_STAR, BINOP_END, FLAG_CXX}
2265   };
2266
2267 /* Identifier-like tokens.  */
2268 static const struct token ident_tokens[] =
2269   {
2270     {"unsigned", UNSIGNED, OP_NULL, 0},
2271     {"template", TEMPLATE, OP_NULL, FLAG_CXX},
2272     {"volatile", VOLATILE_KEYWORD, OP_NULL, 0},
2273     {"struct", STRUCT, OP_NULL, 0},
2274     {"signed", SIGNED_KEYWORD, OP_NULL, 0},
2275     {"sizeof", SIZEOF, OP_NULL, 0},
2276     {"double", DOUBLE_KEYWORD, OP_NULL, 0},
2277     {"false", FALSEKEYWORD, OP_NULL, FLAG_CXX},
2278     {"class", CLASS, OP_NULL, FLAG_CXX},
2279     {"union", UNION, OP_NULL, 0},
2280     {"short", SHORT, OP_NULL, 0},
2281     {"const", CONST_KEYWORD, OP_NULL, 0},
2282     {"enum", ENUM, OP_NULL, 0},
2283     {"long", LONG, OP_NULL, 0},
2284     {"true", TRUEKEYWORD, OP_NULL, FLAG_CXX},
2285     {"int", INT_KEYWORD, OP_NULL, 0},
2286     {"new", NEW, OP_NULL, FLAG_CXX},
2287     {"delete", DELETE, OP_NULL, FLAG_CXX},
2288     {"operator", OPERATOR, OP_NULL, FLAG_CXX},
2289
2290     {"and", ANDAND, BINOP_END, FLAG_CXX},
2291     {"and_eq", ASSIGN_MODIFY, BINOP_BITWISE_AND, FLAG_CXX},
2292     {"bitand", '&', OP_NULL, FLAG_CXX},
2293     {"bitor", '|', OP_NULL, FLAG_CXX},
2294     {"compl", '~', OP_NULL, FLAG_CXX},
2295     {"not", '!', OP_NULL, FLAG_CXX},
2296     {"not_eq", NOTEQUAL, BINOP_END, FLAG_CXX},
2297     {"or", OROR, BINOP_END, FLAG_CXX},
2298     {"or_eq", ASSIGN_MODIFY, BINOP_BITWISE_IOR, FLAG_CXX},
2299     {"xor", '^', OP_NULL, FLAG_CXX},
2300     {"xor_eq", ASSIGN_MODIFY, BINOP_BITWISE_XOR, FLAG_CXX},
2301
2302     {"const_cast", CONST_CAST, OP_NULL, FLAG_CXX },
2303     {"dynamic_cast", DYNAMIC_CAST, OP_NULL, FLAG_CXX },
2304     {"static_cast", STATIC_CAST, OP_NULL, FLAG_CXX },
2305     {"reinterpret_cast", REINTERPRET_CAST, OP_NULL, FLAG_CXX },
2306
2307     {"__typeof__", TYPEOF, OP_TYPEOF, 0 },
2308     {"__typeof", TYPEOF, OP_TYPEOF, 0 },
2309     {"typeof", TYPEOF, OP_TYPEOF, FLAG_SHADOW },
2310     {"__decltype", DECLTYPE, OP_DECLTYPE, FLAG_CXX },
2311     {"decltype", DECLTYPE, OP_DECLTYPE, FLAG_CXX | FLAG_SHADOW },
2312
2313     {"typeid", TYPEID, OP_TYPEID, FLAG_CXX}
2314   };
2315
2316 /* When we find that lexptr (the global var defined in parse.c) is
2317    pointing at a macro invocation, we expand the invocation, and call
2318    scan_macro_expansion to save the old lexptr here and point lexptr
2319    into the expanded text.  When we reach the end of that, we call
2320    end_macro_expansion to pop back to the value we saved here.  The
2321    macro expansion code promises to return only fully-expanded text,
2322    so we don't need to "push" more than one level.
2323
2324    This is disgusting, of course.  It would be cleaner to do all macro
2325    expansion beforehand, and then hand that to lexptr.  But we don't
2326    really know where the expression ends.  Remember, in a command like
2327
2328      (gdb) break *ADDRESS if CONDITION
2329
2330    we evaluate ADDRESS in the scope of the current frame, but we
2331    evaluate CONDITION in the scope of the breakpoint's location.  So
2332    it's simply wrong to try to macro-expand the whole thing at once.  */
2333 static const char *macro_original_text;
2334
2335 /* We save all intermediate macro expansions on this obstack for the
2336    duration of a single parse.  The expansion text may sometimes have
2337    to live past the end of the expansion, due to yacc lookahead.
2338    Rather than try to be clever about saving the data for a single
2339    token, we simply keep it all and delete it after parsing has
2340    completed.  */
2341 static struct obstack expansion_obstack;
2342
2343 static void
2344 scan_macro_expansion (char *expansion)
2345 {
2346   char *copy;
2347
2348   /* We'd better not be trying to push the stack twice.  */
2349   gdb_assert (! macro_original_text);
2350
2351   /* Copy to the obstack, and then free the intermediate
2352      expansion.  */
2353   copy = obstack_copy0 (&expansion_obstack, expansion, strlen (expansion));
2354   xfree (expansion);
2355
2356   /* Save the old lexptr value, so we can return to it when we're done
2357      parsing the expanded text.  */
2358   macro_original_text = lexptr;
2359   lexptr = copy;
2360 }
2361
2362
2363 static int
2364 scanning_macro_expansion (void)
2365 {
2366   return macro_original_text != 0;
2367 }
2368
2369
2370 static void
2371 finished_macro_expansion (void)
2372 {
2373   /* There'd better be something to pop back to.  */
2374   gdb_assert (macro_original_text);
2375
2376   /* Pop back to the original text.  */
2377   lexptr = macro_original_text;
2378   macro_original_text = 0;
2379 }
2380
2381
2382 static void
2383 scan_macro_cleanup (void *dummy)
2384 {
2385   if (macro_original_text)
2386     finished_macro_expansion ();
2387
2388   obstack_free (&expansion_obstack, NULL);
2389 }
2390
2391 /* Return true iff the token represents a C++ cast operator.  */
2392
2393 static int
2394 is_cast_operator (const char *token, int len)
2395 {
2396   return (! strncmp (token, "dynamic_cast", len)
2397           || ! strncmp (token, "static_cast", len)
2398           || ! strncmp (token, "reinterpret_cast", len)
2399           || ! strncmp (token, "const_cast", len));
2400 }
2401
2402 /* The scope used for macro expansion.  */
2403 static struct macro_scope *expression_macro_scope;
2404
2405 /* This is set if a NAME token appeared at the very end of the input
2406    string, with no whitespace separating the name from the EOF.  This
2407    is used only when parsing to do field name completion.  */
2408 static int saw_name_at_eof;
2409
2410 /* This is set if the previously-returned token was a structure
2411    operator -- either '.' or ARROW.  This is used only when parsing to
2412    do field name completion.  */
2413 static int last_was_structop;
2414
2415 /* Read one token, getting characters through lexptr.  */
2416
2417 static int
2418 lex_one_token (void)
2419 {
2420   int c;
2421   int namelen;
2422   unsigned int i;
2423   const char *tokstart;
2424   int saw_structop = last_was_structop;
2425   char *copy;
2426
2427   last_was_structop = 0;
2428
2429  retry:
2430
2431   /* Check if this is a macro invocation that we need to expand.  */
2432   if (! scanning_macro_expansion ())
2433     {
2434       char *expanded = macro_expand_next (&lexptr,
2435                                           standard_macro_lookup,
2436                                           expression_macro_scope);
2437
2438       if (expanded)
2439         scan_macro_expansion (expanded);
2440     }
2441
2442   prev_lexptr = lexptr;
2443
2444   tokstart = lexptr;
2445   /* See if it is a special token of length 3.  */
2446   for (i = 0; i < sizeof tokentab3 / sizeof tokentab3[0]; i++)
2447     if (strncmp (tokstart, tokentab3[i].operator, 3) == 0)
2448       {
2449         if ((tokentab3[i].flags & FLAG_CXX) != 0
2450             && parse_language->la_language != language_cplus)
2451           break;
2452
2453         lexptr += 3;
2454         yylval.opcode = tokentab3[i].opcode;
2455         return tokentab3[i].token;
2456       }
2457
2458   /* See if it is a special token of length 2.  */
2459   for (i = 0; i < sizeof tokentab2 / sizeof tokentab2[0]; i++)
2460     if (strncmp (tokstart, tokentab2[i].operator, 2) == 0)
2461       {
2462         if ((tokentab2[i].flags & FLAG_CXX) != 0
2463             && parse_language->la_language != language_cplus)
2464           break;
2465
2466         lexptr += 2;
2467         yylval.opcode = tokentab2[i].opcode;
2468         if (parse_completion && tokentab2[i].token == ARROW)
2469           last_was_structop = 1;
2470         return tokentab2[i].token;
2471       }
2472
2473   switch (c = *tokstart)
2474     {
2475     case 0:
2476       /* If we were just scanning the result of a macro expansion,
2477          then we need to resume scanning the original text.
2478          If we're parsing for field name completion, and the previous
2479          token allows such completion, return a COMPLETE token.
2480          Otherwise, we were already scanning the original text, and
2481          we're really done.  */
2482       if (scanning_macro_expansion ())
2483         {
2484           finished_macro_expansion ();
2485           goto retry;
2486         }
2487       else if (saw_name_at_eof)
2488         {
2489           saw_name_at_eof = 0;
2490           return COMPLETE;
2491         }
2492       else if (saw_structop)
2493         return COMPLETE;
2494       else
2495         return 0;
2496
2497     case ' ':
2498     case '\t':
2499     case '\n':
2500       lexptr++;
2501       goto retry;
2502
2503     case '[':
2504     case '(':
2505       paren_depth++;
2506       lexptr++;
2507       if (parse_language->la_language == language_objc && c == '[')
2508         return OBJC_LBRAC;
2509       return c;
2510
2511     case ']':
2512     case ')':
2513       if (paren_depth == 0)
2514         return 0;
2515       paren_depth--;
2516       lexptr++;
2517       return c;
2518
2519     case ',':
2520       if (comma_terminates
2521           && paren_depth == 0
2522           && ! scanning_macro_expansion ())
2523         return 0;
2524       lexptr++;
2525       return c;
2526
2527     case '.':
2528       /* Might be a floating point number.  */
2529       if (lexptr[1] < '0' || lexptr[1] > '9')
2530         {
2531           if (parse_completion)
2532             last_was_structop = 1;
2533           goto symbol;          /* Nope, must be a symbol. */
2534         }
2535       /* FALL THRU into number case.  */
2536
2537     case '0':
2538     case '1':
2539     case '2':
2540     case '3':
2541     case '4':
2542     case '5':
2543     case '6':
2544     case '7':
2545     case '8':
2546     case '9':
2547       {
2548         /* It's a number.  */
2549         int got_dot = 0, got_e = 0, toktype;
2550         const char *p = tokstart;
2551         int hex = input_radix > 10;
2552
2553         if (c == '0' && (p[1] == 'x' || p[1] == 'X'))
2554           {
2555             p += 2;
2556             hex = 1;
2557           }
2558         else if (c == '0' && (p[1]=='t' || p[1]=='T' || p[1]=='d' || p[1]=='D'))
2559           {
2560             p += 2;
2561             hex = 0;
2562           }
2563
2564         for (;; ++p)
2565           {
2566             /* This test includes !hex because 'e' is a valid hex digit
2567                and thus does not indicate a floating point number when
2568                the radix is hex.  */
2569             if (!hex && !got_e && (*p == 'e' || *p == 'E'))
2570               got_dot = got_e = 1;
2571             /* This test does not include !hex, because a '.' always indicates
2572                a decimal floating point number regardless of the radix.  */
2573             else if (!got_dot && *p == '.')
2574               got_dot = 1;
2575             else if (got_e && (p[-1] == 'e' || p[-1] == 'E')
2576                      && (*p == '-' || *p == '+'))
2577               /* This is the sign of the exponent, not the end of the
2578                  number.  */
2579               continue;
2580             /* We will take any letters or digits.  parse_number will
2581                complain if past the radix, or if L or U are not final.  */
2582             else if ((*p < '0' || *p > '9')
2583                      && ((*p < 'a' || *p > 'z')
2584                                   && (*p < 'A' || *p > 'Z')))
2585               break;
2586           }
2587         toktype = parse_number (tokstart, p - tokstart, got_dot|got_e, &yylval);
2588         if (toktype == ERROR)
2589           {
2590             char *err_copy = (char *) alloca (p - tokstart + 1);
2591
2592             memcpy (err_copy, tokstart, p - tokstart);
2593             err_copy[p - tokstart] = 0;
2594             error (_("Invalid number \"%s\"."), err_copy);
2595           }
2596         lexptr = p;
2597         return toktype;
2598       }
2599
2600     case '@':
2601       {
2602         const char *p = &tokstart[1];
2603         size_t len = strlen ("entry");
2604
2605         if (parse_language->la_language == language_objc)
2606           {
2607             size_t len = strlen ("selector");
2608
2609             if (strncmp (p, "selector", len) == 0
2610                 && (p[len] == '\0' || isspace (p[len])))
2611               {
2612                 lexptr = p + len;
2613                 return SELECTOR;
2614               }
2615             else if (*p == '"')
2616               goto parse_string;
2617           }
2618
2619         while (isspace (*p))
2620           p++;
2621         if (strncmp (p, "entry", len) == 0 && !isalnum (p[len])
2622             && p[len] != '_')
2623           {
2624             lexptr = &p[len];
2625             return ENTRY;
2626           }
2627       }
2628       /* FALLTHRU */
2629     case '+':
2630     case '-':
2631     case '*':
2632     case '/':
2633     case '%':
2634     case '|':
2635     case '&':
2636     case '^':
2637     case '~':
2638     case '!':
2639     case '<':
2640     case '>':
2641     case '?':
2642     case ':':
2643     case '=':
2644     case '{':
2645     case '}':
2646     symbol:
2647       lexptr++;
2648       return c;
2649
2650     case 'L':
2651     case 'u':
2652     case 'U':
2653       if (tokstart[1] != '"' && tokstart[1] != '\'')
2654         break;
2655       /* Fall through.  */
2656     case '\'':
2657     case '"':
2658
2659     parse_string:
2660       {
2661         int host_len;
2662         int result = parse_string_or_char (tokstart, &lexptr, &yylval.tsval,
2663                                            &host_len);
2664         if (result == CHAR)
2665           {
2666             if (host_len == 0)
2667               error (_("Empty character constant."));
2668             else if (host_len > 2 && c == '\'')
2669               {
2670                 ++tokstart;
2671                 namelen = lexptr - tokstart - 1;
2672                 goto tryname;
2673               }
2674             else if (host_len > 1)
2675               error (_("Invalid character constant."));
2676           }
2677         return result;
2678       }
2679     }
2680
2681   if (!(c == '_' || c == '$'
2682         || (c >= 'a' && c <= 'z') || (c >= 'A' && c <= 'Z')))
2683     /* We must have come across a bad character (e.g. ';').  */
2684     error (_("Invalid character '%c' in expression."), c);
2685
2686   /* It's a name.  See how long it is.  */
2687   namelen = 0;
2688   for (c = tokstart[namelen];
2689        (c == '_' || c == '$' || (c >= '0' && c <= '9')
2690         || (c >= 'a' && c <= 'z') || (c >= 'A' && c <= 'Z') || c == '<');)
2691     {
2692       /* Template parameter lists are part of the name.
2693          FIXME: This mishandles `print $a<4&&$a>3'.  */
2694
2695       if (c == '<')
2696         {
2697           if (! is_cast_operator (tokstart, namelen))
2698             {
2699               /* Scan ahead to get rest of the template specification.  Note
2700                  that we look ahead only when the '<' adjoins non-whitespace
2701                  characters; for comparison expressions, e.g. "a < b > c",
2702                  there must be spaces before the '<', etc. */
2703
2704               const char *p = find_template_name_end (tokstart + namelen);
2705
2706               if (p)
2707                 namelen = p - tokstart;
2708             }
2709           break;
2710         }
2711       c = tokstart[++namelen];
2712     }
2713
2714   /* The token "if" terminates the expression and is NOT removed from
2715      the input stream.  It doesn't count if it appears in the
2716      expansion of a macro.  */
2717   if (namelen == 2
2718       && tokstart[0] == 'i'
2719       && tokstart[1] == 'f'
2720       && ! scanning_macro_expansion ())
2721     {
2722       return 0;
2723     }
2724
2725   /* For the same reason (breakpoint conditions), "thread N"
2726      terminates the expression.  "thread" could be an identifier, but
2727      an identifier is never followed by a number without intervening
2728      punctuation.  "task" is similar.  Handle abbreviations of these,
2729      similarly to breakpoint.c:find_condition_and_thread.  */
2730   if (namelen >= 1
2731       && (strncmp (tokstart, "thread", namelen) == 0
2732           || strncmp (tokstart, "task", namelen) == 0)
2733       && (tokstart[namelen] == ' ' || tokstart[namelen] == '\t')
2734       && ! scanning_macro_expansion ())
2735     {
2736       const char *p = tokstart + namelen + 1;
2737
2738       while (*p == ' ' || *p == '\t')
2739         p++;
2740       if (*p >= '0' && *p <= '9')
2741         return 0;
2742     }
2743
2744   lexptr += namelen;
2745
2746   tryname:
2747
2748   yylval.sval.ptr = tokstart;
2749   yylval.sval.length = namelen;
2750
2751   /* Catch specific keywords.  */
2752   copy = copy_name (yylval.sval);
2753   for (i = 0; i < sizeof ident_tokens / sizeof ident_tokens[0]; i++)
2754     if (strcmp (copy, ident_tokens[i].operator) == 0)
2755       {
2756         if ((ident_tokens[i].flags & FLAG_CXX) != 0
2757             && parse_language->la_language != language_cplus)
2758           break;
2759
2760         if ((ident_tokens[i].flags & FLAG_SHADOW) != 0)
2761           {
2762             struct field_of_this_result is_a_field_of_this;
2763
2764             if (lookup_symbol (copy, expression_context_block,
2765                                VAR_DOMAIN,
2766                                (parse_language->la_language == language_cplus
2767                                 ? &is_a_field_of_this
2768                                 : NULL))
2769                 != NULL)
2770               {
2771                 /* The keyword is shadowed.  */
2772                 break;
2773               }
2774           }
2775
2776         /* It is ok to always set this, even though we don't always
2777            strictly need to.  */
2778         yylval.opcode = ident_tokens[i].opcode;
2779         return ident_tokens[i].token;
2780       }
2781
2782   if (*tokstart == '$')
2783     return VARIABLE;
2784
2785   if (parse_completion && *lexptr == '\0')
2786     saw_name_at_eof = 1;
2787
2788   yylval.ssym.stoken = yylval.sval;
2789   yylval.ssym.sym = NULL;
2790   yylval.ssym.is_a_field_of_this = 0;
2791   return NAME;
2792 }
2793
2794 /* An object of this type is pushed on a FIFO by the "outer" lexer.  */
2795 typedef struct
2796 {
2797   int token;
2798   YYSTYPE value;
2799 } token_and_value;
2800
2801 DEF_VEC_O (token_and_value);
2802
2803 /* A FIFO of tokens that have been read but not yet returned to the
2804    parser.  */
2805 static VEC (token_and_value) *token_fifo;
2806
2807 /* Non-zero if the lexer should return tokens from the FIFO.  */
2808 static int popping;
2809
2810 /* Temporary storage for c_lex; this holds symbol names as they are
2811    built up.  */
2812 static struct obstack name_obstack;
2813
2814 /* Classify a NAME token.  The contents of the token are in `yylval'.
2815    Updates yylval and returns the new token type.  BLOCK is the block
2816    in which lookups start; this can be NULL to mean the global
2817    scope.  */
2818 static int
2819 classify_name (const struct block *block)
2820 {
2821   struct symbol *sym;
2822   char *copy;
2823   struct field_of_this_result is_a_field_of_this;
2824
2825   copy = copy_name (yylval.sval);
2826
2827   /* Initialize this in case we *don't* use it in this call; that way
2828      we can refer to it unconditionally below.  */
2829   memset (&is_a_field_of_this, 0, sizeof (is_a_field_of_this));
2830
2831   sym = lookup_symbol (copy, block, VAR_DOMAIN,
2832                        parse_language->la_name_of_this
2833                        ? &is_a_field_of_this : NULL);
2834
2835   if (sym && SYMBOL_CLASS (sym) == LOC_BLOCK)
2836     {
2837       yylval.ssym.sym = sym;
2838       yylval.ssym.is_a_field_of_this = is_a_field_of_this.type != NULL;
2839       return BLOCKNAME;
2840     }
2841   else if (!sym)
2842     {
2843       /* See if it's a file name. */
2844       struct symtab *symtab;
2845
2846       symtab = lookup_symtab (copy);
2847       if (symtab)
2848         {
2849           yylval.bval = BLOCKVECTOR_BLOCK (BLOCKVECTOR (symtab), STATIC_BLOCK);
2850           return FILENAME;
2851         }
2852
2853       /* If we found a field of 'this', we might have erroneously
2854          found a constructor where we wanted a type name.  Handle this
2855          case by noticing that we found a constructor and then look up
2856          the type tag instead.  */
2857       if (is_a_field_of_this.type != NULL
2858           && is_a_field_of_this.fn_field != NULL
2859           && TYPE_FN_FIELD_CONSTRUCTOR (is_a_field_of_this.fn_field->fn_fields,
2860                                         0))
2861         {
2862           struct field_of_this_result inner_is_a_field_of_this;
2863
2864           sym = lookup_symbol (copy, block, STRUCT_DOMAIN,
2865                                &inner_is_a_field_of_this);
2866           if (sym != NULL)
2867             {
2868               yylval.tsym.type = SYMBOL_TYPE (sym);
2869               return TYPENAME;
2870             }
2871         }
2872     }
2873
2874   if (sym && SYMBOL_CLASS (sym) == LOC_TYPEDEF)
2875     {
2876       yylval.tsym.type = SYMBOL_TYPE (sym);
2877       return TYPENAME;
2878     }
2879
2880   yylval.tsym.type
2881     = language_lookup_primitive_type_by_name (parse_language,
2882                                               parse_gdbarch, copy);
2883   if (yylval.tsym.type != NULL)
2884     return TYPENAME;
2885
2886   /* See if it's an ObjC classname.  */
2887   if (parse_language->la_language == language_objc && !sym)
2888     {
2889       CORE_ADDR Class = lookup_objc_class (parse_gdbarch, copy);
2890       if (Class)
2891         {
2892           yylval.class.class = Class;
2893           sym = lookup_struct_typedef (copy, expression_context_block, 1);
2894           if (sym)
2895             yylval.class.type = SYMBOL_TYPE (sym);
2896           return CLASSNAME;
2897         }
2898     }
2899
2900   /* Input names that aren't symbols but ARE valid hex numbers, when
2901      the input radix permits them, can be names or numbers depending
2902      on the parse.  Note we support radixes > 16 here.  */
2903   if (!sym
2904       && ((copy[0] >= 'a' && copy[0] < 'a' + input_radix - 10)
2905           || (copy[0] >= 'A' && copy[0] < 'A' + input_radix - 10)))
2906     {
2907       YYSTYPE newlval;  /* Its value is ignored.  */
2908       int hextype = parse_number (copy, yylval.sval.length, 0, &newlval);
2909       if (hextype == INT)
2910         {
2911           yylval.ssym.sym = sym;
2912           yylval.ssym.is_a_field_of_this = is_a_field_of_this.type != NULL;
2913           return NAME_OR_INT;
2914         }
2915     }
2916
2917   /* Any other kind of symbol */
2918   yylval.ssym.sym = sym;
2919   yylval.ssym.is_a_field_of_this = is_a_field_of_this.type != NULL;
2920
2921   if (sym == NULL
2922       && parse_language->la_language == language_cplus
2923       && is_a_field_of_this.type == NULL
2924       && !lookup_minimal_symbol (copy, NULL, NULL))
2925     return UNKNOWN_CPP_NAME;
2926
2927   return NAME;
2928 }
2929
2930 /* Like classify_name, but used by the inner loop of the lexer, when a
2931    name might have already been seen.  CONTEXT is the context type, or
2932    NULL if this is the first component of a name.  */
2933
2934 static int
2935 classify_inner_name (const struct block *block, struct type *context)
2936 {
2937   struct type *type;
2938   char *copy;
2939
2940   if (context == NULL)
2941     return classify_name (block);
2942
2943   type = check_typedef (context);
2944   if (TYPE_CODE (type) != TYPE_CODE_STRUCT
2945       && TYPE_CODE (type) != TYPE_CODE_UNION
2946       && TYPE_CODE (type) != TYPE_CODE_NAMESPACE)
2947     return ERROR;
2948
2949   copy = copy_name (yylval.ssym.stoken);
2950   yylval.ssym.sym = cp_lookup_nested_symbol (type, copy, block);
2951   if (yylval.ssym.sym == NULL)
2952     return ERROR;
2953
2954   switch (SYMBOL_CLASS (yylval.ssym.sym))
2955     {
2956     case LOC_BLOCK:
2957     case LOC_LABEL:
2958       return ERROR;
2959
2960     case LOC_TYPEDEF:
2961       yylval.tsym.type = SYMBOL_TYPE (yylval.ssym.sym);;
2962       return TYPENAME;
2963
2964     default:
2965       return NAME;
2966     }
2967   internal_error (__FILE__, __LINE__, _("not reached"));
2968 }
2969
2970 /* The outer level of a two-level lexer.  This calls the inner lexer
2971    to return tokens.  It then either returns these tokens, or
2972    aggregates them into a larger token.  This lets us work around a
2973    problem in our parsing approach, where the parser could not
2974    distinguish between qualified names and qualified types at the
2975    right point.
2976
2977    This approach is still not ideal, because it mishandles template
2978    types.  See the comment in lex_one_token for an example.  However,
2979    this is still an improvement over the earlier approach, and will
2980    suffice until we move to better parsing technology.  */
2981 static int
2982 yylex (void)
2983 {
2984   token_and_value current;
2985   int first_was_coloncolon, last_was_coloncolon;
2986   struct type *context_type = NULL;
2987   int last_to_examine, next_to_examine, checkpoint;
2988   const struct block *search_block;
2989
2990   if (popping && !VEC_empty (token_and_value, token_fifo))
2991     goto do_pop;
2992   popping = 0;
2993
2994   /* Read the first token and decide what to do.  Most of the
2995      subsequent code is C++-only; but also depends on seeing a "::" or
2996      name-like token.  */
2997   current.token = lex_one_token ();
2998   if (current.token == NAME)
2999     current.token = classify_name (expression_context_block);
3000   if (parse_language->la_language != language_cplus
3001       || (current.token != TYPENAME && current.token != COLONCOLON
3002           && current.token != FILENAME))
3003     return current.token;
3004
3005   /* Read any sequence of alternating "::" and name-like tokens into
3006      the token FIFO.  */
3007   current.value = yylval;
3008   VEC_safe_push (token_and_value, token_fifo, &current);
3009   last_was_coloncolon = current.token == COLONCOLON;
3010   while (1)
3011     {
3012       current.token = lex_one_token ();
3013       current.value = yylval;
3014       VEC_safe_push (token_and_value, token_fifo, &current);
3015
3016       if ((last_was_coloncolon && current.token != NAME)
3017           || (!last_was_coloncolon && current.token != COLONCOLON))
3018         break;
3019       last_was_coloncolon = !last_was_coloncolon;
3020     }
3021   popping = 1;
3022
3023   /* We always read one extra token, so compute the number of tokens
3024      to examine accordingly.  */
3025   last_to_examine = VEC_length (token_and_value, token_fifo) - 2;
3026   next_to_examine = 0;
3027
3028   current = *VEC_index (token_and_value, token_fifo, next_to_examine);
3029   ++next_to_examine;
3030
3031   obstack_free (&name_obstack, obstack_base (&name_obstack));
3032   checkpoint = 0;
3033   if (current.token == FILENAME)
3034     search_block = current.value.bval;
3035   else if (current.token == COLONCOLON)
3036     search_block = NULL;
3037   else
3038     {
3039       gdb_assert (current.token == TYPENAME);
3040       search_block = expression_context_block;
3041       obstack_grow (&name_obstack, current.value.sval.ptr,
3042                     current.value.sval.length);
3043       context_type = current.value.tsym.type;
3044       checkpoint = 1;
3045     }
3046
3047   first_was_coloncolon = current.token == COLONCOLON;
3048   last_was_coloncolon = first_was_coloncolon;
3049
3050   while (next_to_examine <= last_to_examine)
3051     {
3052       token_and_value *next;
3053
3054       next = VEC_index (token_and_value, token_fifo, next_to_examine);
3055       ++next_to_examine;
3056
3057       if (next->token == NAME && last_was_coloncolon)
3058         {
3059           int classification;
3060
3061           yylval = next->value;
3062           classification = classify_inner_name (search_block, context_type);
3063           /* We keep going until we either run out of names, or until
3064              we have a qualified name which is not a type.  */
3065           if (classification != TYPENAME && classification != NAME)
3066             break;
3067
3068           /* Accept up to this token.  */
3069           checkpoint = next_to_examine;
3070
3071           /* Update the partial name we are constructing.  */
3072           if (context_type != NULL)
3073             {
3074               /* We don't want to put a leading "::" into the name.  */
3075               obstack_grow_str (&name_obstack, "::");
3076             }
3077           obstack_grow (&name_obstack, next->value.sval.ptr,
3078                         next->value.sval.length);
3079
3080           yylval.sval.ptr = obstack_base (&name_obstack);
3081           yylval.sval.length = obstack_object_size (&name_obstack);
3082           current.value = yylval;
3083           current.token = classification;
3084
3085           last_was_coloncolon = 0;
3086
3087           if (classification == NAME)
3088             break;
3089
3090           context_type = yylval.tsym.type;
3091         }
3092       else if (next->token == COLONCOLON && !last_was_coloncolon)
3093         last_was_coloncolon = 1;
3094       else
3095         {
3096           /* We've reached the end of the name.  */
3097           break;
3098         }
3099     }
3100
3101   /* If we have a replacement token, install it as the first token in
3102      the FIFO, and delete the other constituent tokens.  */
3103   if (checkpoint > 0)
3104     {
3105       current.value.sval.ptr = obstack_copy0 (&expansion_obstack,
3106                                               current.value.sval.ptr,
3107                                               current.value.sval.length);
3108
3109       VEC_replace (token_and_value, token_fifo, 0, &current);
3110       if (checkpoint > 1)
3111         VEC_block_remove (token_and_value, token_fifo, 1, checkpoint - 1);
3112     }
3113
3114  do_pop:
3115   current = *VEC_index (token_and_value, token_fifo, 0);
3116   VEC_ordered_remove (token_and_value, token_fifo, 0);
3117   yylval = current.value;
3118   return current.token;
3119 }
3120
3121 int
3122 c_parse (void)
3123 {
3124   int result;
3125   struct cleanup *back_to = make_cleanup (free_current_contents,
3126                                           &expression_macro_scope);
3127
3128   /* Set up the scope for macro expansion.  */
3129   expression_macro_scope = NULL;
3130
3131   if (expression_context_block)
3132     expression_macro_scope
3133       = sal_macro_scope (find_pc_line (expression_context_pc, 0));
3134   else
3135     expression_macro_scope = default_macro_scope ();
3136   if (! expression_macro_scope)
3137     expression_macro_scope = user_macro_scope ();
3138
3139   /* Initialize macro expansion code.  */
3140   obstack_init (&expansion_obstack);
3141   gdb_assert (! macro_original_text);
3142   make_cleanup (scan_macro_cleanup, 0);
3143
3144   make_cleanup_restore_integer (&yydebug);
3145   yydebug = parser_debug;
3146
3147   /* Initialize some state used by the lexer.  */
3148   last_was_structop = 0;
3149   saw_name_at_eof = 0;
3150
3151   VEC_free (token_and_value, token_fifo);
3152   popping = 0;
3153   obstack_init (&name_obstack);
3154   make_cleanup_obstack_free (&name_obstack);
3155
3156   result = yyparse ();
3157   do_cleanups (back_to);
3158   return result;
3159 }
3160
3161 /* This is called via the YYPRINT macro when parser debugging is
3162    enabled.  It prints a token's value.  */
3163
3164 static void
3165 c_print_token (FILE *file, int type, YYSTYPE value)
3166 {
3167   switch (type)
3168     {
3169     case INT:
3170       fprintf (file, "typed_val_int<%s, %s>",
3171                TYPE_SAFE_NAME (value.typed_val_int.type),
3172                pulongest (value.typed_val_int.val));
3173       break;
3174
3175     case CHAR:
3176     case STRING:
3177       {
3178         char *copy = alloca (value.tsval.length + 1);
3179
3180         memcpy (copy, value.tsval.ptr, value.tsval.length);
3181         copy[value.tsval.length] = '\0';
3182
3183         fprintf (file, "tsval<type=%d, %s>", value.tsval.type, copy);
3184       }
3185       break;
3186
3187     case NSSTRING:
3188     case VARIABLE:
3189       fprintf (file, "sval<%s>", copy_name (value.sval));
3190       break;
3191
3192     case TYPENAME:
3193       fprintf (file, "tsym<type=%s, name=%s>",
3194                TYPE_SAFE_NAME (value.tsym.type),
3195                copy_name (value.tsym.stoken));
3196       break;
3197
3198     case NAME:
3199     case UNKNOWN_CPP_NAME:
3200     case NAME_OR_INT:
3201     case BLOCKNAME:
3202       fprintf (file, "ssym<name=%s, sym=%s, field_of_this=%d>",
3203                copy_name (value.ssym.stoken),
3204                (value.ssym.sym == NULL
3205                 ? "(null)" : SYMBOL_PRINT_NAME (value.ssym.sym)),
3206                value.ssym.is_a_field_of_this);
3207       break;
3208
3209     case FILENAME:
3210       fprintf (file, "bval<%s>", host_address_to_string (value.bval));
3211       break;
3212     }
3213 }
3214
3215 void
3216 yyerror (char *msg)
3217 {
3218   if (prev_lexptr)
3219     lexptr = prev_lexptr;
3220
3221   error (_("A %s in expression, near `%s'."), (msg ? msg : "error"), lexptr);
3222 }