gdb/c-exp.y

   1 /* YACC parser for C expressions, for GDB.
   2    Copyright (C) 1986-2014 Free Software Foundation, Inc.
   3
   4    This file is part of GDB.
   5
   6    This program is free software; you can redistribute it and/or modify
   7    it under the terms of the GNU General Public License as published by
   8    the Free Software Foundation; either version 3 of the License, or
   9    (at your option) any later version.
  10
  11    This program is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14    GNU General Public License for more details.
  15
  16    You should have received a copy of the GNU General Public License
  17    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  18
  19 /* Parse a C expression from text in a string,
  20    and return the result as a  struct expression  pointer.
  21    That structure contains arithmetic operations in reverse polish,
  22    with constants represented by operations that are followed by special data.
  23    See expression.h for the details of the format.
  24    What is important here is that it can be built up sequentially
  25    during the process of parsing; the lower levels of the tree always
  26    come first in the result.
  27
  28    Note that malloc's and realloc's in this file are transformed to
  29    xmalloc and xrealloc respectively by the same sed command in the
  30    makefile that remaps any other malloc/realloc inserted by the parser
  31    generator.  Doing this with #defines and trying to control the interaction
  32    with include files (<malloc.h> and <stdlib.h> for example) just became
  33    too messy, particularly when such includes can be inserted at random
  34    times by the parser generator.  */
  35
  36 %{
  37
  38 #include "defs.h"
  39 #include <string.h>
  40 #include <ctype.h>
  41 #include "expression.h"
  42 #include "value.h"
  43 #include "parser-defs.h"
  44 #include "language.h"
  45 #include "c-lang.h"
  46 #include "bfd.h" /* Required by objfiles.h.  */
  47 #include "symfile.h" /* Required by objfiles.h.  */
  48 #include "objfiles.h" /* For have_full_symbols and have_partial_symbols */
  49 #include "charset.h"
  50 #include "block.h"
  51 #include "cp-support.h"
  52 #include "dfp.h"
  53 #include "gdb_assert.h"
  54 #include "macroscope.h"
  55 #include "objc-lang.h"
  56 #include "typeprint.h"
  57 #include "cp-abi.h"
  58
  59 #define parse_type(ps) builtin_type (parse_gdbarch (ps))
  60
  61 /* Remap normal yacc parser interface names (yyparse, yylex, yyerror, etc),
  62    as well as gratuitiously global symbol names, so we can have multiple
  63    yacc generated parsers in gdb.  Note that these are only the variables
  64    produced by yacc.  If other parser generators (bison, byacc, etc) produce
  65    additional global names that conflict at link time, then those parser
  66    generators need to be fixed instead of adding those names to this list. */
  67
  68 #define yymaxdepth c_maxdepth
  69 #define yyparse c_parse_internal
  70 #define yylex   c_lex
  71 #define yyerror c_error
  72 #define yylval  c_lval
  73 #define yychar  c_char
  74 #define yydebug c_debug
  75 #define yypact  c_pact
  76 #define yyr1    c_r1
  77 #define yyr2    c_r2
  78 #define yydef   c_def
  79 #define yychk   c_chk
  80 #define yypgo   c_pgo
  81 #define yyact   c_act
  82 #define yyexca  c_exca
  83 #define yyerrflag c_errflag
  84 #define yynerrs c_nerrs
  85 #define yyps    c_ps
  86 #define yypv    c_pv
  87 #define yys     c_s
  88 #define yy_yys  c_yys
  89 #define yystate c_state
  90 #define yytmp   c_tmp
  91 #define yyv     c_v
  92 #define yy_yyv  c_yyv
  93 #define yyval   c_val
  94 #define yylloc  c_lloc
  95 #define yyreds  c_reds          /* With YYDEBUG defined */
  96 #define yytoks  c_toks          /* With YYDEBUG defined */
  97 #define yyname  c_name          /* With YYDEBUG defined */
  98 #define yyrule  c_rule          /* With YYDEBUG defined */
  99 #define yylhs   c_yylhs
 100 #define yylen   c_yylen
 101 #define yydefred c_yydefred
 102 #define yydgoto c_yydgoto
 103 #define yysindex c_yysindex
 104 #define yyrindex c_yyrindex
 105 #define yygindex c_yygindex
 106 #define yytable  c_yytable
 107 #define yycheck  c_yycheck
 108 #define yyss    c_yyss
 109 #define yysslim c_yysslim
 110 #define yyssp   c_yyssp
 111 #define yystacksize c_yystacksize
 112 #define yyvs    c_yyvs
 113 #define yyvsp   c_yyvsp
 114
 115 #ifndef YYDEBUG
 116 #define YYDEBUG 1               /* Default to yydebug support */
 117 #endif
 118
 119 #define YYFPRINTF parser_fprintf
 120
 121 /* The state of the parser, used internally when we are parsing the
 122    expression.  */
 123
 124 static struct parser_state *pstate = NULL;
 125
 126 int yyparse (void);
 127
 128 static int yylex (void);
 129
 130 void yyerror (char *);
 131
 132 %}
 133
 134 /* Although the yacc "value" of an expression is not used,
 135    since the result is stored in the structure being created,
 136    other node types do have values.  */
 137
 138 %union
 139   {
 140     LONGEST lval;
 141     struct {
 142       LONGEST val;
 143       struct type *type;
 144     } typed_val_int;
 145     struct {
 146       DOUBLEST dval;
 147       struct type *type;
 148     } typed_val_float;
 149     struct {
 150       gdb_byte val[16];
 151       struct type *type;
 152     } typed_val_decfloat;
 153     struct type *tval;
 154     struct stoken sval;
 155     struct typed_stoken tsval;
 156     struct ttype tsym;
 157     struct symtoken ssym;
 158     int voidval;
 159     struct block *bval;
 160     enum exp_opcode opcode;
 161
 162     struct stoken_vector svec;
 163     VEC (type_ptr) *tvec;
 164
 165     struct type_stack *type_stack;
 166
 167     struct objc_class_str class;
 168   }
 169
 170 %{
 171 /* YYSTYPE gets defined by %union */
 172 static int parse_number (struct parser_state *par_state,
 173                          const char *, int, int, YYSTYPE *);
 174 static struct stoken operator_stoken (const char *);
 175 static void check_parameter_typelist (VEC (type_ptr) *);
 176 static void write_destructor_name (struct parser_state *par_state,
 177                                    struct stoken);
 178
 179 #ifdef YYBISON
 180 static void c_print_token (FILE *file, int type, YYSTYPE value);
 181 #define YYPRINT(FILE, TYPE, VALUE) c_print_token (FILE, TYPE, VALUE)
 182 #endif
 183 %}
 184
 185 %type <voidval> exp exp1 type_exp start variable qualified_name lcurly
 186 %type <lval> rcurly
 187 %type <tval> type typebase
 188 %type <tvec> nonempty_typelist func_mod parameter_typelist
 189 /* %type <bval> block */
 190
 191 /* Fancy type parsing.  */
 192 %type <tval> ptype
 193 %type <lval> array_mod
 194 %type <tval> conversion_type_id
 195
 196 %type <type_stack> ptr_operator_ts abs_decl direct_abs_decl
 197
 198 %token <typed_val_int> INT
 199 %token <typed_val_float> FLOAT
 200 %token <typed_val_decfloat> DECFLOAT
 201
 202 /* Both NAME and TYPENAME tokens represent symbols in the input,
 203    and both convey their data as strings.
 204    But a TYPENAME is a string that happens to be defined as a typedef
 205    or builtin type name (such as int or char)
 206    and a NAME is any other symbol.
 207    Contexts where this distinction is not important can use the
 208    nonterminal "name", which matches either NAME or TYPENAME.  */
 209
 210 %token <tsval> STRING
 211 %token <sval> NSSTRING          /* ObjC Foundation "NSString" literal */
 212 %token SELECTOR                 /* ObjC "@selector" pseudo-operator   */
 213 %token <tsval> CHAR
 214 %token <ssym> NAME /* BLOCKNAME defined below to give it higher precedence. */
 215 %token <ssym> UNKNOWN_CPP_NAME
 216 %token <voidval> COMPLETE
 217 %token <tsym> TYPENAME
 218 %token <class> CLASSNAME        /* ObjC Class name */
 219 %type <sval> name
 220 %type <svec> string_exp
 221 %type <ssym> name_not_typename
 222 %type <tsym> typename
 223
 224  /* This is like a '[' token, but is only generated when parsing
 225     Objective C.  This lets us reuse the same parser without
 226     erroneously parsing ObjC-specific expressions in C.  */
 227 %token OBJC_LBRAC
 228
 229 /* A NAME_OR_INT is a symbol which is not known in the symbol table,
 230    but which would parse as a valid number in the current input radix.
 231    E.g. "c" when input_radix==16.  Depending on the parse, it will be
 232    turned into a name or into a number.  */
 233
 234 %token <ssym> NAME_OR_INT
 235
 236 %token OPERATOR
 237 %token STRUCT CLASS UNION ENUM SIZEOF UNSIGNED COLONCOLON
 238 %token TEMPLATE
 239 %token ERROR
 240 %token NEW DELETE
 241 %type <sval> operator
 242 %token REINTERPRET_CAST DYNAMIC_CAST STATIC_CAST CONST_CAST
 243 %token ENTRY
 244 %token TYPEOF
 245 %token DECLTYPE
 246 %token TYPEID
 247
 248 /* Special type cases, put in to allow the parser to distinguish different
 249    legal basetypes.  */
 250 %token SIGNED_KEYWORD LONG SHORT INT_KEYWORD CONST_KEYWORD VOLATILE_KEYWORD DOUBLE_KEYWORD
 251
 252 %token <sval> VARIABLE
 253
 254 %token <opcode> ASSIGN_MODIFY
 255
 256 /* C++ */
 257 %token TRUEKEYWORD
 258 %token FALSEKEYWORD
 259
 260
 261 %left ','
 262 %left ABOVE_COMMA
 263 %right '=' ASSIGN_MODIFY
 264 %right '?'
 265 %left OROR
 266 %left ANDAND
 267 %left '|'
 268 %left '^'
 269 %left '&'
 270 %left EQUAL NOTEQUAL
 271 %left '<' '>' LEQ GEQ
 272 %left LSH RSH
 273 %left '@'
 274 %left '+' '-'
 275 %left '*' '/' '%'
 276 %right UNARY INCREMENT DECREMENT
 277 %right ARROW ARROW_STAR '.' DOT_STAR '[' OBJC_LBRAC '('
 278 %token <ssym> BLOCKNAME
 279 %token <bval> FILENAME
 280 %type <bval> block
 281 %left COLONCOLON
 282
 283 %token DOTDOTDOT
 284
 285 \f
 286 %%
 287
 288 start   :       exp1
 289         |       type_exp
 290         ;
 291
 292 type_exp:       type
 293                         { write_exp_elt_opcode(pstate, OP_TYPE);
 294                           write_exp_elt_type(pstate, $1);
 295                           write_exp_elt_opcode(pstate, OP_TYPE);}
 296         |       TYPEOF '(' exp ')'
 297                         {
 298                           write_exp_elt_opcode (pstate, OP_TYPEOF);
 299                         }
 300         |       TYPEOF '(' type ')'
 301                         {
 302                           write_exp_elt_opcode (pstate, OP_TYPE);
 303                           write_exp_elt_type (pstate, $3);
 304                           write_exp_elt_opcode (pstate, OP_TYPE);
 305                         }
 306         |       DECLTYPE '(' exp ')'
 307                         {
 308                           write_exp_elt_opcode (pstate, OP_DECLTYPE);
 309                         }
 310         ;
 311
 312 /* Expressions, including the comma operator.  */
 313 exp1    :       exp
 314         |       exp1 ',' exp
 315                         { write_exp_elt_opcode (pstate, BINOP_COMMA); }
 316         ;
 317
 318 /* Expressions, not including the comma operator.  */
 319 exp     :       '*' exp    %prec UNARY
 320                         { write_exp_elt_opcode (pstate, UNOP_IND); }
 321         ;
 322
 323 exp     :       '&' exp    %prec UNARY
 324                         { write_exp_elt_opcode (pstate, UNOP_ADDR); }
 325         ;
 326
 327 exp     :       '-' exp    %prec UNARY
 328                         { write_exp_elt_opcode (pstate, UNOP_NEG); }
 329         ;
 330
 331 exp     :       '+' exp    %prec UNARY
 332                         { write_exp_elt_opcode (pstate, UNOP_PLUS); }
 333         ;
 334
 335 exp     :       '!' exp    %prec UNARY
 336                         { write_exp_elt_opcode (pstate, UNOP_LOGICAL_NOT); }
 337         ;
 338
 339 exp     :       '~' exp    %prec UNARY
 340                         { write_exp_elt_opcode (pstate, UNOP_COMPLEMENT); }
 341         ;
 342
 343 exp     :       INCREMENT exp    %prec UNARY
 344                         { write_exp_elt_opcode (pstate, UNOP_PREINCREMENT); }
 345         ;
 346
 347 exp     :       DECREMENT exp    %prec UNARY
 348                         { write_exp_elt_opcode (pstate, UNOP_PREDECREMENT); }
 349         ;
 350
 351 exp     :       exp INCREMENT    %prec UNARY
 352                         { write_exp_elt_opcode (pstate, UNOP_POSTINCREMENT); }
 353         ;
 354
 355 exp     :       exp DECREMENT    %prec UNARY
 356                         { write_exp_elt_opcode (pstate, UNOP_POSTDECREMENT); }
 357         ;
 358
 359 exp     :       TYPEID '(' exp ')' %prec UNARY
 360                         { write_exp_elt_opcode (pstate, OP_TYPEID); }
 361         ;
 362
 363 exp     :       TYPEID '(' type_exp ')' %prec UNARY
 364                         { write_exp_elt_opcode (pstate, OP_TYPEID); }
 365         ;
 366
 367 exp     :       SIZEOF exp       %prec UNARY
 368                         { write_exp_elt_opcode (pstate, UNOP_SIZEOF); }
 369         ;
 370
 371 exp     :       exp ARROW name
 372                         { write_exp_elt_opcode (pstate, STRUCTOP_PTR);
 373                           write_exp_string (pstate, $3);
 374                           write_exp_elt_opcode (pstate, STRUCTOP_PTR); }
 375         ;
 376
 377 exp     :       exp ARROW name COMPLETE
 378                         { mark_struct_expression (pstate);
 379                           write_exp_elt_opcode (pstate, STRUCTOP_PTR);
 380                           write_exp_string (pstate, $3);
 381                           write_exp_elt_opcode (pstate, STRUCTOP_PTR); }
 382         ;
 383
 384 exp     :       exp ARROW COMPLETE
 385                         { struct stoken s;
 386                           mark_struct_expression (pstate);
 387                           write_exp_elt_opcode (pstate, STRUCTOP_PTR);
 388                           s.ptr = "";
 389                           s.length = 0;
 390                           write_exp_string (pstate, s);
 391                           write_exp_elt_opcode (pstate, STRUCTOP_PTR); }
 392         ;
 393
 394 exp     :       exp ARROW '~' name
 395                         { write_exp_elt_opcode (pstate, STRUCTOP_PTR);
 396                           write_destructor_name (pstate, $4);
 397                           write_exp_elt_opcode (pstate, STRUCTOP_PTR); }
 398         ;
 399
 400 exp     :       exp ARROW '~' name COMPLETE
 401                         { mark_struct_expression (pstate);
 402                           write_exp_elt_opcode (pstate, STRUCTOP_PTR);
 403                           write_destructor_name (pstate, $4);
 404                           write_exp_elt_opcode (pstate, STRUCTOP_PTR); }
 405         ;
 406
 407 exp     :       exp ARROW qualified_name
 408                         { /* exp->type::name becomes exp->*(&type::name) */
 409                           /* Note: this doesn't work if name is a
 410                              static member!  FIXME */
 411                           write_exp_elt_opcode (pstate, UNOP_ADDR);
 412                           write_exp_elt_opcode (pstate, STRUCTOP_MPTR); }
 413         ;
 414
 415 exp     :       exp ARROW_STAR exp
 416                         { write_exp_elt_opcode (pstate, STRUCTOP_MPTR); }
 417         ;
 418
 419 exp     :       exp '.' name
 420                         { write_exp_elt_opcode (pstate, STRUCTOP_STRUCT);
 421                           write_exp_string (pstate, $3);
 422                           write_exp_elt_opcode (pstate, STRUCTOP_STRUCT); }
 423         ;
 424
 425 exp     :       exp '.' name COMPLETE
 426                         { mark_struct_expression (pstate);
 427                           write_exp_elt_opcode (pstate, STRUCTOP_STRUCT);
 428                           write_exp_string (pstate, $3);
 429                           write_exp_elt_opcode (pstate, STRUCTOP_STRUCT); }
 430         ;
 431
 432 exp     :       exp '.' COMPLETE
 433                         { struct stoken s;
 434                           mark_struct_expression (pstate);
 435                           write_exp_elt_opcode (pstate, STRUCTOP_STRUCT);
 436                           s.ptr = "";
 437                           s.length = 0;
 438                           write_exp_string (pstate, s);
 439                           write_exp_elt_opcode (pstate, STRUCTOP_STRUCT); }
 440         ;
 441
 442 exp     :       exp '.' '~' name
 443                         { write_exp_elt_opcode (pstate, STRUCTOP_STRUCT);
 444                           write_destructor_name (pstate, $4);
 445                           write_exp_elt_opcode (pstate, STRUCTOP_STRUCT); }
 446         ;
 447
 448 exp     :       exp '.' '~' name COMPLETE
 449                         { mark_struct_expression (pstate);
 450                           write_exp_elt_opcode (pstate, STRUCTOP_STRUCT);
 451                           write_destructor_name (pstate, $4);
 452                           write_exp_elt_opcode (pstate, STRUCTOP_STRUCT); }
 453         ;
 454
 455 exp     :       exp '.' qualified_name
 456                         { /* exp.type::name becomes exp.*(&type::name) */
 457                           /* Note: this doesn't work if name is a
 458                              static member!  FIXME */
 459                           write_exp_elt_opcode (pstate, UNOP_ADDR);
 460                           write_exp_elt_opcode (pstate, STRUCTOP_MEMBER); }
 461         ;
 462
 463 exp     :       exp DOT_STAR exp
 464                         { write_exp_elt_opcode (pstate, STRUCTOP_MEMBER); }
 465         ;
 466
 467 exp     :       exp '[' exp1 ']'
 468                         { write_exp_elt_opcode (pstate, BINOP_SUBSCRIPT); }
 469         ;
 470
 471 exp     :       exp OBJC_LBRAC exp1 ']'
 472                         { write_exp_elt_opcode (pstate, BINOP_SUBSCRIPT); }
 473         ;
 474
 475 /*
 476  * The rules below parse ObjC message calls of the form:
 477  *      '[' target selector {':' argument}* ']'
 478  */
 479
 480 exp     :       OBJC_LBRAC TYPENAME
 481                         {
 482                           CORE_ADDR class;
 483
 484                           class = lookup_objc_class (parse_gdbarch (pstate),
 485                                                      copy_name ($2.stoken));
 486                           if (class == 0)
 487                             error (_("%s is not an ObjC Class"),
 488                                    copy_name ($2.stoken));
 489                           write_exp_elt_opcode (pstate, OP_LONG);
 490                           write_exp_elt_type (pstate,
 491                                             parse_type (pstate)->builtin_int);
 492                           write_exp_elt_longcst (pstate, (LONGEST) class);
 493                           write_exp_elt_opcode (pstate, OP_LONG);
 494                           start_msglist();
 495                         }
 496                 msglist ']'
 497                         { write_exp_elt_opcode (pstate, OP_OBJC_MSGCALL);
 498                           end_msglist (pstate);
 499                           write_exp_elt_opcode (pstate, OP_OBJC_MSGCALL);
 500                         }
 501         ;
 502
 503 exp     :       OBJC_LBRAC CLASSNAME
 504                         {
 505                           write_exp_elt_opcode (pstate, OP_LONG);
 506                           write_exp_elt_type (pstate,
 507                                             parse_type (pstate)->builtin_int);
 508                           write_exp_elt_longcst (pstate, (LONGEST) $2.class);
 509                           write_exp_elt_opcode (pstate, OP_LONG);
 510                           start_msglist();
 511                         }
 512                 msglist ']'
 513                         { write_exp_elt_opcode (pstate, OP_OBJC_MSGCALL);
 514                           end_msglist (pstate);
 515                           write_exp_elt_opcode (pstate, OP_OBJC_MSGCALL);
 516                         }
 517         ;
 518
 519 exp     :       OBJC_LBRAC exp
 520                         { start_msglist(); }
 521                 msglist ']'
 522                         { write_exp_elt_opcode (pstate, OP_OBJC_MSGCALL);
 523                           end_msglist (pstate);
 524                           write_exp_elt_opcode (pstate, OP_OBJC_MSGCALL);
 525                         }
 526         ;
 527
 528 msglist :       name
 529                         { add_msglist(&$1, 0); }
 530         |       msgarglist
 531         ;
 532
 533 msgarglist :    msgarg
 534         |       msgarglist msgarg
 535         ;
 536
 537 msgarg  :       name ':' exp
 538                         { add_msglist(&$1, 1); }
 539         |       ':' exp /* Unnamed arg.  */
 540                         { add_msglist(0, 1);   }
 541         |       ',' exp /* Variable number of args.  */
 542                         { add_msglist(0, 0);   }
 543         ;
 544
 545 exp     :       exp '('
 546                         /* This is to save the value of arglist_len
 547                            being accumulated by an outer function call.  */
 548                         { start_arglist (); }
 549                 arglist ')'     %prec ARROW
 550                         { write_exp_elt_opcode (pstate, OP_FUNCALL);
 551                           write_exp_elt_longcst (pstate,
 552                                                  (LONGEST) end_arglist ());
 553                           write_exp_elt_opcode (pstate, OP_FUNCALL); }
 554         ;
 555
 556 exp     :       UNKNOWN_CPP_NAME '('
 557                         {
 558                           /* This could potentially be a an argument defined
 559                              lookup function (Koenig).  */
 560                           write_exp_elt_opcode (pstate, OP_ADL_FUNC);
 561                           write_exp_elt_block (pstate,
 562                                                expression_context_block);
 563                           write_exp_elt_sym (pstate,
 564                                              NULL); /* Placeholder.  */
 565                           write_exp_string (pstate, $1.stoken);
 566                           write_exp_elt_opcode (pstate, OP_ADL_FUNC);
 567
 568                         /* This is to save the value of arglist_len
 569                            being accumulated by an outer function call.  */
 570
 571                           start_arglist ();
 572                         }
 573                 arglist ')'     %prec ARROW
 574                         {
 575                           write_exp_elt_opcode (pstate, OP_FUNCALL);
 576                           write_exp_elt_longcst (pstate,
 577                                                  (LONGEST) end_arglist ());
 578                           write_exp_elt_opcode (pstate, OP_FUNCALL);
 579                         }
 580         ;
 581
 582 lcurly  :       '{'
 583                         { start_arglist (); }
 584         ;
 585
 586 arglist :
 587         ;
 588
 589 arglist :       exp
 590                         { arglist_len = 1; }
 591         ;
 592
 593 arglist :       arglist ',' exp   %prec ABOVE_COMMA
 594                         { arglist_len++; }
 595         ;
 596
 597 exp     :       exp '(' parameter_typelist ')' const_or_volatile
 598                         { int i;
 599                           VEC (type_ptr) *type_list = $3;
 600                           struct type *type_elt;
 601                           LONGEST len = VEC_length (type_ptr, type_list);
 602
 603                           write_exp_elt_opcode (pstate, TYPE_INSTANCE);
 604                           write_exp_elt_longcst (pstate, len);
 605                           for (i = 0;
 606                                VEC_iterate (type_ptr, type_list, i, type_elt);
 607                                ++i)
 608                             write_exp_elt_type (pstate, type_elt);
 609                           write_exp_elt_longcst(pstate, len);
 610                           write_exp_elt_opcode (pstate, TYPE_INSTANCE);
 611                           VEC_free (type_ptr, type_list);
 612                         }
 613         ;
 614
 615 rcurly  :       '}'
 616                         { $$ = end_arglist () - 1; }
 617         ;
 618 exp     :       lcurly arglist rcurly   %prec ARROW
 619                         { write_exp_elt_opcode (pstate, OP_ARRAY);
 620                           write_exp_elt_longcst (pstate, (LONGEST) 0);
 621                           write_exp_elt_longcst (pstate, (LONGEST) $3);
 622                           write_exp_elt_opcode (pstate, OP_ARRAY); }
 623         ;
 624
 625 exp     :       lcurly type_exp rcurly exp  %prec UNARY
 626                         { write_exp_elt_opcode (pstate, UNOP_MEMVAL_TYPE); }
 627         ;
 628
 629 exp     :       '(' type_exp ')' exp  %prec UNARY
 630                         { write_exp_elt_opcode (pstate, UNOP_CAST_TYPE); }
 631         ;
 632
 633 exp     :       '(' exp1 ')'
 634                         { }
 635         ;
 636
 637 /* Binary operators in order of decreasing precedence.  */
 638
 639 exp     :       exp '@' exp
 640                         { write_exp_elt_opcode (pstate, BINOP_REPEAT); }
 641         ;
 642
 643 exp     :       exp '*' exp
 644                         { write_exp_elt_opcode (pstate, BINOP_MUL); }
 645         ;
 646
 647 exp     :       exp '/' exp
 648                         { write_exp_elt_opcode (pstate, BINOP_DIV); }
 649         ;
 650
 651 exp     :       exp '%' exp
 652                         { write_exp_elt_opcode (pstate, BINOP_REM); }
 653         ;
 654
 655 exp     :       exp '+' exp
 656                         { write_exp_elt_opcode (pstate, BINOP_ADD); }
 657         ;
 658
 659 exp     :       exp '-' exp
 660                         { write_exp_elt_opcode (pstate, BINOP_SUB); }
 661         ;
 662
 663 exp     :       exp LSH exp
 664                         { write_exp_elt_opcode (pstate, BINOP_LSH); }
 665         ;
 666
 667 exp     :       exp RSH exp
 668                         { write_exp_elt_opcode (pstate, BINOP_RSH); }
 669         ;
 670
 671 exp     :       exp EQUAL exp
 672                         { write_exp_elt_opcode (pstate, BINOP_EQUAL); }
 673         ;
 674
 675 exp     :       exp NOTEQUAL exp
 676                         { write_exp_elt_opcode (pstate, BINOP_NOTEQUAL); }
 677         ;
 678
 679 exp     :       exp LEQ exp
 680                         { write_exp_elt_opcode (pstate, BINOP_LEQ); }
 681         ;
 682
 683 exp     :       exp GEQ exp
 684                         { write_exp_elt_opcode (pstate, BINOP_GEQ); }
 685         ;
 686
 687 exp     :       exp '<' exp
 688                         { write_exp_elt_opcode (pstate, BINOP_LESS); }
 689         ;
 690
 691 exp     :       exp '>' exp
 692                         { write_exp_elt_opcode (pstate, BINOP_GTR); }
 693         ;
 694
 695 exp     :       exp '&' exp
 696                         { write_exp_elt_opcode (pstate, BINOP_BITWISE_AND); }
 697         ;
 698
 699 exp     :       exp '^' exp
 700                         { write_exp_elt_opcode (pstate, BINOP_BITWISE_XOR); }
 701         ;
 702
 703 exp     :       exp '|' exp
 704                         { write_exp_elt_opcode (pstate, BINOP_BITWISE_IOR); }
 705         ;
 706
 707 exp     :       exp ANDAND exp
 708                         { write_exp_elt_opcode (pstate, BINOP_LOGICAL_AND); }
 709         ;
 710
 711 exp     :       exp OROR exp
 712                         { write_exp_elt_opcode (pstate, BINOP_LOGICAL_OR); }
 713         ;
 714
 715 exp     :       exp '?' exp ':' exp     %prec '?'
 716                         { write_exp_elt_opcode (pstate, TERNOP_COND); }
 717         ;
 718
 719 exp     :       exp '=' exp
 720                         { write_exp_elt_opcode (pstate, BINOP_ASSIGN); }
 721         ;
 722
 723 exp     :       exp ASSIGN_MODIFY exp
 724                         { write_exp_elt_opcode (pstate, BINOP_ASSIGN_MODIFY);
 725                           write_exp_elt_opcode (pstate, $2);
 726                           write_exp_elt_opcode (pstate,
 727                                                 BINOP_ASSIGN_MODIFY); }
 728         ;
 729
 730 exp     :       INT
 731                         { write_exp_elt_opcode (pstate, OP_LONG);
 732                           write_exp_elt_type (pstate, $1.type);
 733                           write_exp_elt_longcst (pstate, (LONGEST) ($1.val));
 734                           write_exp_elt_opcode (pstate, OP_LONG); }
 735         ;
 736
 737 exp     :       CHAR
 738                         {
 739                           struct stoken_vector vec;
 740                           vec.len = 1;
 741                           vec.tokens = &$1;
 742                           write_exp_string_vector (pstate, $1.type, &vec);
 743                         }
 744         ;
 745
 746 exp     :       NAME_OR_INT
 747                         { YYSTYPE val;
 748                           parse_number (pstate, $1.stoken.ptr,
 749                                         $1.stoken.length, 0, &val);
 750                           write_exp_elt_opcode (pstate, OP_LONG);
 751                           write_exp_elt_type (pstate, val.typed_val_int.type);
 752                           write_exp_elt_longcst (pstate,
 753                                             (LONGEST) val.typed_val_int.val);
 754                           write_exp_elt_opcode (pstate, OP_LONG);
 755                         }
 756         ;
 757
 758
 759 exp     :       FLOAT
 760                         { write_exp_elt_opcode (pstate, OP_DOUBLE);
 761                           write_exp_elt_type (pstate, $1.type);
 762                           write_exp_elt_dblcst (pstate, $1.dval);
 763                           write_exp_elt_opcode (pstate, OP_DOUBLE); }
 764         ;
 765
 766 exp     :       DECFLOAT
 767                         { write_exp_elt_opcode (pstate, OP_DECFLOAT);
 768                           write_exp_elt_type (pstate, $1.type);
 769                           write_exp_elt_decfloatcst (pstate, $1.val);
 770                           write_exp_elt_opcode (pstate, OP_DECFLOAT); }
 771         ;
 772
 773 exp     :       variable
 774         ;
 775
 776 exp     :       VARIABLE
 777                         {
 778                           write_dollar_variable (pstate, $1);
 779                         }
 780         ;
 781
 782 exp     :       SELECTOR '(' name ')'
 783                         {
 784                           write_exp_elt_opcode (pstate, OP_OBJC_SELECTOR);
 785                           write_exp_string (pstate, $3);
 786                           write_exp_elt_opcode (pstate, OP_OBJC_SELECTOR); }
 787         ;
 788
 789 exp     :       SIZEOF '(' type ')'     %prec UNARY
 790                         { struct type *type = $3;
 791                           write_exp_elt_opcode (pstate, OP_LONG);
 792                           write_exp_elt_type (pstate, lookup_signed_typename
 793                                               (parse_language (pstate),
 794                                                parse_gdbarch (pstate),
 795                                                "int"));
 796                           CHECK_TYPEDEF (type);
 797
 798                             /* $5.3.3/2 of the C++ Standard (n3290 draft)
 799                                says of sizeof:  "When applied to a reference
 800                                or a reference type, the result is the size of
 801                                the referenced type."  */
 802                           if (TYPE_CODE (type) == TYPE_CODE_REF)
 803                             type = check_typedef (TYPE_TARGET_TYPE (type));
 804                           write_exp_elt_longcst (pstate,
 805                                                  (LONGEST) TYPE_LENGTH (type));
 806                           write_exp_elt_opcode (pstate, OP_LONG); }
 807         ;
 808
 809 exp     :       REINTERPRET_CAST '<' type_exp '>' '(' exp ')' %prec UNARY
 810                         { write_exp_elt_opcode (pstate,
 811                                                 UNOP_REINTERPRET_CAST); }
 812         ;
 813
 814 exp     :       STATIC_CAST '<' type_exp '>' '(' exp ')' %prec UNARY
 815                         { write_exp_elt_opcode (pstate, UNOP_CAST_TYPE); }
 816         ;
 817
 818 exp     :       DYNAMIC_CAST '<' type_exp '>' '(' exp ')' %prec UNARY
 819                         { write_exp_elt_opcode (pstate, UNOP_DYNAMIC_CAST); }
 820         ;
 821
 822 exp     :       CONST_CAST '<' type_exp '>' '(' exp ')' %prec UNARY
 823                         { /* We could do more error checking here, but
 824                              it doesn't seem worthwhile.  */
 825                           write_exp_elt_opcode (pstate, UNOP_CAST_TYPE); }
 826         ;
 827
 828 string_exp:
 829                 STRING
 830                         {
 831                           /* We copy the string here, and not in the
 832                              lexer, to guarantee that we do not leak a
 833                              string.  Note that we follow the
 834                              NUL-termination convention of the
 835                              lexer.  */
 836                           struct typed_stoken *vec = XNEW (struct typed_stoken);
 837                           $$.len = 1;
 838                           $$.tokens = vec;
 839
 840                           vec->type = $1.type;
 841                           vec->length = $1.length;
 842                           vec->ptr = malloc ($1.length + 1);
 843                           memcpy (vec->ptr, $1.ptr, $1.length + 1);
 844                         }
 845
 846         |       string_exp STRING
 847                         {
 848                           /* Note that we NUL-terminate here, but just
 849                              for convenience.  */
 850                           char *p;
 851                           ++$$.len;
 852                           $$.tokens = realloc ($$.tokens,
 853                                                $$.len * sizeof (struct typed_stoken));
 854
 855                           p = malloc ($2.length + 1);
 856                           memcpy (p, $2.ptr, $2.length + 1);
 857
 858                           $$.tokens[$$.len - 1].type = $2.type;
 859                           $$.tokens[$$.len - 1].length = $2.length;
 860                           $$.tokens[$$.len - 1].ptr = p;
 861                         }
 862                 ;
 863
 864 exp     :       string_exp
 865                         {
 866                           int i;
 867                           enum c_string_type type = C_STRING;
 868
 869                           for (i = 0; i < $1.len; ++i)
 870                             {
 871                               switch ($1.tokens[i].type)
 872                                 {
 873                                 case C_STRING:
 874                                   break;
 875                                 case C_WIDE_STRING:
 876                                 case C_STRING_16:
 877                                 case C_STRING_32:
 878                                   if (type != C_STRING
 879                                       && type != $1.tokens[i].type)
 880                                     error (_("Undefined string concatenation."));
 881                                   type = $1.tokens[i].type;
 882                                   break;
 883                                 default:
 884                                   /* internal error */
 885                                   internal_error (__FILE__, __LINE__,
 886                                                   "unrecognized type in string concatenation");
 887                                 }
 888                             }
 889
 890                           write_exp_string_vector (pstate, type, &$1);
 891                           for (i = 0; i < $1.len; ++i)
 892                             free ($1.tokens[i].ptr);
 893                           free ($1.tokens);
 894                         }
 895         ;
 896
 897 exp     :       NSSTRING        /* ObjC NextStep NSString constant
 898                                  * of the form '@' '"' string '"'.
 899                                  */
 900                         { write_exp_elt_opcode (pstate, OP_OBJC_NSSTRING);
 901                           write_exp_string (pstate, $1);
 902                           write_exp_elt_opcode (pstate, OP_OBJC_NSSTRING); }
 903         ;
 904
 905 /* C++.  */
 906 exp     :       TRUEKEYWORD
 907                         { write_exp_elt_opcode (pstate, OP_LONG);
 908                           write_exp_elt_type (pstate,
 909                                           parse_type (pstate)->builtin_bool);
 910                           write_exp_elt_longcst (pstate, (LONGEST) 1);
 911                           write_exp_elt_opcode (pstate, OP_LONG); }
 912         ;
 913
 914 exp     :       FALSEKEYWORD
 915                         { write_exp_elt_opcode (pstate, OP_LONG);
 916                           write_exp_elt_type (pstate,
 917                                           parse_type (pstate)->builtin_bool);
 918                           write_exp_elt_longcst (pstate, (LONGEST) 0);
 919                           write_exp_elt_opcode (pstate, OP_LONG); }
 920         ;
 921
 922 /* end of C++.  */
 923
 924 block   :       BLOCKNAME
 925                         {
 926                           if ($1.sym)
 927                             $$ = SYMBOL_BLOCK_VALUE ($1.sym);
 928                           else
 929                             error (_("No file or function \"%s\"."),
 930                                    copy_name ($1.stoken));
 931                         }
 932         |       FILENAME
 933                         {
 934                           $$ = $1;
 935                         }
 936         ;
 937
 938 block   :       block COLONCOLON name
 939                         { struct symbol *tem
 940                             = lookup_symbol (copy_name ($3), $1,
 941                                              VAR_DOMAIN, NULL);
 942                           if (!tem || SYMBOL_CLASS (tem) != LOC_BLOCK)
 943                             error (_("No function \"%s\" in specified context."),
 944                                    copy_name ($3));
 945                           $$ = SYMBOL_BLOCK_VALUE (tem); }
 946         ;
 947
 948 variable:       name_not_typename ENTRY
 949                         { struct symbol *sym = $1.sym;
 950
 951                           if (sym == NULL || !SYMBOL_IS_ARGUMENT (sym)
 952                               || !symbol_read_needs_frame (sym))
 953                             error (_("@entry can be used only for function "
 954                                      "parameters, not for \"%s\""),
 955                                    copy_name ($1.stoken));
 956
 957                           write_exp_elt_opcode (pstate, OP_VAR_ENTRY_VALUE);
 958                           write_exp_elt_sym (pstate, sym);
 959                           write_exp_elt_opcode (pstate, OP_VAR_ENTRY_VALUE);
 960                         }
 961         ;
 962
 963 variable:       block COLONCOLON name
 964                         { struct symbol *sym;
 965                           sym = lookup_symbol (copy_name ($3), $1,
 966                                                VAR_DOMAIN, NULL);
 967                           if (sym == 0)
 968                             error (_("No symbol \"%s\" in specified context."),
 969                                    copy_name ($3));
 970                           if (symbol_read_needs_frame (sym))
 971                             {
 972                               if (innermost_block == 0
 973                                   || contained_in (block_found,
 974                                                    innermost_block))
 975                                 innermost_block = block_found;
 976                             }
 977
 978                           write_exp_elt_opcode (pstate, OP_VAR_VALUE);
 979                           /* block_found is set by lookup_symbol.  */
 980                           write_exp_elt_block (pstate, block_found);
 981                           write_exp_elt_sym (pstate, sym);
 982                           write_exp_elt_opcode (pstate, OP_VAR_VALUE); }
 983         ;
 984
 985 qualified_name: TYPENAME COLONCOLON name
 986                         {
 987                           struct type *type = $1.type;
 988                           CHECK_TYPEDEF (type);
 989                           if (TYPE_CODE (type) != TYPE_CODE_STRUCT
 990                               && TYPE_CODE (type) != TYPE_CODE_UNION
 991                               && TYPE_CODE (type) != TYPE_CODE_NAMESPACE)
 992                             error (_("`%s' is not defined as an aggregate type."),
 993                                    TYPE_SAFE_NAME (type));
 994
 995                           write_exp_elt_opcode (pstate, OP_SCOPE);
 996                           write_exp_elt_type (pstate, type);
 997                           write_exp_string (pstate, $3);
 998                           write_exp_elt_opcode (pstate, OP_SCOPE);
 999                         }
1000         |       TYPENAME COLONCOLON '~' name
1001                         {
1002                           struct type *type = $1.type;
1003                           struct stoken tmp_token;
1004                           char *buf;
1005
1006                           CHECK_TYPEDEF (type);
1007                           if (TYPE_CODE (type) != TYPE_CODE_STRUCT
1008                               && TYPE_CODE (type) != TYPE_CODE_UNION
1009                               && TYPE_CODE (type) != TYPE_CODE_NAMESPACE)
1010                             error (_("`%s' is not defined as an aggregate type."),
1011                                    TYPE_SAFE_NAME (type));
1012                           buf = alloca ($4.length + 2);
1013                           tmp_token.ptr = buf;
1014                           tmp_token.length = $4.length + 1;
1015                           buf[0] = '~';
1016                           memcpy (buf+1, $4.ptr, $4.length);
1017                           buf[tmp_token.length] = 0;
1018
1019                           /* Check for valid destructor name.  */
1020                           destructor_name_p (tmp_token.ptr, $1.type);
1021                           write_exp_elt_opcode (pstate, OP_SCOPE);
1022                           write_exp_elt_type (pstate, type);
1023                           write_exp_string (pstate, tmp_token);
1024                           write_exp_elt_opcode (pstate, OP_SCOPE);
1025                         }
1026         |       TYPENAME COLONCOLON name COLONCOLON name
1027                         {
1028                           char *copy = copy_name ($3);
1029                           error (_("No type \"%s\" within class "
1030                                    "or namespace \"%s\"."),
1031                                  copy, TYPE_SAFE_NAME ($1.type));
1032                         }
1033         ;
1034
1035 variable:       qualified_name
1036         |       COLONCOLON name_not_typename
1037                         {
1038                           char *name = copy_name ($2.stoken);
1039                           struct symbol *sym;
1040                           struct bound_minimal_symbol msymbol;
1041
1042                           sym =
1043                             lookup_symbol (name, (const struct block *) NULL,
1044                                            VAR_DOMAIN, NULL);
1045                           if (sym)
1046                             {
1047                               write_exp_elt_opcode (pstate, OP_VAR_VALUE);
1048                               write_exp_elt_block (pstate, NULL);
1049                               write_exp_elt_sym (pstate, sym);
1050                               write_exp_elt_opcode (pstate, OP_VAR_VALUE);
1051                               break;
1052                             }
1053
1054                           msymbol = lookup_bound_minimal_symbol (name);
1055                           if (msymbol.minsym != NULL)
1056                             write_exp_msymbol (pstate, msymbol);
1057                           else if (!have_full_symbols () && !have_partial_symbols ())
1058                             error (_("No symbol table is loaded.  Use the \"file\" command."));
1059                           else
1060                             error (_("No symbol \"%s\" in current context."), name);
1061                         }
1062         ;
1063
1064 variable:       name_not_typename
1065                         { struct symbol *sym = $1.sym;
1066
1067                           if (sym)
1068                             {
1069                               if (symbol_read_needs_frame (sym))
1070                                 {
1071                                   if (innermost_block == 0
1072                                       || contained_in (block_found,
1073                                                        innermost_block))
1074                                     innermost_block = block_found;
1075                                 }
1076
1077                               write_exp_elt_opcode (pstate, OP_VAR_VALUE);
1078                               /* We want to use the selected frame, not
1079                                  another more inner frame which happens to
1080                                  be in the same block.  */
1081                               write_exp_elt_block (pstate, NULL);
1082                               write_exp_elt_sym (pstate, sym);
1083                               write_exp_elt_opcode (pstate, OP_VAR_VALUE);
1084                             }
1085                           else if ($1.is_a_field_of_this)
1086                             {
1087                               /* C++: it hangs off of `this'.  Must
1088                                  not inadvertently convert from a method call
1089                                  to data ref.  */
1090                               if (innermost_block == 0
1091                                   || contained_in (block_found,
1092                                                    innermost_block))
1093                                 innermost_block = block_found;
1094                               write_exp_elt_opcode (pstate, OP_THIS);
1095                               write_exp_elt_opcode (pstate, OP_THIS);
1096                               write_exp_elt_opcode (pstate, STRUCTOP_PTR);
1097                               write_exp_string (pstate, $1.stoken);
1098                               write_exp_elt_opcode (pstate, STRUCTOP_PTR);
1099                             }
1100                           else
1101                             {
1102                               struct bound_minimal_symbol msymbol;
1103                               char *arg = copy_name ($1.stoken);
1104
1105                               msymbol =
1106                                 lookup_bound_minimal_symbol (arg);
1107                               if (msymbol.minsym != NULL)
1108                                 write_exp_msymbol (pstate, msymbol);
1109                               else if (!have_full_symbols () && !have_partial_symbols ())
1110                                 error (_("No symbol table is loaded.  Use the \"file\" command."));
1111                               else
1112                                 error (_("No symbol \"%s\" in current context."),
1113                                        copy_name ($1.stoken));
1114                             }
1115                         }
1116         ;
1117
1118 space_identifier : '@' NAME
1119                 { insert_type_address_space (pstate, copy_name ($2.stoken)); }
1120         ;
1121
1122 const_or_volatile: const_or_volatile_noopt
1123         |
1124         ;
1125
1126 cv_with_space_id : const_or_volatile space_identifier const_or_volatile
1127         ;
1128
1129 const_or_volatile_or_space_identifier_noopt: cv_with_space_id
1130         | const_or_volatile_noopt
1131         ;
1132
1133 const_or_volatile_or_space_identifier:
1134                 const_or_volatile_or_space_identifier_noopt
1135         |
1136         ;
1137
1138 ptr_operator:
1139                 ptr_operator '*'
1140                         { insert_type (tp_pointer); }
1141                 const_or_volatile_or_space_identifier
1142         |       '*'
1143                         { insert_type (tp_pointer); }
1144                 const_or_volatile_or_space_identifier
1145         |       '&'
1146                         { insert_type (tp_reference); }
1147         |       '&' ptr_operator
1148                         { insert_type (tp_reference); }
1149         ;
1150
1151 ptr_operator_ts: ptr_operator
1152                         {
1153                           $$ = get_type_stack ();
1154                           /* This cleanup is eventually run by
1155                              c_parse.  */
1156                           make_cleanup (type_stack_cleanup, $$);
1157                         }
1158         ;
1159
1160 abs_decl:       ptr_operator_ts direct_abs_decl
1161                         { $$ = append_type_stack ($2, $1); }
1162         |       ptr_operator_ts
1163         |       direct_abs_decl
1164         ;
1165
1166 direct_abs_decl: '(' abs_decl ')'
1167                         { $$ = $2; }
1168         |       direct_abs_decl array_mod
1169                         {
1170                           push_type_stack ($1);
1171                           push_type_int ($2);
1172                           push_type (tp_array);
1173                           $$ = get_type_stack ();
1174                         }
1175         |       array_mod
1176                         {
1177                           push_type_int ($1);
1178                           push_type (tp_array);
1179                           $$ = get_type_stack ();
1180                         }
1181
1182         |       direct_abs_decl func_mod
1183                         {
1184                           push_type_stack ($1);
1185                           push_typelist ($2);
1186                           $$ = get_type_stack ();
1187                         }
1188         |       func_mod
1189                         {
1190                           push_typelist ($1);
1191                           $$ = get_type_stack ();
1192                         }
1193         ;
1194
1195 array_mod:      '[' ']'
1196                         { $$ = -1; }
1197         |       OBJC_LBRAC ']'
1198                         { $$ = -1; }
1199         |       '[' INT ']'
1200                         { $$ = $2.val; }
1201         |       OBJC_LBRAC INT ']'
1202                         { $$ = $2.val; }
1203         ;
1204
1205 func_mod:       '(' ')'
1206                         { $$ = NULL; }
1207         |       '(' parameter_typelist ')'
1208                         { $$ = $2; }
1209         ;
1210
1211 /* We used to try to recognize pointer to member types here, but
1212    that didn't work (shift/reduce conflicts meant that these rules never
1213    got executed).  The problem is that
1214      int (foo::bar::baz::bizzle)
1215    is a function type but
1216      int (foo::bar::baz::bizzle::*)
1217    is a pointer to member type.  Stroustrup loses again!  */
1218
1219 type    :       ptype
1220         ;
1221
1222 typebase  /* Implements (approximately): (type-qualifier)* type-specifier */
1223         :       TYPENAME
1224                         { $$ = $1.type; }
1225         |       INT_KEYWORD
1226                         { $$ = lookup_signed_typename (parse_language (pstate),
1227                                                        parse_gdbarch (pstate),
1228                                                        "int"); }
1229         |       LONG
1230                         { $$ = lookup_signed_typename (parse_language (pstate),
1231                                                        parse_gdbarch (pstate),
1232                                                        "long"); }
1233         |       SHORT
1234                         { $$ = lookup_signed_typename (parse_language (pstate),
1235                                                        parse_gdbarch (pstate),
1236                                                        "short"); }
1237         |       LONG INT_KEYWORD
1238                         { $$ = lookup_signed_typename (parse_language (pstate),
1239                                                        parse_gdbarch (pstate),
1240                                                        "long"); }
1241         |       LONG SIGNED_KEYWORD INT_KEYWORD
1242                         { $$ = lookup_signed_typename (parse_language (pstate),
1243                                                        parse_gdbarch (pstate),
1244                                                        "long"); }
1245         |       LONG SIGNED_KEYWORD
1246                         { $$ = lookup_signed_typename (parse_language (pstate),
1247                                                        parse_gdbarch (pstate),
1248                                                        "long"); }
1249         |       SIGNED_KEYWORD LONG INT_KEYWORD
1250                         { $$ = lookup_signed_typename (parse_language (pstate),
1251                                                        parse_gdbarch (pstate),
1252                                                        "long"); }
1253         |       UNSIGNED LONG INT_KEYWORD
1254                         { $$ = lookup_unsigned_typename (parse_language (pstate),
1255                                                          parse_gdbarch (pstate),
1256                                                          "long"); }
1257         |       LONG UNSIGNED INT_KEYWORD
1258                         { $$ = lookup_unsigned_typename (parse_language (pstate),
1259                                                          parse_gdbarch (pstate),
1260                                                          "long"); }
1261         |       LONG UNSIGNED
1262                         { $$ = lookup_unsigned_typename (parse_language (pstate),
1263                                                          parse_gdbarch (pstate),
1264                                                          "long"); }
1265         |       LONG LONG
1266                         { $$ = lookup_signed_typename (parse_language (pstate),
1267                                                        parse_gdbarch (pstate),
1268                                                        "long long"); }
1269         |       LONG LONG INT_KEYWORD
1270                         { $$ = lookup_signed_typename (parse_language (pstate),
1271                                                        parse_gdbarch (pstate),
1272                                                        "long long"); }
1273         |       LONG LONG SIGNED_KEYWORD INT_KEYWORD
1274                         { $$ = lookup_signed_typename (parse_language (pstate),
1275                                                        parse_gdbarch (pstate),
1276                                                        "long long"); }
1277         |       LONG LONG SIGNED_KEYWORD
1278                         { $$ = lookup_signed_typename (parse_language (pstate),
1279                                                        parse_gdbarch (pstate),
1280                                                        "long long"); }
1281         |       SIGNED_KEYWORD LONG LONG
1282                         { $$ = lookup_signed_typename (parse_language (pstate),
1283                                                        parse_gdbarch (pstate),
1284                                                        "long long"); }
1285         |       SIGNED_KEYWORD LONG LONG INT_KEYWORD
1286                         { $$ = lookup_signed_typename (parse_language (pstate),
1287                                                        parse_gdbarch (pstate),
1288                                                        "long long"); }
1289         |       UNSIGNED LONG LONG
1290                         { $$ = lookup_unsigned_typename (parse_language (pstate),
1291                                                          parse_gdbarch (pstate),
1292                                                          "long long"); }
1293         |       UNSIGNED LONG LONG INT_KEYWORD
1294                         { $$ = lookup_unsigned_typename (parse_language (pstate),
1295                                                          parse_gdbarch (pstate),
1296                                                          "long long"); }
1297         |       LONG LONG UNSIGNED
1298                         { $$ = lookup_unsigned_typename (parse_language (pstate),
1299                                                          parse_gdbarch (pstate),
1300                                                          "long long"); }
1301         |       LONG LONG UNSIGNED INT_KEYWORD
1302                         { $$ = lookup_unsigned_typename (parse_language (pstate),
1303                                                          parse_gdbarch (pstate),
1304                                                          "long long"); }
1305         |       SHORT INT_KEYWORD
1306                         { $$ = lookup_signed_typename (parse_language (pstate),
1307                                                        parse_gdbarch (pstate),
1308                                                        "short"); }
1309         |       SHORT SIGNED_KEYWORD INT_KEYWORD
1310                         { $$ = lookup_signed_typename (parse_language (pstate),
1311                                                        parse_gdbarch (pstate),
1312                                                        "short"); }
1313         |       SHORT SIGNED_KEYWORD
1314                         { $$ = lookup_signed_typename (parse_language (pstate),
1315                                                        parse_gdbarch (pstate),
1316                                                        "short"); }
1317         |       UNSIGNED SHORT INT_KEYWORD
1318                         { $$ = lookup_unsigned_typename (parse_language (pstate),
1319                                                          parse_gdbarch (pstate),
1320                                                          "short"); }
1321         |       SHORT UNSIGNED
1322                         { $$ = lookup_unsigned_typename (parse_language (pstate),
1323                                                          parse_gdbarch (pstate),
1324                                                          "short"); }
1325         |       SHORT UNSIGNED INT_KEYWORD
1326                         { $$ = lookup_unsigned_typename (parse_language (pstate),
1327                                                          parse_gdbarch (pstate),
1328                                                          "short"); }
1329         |       DOUBLE_KEYWORD
1330                         { $$ = lookup_typename (parse_language (pstate),
1331                                                 parse_gdbarch (pstate),
1332                                                 "double",
1333                                                 (struct block *) NULL,
1334                                                 0); }
1335         |       LONG DOUBLE_KEYWORD
1336                         { $$ = lookup_typename (parse_language (pstate),
1337                                                 parse_gdbarch (pstate),
1338                                                 "long double",
1339                                                 (struct block *) NULL,
1340                                                 0); }
1341         |       STRUCT name
1342                         { $$ = lookup_struct (copy_name ($2),
1343                                               expression_context_block); }
1344         |       STRUCT COMPLETE
1345                         {
1346                           mark_completion_tag (TYPE_CODE_STRUCT, "", 0);
1347                           $$ = NULL;
1348                         }
1349         |       STRUCT name COMPLETE
1350                         {
1351                           mark_completion_tag (TYPE_CODE_STRUCT, $2.ptr,
1352                                                $2.length);
1353                           $$ = NULL;
1354                         }
1355         |       CLASS name
1356                         { $$ = lookup_struct (copy_name ($2),
1357                                               expression_context_block); }
1358         |       CLASS COMPLETE
1359                         {
1360                           mark_completion_tag (TYPE_CODE_CLASS, "", 0);
1361                           $$ = NULL;
1362                         }
1363         |       CLASS name COMPLETE
1364                         {
1365                           mark_completion_tag (TYPE_CODE_CLASS, $2.ptr,
1366                                                $2.length);
1367                           $$ = NULL;
1368                         }
1369         |       UNION name
1370                         { $$ = lookup_union (copy_name ($2),
1371                                              expression_context_block); }
1372         |       UNION COMPLETE
1373                         {
1374                           mark_completion_tag (TYPE_CODE_UNION, "", 0);
1375                           $$ = NULL;
1376                         }
1377         |       UNION name COMPLETE
1378                         {
1379                           mark_completion_tag (TYPE_CODE_UNION, $2.ptr,
1380                                                $2.length);
1381                           $$ = NULL;
1382                         }
1383         |       ENUM name
1384                         { $$ = lookup_enum (copy_name ($2),
1385                                             expression_context_block); }
1386         |       ENUM COMPLETE
1387                         {
1388                           mark_completion_tag (TYPE_CODE_ENUM, "", 0);
1389                           $$ = NULL;
1390                         }
1391         |       ENUM name COMPLETE
1392                         {
1393                           mark_completion_tag (TYPE_CODE_ENUM, $2.ptr,
1394                                                $2.length);
1395                           $$ = NULL;
1396                         }
1397         |       UNSIGNED typename
1398                         { $$ = lookup_unsigned_typename (parse_language (pstate),
1399                                                          parse_gdbarch (pstate),
1400                                                          TYPE_NAME($2.type)); }
1401         |       UNSIGNED
1402                         { $$ = lookup_unsigned_typename (parse_language (pstate),
1403                                                          parse_gdbarch (pstate),
1404                                                          "int"); }
1405         |       SIGNED_KEYWORD typename
1406                         { $$ = lookup_signed_typename (parse_language (pstate),
1407                                                        parse_gdbarch (pstate),
1408                                                        TYPE_NAME($2.type)); }
1409         |       SIGNED_KEYWORD
1410                         { $$ = lookup_signed_typename (parse_language (pstate),
1411                                                        parse_gdbarch (pstate),
1412                                                        "int"); }
1413                 /* It appears that this rule for templates is never
1414                    reduced; template recognition happens by lookahead
1415                    in the token processing code in yylex. */
1416         |       TEMPLATE name '<' type '>'
1417                         { $$ = lookup_template_type(copy_name($2), $4,
1418                                                     expression_context_block);
1419                         }
1420         | const_or_volatile_or_space_identifier_noopt typebase
1421                         { $$ = follow_types ($2); }
1422         | typebase const_or_volatile_or_space_identifier_noopt
1423                         { $$ = follow_types ($1); }
1424         ;
1425
1426 typename:       TYPENAME
1427         |       INT_KEYWORD
1428                 {
1429                   $$.stoken.ptr = "int";
1430                   $$.stoken.length = 3;
1431                   $$.type = lookup_signed_typename (parse_language (pstate),
1432                                                     parse_gdbarch (pstate),
1433                                                     "int");
1434                 }
1435         |       LONG
1436                 {
1437                   $$.stoken.ptr = "long";
1438                   $$.stoken.length = 4;
1439                   $$.type = lookup_signed_typename (parse_language (pstate),
1440                                                     parse_gdbarch (pstate),
1441                                                     "long");
1442                 }
1443         |       SHORT
1444                 {
1445                   $$.stoken.ptr = "short";
1446                   $$.stoken.length = 5;
1447                   $$.type = lookup_signed_typename (parse_language (pstate),
1448                                                     parse_gdbarch (pstate),
1449                                                     "short");
1450                 }
1451         ;
1452
1453 parameter_typelist:
1454                 nonempty_typelist
1455                         { check_parameter_typelist ($1); }
1456         |       nonempty_typelist ',' DOTDOTDOT
1457                         {
1458                           VEC_safe_push (type_ptr, $1, NULL);
1459                           check_parameter_typelist ($1);
1460                           $$ = $1;
1461                         }
1462         ;
1463
1464 nonempty_typelist
1465         :       type
1466                 {
1467                   VEC (type_ptr) *typelist = NULL;
1468                   VEC_safe_push (type_ptr, typelist, $1);
1469                   $$ = typelist;
1470                 }
1471         |       nonempty_typelist ',' type
1472                 {
1473                   VEC_safe_push (type_ptr, $1, $3);
1474                   $$ = $1;
1475                 }
1476         ;
1477
1478 ptype   :       typebase
1479         |       ptype abs_decl
1480                 {
1481                   push_type_stack ($2);
1482                   $$ = follow_types ($1);
1483                 }
1484         ;
1485
1486 conversion_type_id: typebase conversion_declarator
1487                 { $$ = follow_types ($1); }
1488         ;
1489
1490 conversion_declarator:  /* Nothing.  */
1491         | ptr_operator conversion_declarator
1492         ;
1493
1494 const_and_volatile:     CONST_KEYWORD VOLATILE_KEYWORD
1495         |               VOLATILE_KEYWORD CONST_KEYWORD
1496         ;
1497
1498 const_or_volatile_noopt:        const_and_volatile
1499                         { insert_type (tp_const);
1500                           insert_type (tp_volatile);
1501                         }
1502         |               CONST_KEYWORD
1503                         { insert_type (tp_const); }
1504         |               VOLATILE_KEYWORD
1505                         { insert_type (tp_volatile); }
1506         ;
1507
1508 operator:       OPERATOR NEW
1509                         { $$ = operator_stoken (" new"); }
1510         |       OPERATOR DELETE
1511                         { $$ = operator_stoken (" delete"); }
1512         |       OPERATOR NEW '[' ']'
1513                         { $$ = operator_stoken (" new[]"); }
1514         |       OPERATOR DELETE '[' ']'
1515                         { $$ = operator_stoken (" delete[]"); }
1516         |       OPERATOR NEW OBJC_LBRAC ']'
1517                         { $$ = operator_stoken (" new[]"); }
1518         |       OPERATOR DELETE OBJC_LBRAC ']'
1519                         { $$ = operator_stoken (" delete[]"); }
1520         |       OPERATOR '+'
1521                         { $$ = operator_stoken ("+"); }
1522         |       OPERATOR '-'
1523                         { $$ = operator_stoken ("-"); }
1524         |       OPERATOR '*'
1525                         { $$ = operator_stoken ("*"); }
1526         |       OPERATOR '/'
1527                         { $$ = operator_stoken ("/"); }
1528         |       OPERATOR '%'
1529                         { $$ = operator_stoken ("%"); }
1530         |       OPERATOR '^'
1531                         { $$ = operator_stoken ("^"); }
1532         |       OPERATOR '&'
1533                         { $$ = operator_stoken ("&"); }
1534         |       OPERATOR '|'
1535                         { $$ = operator_stoken ("|"); }
1536         |       OPERATOR '~'
1537                         { $$ = operator_stoken ("~"); }
1538         |       OPERATOR '!'
1539                         { $$ = operator_stoken ("!"); }
1540         |       OPERATOR '='
1541                         { $$ = operator_stoken ("="); }
1542         |       OPERATOR '<'
1543                         { $$ = operator_stoken ("<"); }
1544         |       OPERATOR '>'
1545                         { $$ = operator_stoken (">"); }
1546         |       OPERATOR ASSIGN_MODIFY
1547                         { const char *op = "unknown";
1548                           switch ($2)
1549                             {
1550                             case BINOP_RSH:
1551                               op = ">>=";
1552                               break;
1553                             case BINOP_LSH:
1554                               op = "<<=";
1555                               break;
1556                             case BINOP_ADD:
1557                               op = "+=";
1558                               break;
1559                             case BINOP_SUB:
1560                               op = "-=";
1561                               break;
1562                             case BINOP_MUL:
1563                               op = "*=";
1564                               break;
1565                             case BINOP_DIV:
1566                               op = "/=";
1567                               break;
1568                             case BINOP_REM:
1569                               op = "%=";
1570                               break;
1571                             case BINOP_BITWISE_IOR:
1572                               op = "|=";
1573                               break;
1574                             case BINOP_BITWISE_AND:
1575                               op = "&=";
1576                               break;
1577                             case BINOP_BITWISE_XOR:
1578                               op = "^=";
1579                               break;
1580                             default:
1581                               break;
1582                             }
1583
1584                           $$ = operator_stoken (op);
1585                         }
1586         |       OPERATOR LSH
1587                         { $$ = operator_stoken ("<<"); }
1588         |       OPERATOR RSH
1589                         { $$ = operator_stoken (">>"); }
1590         |       OPERATOR EQUAL
1591                         { $$ = operator_stoken ("=="); }
1592         |       OPERATOR NOTEQUAL
1593                         { $$ = operator_stoken ("!="); }
1594         |       OPERATOR LEQ
1595                         { $$ = operator_stoken ("<="); }
1596         |       OPERATOR GEQ
1597                         { $$ = operator_stoken (">="); }
1598         |       OPERATOR ANDAND
1599                         { $$ = operator_stoken ("&&"); }
1600         |       OPERATOR OROR
1601                         { $$ = operator_stoken ("||"); }
1602         |       OPERATOR INCREMENT
1603                         { $$ = operator_stoken ("++"); }
1604         |       OPERATOR DECREMENT
1605                         { $$ = operator_stoken ("--"); }
1606         |       OPERATOR ','
1607                         { $$ = operator_stoken (","); }
1608         |       OPERATOR ARROW_STAR
1609                         { $$ = operator_stoken ("->*"); }
1610         |       OPERATOR ARROW
1611                         { $$ = operator_stoken ("->"); }
1612         |       OPERATOR '(' ')'
1613                         { $$ = operator_stoken ("()"); }
1614         |       OPERATOR '[' ']'
1615                         { $$ = operator_stoken ("[]"); }
1616         |       OPERATOR OBJC_LBRAC ']'
1617                         { $$ = operator_stoken ("[]"); }
1618         |       OPERATOR conversion_type_id
1619                         { char *name;
1620                           long length;
1621                           struct ui_file *buf = mem_fileopen ();
1622
1623                           c_print_type ($2, NULL, buf, -1, 0,
1624                                         &type_print_raw_options);
1625                           name = ui_file_xstrdup (buf, &length);
1626                           ui_file_delete (buf);
1627                           $$ = operator_stoken (name);
1628                           free (name);
1629                         }
1630         ;
1631
1632
1633
1634 name    :       NAME { $$ = $1.stoken; }
1635         |       BLOCKNAME { $$ = $1.stoken; }
1636         |       TYPENAME { $$ = $1.stoken; }
1637         |       NAME_OR_INT  { $$ = $1.stoken; }
1638         |       UNKNOWN_CPP_NAME  { $$ = $1.stoken; }
1639         |       operator { $$ = $1; }
1640         ;
1641
1642 name_not_typename :     NAME
1643         |       BLOCKNAME
1644 /* These would be useful if name_not_typename was useful, but it is just
1645    a fake for "variable", so these cause reduce/reduce conflicts because
1646    the parser can't tell whether NAME_OR_INT is a name_not_typename (=variable,
1647    =exp) or just an exp.  If name_not_typename was ever used in an lvalue
1648    context where only a name could occur, this might be useful.
1649         |       NAME_OR_INT
1650  */
1651         |       operator
1652                         {
1653                           struct field_of_this_result is_a_field_of_this;
1654
1655                           $$.stoken = $1;
1656                           $$.sym = lookup_symbol ($1.ptr,
1657                                                   expression_context_block,
1658                                                   VAR_DOMAIN,
1659                                                   &is_a_field_of_this);
1660                           $$.is_a_field_of_this
1661                             = is_a_field_of_this.type != NULL;
1662                         }
1663         |       UNKNOWN_CPP_NAME
1664         ;
1665
1666 %%
1667
1668 /* Like write_exp_string, but prepends a '~'.  */
1669
1670 static void
1671 write_destructor_name (struct parser_state *par_state, struct stoken token)
1672 {
1673   char *copy = alloca (token.length + 1);
1674
1675   copy[0] = '~';
1676   memcpy (&copy[1], token.ptr, token.length);
1677
1678   token.ptr = copy;
1679   ++token.length;
1680
1681   write_exp_string (par_state, token);
1682 }
1683
1684 /* Returns a stoken of the operator name given by OP (which does not
1685    include the string "operator").  */
1686 static struct stoken
1687 operator_stoken (const char *op)
1688 {
1689   static const char *operator_string = "operator";
1690   struct stoken st = { NULL, 0 };
1691   char *buf;
1692
1693   st.length = strlen (operator_string) + strlen (op);
1694   buf = malloc (st.length + 1);
1695   strcpy (buf, operator_string);
1696   strcat (buf, op);
1697   st.ptr = buf;
1698
1699   /* The toplevel (c_parse) will free the memory allocated here.  */
1700   make_cleanup (free, buf);
1701   return st;
1702 };
1703
1704 /* Validate a parameter typelist.  */
1705
1706 static void
1707 check_parameter_typelist (VEC (type_ptr) *params)
1708 {
1709   struct type *type;
1710   int ix;
1711
1712   for (ix = 0; VEC_iterate (type_ptr, params, ix, type); ++ix)
1713     {
1714       if (type != NULL && TYPE_CODE (check_typedef (type)) == TYPE_CODE_VOID)
1715         {
1716           if (ix == 0)
1717             {
1718               if (VEC_length (type_ptr, params) == 1)
1719                 {
1720                   /* Ok.  */
1721                   break;
1722                 }
1723               VEC_free (type_ptr, params);
1724               error (_("parameter types following 'void'"));
1725             }
1726           else
1727             {
1728               VEC_free (type_ptr, params);
1729               error (_("'void' invalid as parameter type"));
1730             }
1731         }
1732     }
1733 }
1734
1735 /* Take care of parsing a number (anything that starts with a digit).
1736    Set yylval and return the token type; update lexptr.
1737    LEN is the number of characters in it.  */
1738
1739 /*** Needs some error checking for the float case ***/
1740
1741 static int
1742 parse_number (struct parser_state *par_state,
1743               const char *buf, int len, int parsed_float, YYSTYPE *putithere)
1744 {
1745   /* FIXME: Shouldn't these be unsigned?  We don't deal with negative values
1746      here, and we do kind of silly things like cast to unsigned.  */
1747   LONGEST n = 0;
1748   LONGEST prevn = 0;
1749   ULONGEST un;
1750
1751   int i = 0;
1752   int c;
1753   int base = input_radix;
1754   int unsigned_p = 0;
1755
1756   /* Number of "L" suffixes encountered.  */
1757   int long_p = 0;
1758
1759   /* We have found a "L" or "U" suffix.  */
1760   int found_suffix = 0;
1761
1762   ULONGEST high_bit;
1763   struct type *signed_type;
1764   struct type *unsigned_type;
1765   char *p;
1766
1767   p = alloca (len);
1768   memcpy (p, buf, len);
1769
1770   if (parsed_float)
1771     {
1772       /* If it ends at "df", "dd" or "dl", take it as type of decimal floating
1773          point.  Return DECFLOAT.  */
1774
1775       if (len >= 2 && p[len - 2] == 'd' && p[len - 1] == 'f')
1776         {
1777           p[len - 2] = '\0';
1778           putithere->typed_val_decfloat.type
1779             = parse_type (par_state)->builtin_decfloat;
1780           decimal_from_string (putithere->typed_val_decfloat.val, 4,
1781                                gdbarch_byte_order (parse_gdbarch (par_state)),
1782                                p);
1783           p[len - 2] = 'd';
1784           return DECFLOAT;
1785         }
1786
1787       if (len >= 2 && p[len - 2] == 'd' && p[len - 1] == 'd')
1788         {
1789           p[len - 2] = '\0';
1790           putithere->typed_val_decfloat.type
1791             = parse_type (par_state)->builtin_decdouble;
1792           decimal_from_string (putithere->typed_val_decfloat.val, 8,
1793                                gdbarch_byte_order (parse_gdbarch (par_state)),
1794                                p);
1795           p[len - 2] = 'd';
1796           return DECFLOAT;
1797         }
1798
1799       if (len >= 2 && p[len - 2] == 'd' && p[len - 1] == 'l')
1800         {
1801           p[len - 2] = '\0';
1802           putithere->typed_val_decfloat.type
1803             = parse_type (par_state)->builtin_declong;
1804           decimal_from_string (putithere->typed_val_decfloat.val, 16,
1805                                gdbarch_byte_order (parse_gdbarch (par_state)),
1806                                p);
1807           p[len - 2] = 'd';
1808           return DECFLOAT;
1809         }
1810
1811       if (! parse_c_float (parse_gdbarch (par_state), p, len,
1812                            &putithere->typed_val_float.dval,
1813                            &putithere->typed_val_float.type))
1814         return ERROR;
1815       return FLOAT;
1816     }
1817
1818   /* Handle base-switching prefixes 0x, 0t, 0d, 0 */
1819   if (p[0] == '0')
1820     switch (p[1])
1821       {
1822       case 'x':
1823       case 'X':
1824         if (len >= 3)
1825           {
1826             p += 2;
1827             base = 16;
1828             len -= 2;
1829           }
1830         break;
1831
1832       case 'b':
1833       case 'B':
1834         if (len >= 3)
1835           {
1836             p += 2;
1837             base = 2;
1838             len -= 2;
1839           }
1840         break;
1841
1842       case 't':
1843       case 'T':
1844       case 'd':
1845       case 'D':
1846         if (len >= 3)
1847           {
1848             p += 2;
1849             base = 10;
1850             len -= 2;
1851           }
1852         break;
1853
1854       default:
1855         base = 8;
1856         break;
1857       }
1858
1859   while (len-- > 0)
1860     {
1861       c = *p++;
1862       if (c >= 'A' && c <= 'Z')
1863         c += 'a' - 'A';
1864       if (c != 'l' && c != 'u')
1865         n *= base;
1866       if (c >= '0' && c <= '9')
1867         {
1868           if (found_suffix)
1869             return ERROR;
1870           n += i = c - '0';
1871         }
1872       else
1873         {
1874           if (base > 10 && c >= 'a' && c <= 'f')
1875             {
1876               if (found_suffix)
1877                 return ERROR;
1878               n += i = c - 'a' + 10;
1879             }
1880           else if (c == 'l')
1881             {
1882               ++long_p;
1883               found_suffix = 1;
1884             }
1885           else if (c == 'u')
1886             {
1887               unsigned_p = 1;
1888               found_suffix = 1;
1889             }
1890           else
1891             return ERROR;       /* Char not a digit */
1892         }
1893       if (i >= base)
1894         return ERROR;           /* Invalid digit in this base */
1895
1896       /* Portably test for overflow (only works for nonzero values, so make
1897          a second check for zero).  FIXME: Can't we just make n and prevn
1898          unsigned and avoid this?  */
1899       if (c != 'l' && c != 'u' && (prevn >= n) && n != 0)
1900         unsigned_p = 1;         /* Try something unsigned */
1901
1902       /* Portably test for unsigned overflow.
1903          FIXME: This check is wrong; for example it doesn't find overflow
1904          on 0x123456789 when LONGEST is 32 bits.  */
1905       if (c != 'l' && c != 'u' && n != 0)
1906         {
1907           if ((unsigned_p && (ULONGEST) prevn >= (ULONGEST) n))
1908             error (_("Numeric constant too large."));
1909         }
1910       prevn = n;
1911     }
1912
1913   /* An integer constant is an int, a long, or a long long.  An L
1914      suffix forces it to be long; an LL suffix forces it to be long
1915      long.  If not forced to a larger size, it gets the first type of
1916      the above that it fits in.  To figure out whether it fits, we
1917      shift it right and see whether anything remains.  Note that we
1918      can't shift sizeof (LONGEST) * HOST_CHAR_BIT bits or more in one
1919      operation, because many compilers will warn about such a shift
1920      (which always produces a zero result).  Sometimes gdbarch_int_bit
1921      or gdbarch_long_bit will be that big, sometimes not.  To deal with
1922      the case where it is we just always shift the value more than
1923      once, with fewer bits each time.  */
1924
1925   un = (ULONGEST)n >> 2;
1926   if (long_p == 0
1927       && (un >> (gdbarch_int_bit (parse_gdbarch (par_state)) - 2)) == 0)
1928     {
1929       high_bit
1930         = ((ULONGEST)1) << (gdbarch_int_bit (parse_gdbarch (par_state)) - 1);
1931
1932       /* A large decimal (not hex or octal) constant (between INT_MAX
1933          and UINT_MAX) is a long or unsigned long, according to ANSI,
1934          never an unsigned int, but this code treats it as unsigned
1935          int.  This probably should be fixed.  GCC gives a warning on
1936          such constants.  */
1937
1938       unsigned_type = parse_type (par_state)->builtin_unsigned_int;
1939       signed_type = parse_type (par_state)->builtin_int;
1940     }
1941   else if (long_p <= 1
1942            && (un >> (gdbarch_long_bit (parse_gdbarch (par_state)) - 2)) == 0)
1943     {
1944       high_bit
1945         = ((ULONGEST)1) << (gdbarch_long_bit (parse_gdbarch (par_state)) - 1);
1946       unsigned_type = parse_type (par_state)->builtin_unsigned_long;
1947       signed_type = parse_type (par_state)->builtin_long;
1948     }
1949   else
1950     {
1951       int shift;
1952       if (sizeof (ULONGEST) * HOST_CHAR_BIT
1953           < gdbarch_long_long_bit (parse_gdbarch (par_state)))
1954         /* A long long does not fit in a LONGEST.  */
1955         shift = (sizeof (ULONGEST) * HOST_CHAR_BIT - 1);
1956       else
1957         shift = (gdbarch_long_long_bit (parse_gdbarch (par_state)) - 1);
1958       high_bit = (ULONGEST) 1 << shift;
1959       unsigned_type = parse_type (par_state)->builtin_unsigned_long_long;
1960       signed_type = parse_type (par_state)->builtin_long_long;
1961     }
1962
1963    putithere->typed_val_int.val = n;
1964
1965    /* If the high bit of the worked out type is set then this number
1966       has to be unsigned. */
1967
1968    if (unsigned_p || (n & high_bit))
1969      {
1970        putithere->typed_val_int.type = unsigned_type;
1971      }
1972    else
1973      {
1974        putithere->typed_val_int.type = signed_type;
1975      }
1976
1977    return INT;
1978 }
1979
1980 /* Temporary obstack used for holding strings.  */
1981 static struct obstack tempbuf;
1982 static int tempbuf_init;
1983
1984 /* Parse a C escape sequence.  The initial backslash of the sequence
1985    is at (*PTR)[-1].  *PTR will be updated to point to just after the
1986    last character of the sequence.  If OUTPUT is not NULL, the
1987    translated form of the escape sequence will be written there.  If
1988    OUTPUT is NULL, no output is written and the call will only affect
1989    *PTR.  If an escape sequence is expressed in target bytes, then the
1990    entire sequence will simply be copied to OUTPUT.  Return 1 if any
1991    character was emitted, 0 otherwise.  */
1992
1993 int
1994 c_parse_escape (const char **ptr, struct obstack *output)
1995 {
1996   const char *tokptr = *ptr;
1997   int result = 1;
1998
1999   /* Some escape sequences undergo character set conversion.  Those we
2000      translate here.  */
2001   switch (*tokptr)
2002     {
2003       /* Hex escapes do not undergo character set conversion, so keep
2004          the escape sequence for later.  */
2005     case 'x':
2006       if (output)
2007         obstack_grow_str (output, "\\x");
2008       ++tokptr;
2009       if (!isxdigit (*tokptr))
2010         error (_("\\x escape without a following hex digit"));
2011       while (isxdigit (*tokptr))
2012         {
2013           if (output)
2014             obstack_1grow (output, *tokptr);
2015           ++tokptr;
2016         }
2017       break;
2018
2019       /* Octal escapes do not undergo character set conversion, so
2020          keep the escape sequence for later.  */
2021     case '0':
2022     case '1':
2023     case '2':
2024     case '3':
2025     case '4':
2026     case '5':
2027     case '6':
2028     case '7':
2029       {
2030         int i;
2031         if (output)
2032           obstack_grow_str (output, "\\");
2033         for (i = 0;
2034              i < 3 && isdigit (*tokptr) && *tokptr != '8' && *tokptr != '9';
2035              ++i)
2036           {
2037             if (output)
2038               obstack_1grow (output, *tokptr);
2039             ++tokptr;
2040           }
2041       }
2042       break;
2043
2044       /* We handle UCNs later.  We could handle them here, but that
2045          would mean a spurious error in the case where the UCN could
2046          be converted to the target charset but not the host
2047          charset.  */
2048     case 'u':
2049     case 'U':
2050       {
2051         char c = *tokptr;
2052         int i, len = c == 'U' ? 8 : 4;
2053         if (output)
2054           {
2055             obstack_1grow (output, '\\');
2056             obstack_1grow (output, *tokptr);
2057           }
2058         ++tokptr;
2059         if (!isxdigit (*tokptr))
2060           error (_("\\%c escape without a following hex digit"), c);
2061         for (i = 0; i < len && isxdigit (*tokptr); ++i)
2062           {
2063             if (output)
2064               obstack_1grow (output, *tokptr);
2065             ++tokptr;
2066           }
2067       }
2068       break;
2069
2070       /* We must pass backslash through so that it does not
2071          cause quoting during the second expansion.  */
2072     case '\\':
2073       if (output)
2074         obstack_grow_str (output, "\\\\");
2075       ++tokptr;
2076       break;
2077
2078       /* Escapes which undergo conversion.  */
2079     case 'a':
2080       if (output)
2081         obstack_1grow (output, '\a');
2082       ++tokptr;
2083       break;
2084     case 'b':
2085       if (output)
2086         obstack_1grow (output, '\b');
2087       ++tokptr;
2088       break;
2089     case 'f':
2090       if (output)
2091         obstack_1grow (output, '\f');
2092       ++tokptr;
2093       break;
2094     case 'n':
2095       if (output)
2096         obstack_1grow (output, '\n');
2097       ++tokptr;
2098       break;
2099     case 'r':
2100       if (output)
2101         obstack_1grow (output, '\r');
2102       ++tokptr;
2103       break;
2104     case 't':
2105       if (output)
2106         obstack_1grow (output, '\t');
2107       ++tokptr;
2108       break;
2109     case 'v':
2110       if (output)
2111         obstack_1grow (output, '\v');
2112       ++tokptr;
2113       break;
2114
2115       /* GCC extension.  */
2116     case 'e':
2117       if (output)
2118         obstack_1grow (output, HOST_ESCAPE_CHAR);
2119       ++tokptr;
2120       break;
2121
2122       /* Backslash-newline expands to nothing at all.  */
2123     case '\n':
2124       ++tokptr;
2125       result = 0;
2126       break;
2127
2128       /* A few escapes just expand to the character itself.  */
2129     case '\'':
2130     case '\"':
2131     case '?':
2132       /* GCC extensions.  */
2133     case '(':
2134     case '{':
2135     case '[':
2136     case '%':
2137       /* Unrecognized escapes turn into the character itself.  */
2138     default:
2139       if (output)
2140         obstack_1grow (output, *tokptr);
2141       ++tokptr;
2142       break;
2143     }
2144   *ptr = tokptr;
2145   return result;
2146 }
2147
2148 /* Parse a string or character literal from TOKPTR.  The string or
2149    character may be wide or unicode.  *OUTPTR is set to just after the
2150    end of the literal in the input string.  The resulting token is
2151    stored in VALUE.  This returns a token value, either STRING or
2152    CHAR, depending on what was parsed.  *HOST_CHARS is set to the
2153    number of host characters in the literal.  */
2154 static int
2155 parse_string_or_char (const char *tokptr, const char **outptr,
2156                       struct typed_stoken *value, int *host_chars)
2157 {
2158   int quote;
2159   enum c_string_type type;
2160   int is_objc = 0;
2161
2162   /* Build the gdb internal form of the input string in tempbuf.  Note
2163      that the buffer is null byte terminated *only* for the
2164      convenience of debugging gdb itself and printing the buffer
2165      contents when the buffer contains no embedded nulls.  Gdb does
2166      not depend upon the buffer being null byte terminated, it uses
2167      the length string instead.  This allows gdb to handle C strings
2168      (as well as strings in other languages) with embedded null
2169      bytes */
2170
2171   if (!tempbuf_init)
2172     tempbuf_init = 1;
2173   else
2174     obstack_free (&tempbuf, NULL);
2175   obstack_init (&tempbuf);
2176
2177   /* Record the string type.  */
2178   if (*tokptr == 'L')
2179     {
2180       type = C_WIDE_STRING;
2181       ++tokptr;
2182     }
2183   else if (*tokptr == 'u')
2184     {
2185       type = C_STRING_16;
2186       ++tokptr;
2187     }
2188   else if (*tokptr == 'U')
2189     {
2190       type = C_STRING_32;
2191       ++tokptr;
2192     }
2193   else if (*tokptr == '@')
2194     {
2195       /* An Objective C string.  */
2196       is_objc = 1;
2197       type = C_STRING;
2198       ++tokptr;
2199     }
2200   else
2201     type = C_STRING;
2202
2203   /* Skip the quote.  */
2204   quote = *tokptr;
2205   if (quote == '\'')
2206     type |= C_CHAR;
2207   ++tokptr;
2208
2209   *host_chars = 0;
2210
2211   while (*tokptr)
2212     {
2213       char c = *tokptr;
2214       if (c == '\\')
2215         {
2216           ++tokptr;
2217           *host_chars += c_parse_escape (&tokptr, &tempbuf);
2218         }
2219       else if (c == quote)
2220         break;
2221       else
2222         {
2223           obstack_1grow (&tempbuf, c);
2224           ++tokptr;
2225           /* FIXME: this does the wrong thing with multi-byte host
2226              characters.  We could use mbrlen here, but that would
2227              make "set host-charset" a bit less useful.  */
2228           ++*host_chars;
2229         }
2230     }
2231
2232   if (*tokptr != quote)
2233     {
2234       if (quote == '"')
2235         error (_("Unterminated string in expression."));
2236       else
2237         error (_("Unmatched single quote."));
2238     }
2239   ++tokptr;
2240
2241   value->type = type;
2242   value->ptr = obstack_base (&tempbuf);
2243   value->length = obstack_object_size (&tempbuf);
2244
2245   *outptr = tokptr;
2246
2247   return quote == '"' ? (is_objc ? NSSTRING : STRING) : CHAR;
2248 }
2249
2250 /* This is used to associate some attributes with a token.  */
2251
2252 enum token_flags
2253 {
2254   /* If this bit is set, the token is C++-only.  */
2255
2256   FLAG_CXX = 1,
2257
2258   /* If this bit is set, the token is conditional: if there is a
2259      symbol of the same name, then the token is a symbol; otherwise,
2260      the token is a keyword.  */
2261
2262   FLAG_SHADOW = 2
2263 };
2264
2265 struct token
2266 {
2267   char *operator;
2268   int token;
2269   enum exp_opcode opcode;
2270   enum token_flags flags;
2271 };
2272
2273 static const struct token tokentab3[] =
2274   {
2275     {">>=", ASSIGN_MODIFY, BINOP_RSH, 0},
2276     {"<<=", ASSIGN_MODIFY, BINOP_LSH, 0},
2277     {"->*", ARROW_STAR, BINOP_END, FLAG_CXX},
2278     {"...", DOTDOTDOT, BINOP_END, 0}
2279   };
2280
2281 static const struct token tokentab2[] =
2282   {
2283     {"+=", ASSIGN_MODIFY, BINOP_ADD, 0},
2284     {"-=", ASSIGN_MODIFY, BINOP_SUB, 0},
2285     {"*=", ASSIGN_MODIFY, BINOP_MUL, 0},
2286     {"/=", ASSIGN_MODIFY, BINOP_DIV, 0},
2287     {"%=", ASSIGN_MODIFY, BINOP_REM, 0},
2288     {"|=", ASSIGN_MODIFY, BINOP_BITWISE_IOR, 0},
2289     {"&=", ASSIGN_MODIFY, BINOP_BITWISE_AND, 0},
2290     {"^=", ASSIGN_MODIFY, BINOP_BITWISE_XOR, 0},
2291     {"++", INCREMENT, BINOP_END, 0},
2292     {"--", DECREMENT, BINOP_END, 0},
2293     {"->", ARROW, BINOP_END, 0},
2294     {"&&", ANDAND, BINOP_END, 0},
2295     {"||", OROR, BINOP_END, 0},
2296     /* "::" is *not* only C++: gdb overrides its meaning in several
2297        different ways, e.g., 'filename'::func, function::variable.  */
2298     {"::", COLONCOLON, BINOP_END, 0},
2299     {"<<", LSH, BINOP_END, 0},
2300     {">>", RSH, BINOP_END, 0},
2301     {"==", EQUAL, BINOP_END, 0},
2302     {"!=", NOTEQUAL, BINOP_END, 0},
2303     {"<=", LEQ, BINOP_END, 0},
2304     {">=", GEQ, BINOP_END, 0},
2305     {".*", DOT_STAR, BINOP_END, FLAG_CXX}
2306   };
2307
2308 /* Identifier-like tokens.  */
2309 static const struct token ident_tokens[] =
2310   {
2311     {"unsigned", UNSIGNED, OP_NULL, 0},
2312     {"template", TEMPLATE, OP_NULL, FLAG_CXX},
2313     {"volatile", VOLATILE_KEYWORD, OP_NULL, 0},
2314     {"struct", STRUCT, OP_NULL, 0},
2315     {"signed", SIGNED_KEYWORD, OP_NULL, 0},
2316     {"sizeof", SIZEOF, OP_NULL, 0},
2317     {"double", DOUBLE_KEYWORD, OP_NULL, 0},
2318     {"false", FALSEKEYWORD, OP_NULL, FLAG_CXX},
2319     {"class", CLASS, OP_NULL, FLAG_CXX},
2320     {"union", UNION, OP_NULL, 0},
2321     {"short", SHORT, OP_NULL, 0},
2322     {"const", CONST_KEYWORD, OP_NULL, 0},
2323     {"enum", ENUM, OP_NULL, 0},
2324     {"long", LONG, OP_NULL, 0},
2325     {"true", TRUEKEYWORD, OP_NULL, FLAG_CXX},
2326     {"int", INT_KEYWORD, OP_NULL, 0},
2327     {"new", NEW, OP_NULL, FLAG_CXX},
2328     {"delete", DELETE, OP_NULL, FLAG_CXX},
2329     {"operator", OPERATOR, OP_NULL, FLAG_CXX},
2330
2331     {"and", ANDAND, BINOP_END, FLAG_CXX},
2332     {"and_eq", ASSIGN_MODIFY, BINOP_BITWISE_AND, FLAG_CXX},
2333     {"bitand", '&', OP_NULL, FLAG_CXX},
2334     {"bitor", '|', OP_NULL, FLAG_CXX},
2335     {"compl", '~', OP_NULL, FLAG_CXX},
2336     {"not", '!', OP_NULL, FLAG_CXX},
2337     {"not_eq", NOTEQUAL, BINOP_END, FLAG_CXX},
2338     {"or", OROR, BINOP_END, FLAG_CXX},
2339     {"or_eq", ASSIGN_MODIFY, BINOP_BITWISE_IOR, FLAG_CXX},
2340     {"xor", '^', OP_NULL, FLAG_CXX},
2341     {"xor_eq", ASSIGN_MODIFY, BINOP_BITWISE_XOR, FLAG_CXX},
2342
2343     {"const_cast", CONST_CAST, OP_NULL, FLAG_CXX },
2344     {"dynamic_cast", DYNAMIC_CAST, OP_NULL, FLAG_CXX },
2345     {"static_cast", STATIC_CAST, OP_NULL, FLAG_CXX },
2346     {"reinterpret_cast", REINTERPRET_CAST, OP_NULL, FLAG_CXX },
2347
2348     {"__typeof__", TYPEOF, OP_TYPEOF, 0 },
2349     {"__typeof", TYPEOF, OP_TYPEOF, 0 },
2350     {"typeof", TYPEOF, OP_TYPEOF, FLAG_SHADOW },
2351     {"__decltype", DECLTYPE, OP_DECLTYPE, FLAG_CXX },
2352     {"decltype", DECLTYPE, OP_DECLTYPE, FLAG_CXX | FLAG_SHADOW },
2353
2354     {"typeid", TYPEID, OP_TYPEID, FLAG_CXX}
2355   };
2356
2357 /* When we find that lexptr (the global var defined in parse.c) is
2358    pointing at a macro invocation, we expand the invocation, and call
2359    scan_macro_expansion to save the old lexptr here and point lexptr
2360    into the expanded text.  When we reach the end of that, we call
2361    end_macro_expansion to pop back to the value we saved here.  The
2362    macro expansion code promises to return only fully-expanded text,
2363    so we don't need to "push" more than one level.
2364
2365    This is disgusting, of course.  It would be cleaner to do all macro
2366    expansion beforehand, and then hand that to lexptr.  But we don't
2367    really know where the expression ends.  Remember, in a command like
2368
2369      (gdb) break *ADDRESS if CONDITION
2370
2371    we evaluate ADDRESS in the scope of the current frame, but we
2372    evaluate CONDITION in the scope of the breakpoint's location.  So
2373    it's simply wrong to try to macro-expand the whole thing at once.  */
2374 static const char *macro_original_text;
2375
2376 /* We save all intermediate macro expansions on this obstack for the
2377    duration of a single parse.  The expansion text may sometimes have
2378    to live past the end of the expansion, due to yacc lookahead.
2379    Rather than try to be clever about saving the data for a single
2380    token, we simply keep it all and delete it after parsing has
2381    completed.  */
2382 static struct obstack expansion_obstack;
2383
2384 static void
2385 scan_macro_expansion (char *expansion)
2386 {
2387   char *copy;
2388
2389   /* We'd better not be trying to push the stack twice.  */
2390   gdb_assert (! macro_original_text);
2391
2392   /* Copy to the obstack, and then free the intermediate
2393      expansion.  */
2394   copy = obstack_copy0 (&expansion_obstack, expansion, strlen (expansion));
2395   xfree (expansion);
2396
2397   /* Save the old lexptr value, so we can return to it when we're done
2398      parsing the expanded text.  */
2399   macro_original_text = lexptr;
2400   lexptr = copy;
2401 }
2402
2403
2404 static int
2405 scanning_macro_expansion (void)
2406 {
2407   return macro_original_text != 0;
2408 }
2409
2410
2411 static void
2412 finished_macro_expansion (void)
2413 {
2414   /* There'd better be something to pop back to.  */
2415   gdb_assert (macro_original_text);
2416
2417   /* Pop back to the original text.  */
2418   lexptr = macro_original_text;
2419   macro_original_text = 0;
2420 }
2421
2422
2423 static void
2424 scan_macro_cleanup (void *dummy)
2425 {
2426   if (macro_original_text)
2427     finished_macro_expansion ();
2428
2429   obstack_free (&expansion_obstack, NULL);
2430 }
2431
2432 /* Return true iff the token represents a C++ cast operator.  */
2433
2434 static int
2435 is_cast_operator (const char *token, int len)
2436 {
2437   return (! strncmp (token, "dynamic_cast", len)
2438           || ! strncmp (token, "static_cast", len)
2439           || ! strncmp (token, "reinterpret_cast", len)
2440           || ! strncmp (token, "const_cast", len));
2441 }
2442
2443 /* The scope used for macro expansion.  */
2444 static struct macro_scope *expression_macro_scope;
2445
2446 /* This is set if a NAME token appeared at the very end of the input
2447    string, with no whitespace separating the name from the EOF.  This
2448    is used only when parsing to do field name completion.  */
2449 static int saw_name_at_eof;
2450
2451 /* This is set if the previously-returned token was a structure
2452    operator -- either '.' or ARROW.  This is used only when parsing to
2453    do field name completion.  */
2454 static int last_was_structop;
2455
2456 /* Read one token, getting characters through lexptr.  */
2457
2458 static int
2459 lex_one_token (struct parser_state *par_state, int *is_quoted_name)
2460 {
2461   int c;
2462   int namelen;
2463   unsigned int i;
2464   const char *tokstart;
2465   int saw_structop = last_was_structop;
2466   char *copy;
2467
2468   last_was_structop = 0;
2469   *is_quoted_name = 0;
2470
2471  retry:
2472
2473   /* Check if this is a macro invocation that we need to expand.  */
2474   if (! scanning_macro_expansion ())
2475     {
2476       char *expanded = macro_expand_next (&lexptr,
2477                                           standard_macro_lookup,
2478                                           expression_macro_scope);
2479
2480       if (expanded)
2481         scan_macro_expansion (expanded);
2482     }
2483
2484   prev_lexptr = lexptr;
2485
2486   tokstart = lexptr;
2487   /* See if it is a special token of length 3.  */
2488   for (i = 0; i < sizeof tokentab3 / sizeof tokentab3[0]; i++)
2489     if (strncmp (tokstart, tokentab3[i].operator, 3) == 0)
2490       {
2491         if ((tokentab3[i].flags & FLAG_CXX) != 0
2492             && parse_language (par_state)->la_language != language_cplus)
2493           break;
2494
2495         lexptr += 3;
2496         yylval.opcode = tokentab3[i].opcode;
2497         return tokentab3[i].token;
2498       }
2499
2500   /* See if it is a special token of length 2.  */
2501   for (i = 0; i < sizeof tokentab2 / sizeof tokentab2[0]; i++)
2502     if (strncmp (tokstart, tokentab2[i].operator, 2) == 0)
2503       {
2504         if ((tokentab2[i].flags & FLAG_CXX) != 0
2505             && parse_language (par_state)->la_language != language_cplus)
2506           break;
2507
2508         lexptr += 2;
2509         yylval.opcode = tokentab2[i].opcode;
2510         if (parse_completion && tokentab2[i].token == ARROW)
2511           last_was_structop = 1;
2512         return tokentab2[i].token;
2513       }
2514
2515   switch (c = *tokstart)
2516     {
2517     case 0:
2518       /* If we were just scanning the result of a macro expansion,
2519          then we need to resume scanning the original text.
2520          If we're parsing for field name completion, and the previous
2521          token allows such completion, return a COMPLETE token.
2522          Otherwise, we were already scanning the original text, and
2523          we're really done.  */
2524       if (scanning_macro_expansion ())
2525         {
2526           finished_macro_expansion ();
2527           goto retry;
2528         }
2529       else if (saw_name_at_eof)
2530         {
2531           saw_name_at_eof = 0;
2532           return COMPLETE;
2533         }
2534       else if (saw_structop)
2535         return COMPLETE;
2536       else
2537         return 0;
2538
2539     case ' ':
2540     case '\t':
2541     case '\n':
2542       lexptr++;
2543       goto retry;
2544
2545     case '[':
2546     case '(':
2547       paren_depth++;
2548       lexptr++;
2549       if (parse_language (par_state)->la_language == language_objc
2550           && c == '[')
2551         return OBJC_LBRAC;
2552       return c;
2553
2554     case ']':
2555     case ')':
2556       if (paren_depth == 0)
2557         return 0;
2558       paren_depth--;
2559       lexptr++;
2560       return c;
2561
2562     case ',':
2563       if (comma_terminates
2564           && paren_depth == 0
2565           && ! scanning_macro_expansion ())
2566         return 0;
2567       lexptr++;
2568       return c;
2569
2570     case '.':
2571       /* Might be a floating point number.  */
2572       if (lexptr[1] < '0' || lexptr[1] > '9')
2573         {
2574           if (parse_completion)
2575             last_was_structop = 1;
2576           goto symbol;          /* Nope, must be a symbol. */
2577         }
2578       /* FALL THRU into number case.  */
2579
2580     case '0':
2581     case '1':
2582     case '2':
2583     case '3':
2584     case '4':
2585     case '5':
2586     case '6':
2587     case '7':
2588     case '8':
2589     case '9':
2590       {
2591         /* It's a number.  */
2592         int got_dot = 0, got_e = 0, toktype;
2593         const char *p = tokstart;
2594         int hex = input_radix > 10;
2595
2596         if (c == '0' && (p[1] == 'x' || p[1] == 'X'))
2597           {
2598             p += 2;
2599             hex = 1;
2600           }
2601         else if (c == '0' && (p[1]=='t' || p[1]=='T' || p[1]=='d' || p[1]=='D'))
2602           {
2603             p += 2;
2604             hex = 0;
2605           }
2606
2607         for (;; ++p)
2608           {
2609             /* This test includes !hex because 'e' is a valid hex digit
2610                and thus does not indicate a floating point number when
2611                the radix is hex.  */
2612             if (!hex && !got_e && (*p == 'e' || *p == 'E'))
2613               got_dot = got_e = 1;
2614             /* This test does not include !hex, because a '.' always indicates
2615                a decimal floating point number regardless of the radix.  */
2616             else if (!got_dot && *p == '.')
2617               got_dot = 1;
2618             else if (got_e && (p[-1] == 'e' || p[-1] == 'E')
2619                      && (*p == '-' || *p == '+'))
2620               /* This is the sign of the exponent, not the end of the
2621                  number.  */
2622               continue;
2623             /* We will take any letters or digits.  parse_number will
2624                complain if past the radix, or if L or U are not final.  */
2625             else if ((*p < '0' || *p > '9')
2626                      && ((*p < 'a' || *p > 'z')
2627                                   && (*p < 'A' || *p > 'Z')))
2628               break;
2629           }
2630         toktype = parse_number (par_state, tokstart, p - tokstart,
2631                                 got_dot|got_e, &yylval);
2632         if (toktype == ERROR)
2633           {
2634             char *err_copy = (char *) alloca (p - tokstart + 1);
2635
2636             memcpy (err_copy, tokstart, p - tokstart);
2637             err_copy[p - tokstart] = 0;
2638             error (_("Invalid number \"%s\"."), err_copy);
2639           }
2640         lexptr = p;
2641         return toktype;
2642       }
2643
2644     case '@':
2645       {
2646         const char *p = &tokstart[1];
2647         size_t len = strlen ("entry");
2648
2649         if (parse_language (par_state)->la_language == language_objc)
2650           {
2651             size_t len = strlen ("selector");
2652
2653             if (strncmp (p, "selector", len) == 0
2654                 && (p[len] == '\0' || isspace (p[len])))
2655               {
2656                 lexptr = p + len;
2657                 return SELECTOR;
2658               }
2659             else if (*p == '"')
2660               goto parse_string;
2661           }
2662
2663         while (isspace (*p))
2664           p++;
2665         if (strncmp (p, "entry", len) == 0 && !isalnum (p[len])
2666             && p[len] != '_')
2667           {
2668             lexptr = &p[len];
2669             return ENTRY;
2670           }
2671       }
2672       /* FALLTHRU */
2673     case '+':
2674     case '-':
2675     case '*':
2676     case '/':
2677     case '%':
2678     case '|':
2679     case '&':
2680     case '^':
2681     case '~':
2682     case '!':
2683     case '<':
2684     case '>':
2685     case '?':
2686     case ':':
2687     case '=':
2688     case '{':
2689     case '}':
2690     symbol:
2691       lexptr++;
2692       return c;
2693
2694     case 'L':
2695     case 'u':
2696     case 'U':
2697       if (tokstart[1] != '"' && tokstart[1] != '\'')
2698         break;
2699       /* Fall through.  */
2700     case '\'':
2701     case '"':
2702
2703     parse_string:
2704       {
2705         int host_len;
2706         int result = parse_string_or_char (tokstart, &lexptr, &yylval.tsval,
2707                                            &host_len);
2708         if (result == CHAR)
2709           {
2710             if (host_len == 0)
2711               error (_("Empty character constant."));
2712             else if (host_len > 2 && c == '\'')
2713               {
2714                 ++tokstart;
2715                 namelen = lexptr - tokstart - 1;
2716                 *is_quoted_name = 1;
2717
2718                 goto tryname;
2719               }
2720             else if (host_len > 1)
2721               error (_("Invalid character constant."));
2722           }
2723         return result;
2724       }
2725     }
2726
2727   if (!(c == '_' || c == '$'
2728         || (c >= 'a' && c <= 'z') || (c >= 'A' && c <= 'Z')))
2729     /* We must have come across a bad character (e.g. ';').  */
2730     error (_("Invalid character '%c' in expression."), c);
2731
2732   /* It's a name.  See how long it is.  */
2733   namelen = 0;
2734   for (c = tokstart[namelen];
2735        (c == '_' || c == '$' || (c >= '0' && c <= '9')
2736         || (c >= 'a' && c <= 'z') || (c >= 'A' && c <= 'Z') || c == '<');)
2737     {
2738       /* Template parameter lists are part of the name.
2739          FIXME: This mishandles `print $a<4&&$a>3'.  */
2740
2741       if (c == '<')
2742         {
2743           if (! is_cast_operator (tokstart, namelen))
2744             {
2745               /* Scan ahead to get rest of the template specification.  Note
2746                  that we look ahead only when the '<' adjoins non-whitespace
2747                  characters; for comparison expressions, e.g. "a < b > c",
2748                  there must be spaces before the '<', etc. */
2749
2750               const char *p = find_template_name_end (tokstart + namelen);
2751
2752               if (p)
2753                 namelen = p - tokstart;
2754             }
2755           break;
2756         }
2757       c = tokstart[++namelen];
2758     }
2759
2760   /* The token "if" terminates the expression and is NOT removed from
2761      the input stream.  It doesn't count if it appears in the
2762      expansion of a macro.  */
2763   if (namelen == 2
2764       && tokstart[0] == 'i'
2765       && tokstart[1] == 'f'
2766       && ! scanning_macro_expansion ())
2767     {
2768       return 0;
2769     }
2770
2771   /* For the same reason (breakpoint conditions), "thread N"
2772      terminates the expression.  "thread" could be an identifier, but
2773      an identifier is never followed by a number without intervening
2774      punctuation.  "task" is similar.  Handle abbreviations of these,
2775      similarly to breakpoint.c:find_condition_and_thread.  */
2776   if (namelen >= 1
2777       && (strncmp (tokstart, "thread", namelen) == 0
2778           || strncmp (tokstart, "task", namelen) == 0)
2779       && (tokstart[namelen] == ' ' || tokstart[namelen] == '\t')
2780       && ! scanning_macro_expansion ())
2781     {
2782       const char *p = tokstart + namelen + 1;
2783
2784       while (*p == ' ' || *p == '\t')
2785         p++;
2786       if (*p >= '0' && *p <= '9')
2787         return 0;
2788     }
2789
2790   lexptr += namelen;
2791
2792   tryname:
2793
2794   yylval.sval.ptr = tokstart;
2795   yylval.sval.length = namelen;
2796
2797   /* Catch specific keywords.  */
2798   copy = copy_name (yylval.sval);
2799   for (i = 0; i < sizeof ident_tokens / sizeof ident_tokens[0]; i++)
2800     if (strcmp (copy, ident_tokens[i].operator) == 0)
2801       {
2802         if ((ident_tokens[i].flags & FLAG_CXX) != 0
2803             && parse_language (par_state)->la_language != language_cplus)
2804           break;
2805
2806         if ((ident_tokens[i].flags & FLAG_SHADOW) != 0)
2807           {
2808             struct field_of_this_result is_a_field_of_this;
2809
2810             if (lookup_symbol (copy, expression_context_block,
2811                                VAR_DOMAIN,
2812                                (parse_language (par_state)->la_language
2813                                 == language_cplus ? &is_a_field_of_this
2814                                 : NULL))
2815                 != NULL)
2816               {
2817                 /* The keyword is shadowed.  */
2818                 break;
2819               }
2820           }
2821
2822         /* It is ok to always set this, even though we don't always
2823            strictly need to.  */
2824         yylval.opcode = ident_tokens[i].opcode;
2825         return ident_tokens[i].token;
2826       }
2827
2828   if (*tokstart == '$')
2829     return VARIABLE;
2830
2831   if (parse_completion && *lexptr == '\0')
2832     saw_name_at_eof = 1;
2833
2834   yylval.ssym.stoken = yylval.sval;
2835   yylval.ssym.sym = NULL;
2836   yylval.ssym.is_a_field_of_this = 0;
2837   return NAME;
2838 }
2839
2840 /* An object of this type is pushed on a FIFO by the "outer" lexer.  */
2841 typedef struct
2842 {
2843   int token;
2844   YYSTYPE value;
2845 } token_and_value;
2846
2847 DEF_VEC_O (token_and_value);
2848
2849 /* A FIFO of tokens that have been read but not yet returned to the
2850    parser.  */
2851 static VEC (token_and_value) *token_fifo;
2852
2853 /* Non-zero if the lexer should return tokens from the FIFO.  */
2854 static int popping;
2855
2856 /* Temporary storage for c_lex; this holds symbol names as they are
2857    built up.  */
2858 static struct obstack name_obstack;
2859
2860 /* Classify a NAME token.  The contents of the token are in `yylval'.
2861    Updates yylval and returns the new token type.  BLOCK is the block
2862    in which lookups start; this can be NULL to mean the global scope.
2863    IS_QUOTED_NAME is non-zero if the name token was originally quoted
2864    in single quotes.  */
2865 static int
2866 classify_name (struct parser_state *par_state, const struct block *block,
2867                int is_quoted_name)
2868 {
2869   struct symbol *sym;
2870   char *copy;
2871   struct field_of_this_result is_a_field_of_this;
2872
2873   copy = copy_name (yylval.sval);
2874
2875   /* Initialize this in case we *don't* use it in this call; that way
2876      we can refer to it unconditionally below.  */
2877   memset (&is_a_field_of_this, 0, sizeof (is_a_field_of_this));
2878
2879   sym = lookup_symbol (copy, block, VAR_DOMAIN,
2880                        parse_language (par_state)->la_name_of_this
2881                        ? &is_a_field_of_this : NULL);
2882
2883   if (sym && SYMBOL_CLASS (sym) == LOC_BLOCK)
2884     {
2885       yylval.ssym.sym = sym;
2886       yylval.ssym.is_a_field_of_this = is_a_field_of_this.type != NULL;
2887       return BLOCKNAME;
2888     }
2889   else if (!sym)
2890     {
2891       /* If we found a field of 'this', we might have erroneously
2892          found a constructor where we wanted a type name.  Handle this
2893          case by noticing that we found a constructor and then look up
2894          the type tag instead.  */
2895       if (is_a_field_of_this.type != NULL
2896           && is_a_field_of_this.fn_field != NULL
2897           && TYPE_FN_FIELD_CONSTRUCTOR (is_a_field_of_this.fn_field->fn_fields,
2898                                         0))
2899         {
2900           struct field_of_this_result inner_is_a_field_of_this;
2901
2902           sym = lookup_symbol (copy, block, STRUCT_DOMAIN,
2903                                &inner_is_a_field_of_this);
2904           if (sym != NULL)
2905             {
2906               yylval.tsym.type = SYMBOL_TYPE (sym);
2907               return TYPENAME;
2908             }
2909         }
2910
2911       /* If we found a field, then we want to prefer it over a
2912          filename.  However, if the name was quoted, then it is better
2913          to check for a filename or a block, since this is the only
2914          way the user has of requiring the extension to be used.  */
2915       if (is_a_field_of_this.type == NULL || is_quoted_name)
2916         {
2917           /* See if it's a file name. */
2918           struct symtab *symtab;
2919
2920           symtab = lookup_symtab (copy);
2921           if (symtab)
2922             {
2923               yylval.bval = BLOCKVECTOR_BLOCK (BLOCKVECTOR (symtab),
2924                                                STATIC_BLOCK);
2925               return FILENAME;
2926             }
2927         }
2928     }
2929
2930   if (sym && SYMBOL_CLASS (sym) == LOC_TYPEDEF)
2931     {
2932       yylval.tsym.type = SYMBOL_TYPE (sym);
2933       return TYPENAME;
2934     }
2935
2936   yylval.tsym.type
2937     = language_lookup_primitive_type_by_name (parse_language (par_state),
2938                                               parse_gdbarch (par_state),
2939                                               copy);
2940   if (yylval.tsym.type != NULL)
2941     return TYPENAME;
2942
2943   /* See if it's an ObjC classname.  */
2944   if (parse_language (par_state)->la_language == language_objc && !sym)
2945     {
2946       CORE_ADDR Class = lookup_objc_class (parse_gdbarch (par_state), copy);
2947       if (Class)
2948         {
2949           yylval.class.class = Class;
2950           sym = lookup_struct_typedef (copy, expression_context_block, 1);
2951           if (sym)
2952             yylval.class.type = SYMBOL_TYPE (sym);
2953           return CLASSNAME;
2954         }
2955     }
2956
2957   /* Input names that aren't symbols but ARE valid hex numbers, when
2958      the input radix permits them, can be names or numbers depending
2959      on the parse.  Note we support radixes > 16 here.  */
2960   if (!sym
2961       && ((copy[0] >= 'a' && copy[0] < 'a' + input_radix - 10)
2962           || (copy[0] >= 'A' && copy[0] < 'A' + input_radix - 10)))
2963     {
2964       YYSTYPE newlval;  /* Its value is ignored.  */
2965       int hextype = parse_number (par_state, copy, yylval.sval.length,
2966                                   0, &newlval);
2967       if (hextype == INT)
2968         {
2969           yylval.ssym.sym = sym;
2970           yylval.ssym.is_a_field_of_this = is_a_field_of_this.type != NULL;
2971           return NAME_OR_INT;
2972         }
2973     }
2974
2975   /* Any other kind of symbol */
2976   yylval.ssym.sym = sym;
2977   yylval.ssym.is_a_field_of_this = is_a_field_of_this.type != NULL;
2978
2979   if (sym == NULL
2980       && parse_language (par_state)->la_language == language_cplus
2981       && is_a_field_of_this.type == NULL
2982       && lookup_minimal_symbol (copy, NULL, NULL).minsym == NULL)
2983     return UNKNOWN_CPP_NAME;
2984
2985   return NAME;
2986 }
2987
2988 /* Like classify_name, but used by the inner loop of the lexer, when a
2989    name might have already been seen.  CONTEXT is the context type, or
2990    NULL if this is the first component of a name.  */
2991
2992 static int
2993 classify_inner_name (struct parser_state *par_state,
2994                      const struct block *block, struct type *context)
2995 {
2996   struct type *type;
2997   char *copy;
2998
2999   if (context == NULL)
3000     return classify_name (par_state, block, 0);
3001
3002   type = check_typedef (context);
3003   if (TYPE_CODE (type) != TYPE_CODE_STRUCT
3004       && TYPE_CODE (type) != TYPE_CODE_UNION
3005       && TYPE_CODE (type) != TYPE_CODE_NAMESPACE)
3006     return ERROR;
3007
3008   copy = copy_name (yylval.ssym.stoken);
3009   yylval.ssym.sym = cp_lookup_nested_symbol (type, copy, block);
3010
3011   /* If no symbol was found, search for a matching base class named
3012      COPY.  This will allow users to enter qualified names of class members
3013      relative to the `this' pointer.  */
3014   if (yylval.ssym.sym == NULL)
3015     {
3016       struct type *base_type = find_type_baseclass_by_name (type, copy);
3017
3018       if (base_type != NULL)
3019         {
3020           yylval.tsym.type = base_type;
3021           return TYPENAME;
3022         }
3023
3024       return ERROR;
3025     }
3026
3027   switch (SYMBOL_CLASS (yylval.ssym.sym))
3028     {
3029     case LOC_BLOCK:
3030     case LOC_LABEL:
3031       /* cp_lookup_nested_symbol might have accidentally found a constructor
3032          named COPY when we really wanted a base class of the same name.
3033          Double-check this case by looking for a base class.  */
3034       {
3035         struct type *base_type = find_type_baseclass_by_name (type, copy);
3036
3037         if (base_type != NULL)
3038           {
3039             yylval.tsym.type = base_type;
3040             return TYPENAME;
3041           }
3042       }
3043       return ERROR;
3044
3045     case LOC_TYPEDEF:
3046       yylval.tsym.type = SYMBOL_TYPE (yylval.ssym.sym);;
3047       return TYPENAME;
3048
3049     default:
3050       return NAME;
3051     }
3052   internal_error (__FILE__, __LINE__, _("not reached"));
3053 }
3054
3055 /* The outer level of a two-level lexer.  This calls the inner lexer
3056    to return tokens.  It then either returns these tokens, or
3057    aggregates them into a larger token.  This lets us work around a
3058    problem in our parsing approach, where the parser could not
3059    distinguish between qualified names and qualified types at the
3060    right point.
3061
3062    This approach is still not ideal, because it mishandles template
3063    types.  See the comment in lex_one_token for an example.  However,
3064    this is still an improvement over the earlier approach, and will
3065    suffice until we move to better parsing technology.  */
3066 static int
3067 yylex (void)
3068 {
3069   token_and_value current;
3070   int first_was_coloncolon, last_was_coloncolon;
3071   struct type *context_type = NULL;
3072   int last_to_examine, next_to_examine, checkpoint;
3073   const struct block *search_block;
3074   int is_quoted_name;
3075
3076   if (popping && !VEC_empty (token_and_value, token_fifo))
3077     goto do_pop;
3078   popping = 0;
3079
3080   /* Read the first token and decide what to do.  Most of the
3081      subsequent code is C++-only; but also depends on seeing a "::" or
3082      name-like token.  */
3083   current.token = lex_one_token (pstate, &is_quoted_name);
3084   if (current.token == NAME)
3085     current.token = classify_name (pstate, expression_context_block,
3086                                    is_quoted_name);
3087   if (parse_language (pstate)->la_language != language_cplus
3088       || (current.token != TYPENAME && current.token != COLONCOLON
3089           && current.token != FILENAME))
3090     return current.token;
3091
3092   /* Read any sequence of alternating "::" and name-like tokens into
3093      the token FIFO.  */
3094   current.value = yylval;
3095   VEC_safe_push (token_and_value, token_fifo, &current);
3096   last_was_coloncolon = current.token == COLONCOLON;
3097   while (1)
3098     {
3099       int ignore;
3100
3101       /* We ignore quoted names other than the very first one.
3102          Subsequent ones do not have any special meaning.  */
3103       current.token = lex_one_token (pstate, &ignore);
3104       current.value = yylval;
3105       VEC_safe_push (token_and_value, token_fifo, &current);
3106
3107       if ((last_was_coloncolon && current.token != NAME)
3108           || (!last_was_coloncolon && current.token != COLONCOLON))
3109         break;
3110       last_was_coloncolon = !last_was_coloncolon;
3111     }
3112   popping = 1;
3113
3114   /* We always read one extra token, so compute the number of tokens
3115      to examine accordingly.  */
3116   last_to_examine = VEC_length (token_and_value, token_fifo) - 2;
3117   next_to_examine = 0;
3118
3119   current = *VEC_index (token_and_value, token_fifo, next_to_examine);
3120   ++next_to_examine;
3121
3122   obstack_free (&name_obstack, obstack_base (&name_obstack));
3123   checkpoint = 0;
3124   if (current.token == FILENAME)
3125     search_block = current.value.bval;
3126   else if (current.token == COLONCOLON)
3127     search_block = NULL;
3128   else
3129     {
3130       gdb_assert (current.token == TYPENAME);
3131       search_block = expression_context_block;
3132       obstack_grow (&name_obstack, current.value.sval.ptr,
3133                     current.value.sval.length);
3134       context_type = current.value.tsym.type;
3135       checkpoint = 1;
3136     }
3137
3138   first_was_coloncolon = current.token == COLONCOLON;
3139   last_was_coloncolon = first_was_coloncolon;
3140
3141   while (next_to_examine <= last_to_examine)
3142     {
3143       token_and_value *next;
3144
3145       next = VEC_index (token_and_value, token_fifo, next_to_examine);
3146       ++next_to_examine;
3147
3148       if (next->token == NAME && last_was_coloncolon)
3149         {
3150           int classification;
3151
3152           yylval = next->value;
3153           classification = classify_inner_name (pstate, search_block,
3154                                                 context_type);
3155           /* We keep going until we either run out of names, or until
3156              we have a qualified name which is not a type.  */
3157           if (classification != TYPENAME && classification != NAME)
3158             break;
3159
3160           /* Accept up to this token.  */
3161           checkpoint = next_to_examine;
3162
3163           /* Update the partial name we are constructing.  */
3164           if (context_type != NULL)
3165             {
3166               /* We don't want to put a leading "::" into the name.  */
3167               obstack_grow_str (&name_obstack, "::");
3168             }
3169           obstack_grow (&name_obstack, next->value.sval.ptr,
3170                         next->value.sval.length);
3171
3172           yylval.sval.ptr = obstack_base (&name_obstack);
3173           yylval.sval.length = obstack_object_size (&name_obstack);
3174           current.value = yylval;
3175           current.token = classification;
3176
3177           last_was_coloncolon = 0;
3178
3179           if (classification == NAME)
3180             break;
3181
3182           context_type = yylval.tsym.type;
3183         }
3184       else if (next->token == COLONCOLON && !last_was_coloncolon)
3185         last_was_coloncolon = 1;
3186       else
3187         {
3188           /* We've reached the end of the name.  */
3189           break;
3190         }
3191     }
3192
3193   /* If we have a replacement token, install it as the first token in
3194      the FIFO, and delete the other constituent tokens.  */
3195   if (checkpoint > 0)
3196     {
3197       current.value.sval.ptr = obstack_copy0 (&expansion_obstack,
3198                                               current.value.sval.ptr,
3199                                               current.value.sval.length);
3200
3201       VEC_replace (token_and_value, token_fifo, 0, &current);
3202       if (checkpoint > 1)
3203         VEC_block_remove (token_and_value, token_fifo, 1, checkpoint - 1);
3204     }
3205
3206  do_pop:
3207   current = *VEC_index (token_and_value, token_fifo, 0);
3208   VEC_ordered_remove (token_and_value, token_fifo, 0);
3209   yylval = current.value;
3210   return current.token;
3211 }
3212
3213 int
3214 c_parse (struct parser_state *par_state)
3215 {
3216   int result;
3217   struct cleanup *back_to;
3218
3219   /* Setting up the parser state.  */
3220   gdb_assert (par_state != NULL);
3221   pstate = par_state;
3222
3223   back_to = make_cleanup (free_current_contents, &expression_macro_scope);
3224   make_cleanup_clear_parser_state (&pstate);
3225
3226   /* Set up the scope for macro expansion.  */
3227   expression_macro_scope = NULL;
3228
3229   if (expression_context_block)
3230     expression_macro_scope
3231       = sal_macro_scope (find_pc_line (expression_context_pc, 0));
3232   else
3233     expression_macro_scope = default_macro_scope ();
3234   if (! expression_macro_scope)
3235     expression_macro_scope = user_macro_scope ();
3236
3237   /* Initialize macro expansion code.  */
3238   obstack_init (&expansion_obstack);
3239   gdb_assert (! macro_original_text);
3240   make_cleanup (scan_macro_cleanup, 0);
3241
3242   make_cleanup_restore_integer (&yydebug);
3243   yydebug = parser_debug;
3244
3245   /* Initialize some state used by the lexer.  */
3246   last_was_structop = 0;
3247   saw_name_at_eof = 0;
3248
3249   VEC_free (token_and_value, token_fifo);
3250   popping = 0;
3251   obstack_init (&name_obstack);
3252   make_cleanup_obstack_free (&name_obstack);
3253
3254   result = yyparse ();
3255   do_cleanups (back_to);
3256
3257   return result;
3258 }
3259
3260 #ifdef YYBISON
3261
3262 /* This is called via the YYPRINT macro when parser debugging is
3263    enabled.  It prints a token's value.  */
3264
3265 static void
3266 c_print_token (FILE *file, int type, YYSTYPE value)
3267 {
3268   switch (type)
3269     {
3270     case INT:
3271       fprintf (file, "typed_val_int<%s, %s>",
3272                TYPE_SAFE_NAME (value.typed_val_int.type),
3273                pulongest (value.typed_val_int.val));
3274       break;
3275
3276     case CHAR:
3277     case STRING:
3278       {
3279         char *copy = alloca (value.tsval.length + 1);
3280
3281         memcpy (copy, value.tsval.ptr, value.tsval.length);
3282         copy[value.tsval.length] = '\0';
3283
3284         fprintf (file, "tsval<type=%d, %s>", value.tsval.type, copy);
3285       }
3286       break;
3287
3288     case NSSTRING:
3289     case VARIABLE:
3290       fprintf (file, "sval<%s>", copy_name (value.sval));
3291       break;
3292
3293     case TYPENAME:
3294       fprintf (file, "tsym<type=%s, name=%s>",
3295                TYPE_SAFE_NAME (value.tsym.type),
3296                copy_name (value.tsym.stoken));
3297       break;
3298
3299     case NAME:
3300     case UNKNOWN_CPP_NAME:
3301     case NAME_OR_INT:
3302     case BLOCKNAME:
3303       fprintf (file, "ssym<name=%s, sym=%s, field_of_this=%d>",
3304                copy_name (value.ssym.stoken),
3305                (value.ssym.sym == NULL
3306                 ? "(null)" : SYMBOL_PRINT_NAME (value.ssym.sym)),
3307                value.ssym.is_a_field_of_this);
3308       break;
3309
3310     case FILENAME:
3311       fprintf (file, "bval<%s>", host_address_to_string (value.bval));
3312       break;
3313     }
3314 }
3315
3316 #endif
3317
3318 void
3319 yyerror (char *msg)
3320 {
3321   if (prev_lexptr)
3322     lexptr = prev_lexptr;
3323
3324   error (_("A %s in expression, near `%s'."), (msg ? msg : "error"), lexptr);
3325 }