gdb/acinclude.m4

   1 dnl written by Rob Savoye <rob@cygnus.com> for Cygnus Support
   2 dnl major rewriting for Tcl 7.5 by Don Libes <libes@nist.gov>
   3
   4 dnl gdb/configure.in uses BFD_NEED_DECLARATION, so get its definition.
   5 sinclude(../bfd/bfd.m4)
   6
   7 dnl This gets the standard macros
   8 sinclude(../config/acinclude.m4)
   9
  10 dnl This gets autoconf bugfixes
  11 sinclude(../config/override.m4)
  12
  13 sinclude(../config/gettext-sister.m4)
  14
  15 dnl For AC_LIB_HAVE_LINKFLAGS.
  16 sinclude(../config/lib-ld.m4)
  17 sinclude(../config/lib-prefix.m4)
  18 sinclude(../config/lib-link.m4)
  19
  20 dnl For ACX_PKGVERSION and ACX_BUGURL.
  21 sinclude(../config/acx.m4)
  22
  23 dnl for TCL definitions
  24 sinclude(../config/tcl.m4)
  25
  26 dnl For dependency tracking macros.
  27 sinclude([../config/depstand.m4])
  28
  29 dnl For AM_LC_MESSAGES
  30 sinclude([../config/lcmessage.m4])
  31
  32 #
  33 # Sometimes the native compiler is a bogus stub for gcc or /usr/ucb/cc. This
  34 # makes configure think it's cross compiling. If --target wasn't used, then
  35 # we can't configure, so something is wrong. We don't use the cache
  36 # here cause if somebody fixes their compiler install, we want this to work.
  37 AC_DEFUN([CY_AC_C_WORKS],
  38 [# If we cannot compile and link a trivial program, we can't expect anything to work
  39 AC_MSG_CHECKING(whether the compiler ($CC) actually works)
  40 AC_TRY_COMPILE(, [/* don't need anything here */],
  41         c_compiles=yes, c_compiles=no)
  42
  43 AC_TRY_LINK(, [/* don't need anything here */],
  44         c_links=yes, c_links=no)
  45
  46 if test x"${c_compiles}" = x"no" ; then
  47   AC_MSG_ERROR(the native compiler is broken and won't compile.)
  48 fi
  49
  50 if test x"${c_links}" = x"no" ; then
  51   AC_MSG_ERROR(the native compiler is broken and won't link.)
  52 fi
  53 AC_MSG_RESULT(yes)
  54 ])
  55
  56 ## ----------------------------------------- ##
  57 ## ANSIfy the C compiler whenever possible.  ##
  58 ## From Franc,ois Pinard                     ##
  59 ## ----------------------------------------- ##
  60
  61 # Copyright (C) 1996, 1997, 1999, 2000, 2001, 2008 Free Software Foundation, Inc.
  62
  63 # This program is free software; you can redistribute it and/or modify
  64 # it under the terms of the GNU General Public License as published by
  65 # the Free Software Foundation; either version 2, or (at your option)
  66 # any later version.
  67
  68 # This program is distributed in the hope that it will be useful,
  69 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  70 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  71 # GNU General Public License for more details.
  72
  73 # You should have received a copy of the GNU General Public License
  74 # along with this program; if not, write to the Free Software
  75 # Foundation, Inc., 51 Franklin Street, Fifth Floor,
  76 # Boston, MA 02110-1301, USA.
  77
  78 # serial 1
  79
  80 # @defmac AC_PROG_CC_STDC
  81 # @maindex PROG_CC_STDC
  82 # @ovindex CC
  83 # If the C compiler in not in ANSI C mode by default, try to add an option
  84 # to output variable @code{CC} to make it so.  This macro tries various
  85 # options that select ANSI C on some system or another.  It considers the
  86 # compiler to be in ANSI C mode if it handles function prototypes correctly.
  87 #
  88 # If you use this macro, you should check after calling it whether the C
  89 # compiler has been set to accept ANSI C; if not, the shell variable
  90 # @code{am_cv_prog_cc_stdc} is set to @samp{no}.  If you wrote your source
  91 # code in ANSI C, you can make an un-ANSIfied copy of it by using the
  92 # program @code{ansi2knr}, which comes with Ghostscript.
  93 # @end defmac
  94
  95 AC_DEFUN([AM_PROG_CC_STDC],
  96 [AC_REQUIRE([AC_PROG_CC])
  97 AC_BEFORE([$0], [AC_C_INLINE])
  98 AC_BEFORE([$0], [AC_C_CONST])
  99 dnl Force this before AC_PROG_CPP.  Some cpp's, eg on HPUX, require
 100 dnl a magic option to avoid problems with ANSI preprocessor commands
 101 dnl like #elif.
 102 dnl FIXME: can't do this because then AC_AIX won't work due to a
 103 dnl circular dependency.
 104 dnl AC_BEFORE([$0], [AC_PROG_CPP])
 105 AC_MSG_CHECKING([for ${CC-cc} option to accept ANSI C])
 106 AC_CACHE_VAL(am_cv_prog_cc_stdc,
 107 [am_cv_prog_cc_stdc=no
 108 ac_save_CC="$CC"
 109 # Don't try gcc -ansi; that turns off useful extensions and
 110 # breaks some systems' header files.
 111 # AIX                   -qlanglvl=ansi
 112 # Ultrix and OSF/1      -std1
 113 # HP-UX 10.20 and later -Ae
 114 # HP-UX older versions  -Aa -D_HPUX_SOURCE
 115 # SVR4                  -Xc -D__EXTENSIONS__
 116 for ac_arg in "" -qlanglvl=ansi -std1 -Ae "-Aa -D_HPUX_SOURCE" "-Xc -D__EXTENSIONS__"
 117 do
 118   CC="$ac_save_CC $ac_arg"
 119   AC_TRY_COMPILE(
 120 [#include <stdarg.h>
 121 #include <stdio.h>
 122 #include <sys/types.h>
 123 #include <sys/stat.h>
 124 /* Most of the following tests are stolen from RCS 5.7's src/conf.sh.  */
 125 struct buf { int x; };
 126 FILE * (*rcsopen) (struct buf *, struct stat *, int);
 127 static char *e (p, i)
 128      char **p;
 129      int i;
 130 {
 131   return p[i];
 132 }
 133 static char *f (char * (*g) (char **, int), char **p, ...)
 134 {
 135   char *s;
 136   va_list v;
 137   va_start (v,p);
 138   s = g (p, va_arg (v,int));
 139   va_end (v);
 140   return s;
 141 }
 142 int test (int i, double x);
 143 struct s1 {int (*f) (int a);};
 144 struct s2 {int (*f) (double a);};
 145 int pairnames (int, char **, FILE *(*)(struct buf *, struct stat *, int), int, int);
 146 int argc;
 147 char **argv;
 148 ], [
 149 return f (e, argv, 0) != argv[0]  ||  f (e, argv, 1) != argv[1];
 150 ],
 151 [am_cv_prog_cc_stdc="$ac_arg"; break])
 152 done
 153 CC="$ac_save_CC"
 154 ])
 155 if test -z "$am_cv_prog_cc_stdc"; then
 156   AC_MSG_RESULT([none needed])
 157 else
 158   AC_MSG_RESULT([$am_cv_prog_cc_stdc])
 159 fi
 160 case "x$am_cv_prog_cc_stdc" in
 161   x|xno) ;;
 162   *) CC="$CC $am_cv_prog_cc_stdc" ;;
 163 esac
 164 ])
 165
 166 dnl From Bruno Haible.
 167
 168 AC_DEFUN([AM_ICONV],
 169 [
 170   dnl Some systems have iconv in libc, some have it in libiconv (OSF/1 and
 171   dnl those with the standalone portable GNU libiconv installed).
 172
 173   AC_ARG_WITH([libiconv-prefix],
 174 [  --with-libiconv-prefix=DIR  search for libiconv in DIR/include and DIR/lib], [
 175     for dir in `echo "$withval" | tr : ' '`; do
 176       if test -d $dir/include; then CPPFLAGS="$CPPFLAGS -I$dir/include"; fi
 177       if test -d $dir/lib; then LDFLAGS="$LDFLAGS -L$dir/lib"; fi
 178     done
 179    ])
 180
 181   AC_CACHE_CHECK(for iconv, am_cv_func_iconv, [
 182     am_cv_func_iconv="no, consider installing GNU libiconv"
 183     am_cv_lib_iconv=no
 184     AC_TRY_LINK([#include <stdlib.h>
 185 #include <iconv.h>],
 186       [iconv_t cd = iconv_open("","");
 187        iconv(cd,NULL,NULL,NULL,NULL);
 188        iconv_close(cd);],
 189       am_cv_func_iconv=yes)
 190     if test "$am_cv_func_iconv" != yes; then
 191       am_save_LIBS="$LIBS"
 192       LIBS="$LIBS -liconv"
 193       AC_TRY_LINK([#include <stdlib.h>
 194 #include <iconv.h>],
 195         [iconv_t cd = iconv_open("","");
 196          iconv(cd,NULL,NULL,NULL,NULL);
 197          iconv_close(cd);],
 198         am_cv_lib_iconv=yes
 199         am_cv_func_iconv=yes)
 200       LIBS="$am_save_LIBS"
 201     fi
 202   ])
 203   if test "$am_cv_func_iconv" = yes; then
 204     AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 205     AC_MSG_CHECKING([for iconv declaration])
 206     AC_CACHE_VAL(am_cv_proto_iconv, [
 207       AC_TRY_COMPILE([
 208 #include <stdlib.h>
 209 #include <iconv.h>
 210 extern
 211 #ifdef __cplusplus
 212 "C"
 213 #endif
 214 #if defined(__STDC__) || defined(__cplusplus)
 215 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 216 #else
 217 size_t iconv();
 218 #endif
 219 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
 220       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 221     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 222     AC_MSG_RESULT([$]{ac_t:-
 223          }[$]am_cv_proto_iconv)
 224     AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 225       [Define as const if the declaration of iconv() needs const.])
 226   fi
 227   LIBICONV=
 228   if test "$am_cv_lib_iconv" = yes; then
 229     LIBICONV="-liconv"
 230   fi
 231   AC_SUBST(LIBICONV)
 232 ])
 233
 234 dnl written by Guido Draheim <guidod@gmx.de>, original by Alexandre Oliva
 235 dnl Version 1.3 (2001/03/02)
 236 dnl source http://www.gnu.org/software/ac-archive/Miscellaneous/ac_define_dir.html
 237
 238 AC_DEFUN([AC_DEFINE_DIR], [
 239   test "x$prefix" = xNONE && prefix="$ac_default_prefix"
 240   test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 241   ac_define_dir=`eval echo [$]$2`
 242   ac_define_dir=`eval echo [$]ac_define_dir`
 243   ifelse($3, ,
 244     AC_DEFINE_UNQUOTED($1, "$ac_define_dir"),
 245     AC_DEFINE_UNQUOTED($1, "$ac_define_dir", $3))
 246 ])
 247
 248 dnl See whether we need a declaration for a function.
 249 dnl The result is highly dependent on the INCLUDES passed in, so make sure
 250 dnl to use a different cache variable name in this macro if it is invoked
 251 dnl in a different context somewhere else.
 252 dnl gcc_AC_CHECK_DECL(SYMBOL,
 253 dnl     [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND [, INCLUDES]]])
 254 AC_DEFUN([gcc_AC_CHECK_DECL],
 255 [AC_MSG_CHECKING([whether $1 is declared])
 256 AC_CACHE_VAL(gcc_cv_have_decl_$1,
 257 [AC_TRY_COMPILE([$4],
 258 [#ifndef $1
 259 char *(*pfn) = (char *(*)) $1 ;
 260 #endif], eval "gcc_cv_have_decl_$1=yes", eval "gcc_cv_have_decl_$1=no")])
 261 if eval "test \"`echo '$gcc_cv_have_decl_'$1`\" = yes"; then
 262   AC_MSG_RESULT(yes) ; ifelse([$2], , :, [$2])
 263 else
 264   AC_MSG_RESULT(no) ; ifelse([$3], , :, [$3])
 265 fi
 266 ])dnl
 267
 268 dnl Check multiple functions to see whether each needs a declaration.
 269 dnl Arrange to define HAVE_DECL_<FUNCTION> to 0 or 1 as appropriate.
 270 dnl gcc_AC_CHECK_DECLS(SYMBOLS,
 271 dnl     [ACTION-IF-NEEDED [, ACTION-IF-NOT-NEEDED [, INCLUDES]]])
 272 AC_DEFUN([gcc_AC_CHECK_DECLS],
 273 [for ac_func in $1
 274 do
 275 changequote(, )dnl
 276   ac_tr_decl=HAVE_DECL_`echo $ac_func | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 277 changequote([, ])dnl
 278 gcc_AC_CHECK_DECL($ac_func,
 279   [AC_DEFINE_UNQUOTED($ac_tr_decl, 1) $2],
 280   [AC_DEFINE_UNQUOTED($ac_tr_decl, 0) $3],
 281 dnl It is possible that the include files passed in here are local headers
 282 dnl which supply a backup declaration for the relevant prototype based on
 283 dnl the definition of (or lack of) the HAVE_DECL_ macro.  If so, this test
 284 dnl will always return success.  E.g. see libiberty.h's handling of
 285 dnl `basename'.  To avoid this, we define the relevant HAVE_DECL_ macro to
 286 dnl 1 so that any local headers used do not provide their own prototype
 287 dnl during this test.
 288 #undef $ac_tr_decl
 289 #define $ac_tr_decl 1
 290   $4
 291 )
 292 done
 293 dnl Automatically generate config.h entries via autoheader.
 294 if test x = y ; then
 295   patsubst(translit([$1], [a-z], [A-Z]), [\w+],
 296     [AC_DEFINE([HAVE_DECL_\&], 1,
 297       [Define to 1 if we found this declaration otherwise define to 0.])])dnl
 298 fi
 299 ])
 300
 301 dnl Find the location of the private Tcl headers
 302 dnl When Tcl is installed, this is TCL_INCLUDE_SPEC/tcl-private/generic
 303 dnl When Tcl is in the build tree, this is not needed.
 304 dnl
 305 dnl Note: you must use first use SC_LOAD_TCLCONFIG!
 306 AC_DEFUN([CY_AC_TCL_PRIVATE_HEADERS], [
 307   AC_MSG_CHECKING([for Tcl private headers])
 308   private_dir=""
 309   dir=`echo ${TCL_INCLUDE_SPEC}/tcl-private/generic | sed -e s/-I//`
 310   if test -f ${dir}/tclInt.h ; then
 311     private_dir=${dir}
 312   fi
 313
 314   if test x"${private_dir}" = x; then
 315     AC_ERROR(could not find private Tcl headers)
 316   else
 317     TCL_PRIVATE_INCLUDE="-I${private_dir}"
 318     AC_MSG_RESULT(${private_dir})
 319   fi
 320 ])
 321
 322 dnl Find the location of the private Tk headers
 323 dnl When Tk is installed, this is TK_INCLUDE_SPEC/tk-private/generic
 324 dnl When Tk is in the build tree, this not needed.
 325 dnl
 326 dnl Note: you must first use SC_LOAD_TKCONFIG
 327 AC_DEFUN([CY_AC_TK_PRIVATE_HEADERS], [
 328   AC_MSG_CHECKING([for Tk private headers])
 329   private_dir=""
 330   dir=`echo ${TK_INCLUDE_SPEC}/tk-private/generic | sed -e s/-I//`
 331   if test -f ${dir}/tkInt.h; then
 332     private_dir=${dir}
 333   fi
 334
 335   if test x"${private_dir}" = x; then
 336     AC_ERROR(could not find Tk private headers)
 337   else
 338     TK_PRIVATE_INCLUDE="-I${private_dir}"
 339     AC_MSG_RESULT(${private_dir})
 340   fi
 341 ])