gdb/acinclude.m4

   1 dnl written by Rob Savoye <rob@cygnus.com> for Cygnus Support
   2 dnl major rewriting for Tcl 7.5 by Don Libes <libes@nist.gov>
   3
   4 dnl gdb/configure.in uses BFD_NEED_DECLARATION, so get its definition.
   5 sinclude(../bfd/bfd.m4)
   6
   7 dnl This gets the standard macros
   8 sinclude(../config/acinclude.m4)
   9
  10 dnl This gets autoconf bugfixes
  11 sinclude(../config/override.m4)
  12
  13 sinclude(../config/gettext-sister.m4)
  14
  15 dnl For AC_LIB_HAVE_LINKFLAGS.
  16 sinclude(../config/lib-ld.m4)
  17 sinclude(../config/lib-prefix.m4)
  18 sinclude(../config/lib-link.m4)
  19
  20 dnl For ACX_PKGVERSION and ACX_BUGURL.
  21 sinclude(../config/acx.m4)
  22
  23 dnl for TCL definitions
  24 sinclude(../config/tcl.m4)
  25
  26 dnl For dependency tracking macros.
  27 sinclude([../config/depstand.m4])
  28
  29 dnl For AM_LC_MESSAGES
  30 sinclude([../config/lcmessage.m4])
  31
  32 dnl For AM_LANGINFO_CODESET.
  33 sinclude([../config/codeset.m4])
  34
  35 #
  36 # Sometimes the native compiler is a bogus stub for gcc or /usr/ucb/cc. This
  37 # makes configure think it's cross compiling. If --target wasn't used, then
  38 # we can't configure, so something is wrong. We don't use the cache
  39 # here cause if somebody fixes their compiler install, we want this to work.
  40 AC_DEFUN([CY_AC_C_WORKS],
  41 [# If we cannot compile and link a trivial program, we can't expect anything to work
  42 AC_MSG_CHECKING(whether the compiler ($CC) actually works)
  43 AC_TRY_COMPILE(, [/* don't need anything here */],
  44         c_compiles=yes, c_compiles=no)
  45
  46 AC_TRY_LINK(, [/* don't need anything here */],
  47         c_links=yes, c_links=no)
  48
  49 if test x"${c_compiles}" = x"no" ; then
  50   AC_MSG_ERROR(the native compiler is broken and won't compile.)
  51 fi
  52
  53 if test x"${c_links}" = x"no" ; then
  54   AC_MSG_ERROR(the native compiler is broken and won't link.)
  55 fi
  56 AC_MSG_RESULT(yes)
  57 ])
  58
  59 ## ----------------------------------------- ##
  60 ## ANSIfy the C compiler whenever possible.  ##
  61 ## From Franc,ois Pinard                     ##
  62 ## ----------------------------------------- ##
  63
  64 # Copyright (C) 1996, 1997, 1999, 2000, 2001, 2008, 2009
  65   Free Software Foundation, Inc.
  66
  67 # This program is free software; you can redistribute it and/or modify
  68 # it under the terms of the GNU General Public License as published by
  69 # the Free Software Foundation; either version 2, or (at your option)
  70 # any later version.
  71
  72 # This program is distributed in the hope that it will be useful,
  73 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  74 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  75 # GNU General Public License for more details.
  76
  77 # You should have received a copy of the GNU General Public License
  78 # along with this program; if not, write to the Free Software
  79 # Foundation, Inc., 51 Franklin Street, Fifth Floor,
  80 # Boston, MA 02110-1301, USA.
  81
  82 # serial 1
  83
  84 # @defmac AC_PROG_CC_STDC
  85 # @maindex PROG_CC_STDC
  86 # @ovindex CC
  87 # If the C compiler in not in ANSI C mode by default, try to add an option
  88 # to output variable @code{CC} to make it so.  This macro tries various
  89 # options that select ANSI C on some system or another.  It considers the
  90 # compiler to be in ANSI C mode if it handles function prototypes correctly.
  91 #
  92 # If you use this macro, you should check after calling it whether the C
  93 # compiler has been set to accept ANSI C; if not, the shell variable
  94 # @code{am_cv_prog_cc_stdc} is set to @samp{no}.  If you wrote your source
  95 # code in ANSI C, you can make an un-ANSIfied copy of it by using the
  96 # program @code{ansi2knr}, which comes with Ghostscript.
  97 # @end defmac
  98
  99 AC_DEFUN([AM_PROG_CC_STDC],
 100 [AC_REQUIRE([AC_PROG_CC])
 101 AC_BEFORE([$0], [AC_C_INLINE])
 102 AC_BEFORE([$0], [AC_C_CONST])
 103 dnl Force this before AC_PROG_CPP.  Some cpp's, eg on HPUX, require
 104 dnl a magic option to avoid problems with ANSI preprocessor commands
 105 dnl like #elif.
 106 dnl FIXME: can't do this because then AC_AIX won't work due to a
 107 dnl circular dependency.
 108 dnl AC_BEFORE([$0], [AC_PROG_CPP])
 109 AC_MSG_CHECKING([for ${CC-cc} option to accept ANSI C])
 110 AC_CACHE_VAL(am_cv_prog_cc_stdc,
 111 [am_cv_prog_cc_stdc=no
 112 ac_save_CC="$CC"
 113 # Don't try gcc -ansi; that turns off useful extensions and
 114 # breaks some systems' header files.
 115 # AIX                   -qlanglvl=ansi
 116 # Ultrix and OSF/1      -std1
 117 # HP-UX 10.20 and later -Ae
 118 # HP-UX older versions  -Aa -D_HPUX_SOURCE
 119 # SVR4                  -Xc -D__EXTENSIONS__
 120 for ac_arg in "" -qlanglvl=ansi -std1 -Ae "-Aa -D_HPUX_SOURCE" "-Xc -D__EXTENSIONS__"
 121 do
 122   CC="$ac_save_CC $ac_arg"
 123   AC_TRY_COMPILE(
 124 [#include <stdarg.h>
 125 #include <stdio.h>
 126 #include <sys/types.h>
 127 #include <sys/stat.h>
 128 /* Most of the following tests are stolen from RCS 5.7's src/conf.sh.  */
 129 struct buf { int x; };
 130 FILE * (*rcsopen) (struct buf *, struct stat *, int);
 131 static char *e (p, i)
 132      char **p;
 133      int i;
 134 {
 135   return p[i];
 136 }
 137 static char *f (char * (*g) (char **, int), char **p, ...)
 138 {
 139   char *s;
 140   va_list v;
 141   va_start (v,p);
 142   s = g (p, va_arg (v,int));
 143   va_end (v);
 144   return s;
 145 }
 146 int test (int i, double x);
 147 struct s1 {int (*f) (int a);};
 148 struct s2 {int (*f) (double a);};
 149 int pairnames (int, char **, FILE *(*)(struct buf *, struct stat *, int), int, int);
 150 int argc;
 151 char **argv;
 152 ], [
 153 return f (e, argv, 0) != argv[0]  ||  f (e, argv, 1) != argv[1];
 154 ],
 155 [am_cv_prog_cc_stdc="$ac_arg"; break])
 156 done
 157 CC="$ac_save_CC"
 158 ])
 159 if test -z "$am_cv_prog_cc_stdc"; then
 160   AC_MSG_RESULT([none needed])
 161 else
 162   AC_MSG_RESULT([$am_cv_prog_cc_stdc])
 163 fi
 164 case "x$am_cv_prog_cc_stdc" in
 165   x|xno) ;;
 166   *) CC="$CC $am_cv_prog_cc_stdc" ;;
 167 esac
 168 ])
 169
 170 dnl From Bruno Haible.
 171
 172 AC_DEFUN([AM_ICONV],
 173 [
 174   dnl Some systems have iconv in libc, some have it in libiconv (OSF/1 and
 175   dnl those with the standalone portable GNU libiconv installed).
 176
 177   AC_ARG_WITH([libiconv-prefix],
 178 [  --with-libiconv-prefix=DIR  search for libiconv in DIR/include and DIR/lib], [
 179     for dir in `echo "$withval" | tr : ' '`; do
 180       if test -d $dir/include; then LIBICONV_INCLUDE="-I$dir/include"; CPPFLAGS="$CPPFLAGS -I$dir/include"; fi
 181       if test -d $dir/lib; then LIBICONV_LIBDIR="-L$dir/lib"; LDFLAGS="$LDFLAGS -L$dir/lib"; fi
 182     done
 183    ])
 184
 185   BUILD_LIBICONV_LIBDIR="-L../libiconv/lib/.libs -L../libiconv/lib/_libs"
 186   BUILD_LIBICONV_INCLUDE="-I../libiconv/include"
 187
 188   AC_CACHE_CHECK(for iconv, am_cv_func_iconv, [
 189     am_cv_func_iconv="no, consider installing GNU libiconv"
 190     am_cv_lib_iconv=no
 191     am_cv_use_build_libiconv=no
 192     AC_TRY_LINK([#include <stdlib.h>
 193 #include <iconv.h>],
 194       [iconv_t cd = iconv_open("","");
 195        iconv(cd,NULL,NULL,NULL,NULL);
 196        iconv_close(cd);],
 197       am_cv_func_iconv=yes)
 198     if test "$am_cv_func_iconv" != yes; then
 199       am_save_LIBS="$LIBS"
 200       LIBS="$LIBS -liconv"
 201       AC_TRY_LINK([#include <stdlib.h>
 202 #include <iconv.h>],
 203         [iconv_t cd = iconv_open("","");
 204          iconv(cd,NULL,NULL,NULL,NULL);
 205          iconv_close(cd);],
 206         am_cv_lib_iconv=yes
 207         am_cv_func_iconv=yes)
 208       LIBS="$am_save_LIBS"
 209     fi
 210     # Look for libiconv in the build tree.
 211     if test "$am_cv_func_iconv" != yes && test -d ../libiconv; then
 212       am_save_LIBS="$LIBS"
 213       am_save_CPPFLAGS="$CPPFLAGS"
 214       LIBS="$LIBS $BUILD_LIBICONV_LIBDIR -liconv"
 215       CPPFLAGS="$CPPFLAGS $BUILD_LIBICONV_INCLUDE"
 216       AC_TRY_LINK([#include <stdlib.h>
 217 #include <iconv.h>],
 218         [iconv_t cd = iconv_open("","");
 219          iconv(cd,NULL,NULL,NULL,NULL);
 220          iconv_close(cd);],
 221         am_cv_lib_iconv=yes
 222         am_cv_func_iconv=yes)
 223       LIBS="$am_save_LIBS"
 224       if test "$am_cv_func_iconv" = "yes"; then
 225          am_cv_use_build_libiconv=yes
 226       else
 227          CPPFLAGS="$am_save_CPPFLAGS"
 228       fi
 229     fi
 230   ])
 231   if test "$am_cv_func_iconv" = yes; then
 232     AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 233     AC_MSG_CHECKING([for iconv declaration])
 234     AC_CACHE_VAL(am_cv_proto_iconv, [
 235       AC_TRY_COMPILE([
 236 #include <stdlib.h>
 237 #include <iconv.h>
 238 extern
 239 #ifdef __cplusplus
 240 "C"
 241 #endif
 242 #if defined(__STDC__) || defined(__cplusplus)
 243 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 244 #else
 245 size_t iconv();
 246 #endif
 247 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
 248       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 249     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 250     AC_MSG_RESULT([$]{ac_t:-
 251          }[$]am_cv_proto_iconv)
 252     AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 253       [Define as const if the declaration of iconv() needs const.])
 254   fi
 255   LIBICONV=
 256   if test "$am_cv_lib_iconv" = yes; then
 257     LIBICONV="-liconv"
 258   fi
 259   if test "$am_cv_use_build_libiconv" = yes; then
 260     LIBICONV_LIBDIR="$BUILD_LIBICONV_LIBDIR"
 261     LIBICONV_INCLUDE="$BUILD_LIBICONV_INCLUDE"
 262   fi
 263   AC_SUBST(LIBICONV)
 264   AC_SUBST(LIBICONV_INCLUDE)
 265   AC_SUBST(LIBICONV_LIBDIR)
 266 ])
 267
 268 dnl written by Guido Draheim <guidod@gmx.de>, original by Alexandre Oliva
 269 dnl Version 1.3 (2001/03/02)
 270 dnl source http://www.gnu.org/software/ac-archive/Miscellaneous/ac_define_dir.html
 271
 272 AC_DEFUN([AC_DEFINE_DIR], [
 273   test "x$prefix" = xNONE && prefix="$ac_default_prefix"
 274   test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 275   ac_define_dir=`eval echo [$]$2`
 276   ac_define_dir=`eval echo [$]ac_define_dir`
 277   ifelse($3, ,
 278     AC_DEFINE_UNQUOTED($1, "$ac_define_dir"),
 279     AC_DEFINE_UNQUOTED($1, "$ac_define_dir", $3))
 280 ])
 281
 282 dnl See whether we need a declaration for a function.
 283 dnl The result is highly dependent on the INCLUDES passed in, so make sure
 284 dnl to use a different cache variable name in this macro if it is invoked
 285 dnl in a different context somewhere else.
 286 dnl gcc_AC_CHECK_DECL(SYMBOL,
 287 dnl     [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND [, INCLUDES]]])
 288 AC_DEFUN([gcc_AC_CHECK_DECL],
 289 [AC_MSG_CHECKING([whether $1 is declared])
 290 AC_CACHE_VAL(gcc_cv_have_decl_$1,
 291 [AC_TRY_COMPILE([$4],
 292 [#ifndef $1
 293 char *(*pfn) = (char *(*)) $1 ;
 294 #endif], eval "gcc_cv_have_decl_$1=yes", eval "gcc_cv_have_decl_$1=no")])
 295 if eval "test \"`echo '$gcc_cv_have_decl_'$1`\" = yes"; then
 296   AC_MSG_RESULT(yes) ; ifelse([$2], , :, [$2])
 297 else
 298   AC_MSG_RESULT(no) ; ifelse([$3], , :, [$3])
 299 fi
 300 ])dnl
 301
 302 dnl Check multiple functions to see whether each needs a declaration.
 303 dnl Arrange to define HAVE_DECL_<FUNCTION> to 0 or 1 as appropriate.
 304 dnl gcc_AC_CHECK_DECLS(SYMBOLS,
 305 dnl     [ACTION-IF-NEEDED [, ACTION-IF-NOT-NEEDED [, INCLUDES]]])
 306 AC_DEFUN([gcc_AC_CHECK_DECLS],
 307 [for ac_func in $1
 308 do
 309 changequote(, )dnl
 310   ac_tr_decl=HAVE_DECL_`echo $ac_func | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 311 changequote([, ])dnl
 312 gcc_AC_CHECK_DECL($ac_func,
 313   [AC_DEFINE_UNQUOTED($ac_tr_decl, 1) $2],
 314   [AC_DEFINE_UNQUOTED($ac_tr_decl, 0) $3],
 315 dnl It is possible that the include files passed in here are local headers
 316 dnl which supply a backup declaration for the relevant prototype based on
 317 dnl the definition of (or lack of) the HAVE_DECL_ macro.  If so, this test
 318 dnl will always return success.  E.g. see libiberty.h's handling of
 319 dnl `basename'.  To avoid this, we define the relevant HAVE_DECL_ macro to
 320 dnl 1 so that any local headers used do not provide their own prototype
 321 dnl during this test.
 322 #undef $ac_tr_decl
 323 #define $ac_tr_decl 1
 324   $4
 325 )
 326 done
 327 dnl Automatically generate config.h entries via autoheader.
 328 if test x = y ; then
 329   patsubst(translit([$1], [a-z], [A-Z]), [\w+],
 330     [AC_DEFINE([HAVE_DECL_\&], 1,
 331       [Define to 1 if we found this declaration otherwise define to 0.])])dnl
 332 fi
 333 ])
 334
 335 dnl Find the location of the private Tcl headers
 336 dnl When Tcl is installed, this is TCL_INCLUDE_SPEC/tcl-private/generic
 337 dnl When Tcl is in the build tree, this is not needed.
 338 dnl
 339 dnl Note: you must use first use SC_LOAD_TCLCONFIG!
 340 AC_DEFUN([CY_AC_TCL_PRIVATE_HEADERS], [
 341   AC_MSG_CHECKING([for Tcl private headers])
 342   private_dir=""
 343   dir=`echo ${TCL_INCLUDE_SPEC}/tcl-private/generic | sed -e s/-I//`
 344   if test -f ${dir}/tclInt.h ; then
 345     private_dir=${dir}
 346   fi
 347
 348   if test x"${private_dir}" = x; then
 349     AC_ERROR(could not find private Tcl headers)
 350   else
 351     TCL_PRIVATE_INCLUDE="-I${private_dir}"
 352     AC_MSG_RESULT(${private_dir})
 353   fi
 354 ])
 355
 356 dnl Find the location of the private Tk headers
 357 dnl When Tk is installed, this is TK_INCLUDE_SPEC/tk-private/generic
 358 dnl When Tk is in the build tree, this not needed.
 359 dnl
 360 dnl Note: you must first use SC_LOAD_TKCONFIG
 361 AC_DEFUN([CY_AC_TK_PRIVATE_HEADERS], [
 362   AC_MSG_CHECKING([for Tk private headers])
 363   private_dir=""
 364   dir=`echo ${TK_INCLUDE_SPEC}/tk-private/generic | sed -e s/-I//`
 365   if test -f ${dir}/tkInt.h; then
 366     private_dir=${dir}
 367   fi
 368
 369   if test x"${private_dir}" = x; then
 370     AC_ERROR(could not find Tk private headers)
 371   else
 372     TK_PRIVATE_INCLUDE="-I${private_dir}"
 373     AC_MSG_RESULT(${private_dir})
 374   fi
 375 ])