gdb/acinclude.m4

   1 dnl written by Rob Savoye <rob@cygnus.com> for Cygnus Support
   2 dnl major rewriting for Tcl 7.5 by Don Libes <libes@nist.gov>
   3
   4 # Keep these includes in sync with the aclocal_m4_deps list in
   5 # Makefile.in.
   6
   7 sinclude(acx_configure_dir.m4)
   8
   9 # This gets GDB_AC_LIBMCHECK.
  10 sinclude(libmcheck.m4)
  11
  12 dnl gdb/configure.in uses BFD_NEED_DECLARATION, so get its definition.
  13 sinclude(../bfd/bfd.m4)
  14
  15 dnl This gets the standard macros.
  16 sinclude(../config/acinclude.m4)
  17
  18 dnl This gets AC_PLUGINS, needed by ACX_LARGEFILE.
  19 sinclude(../config/plugins.m4)
  20
  21 dnl For ACX_LARGEFILE.
  22 sinclude(../config/largefile.m4)
  23
  24 dnl For AM_SET_LEADING_DOT.
  25 sinclude(../config/lead-dot.m4)
  26
  27 dnl This gets autoconf bugfixes.
  28 sinclude(../config/override.m4)
  29
  30 dnl For ZW_GNU_GETTEXT_SISTER_DIR.
  31 sinclude(../config/gettext-sister.m4)
  32
  33 dnl For AC_LIB_HAVE_LINKFLAGS.
  34 sinclude(../config/lib-ld.m4)
  35 sinclude(../config/lib-prefix.m4)
  36 sinclude(../config/lib-link.m4)
  37
  38 dnl For ACX_PKGVERSION and ACX_BUGURL.
  39 sinclude(../config/acx.m4)
  40
  41 dnl for TCL definitions
  42 sinclude(../config/tcl.m4)
  43
  44 dnl For dependency tracking macros.
  45 sinclude([../config/depstand.m4])
  46
  47 dnl For AM_LC_MESSAGES
  48 sinclude([../config/lcmessage.m4])
  49
  50 dnl For AM_LANGINFO_CODESET.
  51 sinclude([../config/codeset.m4])
  52
  53 sinclude([../config/zlib.m4])
  54
  55 m4_include([common/common.m4])
  56
  57 ## ----------------------------------------- ##
  58 ## ANSIfy the C compiler whenever possible.  ##
  59 ## From Franc,ois Pinard                     ##
  60 ## ----------------------------------------- ##
  61
  62 # Copyright (C) 1996-2013 Free Software Foundation, Inc.
  63
  64 # This program is free software; you can redistribute it and/or modify
  65 # it under the terms of the GNU General Public License as published by
  66 # the Free Software Foundation; either version 2, or (at your option)
  67 # any later version.
  68
  69 # This program is distributed in the hope that it will be useful,
  70 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  71 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  72 # GNU General Public License for more details.
  73
  74 # You should have received a copy of the GNU General Public License
  75 # along with this program; if not, see <http://www.gnu.org/licenses/>.
  76
  77 # serial 1
  78
  79 # @defmac AC_PROG_CC_STDC
  80 # @maindex PROG_CC_STDC
  81 # @ovindex CC
  82 # If the C compiler in not in ANSI C mode by default, try to add an option
  83 # to output variable @code{CC} to make it so.  This macro tries various
  84 # options that select ANSI C on some system or another.  It considers the
  85 # compiler to be in ANSI C mode if it handles function prototypes correctly.
  86 #
  87 # If you use this macro, you should check after calling it whether the C
  88 # compiler has been set to accept ANSI C; if not, the shell variable
  89 # @code{am_cv_prog_cc_stdc} is set to @samp{no}.  If you wrote your source
  90 # code in ANSI C, you can make an un-ANSIfied copy of it by using the
  91 # program @code{ansi2knr}, which comes with Ghostscript.
  92 # @end defmac
  93
  94 AC_DEFUN([AM_PROG_CC_STDC],
  95 [AC_REQUIRE([AC_PROG_CC])
  96 AC_BEFORE([$0], [AC_C_INLINE])
  97 AC_BEFORE([$0], [AC_C_CONST])
  98 dnl Force this before AC_PROG_CPP.  Some cpp's, eg on HPUX, require
  99 dnl a magic option to avoid problems with ANSI preprocessor commands
 100 dnl like #elif.
 101 dnl FIXME: can't do this because then AC_AIX won't work due to a
 102 dnl circular dependency.
 103 dnl AC_BEFORE([$0], [AC_PROG_CPP])
 104 AC_MSG_CHECKING([for ${CC-cc} option to accept ANSI C])
 105 AC_CACHE_VAL(am_cv_prog_cc_stdc,
 106 [am_cv_prog_cc_stdc=no
 107 ac_save_CC="$CC"
 108 # Don't try gcc -ansi; that turns off useful extensions and
 109 # breaks some systems' header files.
 110 # AIX                   -qlanglvl=ansi
 111 # Ultrix and OSF/1      -std1
 112 # HP-UX 10.20 and later -Ae
 113 # HP-UX older versions  -Aa -D_HPUX_SOURCE
 114 # SVR4                  -Xc -D__EXTENSIONS__
 115 for ac_arg in "" -qlanglvl=ansi -std1 -Ae "-Aa -D_HPUX_SOURCE" "-Xc -D__EXTENSIONS__"
 116 do
 117   CC="$ac_save_CC $ac_arg"
 118   AC_TRY_COMPILE(
 119 [#include <stdarg.h>
 120 #include <stdio.h>
 121 #include <sys/types.h>
 122 #include <sys/stat.h>
 123 /* Most of the following tests are stolen from RCS 5.7's src/conf.sh.  */
 124 struct buf { int x; };
 125 FILE * (*rcsopen) (struct buf *, struct stat *, int);
 126 static char *e (p, i)
 127      char **p;
 128      int i;
 129 {
 130   return p[i];
 131 }
 132 static char *f (char * (*g) (char **, int), char **p, ...)
 133 {
 134   char *s;
 135   va_list v;
 136   va_start (v,p);
 137   s = g (p, va_arg (v,int));
 138   va_end (v);
 139   return s;
 140 }
 141 int test (int i, double x);
 142 struct s1 {int (*f) (int a);};
 143 struct s2 {int (*f) (double a);};
 144 int pairnames (int, char **, FILE *(*)(struct buf *, struct stat *, int), int, int);
 145 int argc;
 146 char **argv;
 147 ], [
 148 return f (e, argv, 0) != argv[0]  ||  f (e, argv, 1) != argv[1];
 149 ],
 150 [am_cv_prog_cc_stdc="$ac_arg"; break])
 151 done
 152 CC="$ac_save_CC"
 153 ])
 154 if test -z "$am_cv_prog_cc_stdc"; then
 155   AC_MSG_RESULT([none needed])
 156 else
 157   AC_MSG_RESULT([$am_cv_prog_cc_stdc])
 158 fi
 159 case "x$am_cv_prog_cc_stdc" in
 160   x|xno) ;;
 161   *) CC="$CC $am_cv_prog_cc_stdc" ;;
 162 esac
 163 ])
 164
 165 dnl Originally from Bruno Haible, but with some modifications
 166 dnl for the GDB project.
 167
 168 AC_DEFUN([AM_ICONV],
 169 [
 170   dnl Some systems have iconv in libc, some have it in libiconv (OSF/1 and
 171   dnl those with the standalone portable GNU libiconv installed).
 172
 173   AC_ARG_WITH([libiconv-prefix],
 174     AS_HELP_STRING([--with-libiconv-prefix=DIR], [search for libiconv in DIR/include and DIR/lib]), [
 175     for dir in `echo "$withval" | tr : ' '`; do
 176       if test -d $dir/include; then LIBICONV_INCLUDE="-I$dir/include"; fi
 177       if test -d $dir/lib; then LIBICONV_LIBDIR="-L$dir/lib"; fi
 178     done
 179    ])
 180
 181   BUILD_LIBICONV_LIBDIRS="../libiconv/lib/.libs ../libiconv/lib/_libs"
 182   BUILD_LIBICONV_INCLUDE="-I../libiconv/include"
 183
 184   AC_CACHE_CHECK(for iconv, am_cv_func_iconv, [
 185     am_cv_func_iconv="no, consider installing GNU libiconv"
 186     am_cv_lib_iconv=no
 187     am_cv_use_build_libiconv=no
 188     am_cv_build_libiconv_path=
 189
 190     # If libiconv is part of the build tree, then try using it over
 191     # any system iconv.
 192     if test -d ../libiconv; then
 193       for lib_dir in $BUILD_LIBICONV_LIBDIRS; do
 194         am_save_LIBS="$LIBS"
 195         am_save_CPPFLAGS="$CPPFLAGS"
 196         LIBS="$LIBS $lib_dir/libiconv.a"
 197         CPPFLAGS="$CPPFLAGS $BUILD_LIBICONV_INCLUDE"
 198         AC_TRY_LINK([#include <stdlib.h>
 199 #include <iconv.h>],
 200           [iconv_t cd = iconv_open("","");
 201            iconv(cd,NULL,NULL,NULL,NULL);
 202            iconv_close(cd);],
 203           am_cv_use_build_libiconv=yes
 204           am_cv_build_libiconv_path=$lib_dir/libiconv.a
 205           am_cv_lib_iconv=yes
 206           am_cv_func_iconv=yes)
 207         LIBS="$am_save_LIBS"
 208         CPPFLAGS="$am_save_CPPFLAGS"
 209         if test "$am_cv_use_build_libiconv" = "yes"; then
 210           break
 211         fi
 212       done
 213     fi
 214
 215     # Next, try to find iconv in libc.
 216     if test "$am_cv_func_iconv" != yes; then
 217       AC_TRY_LINK([#include <stdlib.h>
 218 #include <iconv.h>],
 219         [iconv_t cd = iconv_open("","");
 220          iconv(cd,NULL,NULL,NULL,NULL);
 221          iconv_close(cd);],
 222         am_cv_func_iconv=yes)
 223     fi
 224
 225     # If iconv was not in libc, try -liconv.  In this case, arrange to
 226     # look in the libiconv prefix, if it was specified by the user.
 227     if test "$am_cv_func_iconv" != yes; then
 228       am_save_CPPFLAGS="$CPPFLAGS"
 229       am_save_LIBS="$LIBS"
 230       if test -n "$LIBICONV_INCLUDE"; then
 231         CPPFLAGS="$CPPFLAGS $LIBICONV_INCLUDE"
 232         LIBS="$LIBS $LIBICONV_LIBDIR"
 233       fi
 234       LIBS="$LIBS -liconv"
 235       AC_TRY_LINK([#include <stdlib.h>
 236 #include <iconv.h>],
 237         [iconv_t cd = iconv_open("","");
 238          iconv(cd,NULL,NULL,NULL,NULL);
 239          iconv_close(cd);],
 240         am_cv_lib_iconv=yes
 241         am_cv_func_iconv=yes)
 242       LIBS="$am_save_LIBS"
 243       CPPFLAGS="$am_save_CPPFLAGS"
 244     fi
 245   ])
 246
 247   # Set the various flags based on the cache variables.  We can't rely
 248   # on the flags to remain set from the above code, due to caching.
 249   LIBICONV=
 250   if test "$am_cv_lib_iconv" = yes; then
 251     LIBICONV="-liconv"
 252   else
 253     LIBICONV_LIBDIR=
 254     LIBICONV_INCLUDE=
 255   fi
 256   if test "$am_cv_use_build_libiconv" = yes; then
 257     LIBICONV="$am_cv_build_libiconv_path"
 258     LIBICONV_LIBDIR=""
 259     LIBICONV_INCLUDE="$BUILD_LIBICONV_INCLUDE"
 260   fi
 261   CPPFLAGS="$CPPFLAGS $LIBICONV_INCLUDE"
 262   LIBS="$LIBS $LIBICONV_LIBDIR $LIBICONV"
 263
 264   if test "$am_cv_func_iconv" = yes; then
 265     AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 266     AC_MSG_CHECKING([for iconv declaration])
 267     AC_CACHE_VAL(am_cv_proto_iconv, [
 268       AC_TRY_COMPILE([
 269 #include <stdlib.h>
 270 #include <iconv.h>
 271 extern
 272 #ifdef __cplusplus
 273 "C"
 274 #endif
 275 #if defined(__STDC__) || defined(__cplusplus)
 276 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 277 #else
 278 size_t iconv();
 279 #endif
 280 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
 281       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 282     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 283     AC_MSG_RESULT([$]{ac_t:-
 284          }[$]am_cv_proto_iconv)
 285     AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 286       [Define as const if the declaration of iconv() needs const.])
 287   fi
 288 ])
 289
 290 dnl written by Guido Draheim <guidod@gmx.de>, original by Alexandre Oliva
 291 dnl Version 1.3 (2001/03/02)
 292 dnl source http://www.gnu.org/software/ac-archive/Miscellaneous/ac_define_dir.html
 293
 294 AC_DEFUN([AC_DEFINE_DIR], [
 295   test "x$prefix" = xNONE && prefix="$ac_default_prefix"
 296   test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 297   ac_define_dir=`eval echo [$]$2`
 298   ac_define_dir=`eval echo [$]ac_define_dir`
 299   ifelse($3, ,
 300     AC_DEFINE_UNQUOTED($1, "$ac_define_dir"),
 301     AC_DEFINE_UNQUOTED($1, "$ac_define_dir", $3))
 302 ])
 303
 304 dnl See whether we need a declaration for a function.
 305 dnl The result is highly dependent on the INCLUDES passed in, so make sure
 306 dnl to use a different cache variable name in this macro if it is invoked
 307 dnl in a different context somewhere else.
 308 dnl gcc_AC_CHECK_DECL(SYMBOL,
 309 dnl     [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND [, INCLUDES]]])
 310 AC_DEFUN([gcc_AC_CHECK_DECL],
 311 [AC_MSG_CHECKING([whether $1 is declared])
 312 AC_CACHE_VAL(gcc_cv_have_decl_$1,
 313 [AC_TRY_COMPILE([$4],
 314 [#ifndef $1
 315 char *(*pfn) = (char *(*)) $1 ;
 316 #endif], eval "gcc_cv_have_decl_$1=yes", eval "gcc_cv_have_decl_$1=no")])
 317 if eval "test \"`echo '$gcc_cv_have_decl_'$1`\" = yes"; then
 318   AC_MSG_RESULT(yes) ; ifelse([$2], , :, [$2])
 319 else
 320   AC_MSG_RESULT(no) ; ifelse([$3], , :, [$3])
 321 fi
 322 ])dnl
 323
 324 dnl Check multiple functions to see whether each needs a declaration.
 325 dnl Arrange to define HAVE_DECL_<FUNCTION> to 0 or 1 as appropriate.
 326 dnl gcc_AC_CHECK_DECLS(SYMBOLS,
 327 dnl     [ACTION-IF-NEEDED [, ACTION-IF-NOT-NEEDED [, INCLUDES]]])
 328 AC_DEFUN([gcc_AC_CHECK_DECLS],
 329 [for ac_func in $1
 330 do
 331 changequote(, )dnl
 332   ac_tr_decl=HAVE_DECL_`echo $ac_func | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 333 changequote([, ])dnl
 334 gcc_AC_CHECK_DECL($ac_func,
 335   [AC_DEFINE_UNQUOTED($ac_tr_decl, 1) $2],
 336   [AC_DEFINE_UNQUOTED($ac_tr_decl, 0) $3],
 337 dnl It is possible that the include files passed in here are local headers
 338 dnl which supply a backup declaration for the relevant prototype based on
 339 dnl the definition of (or lack of) the HAVE_DECL_ macro.  If so, this test
 340 dnl will always return success.  E.g. see libiberty.h's handling of
 341 dnl `basename'.  To avoid this, we define the relevant HAVE_DECL_ macro to
 342 dnl 1 so that any local headers used do not provide their own prototype
 343 dnl during this test.
 344 #undef $ac_tr_decl
 345 #define $ac_tr_decl 1
 346   $4
 347 )
 348 done
 349 dnl Automatically generate config.h entries via autoheader.
 350 if test x = y ; then
 351   patsubst(translit([$1], [a-z], [A-Z]), [\w+],
 352     [AC_DEFINE([HAVE_DECL_\&], 1,
 353       [Define to 1 if we found this declaration otherwise define to 0.])])dnl
 354 fi
 355 ])
 356
 357 dnl Find the location of the private Tcl headers
 358 dnl When Tcl is installed, this is TCL_INCLUDE_SPEC/tcl-private/generic
 359 dnl When Tcl is in the build tree, this is not needed.
 360 dnl
 361 dnl Note: you must use first use SC_LOAD_TCLCONFIG!
 362 AC_DEFUN([CY_AC_TCL_PRIVATE_HEADERS], [
 363   AC_MSG_CHECKING([for Tcl private headers])
 364   private_dir=""
 365   dir=`echo ${TCL_INCLUDE_SPEC}/tcl-private/generic | sed -e s/-I//`
 366   if test -f ${dir}/tclInt.h ; then
 367     private_dir=${dir}
 368   fi
 369
 370   if test x"${private_dir}" = x; then
 371     AC_ERROR(could not find private Tcl headers)
 372   else
 373     TCL_PRIVATE_INCLUDE="-I${private_dir}"
 374     AC_MSG_RESULT(${private_dir})
 375   fi
 376 ])
 377
 378 dnl Find the location of the private Tk headers
 379 dnl When Tk is installed, this is TK_INCLUDE_SPEC/tk-private/generic
 380 dnl When Tk is in the build tree, this not needed.
 381 dnl
 382 dnl Note: you must first use SC_LOAD_TKCONFIG
 383 AC_DEFUN([CY_AC_TK_PRIVATE_HEADERS], [
 384   AC_MSG_CHECKING([for Tk private headers])
 385   private_dir=""
 386   dir=`echo ${TK_INCLUDE_SPEC}/tk-private/generic | sed -e s/-I//`
 387   if test -f ${dir}/tkInt.h; then
 388     private_dir=${dir}
 389   fi
 390
 391   if test x"${private_dir}" = x; then
 392     AC_ERROR(could not find Tk private headers)
 393   else
 394     TK_PRIVATE_INCLUDE="-I${private_dir}"
 395     AC_MSG_RESULT(${private_dir})
 396   fi
 397 ])
 398
 399 dnl GDB_AC_DEFINE_RELOCATABLE([VARIABLE], [ARG-NAME], [SHELL-VARIABLE])
 400 dnl For use in processing directory values for --with-foo.
 401 dnl If the path in SHELL_VARIABLE is relative to the prefix, then the
 402 dnl result is relocatable, then this will define the C macro
 403 dnl VARIABLE_RELOCATABLE to 1; otherwise it is defined as 0.
 404 AC_DEFUN([GDB_AC_DEFINE_RELOCATABLE], [
 405   if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
 406      if test "x$prefix" = xNONE; then
 407         test_prefix=/usr/local
 408      else
 409         test_prefix=$prefix
 410      fi
 411   else
 412      test_prefix=$exec_prefix
 413   fi
 414   value=0
 415   case [$3] in
 416      "${test_prefix}"|"${test_prefix}/"*|\
 417         '${exec_prefix}'|'${exec_prefix}/'*)
 418      value=1
 419      ;;
 420   esac
 421   AC_DEFINE_UNQUOTED([$1]_RELOCATABLE, $value, [Define if the $2 directory should be relocated when GDB is moved.])
 422 ])
 423
 424 dnl GDB_AC_WITH_DIR([VARIABLE], [ARG-NAME], [HELP], [DEFAULT])
 425 dnl Add a new --with option that defines a directory.
 426 dnl The result is stored in VARIABLE.  AC_DEFINE_DIR is called
 427 dnl on this variable, as is AC_SUBST.
 428 dnl ARG-NAME is the base name of the argument (without "--with").
 429 dnl HELP is the help text to use.
 430 dnl If the user's choice is relative to the prefix, then the
 431 dnl result is relocatable, then this will define the C macro
 432 dnl VARIABLE_RELOCATABLE to 1; otherwise it is defined as 0.
 433 dnl DEFAULT is the default value, which is used if the user
 434 dnl does not specify the argument.
 435 AC_DEFUN([GDB_AC_WITH_DIR], [
 436   AC_ARG_WITH([$2], AS_HELP_STRING([--with-][$2][=PATH], [$3]), [
 437     [$1]=$withval], [[$1]=[$4]])
 438   AC_DEFINE_DIR([$1], [$1], [$3])
 439   AC_SUBST([$1])
 440   GDB_AC_DEFINE_RELOCATABLE([$1], [$2], ${ac_define_dir})
 441   ])
 442
 443 dnl GDB_AC_CHECK_BFD([MESSAGE], [CV], [CODE], [HEADER])
 444 dnl Check whether BFD provides a feature.
 445 dnl MESSAGE is the "checking" message to display.
 446 dnl CV is the name of the cache variable where the result is stored.
 447 dnl The result will be "yes" or "no".
 448 dnl CODE is some code to compile that checks for the feature.
 449 dnl A link test is run.
 450 dnl HEADER is the name of an extra BFD header to include.
 451 AC_DEFUN([GDB_AC_CHECK_BFD], [
 452   OLD_CFLAGS=$CFLAGS
 453   OLD_LDFLAGS=$LDFLAGS
 454   OLD_LIBS=$LIBS
 455   # Put the old CFLAGS/LDFLAGS last, in case the user's (C|LD)FLAGS
 456   # points somewhere with bfd, with -I/foo/lib and -L/foo/lib.  We
 457   # always want our bfd.
 458   CFLAGS="-I${srcdir}/../include -I../bfd -I${srcdir}/../bfd $CFLAGS"
 459   LDFLAGS="-L../bfd -L../libiberty $LDFLAGS"
 460   intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
 461   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
 462   if test "$plugins" = "yes"; then
 463     AC_SEARCH_LIBS(dlopen, dl)
 464   fi
 465   LIBS="-lbfd -liberty $intl $LIBS"
 466   AC_CACHE_CHECK([$1], [$2],
 467   [AC_TRY_LINK(
 468   [#include <stdlib.h>
 469   #include "bfd.h"
 470   #include "$4"
 471   ],
 472   [return $3;], [[$2]=yes], [[$2]=no])])
 473   CFLAGS=$OLD_CFLAGS
 474   LDFLAGS=$OLD_LDFLAGS
 475   LIBS=$OLD_LIBS])