gdb/acinclude.m4

   1 dnl written by Rob Savoye <rob@cygnus.com> for Cygnus Support
   2 dnl major rewriting for Tcl 7.5 by Don Libes <libes@nist.gov>
   3
   4 # Keep these includes in sync with the aclocal_m4_deps list in
   5 # Makefile.in.
   6
   7 sinclude(acx_configure_dir.m4)
   8
   9 # This gets GDB_AC_LIBMCHECK.
  10 sinclude(libmcheck.m4)
  11
  12 dnl gdb/configure.in uses BFD_NEED_DECLARATION, so get its definition.
  13 sinclude(../bfd/bfd.m4)
  14
  15 dnl This gets the standard macros.
  16 sinclude(../config/acinclude.m4)
  17
  18 dnl This gets AC_PLUGINS, needed by ACX_LARGEFILE.
  19 sinclude(../config/plugins.m4)
  20
  21 dnl For ACX_LARGEFILE.
  22 sinclude(../config/largefile.m4)
  23
  24 dnl For AM_SET_LEADING_DOT.
  25 sinclude(../config/lead-dot.m4)
  26
  27 dnl This gets autoconf bugfixes.
  28 sinclude(../config/override.m4)
  29
  30 dnl For ZW_GNU_GETTEXT_SISTER_DIR.
  31 sinclude(../config/gettext-sister.m4)
  32
  33 dnl For AC_LIB_HAVE_LINKFLAGS.
  34 sinclude(../config/lib-ld.m4)
  35 sinclude(../config/lib-prefix.m4)
  36 sinclude(../config/lib-link.m4)
  37
  38 dnl For ACX_PKGVERSION and ACX_BUGURL.
  39 sinclude(../config/acx.m4)
  40
  41 dnl for TCL definitions
  42 sinclude(../config/tcl.m4)
  43
  44 dnl For dependency tracking macros.
  45 sinclude([../config/depstand.m4])
  46
  47 dnl For AM_LC_MESSAGES
  48 sinclude([../config/lcmessage.m4])
  49
  50 dnl For AM_LANGINFO_CODESET.
  51 sinclude([../config/codeset.m4])
  52
  53 sinclude([../config/zlib.m4])
  54
  55 ## ----------------------------------------- ##
  56 ## ANSIfy the C compiler whenever possible.  ##
  57 ## From Franc,ois Pinard                     ##
  58 ## ----------------------------------------- ##
  59
  60 # Copyright (C) 1996-2013 Free Software Foundation, Inc.
  61
  62 # This program is free software; you can redistribute it and/or modify
  63 # it under the terms of the GNU General Public License as published by
  64 # the Free Software Foundation; either version 2, or (at your option)
  65 # any later version.
  66
  67 # This program is distributed in the hope that it will be useful,
  68 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  69 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  70 # GNU General Public License for more details.
  71
  72 # You should have received a copy of the GNU General Public License
  73 # along with this program; if not, see <http://www.gnu.org/licenses/>.
  74
  75 # serial 1
  76
  77 # @defmac AC_PROG_CC_STDC
  78 # @maindex PROG_CC_STDC
  79 # @ovindex CC
  80 # If the C compiler in not in ANSI C mode by default, try to add an option
  81 # to output variable @code{CC} to make it so.  This macro tries various
  82 # options that select ANSI C on some system or another.  It considers the
  83 # compiler to be in ANSI C mode if it handles function prototypes correctly.
  84 #
  85 # If you use this macro, you should check after calling it whether the C
  86 # compiler has been set to accept ANSI C; if not, the shell variable
  87 # @code{am_cv_prog_cc_stdc} is set to @samp{no}.  If you wrote your source
  88 # code in ANSI C, you can make an un-ANSIfied copy of it by using the
  89 # program @code{ansi2knr}, which comes with Ghostscript.
  90 # @end defmac
  91
  92 AC_DEFUN([AM_PROG_CC_STDC],
  93 [AC_REQUIRE([AC_PROG_CC])
  94 AC_BEFORE([$0], [AC_C_INLINE])
  95 AC_BEFORE([$0], [AC_C_CONST])
  96 dnl Force this before AC_PROG_CPP.  Some cpp's, eg on HPUX, require
  97 dnl a magic option to avoid problems with ANSI preprocessor commands
  98 dnl like #elif.
  99 dnl FIXME: can't do this because then AC_AIX won't work due to a
 100 dnl circular dependency.
 101 dnl AC_BEFORE([$0], [AC_PROG_CPP])
 102 AC_MSG_CHECKING([for ${CC-cc} option to accept ANSI C])
 103 AC_CACHE_VAL(am_cv_prog_cc_stdc,
 104 [am_cv_prog_cc_stdc=no
 105 ac_save_CC="$CC"
 106 # Don't try gcc -ansi; that turns off useful extensions and
 107 # breaks some systems' header files.
 108 # AIX                   -qlanglvl=ansi
 109 # Ultrix and OSF/1      -std1
 110 # HP-UX 10.20 and later -Ae
 111 # HP-UX older versions  -Aa -D_HPUX_SOURCE
 112 # SVR4                  -Xc -D__EXTENSIONS__
 113 for ac_arg in "" -qlanglvl=ansi -std1 -Ae "-Aa -D_HPUX_SOURCE" "-Xc -D__EXTENSIONS__"
 114 do
 115   CC="$ac_save_CC $ac_arg"
 116   AC_TRY_COMPILE(
 117 [#include <stdarg.h>
 118 #include <stdio.h>
 119 #include <sys/types.h>
 120 #include <sys/stat.h>
 121 /* Most of the following tests are stolen from RCS 5.7's src/conf.sh.  */
 122 struct buf { int x; };
 123 FILE * (*rcsopen) (struct buf *, struct stat *, int);
 124 static char *e (p, i)
 125      char **p;
 126      int i;
 127 {
 128   return p[i];
 129 }
 130 static char *f (char * (*g) (char **, int), char **p, ...)
 131 {
 132   char *s;
 133   va_list v;
 134   va_start (v,p);
 135   s = g (p, va_arg (v,int));
 136   va_end (v);
 137   return s;
 138 }
 139 int test (int i, double x);
 140 struct s1 {int (*f) (int a);};
 141 struct s2 {int (*f) (double a);};
 142 int pairnames (int, char **, FILE *(*)(struct buf *, struct stat *, int), int, int);
 143 int argc;
 144 char **argv;
 145 ], [
 146 return f (e, argv, 0) != argv[0]  ||  f (e, argv, 1) != argv[1];
 147 ],
 148 [am_cv_prog_cc_stdc="$ac_arg"; break])
 149 done
 150 CC="$ac_save_CC"
 151 ])
 152 if test -z "$am_cv_prog_cc_stdc"; then
 153   AC_MSG_RESULT([none needed])
 154 else
 155   AC_MSG_RESULT([$am_cv_prog_cc_stdc])
 156 fi
 157 case "x$am_cv_prog_cc_stdc" in
 158   x|xno) ;;
 159   *) CC="$CC $am_cv_prog_cc_stdc" ;;
 160 esac
 161 ])
 162
 163 dnl Originally from Bruno Haible, but with some modifications
 164 dnl for the GDB project.
 165
 166 AC_DEFUN([AM_ICONV],
 167 [
 168   dnl Some systems have iconv in libc, some have it in libiconv (OSF/1 and
 169   dnl those with the standalone portable GNU libiconv installed).
 170
 171   AC_ARG_WITH([libiconv-prefix],
 172     AS_HELP_STRING([--with-libiconv-prefix=DIR], [search for libiconv in DIR/include and DIR/lib]), [
 173     for dir in `echo "$withval" | tr : ' '`; do
 174       if test -d $dir/include; then LIBICONV_INCLUDE="-I$dir/include"; fi
 175       if test -d $dir/lib; then LIBICONV_LIBDIR="-L$dir/lib"; fi
 176     done
 177    ])
 178
 179   BUILD_LIBICONV_LIBDIRS="../libiconv/lib/.libs ../libiconv/lib/_libs"
 180   BUILD_LIBICONV_INCLUDE="-I../libiconv/include"
 181
 182   AC_CACHE_CHECK(for iconv, am_cv_func_iconv, [
 183     am_cv_func_iconv="no, consider installing GNU libiconv"
 184     am_cv_lib_iconv=no
 185     am_cv_use_build_libiconv=no
 186     am_cv_build_libiconv_path=
 187
 188     # If libiconv is part of the build tree, then try using it over
 189     # any system iconv.
 190     if test -d ../libiconv; then
 191       for lib_dir in $BUILD_LIBICONV_LIBDIRS; do
 192         am_save_LIBS="$LIBS"
 193         am_save_CPPFLAGS="$CPPFLAGS"
 194         LIBS="$LIBS $lib_dir/libiconv.a"
 195         CPPFLAGS="$CPPFLAGS $BUILD_LIBICONV_INCLUDE"
 196         AC_TRY_LINK([#include <stdlib.h>
 197 #include <iconv.h>],
 198           [iconv_t cd = iconv_open("","");
 199            iconv(cd,NULL,NULL,NULL,NULL);
 200            iconv_close(cd);],
 201           am_cv_use_build_libiconv=yes
 202           am_cv_build_libiconv_path=$lib_dir/libiconv.a
 203           am_cv_lib_iconv=yes
 204           am_cv_func_iconv=yes)
 205         LIBS="$am_save_LIBS"
 206         CPPFLAGS="$am_save_CPPFLAGS"
 207         if test "$am_cv_use_build_libiconv" = "yes"; then
 208           break
 209         fi
 210       done
 211     fi
 212
 213     # Next, try to find iconv in libc.
 214     if test "$am_cv_func_iconv" != yes; then
 215       AC_TRY_LINK([#include <stdlib.h>
 216 #include <iconv.h>],
 217         [iconv_t cd = iconv_open("","");
 218          iconv(cd,NULL,NULL,NULL,NULL);
 219          iconv_close(cd);],
 220         am_cv_func_iconv=yes)
 221     fi
 222
 223     # If iconv was not in libc, try -liconv.  In this case, arrange to
 224     # look in the libiconv prefix, if it was specified by the user.
 225     if test "$am_cv_func_iconv" != yes; then
 226       am_save_CPPFLAGS="$CPPFLAGS"
 227       am_save_LIBS="$LIBS"
 228       if test -n "$LIBICONV_INCLUDE"; then
 229         CPPFLAGS="$CPPFLAGS $LIBICONV_INCLUDE"
 230         LIBS="$LIBS $LIBICONV_LIBDIR"
 231       fi
 232       LIBS="$LIBS -liconv"
 233       AC_TRY_LINK([#include <stdlib.h>
 234 #include <iconv.h>],
 235         [iconv_t cd = iconv_open("","");
 236          iconv(cd,NULL,NULL,NULL,NULL);
 237          iconv_close(cd);],
 238         am_cv_lib_iconv=yes
 239         am_cv_func_iconv=yes)
 240       LIBS="$am_save_LIBS"
 241       CPPFLAGS="$am_save_CPPFLAGS"
 242     fi
 243   ])
 244
 245   # Set the various flags based on the cache variables.  We can't rely
 246   # on the flags to remain set from the above code, due to caching.
 247   LIBICONV=
 248   if test "$am_cv_lib_iconv" = yes; then
 249     LIBICONV="-liconv"
 250   else
 251     LIBICONV_LIBDIR=
 252     LIBICONV_INCLUDE=
 253   fi
 254   if test "$am_cv_use_build_libiconv" = yes; then
 255     LIBICONV="$am_cv_build_libiconv_path"
 256     LIBICONV_LIBDIR=""
 257     LIBICONV_INCLUDE="$BUILD_LIBICONV_INCLUDE"
 258   fi
 259   CPPFLAGS="$CPPFLAGS $LIBICONV_INCLUDE"
 260   LIBS="$LIBS $LIBICONV_LIBDIR $LIBICONV"
 261
 262   if test "$am_cv_func_iconv" = yes; then
 263     AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 264     AC_MSG_CHECKING([for iconv declaration])
 265     AC_CACHE_VAL(am_cv_proto_iconv, [
 266       AC_TRY_COMPILE([
 267 #include <stdlib.h>
 268 #include <iconv.h>
 269 extern
 270 #ifdef __cplusplus
 271 "C"
 272 #endif
 273 #if defined(__STDC__) || defined(__cplusplus)
 274 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 275 #else
 276 size_t iconv();
 277 #endif
 278 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
 279       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 280     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 281     AC_MSG_RESULT([$]{ac_t:-
 282          }[$]am_cv_proto_iconv)
 283     AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 284       [Define as const if the declaration of iconv() needs const.])
 285   fi
 286 ])
 287
 288 dnl written by Guido Draheim <guidod@gmx.de>, original by Alexandre Oliva
 289 dnl Version 1.3 (2001/03/02)
 290 dnl source http://www.gnu.org/software/ac-archive/Miscellaneous/ac_define_dir.html
 291
 292 AC_DEFUN([AC_DEFINE_DIR], [
 293   test "x$prefix" = xNONE && prefix="$ac_default_prefix"
 294   test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 295   ac_define_dir=`eval echo [$]$2`
 296   ac_define_dir=`eval echo [$]ac_define_dir`
 297   ifelse($3, ,
 298     AC_DEFINE_UNQUOTED($1, "$ac_define_dir"),
 299     AC_DEFINE_UNQUOTED($1, "$ac_define_dir", $3))
 300 ])
 301
 302 dnl See whether we need a declaration for a function.
 303 dnl The result is highly dependent on the INCLUDES passed in, so make sure
 304 dnl to use a different cache variable name in this macro if it is invoked
 305 dnl in a different context somewhere else.
 306 dnl gcc_AC_CHECK_DECL(SYMBOL,
 307 dnl     [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND [, INCLUDES]]])
 308 AC_DEFUN([gcc_AC_CHECK_DECL],
 309 [AC_MSG_CHECKING([whether $1 is declared])
 310 AC_CACHE_VAL(gcc_cv_have_decl_$1,
 311 [AC_TRY_COMPILE([$4],
 312 [#ifndef $1
 313 char *(*pfn) = (char *(*)) $1 ;
 314 #endif], eval "gcc_cv_have_decl_$1=yes", eval "gcc_cv_have_decl_$1=no")])
 315 if eval "test \"`echo '$gcc_cv_have_decl_'$1`\" = yes"; then
 316   AC_MSG_RESULT(yes) ; ifelse([$2], , :, [$2])
 317 else
 318   AC_MSG_RESULT(no) ; ifelse([$3], , :, [$3])
 319 fi
 320 ])dnl
 321
 322 dnl Check multiple functions to see whether each needs a declaration.
 323 dnl Arrange to define HAVE_DECL_<FUNCTION> to 0 or 1 as appropriate.
 324 dnl gcc_AC_CHECK_DECLS(SYMBOLS,
 325 dnl     [ACTION-IF-NEEDED [, ACTION-IF-NOT-NEEDED [, INCLUDES]]])
 326 AC_DEFUN([gcc_AC_CHECK_DECLS],
 327 [for ac_func in $1
 328 do
 329 changequote(, )dnl
 330   ac_tr_decl=HAVE_DECL_`echo $ac_func | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 331 changequote([, ])dnl
 332 gcc_AC_CHECK_DECL($ac_func,
 333   [AC_DEFINE_UNQUOTED($ac_tr_decl, 1) $2],
 334   [AC_DEFINE_UNQUOTED($ac_tr_decl, 0) $3],
 335 dnl It is possible that the include files passed in here are local headers
 336 dnl which supply a backup declaration for the relevant prototype based on
 337 dnl the definition of (or lack of) the HAVE_DECL_ macro.  If so, this test
 338 dnl will always return success.  E.g. see libiberty.h's handling of
 339 dnl `basename'.  To avoid this, we define the relevant HAVE_DECL_ macro to
 340 dnl 1 so that any local headers used do not provide their own prototype
 341 dnl during this test.
 342 #undef $ac_tr_decl
 343 #define $ac_tr_decl 1
 344   $4
 345 )
 346 done
 347 dnl Automatically generate config.h entries via autoheader.
 348 if test x = y ; then
 349   patsubst(translit([$1], [a-z], [A-Z]), [\w+],
 350     [AC_DEFINE([HAVE_DECL_\&], 1,
 351       [Define to 1 if we found this declaration otherwise define to 0.])])dnl
 352 fi
 353 ])
 354
 355 dnl Find the location of the private Tcl headers
 356 dnl When Tcl is installed, this is TCL_INCLUDE_SPEC/tcl-private/generic
 357 dnl When Tcl is in the build tree, this is not needed.
 358 dnl
 359 dnl Note: you must use first use SC_LOAD_TCLCONFIG!
 360 AC_DEFUN([CY_AC_TCL_PRIVATE_HEADERS], [
 361   AC_MSG_CHECKING([for Tcl private headers])
 362   private_dir=""
 363   dir=`echo ${TCL_INCLUDE_SPEC}/tcl-private/generic | sed -e s/-I//`
 364   if test -f ${dir}/tclInt.h ; then
 365     private_dir=${dir}
 366   fi
 367
 368   if test x"${private_dir}" = x; then
 369     AC_ERROR(could not find private Tcl headers)
 370   else
 371     TCL_PRIVATE_INCLUDE="-I${private_dir}"
 372     AC_MSG_RESULT(${private_dir})
 373   fi
 374 ])
 375
 376 dnl Find the location of the private Tk headers
 377 dnl When Tk is installed, this is TK_INCLUDE_SPEC/tk-private/generic
 378 dnl When Tk is in the build tree, this not needed.
 379 dnl
 380 dnl Note: you must first use SC_LOAD_TKCONFIG
 381 AC_DEFUN([CY_AC_TK_PRIVATE_HEADERS], [
 382   AC_MSG_CHECKING([for Tk private headers])
 383   private_dir=""
 384   dir=`echo ${TK_INCLUDE_SPEC}/tk-private/generic | sed -e s/-I//`
 385   if test -f ${dir}/tkInt.h; then
 386     private_dir=${dir}
 387   fi
 388
 389   if test x"${private_dir}" = x; then
 390     AC_ERROR(could not find Tk private headers)
 391   else
 392     TK_PRIVATE_INCLUDE="-I${private_dir}"
 393     AC_MSG_RESULT(${private_dir})
 394   fi
 395 ])
 396
 397 dnl GDB_AC_DEFINE_RELOCATABLE([VARIABLE], [ARG-NAME], [SHELL-VARIABLE])
 398 dnl For use in processing directory values for --with-foo.
 399 dnl If the path in SHELL_VARIABLE is relative to the prefix, then the
 400 dnl result is relocatable, then this will define the C macro
 401 dnl VARIABLE_RELOCATABLE to 1; otherwise it is defined as 0.
 402 AC_DEFUN([GDB_AC_DEFINE_RELOCATABLE], [
 403   if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
 404      if test "x$prefix" = xNONE; then
 405         test_prefix=/usr/local
 406      else
 407         test_prefix=$prefix
 408      fi
 409   else
 410      test_prefix=$exec_prefix
 411   fi
 412   value=0
 413   case [$3] in
 414      "${test_prefix}"|"${test_prefix}/"*|\
 415         '${exec_prefix}'|'${exec_prefix}/'*)
 416      value=1
 417      ;;
 418   esac
 419   AC_DEFINE_UNQUOTED([$1]_RELOCATABLE, $value, [Define if the $2 directory should be relocated when GDB is moved.])
 420 ])
 421
 422 dnl GDB_AC_WITH_DIR([VARIABLE], [ARG-NAME], [HELP], [DEFAULT])
 423 dnl Add a new --with option that defines a directory.
 424 dnl The result is stored in VARIABLE.  AC_DEFINE_DIR is called
 425 dnl on this variable, as is AC_SUBST.
 426 dnl ARG-NAME is the base name of the argument (without "--with").
 427 dnl HELP is the help text to use.
 428 dnl If the user's choice is relative to the prefix, then the
 429 dnl result is relocatable, then this will define the C macro
 430 dnl VARIABLE_RELOCATABLE to 1; otherwise it is defined as 0.
 431 dnl DEFAULT is the default value, which is used if the user
 432 dnl does not specify the argument.
 433 AC_DEFUN([GDB_AC_WITH_DIR], [
 434   AC_ARG_WITH([$2], AS_HELP_STRING([--with-][$2][=PATH], [$3]), [
 435     [$1]=$withval], [[$1]=[$4]])
 436   AC_DEFINE_DIR([$1], [$1], [$3])
 437   AC_SUBST([$1])
 438   GDB_AC_DEFINE_RELOCATABLE([$1], [$2], ${ac_define_dir})
 439   ])
 440
 441 dnl GDB_AC_CHECK_BFD([MESSAGE], [CV], [CODE], [HEADER])
 442 dnl Check whether BFD provides a feature.
 443 dnl MESSAGE is the "checking" message to display.
 444 dnl CV is the name of the cache variable where the result is stored.
 445 dnl The result will be "yes" or "no".
 446 dnl CODE is some code to compile that checks for the feature.
 447 dnl A link test is run.
 448 dnl HEADER is the name of an extra BFD header to include.
 449 AC_DEFUN([GDB_AC_CHECK_BFD], [
 450   OLD_CFLAGS=$CFLAGS
 451   OLD_LDFLAGS=$LDFLAGS
 452   OLD_LIBS=$LIBS
 453   # Put the old CFLAGS/LDFLAGS last, in case the user's (C|LD)FLAGS
 454   # points somewhere with bfd, with -I/foo/lib and -L/foo/lib.  We
 455   # always want our bfd.
 456   CFLAGS="-I${srcdir}/../include -I../bfd -I${srcdir}/../bfd $CFLAGS"
 457   LDFLAGS="-L../bfd -L../libiberty $LDFLAGS"
 458   intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
 459   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
 460   if test "$plugins" = "yes"; then
 461     AC_SEARCH_LIBS(dlopen, dl)
 462   fi
 463   LIBS="-lbfd -liberty $intl $LIBS"
 464   AC_CACHE_CHECK([$1], [$2],
 465   [AC_TRY_LINK(
 466   [#include <stdlib.h>
 467   #include "bfd.h"
 468   #include "$4"
 469   ],
 470   [return $3;], [[$2]=yes], [[$2]=no])])
 471   CFLAGS=$OLD_CFLAGS
 472   LDFLAGS=$OLD_LDFLAGS
 473   LIBS=$OLD_LIBS])