gdb/acinclude.m4

   1 dnl written by Rob Savoye <rob@cygnus.com> for Cygnus Support
   2 dnl major rewriting for Tcl 7.5 by Don Libes <libes@nist.gov>
   3
   4 dnl gdb/configure.in uses BFD_NEED_DECLARATION, so get its definition.
   5 sinclude(../bfd/bfd.m4)
   6
   7 dnl This gets the standard macros
   8 sinclude(../config/acinclude.m4)
   9
  10 dnl This gets autoconf bugfixes
  11 sinclude(../config/override.m4)
  12
  13 sinclude(../config/gettext-sister.m4)
  14
  15 dnl For AC_LIB_HAVE_LINKFLAGS.
  16 sinclude(../config/lib-ld.m4)
  17 sinclude(../config/lib-prefix.m4)
  18 sinclude(../config/lib-link.m4)
  19
  20 dnl For ACX_PKGVERSION and ACX_BUGURL.
  21 sinclude(../config/acx.m4)
  22
  23 dnl for TCL definitions
  24 sinclude(../config/tcl.m4)
  25
  26 dnl For dependency tracking macros.
  27 sinclude([../config/depstand.m4])
  28
  29 dnl For AM_LC_MESSAGES
  30 sinclude([../config/lcmessage.m4])
  31
  32 #
  33 # Sometimes the native compiler is a bogus stub for gcc or /usr/ucb/cc. This
  34 # makes configure think it's cross compiling. If --target wasn't used, then
  35 # we can't configure, so something is wrong. We don't use the cache
  36 # here cause if somebody fixes their compiler install, we want this to work.
  37 AC_DEFUN([CY_AC_C_WORKS],
  38 [# If we cannot compile and link a trivial program, we can't expect anything to work
  39 AC_MSG_CHECKING(whether the compiler ($CC) actually works)
  40 AC_TRY_COMPILE(, [/* don't need anything here */],
  41         c_compiles=yes, c_compiles=no)
  42
  43 AC_TRY_LINK(, [/* don't need anything here */],
  44         c_links=yes, c_links=no)
  45
  46 if test x"${c_compiles}" = x"no" ; then
  47   AC_MSG_ERROR(the native compiler is broken and won't compile.)
  48 fi
  49
  50 if test x"${c_links}" = x"no" ; then
  51   AC_MSG_ERROR(the native compiler is broken and won't link.)
  52 fi
  53 AC_MSG_RESULT(yes)
  54 ])
  55
  56 ## ----------------------------------------- ##
  57 ## ANSIfy the C compiler whenever possible.  ##
  58 ## From Franc,ois Pinard                     ##
  59 ## ----------------------------------------- ##
  60
  61 # Copyright (C) 1996, 1997, 1999, 2000, 2001, 2008, 2009
  62   Free Software Foundation, Inc.
  63
  64 # This program is free software; you can redistribute it and/or modify
  65 # it under the terms of the GNU General Public License as published by
  66 # the Free Software Foundation; either version 2, or (at your option)
  67 # any later version.
  68
  69 # This program is distributed in the hope that it will be useful,
  70 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  71 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  72 # GNU General Public License for more details.
  73
  74 # You should have received a copy of the GNU General Public License
  75 # along with this program; if not, write to the Free Software
  76 # Foundation, Inc., 51 Franklin Street, Fifth Floor,
  77 # Boston, MA 02110-1301, USA.
  78
  79 # serial 1
  80
  81 # @defmac AC_PROG_CC_STDC
  82 # @maindex PROG_CC_STDC
  83 # @ovindex CC
  84 # If the C compiler in not in ANSI C mode by default, try to add an option
  85 # to output variable @code{CC} to make it so.  This macro tries various
  86 # options that select ANSI C on some system or another.  It considers the
  87 # compiler to be in ANSI C mode if it handles function prototypes correctly.
  88 #
  89 # If you use this macro, you should check after calling it whether the C
  90 # compiler has been set to accept ANSI C; if not, the shell variable
  91 # @code{am_cv_prog_cc_stdc} is set to @samp{no}.  If you wrote your source
  92 # code in ANSI C, you can make an un-ANSIfied copy of it by using the
  93 # program @code{ansi2knr}, which comes with Ghostscript.
  94 # @end defmac
  95
  96 AC_DEFUN([AM_PROG_CC_STDC],
  97 [AC_REQUIRE([AC_PROG_CC])
  98 AC_BEFORE([$0], [AC_C_INLINE])
  99 AC_BEFORE([$0], [AC_C_CONST])
 100 dnl Force this before AC_PROG_CPP.  Some cpp's, eg on HPUX, require
 101 dnl a magic option to avoid problems with ANSI preprocessor commands
 102 dnl like #elif.
 103 dnl FIXME: can't do this because then AC_AIX won't work due to a
 104 dnl circular dependency.
 105 dnl AC_BEFORE([$0], [AC_PROG_CPP])
 106 AC_MSG_CHECKING([for ${CC-cc} option to accept ANSI C])
 107 AC_CACHE_VAL(am_cv_prog_cc_stdc,
 108 [am_cv_prog_cc_stdc=no
 109 ac_save_CC="$CC"
 110 # Don't try gcc -ansi; that turns off useful extensions and
 111 # breaks some systems' header files.
 112 # AIX                   -qlanglvl=ansi
 113 # Ultrix and OSF/1      -std1
 114 # HP-UX 10.20 and later -Ae
 115 # HP-UX older versions  -Aa -D_HPUX_SOURCE
 116 # SVR4                  -Xc -D__EXTENSIONS__
 117 for ac_arg in "" -qlanglvl=ansi -std1 -Ae "-Aa -D_HPUX_SOURCE" "-Xc -D__EXTENSIONS__"
 118 do
 119   CC="$ac_save_CC $ac_arg"
 120   AC_TRY_COMPILE(
 121 [#include <stdarg.h>
 122 #include <stdio.h>
 123 #include <sys/types.h>
 124 #include <sys/stat.h>
 125 /* Most of the following tests are stolen from RCS 5.7's src/conf.sh.  */
 126 struct buf { int x; };
 127 FILE * (*rcsopen) (struct buf *, struct stat *, int);
 128 static char *e (p, i)
 129      char **p;
 130      int i;
 131 {
 132   return p[i];
 133 }
 134 static char *f (char * (*g) (char **, int), char **p, ...)
 135 {
 136   char *s;
 137   va_list v;
 138   va_start (v,p);
 139   s = g (p, va_arg (v,int));
 140   va_end (v);
 141   return s;
 142 }
 143 int test (int i, double x);
 144 struct s1 {int (*f) (int a);};
 145 struct s2 {int (*f) (double a);};
 146 int pairnames (int, char **, FILE *(*)(struct buf *, struct stat *, int), int, int);
 147 int argc;
 148 char **argv;
 149 ], [
 150 return f (e, argv, 0) != argv[0]  ||  f (e, argv, 1) != argv[1];
 151 ],
 152 [am_cv_prog_cc_stdc="$ac_arg"; break])
 153 done
 154 CC="$ac_save_CC"
 155 ])
 156 if test -z "$am_cv_prog_cc_stdc"; then
 157   AC_MSG_RESULT([none needed])
 158 else
 159   AC_MSG_RESULT([$am_cv_prog_cc_stdc])
 160 fi
 161 case "x$am_cv_prog_cc_stdc" in
 162   x|xno) ;;
 163   *) CC="$CC $am_cv_prog_cc_stdc" ;;
 164 esac
 165 ])
 166
 167 dnl From Bruno Haible.
 168
 169 AC_DEFUN([AM_ICONV],
 170 [
 171   dnl Some systems have iconv in libc, some have it in libiconv (OSF/1 and
 172   dnl those with the standalone portable GNU libiconv installed).
 173
 174   AC_ARG_WITH([libiconv-prefix],
 175 [  --with-libiconv-prefix=DIR  search for libiconv in DIR/include and DIR/lib], [
 176     for dir in `echo "$withval" | tr : ' '`; do
 177       if test -d $dir/include; then CPPFLAGS="$CPPFLAGS -I$dir/include"; fi
 178       if test -d $dir/lib; then LDFLAGS="$LDFLAGS -L$dir/lib"; fi
 179     done
 180    ])
 181
 182   AC_CACHE_CHECK(for iconv, am_cv_func_iconv, [
 183     am_cv_func_iconv="no, consider installing GNU libiconv"
 184     am_cv_lib_iconv=no
 185     AC_TRY_LINK([#include <stdlib.h>
 186 #include <iconv.h>],
 187       [iconv_t cd = iconv_open("","");
 188        iconv(cd,NULL,NULL,NULL,NULL);
 189        iconv_close(cd);],
 190       am_cv_func_iconv=yes)
 191     if test "$am_cv_func_iconv" != yes; then
 192       am_save_LIBS="$LIBS"
 193       LIBS="$LIBS -liconv"
 194       AC_TRY_LINK([#include <stdlib.h>
 195 #include <iconv.h>],
 196         [iconv_t cd = iconv_open("","");
 197          iconv(cd,NULL,NULL,NULL,NULL);
 198          iconv_close(cd);],
 199         am_cv_lib_iconv=yes
 200         am_cv_func_iconv=yes)
 201       LIBS="$am_save_LIBS"
 202     fi
 203   ])
 204   if test "$am_cv_func_iconv" = yes; then
 205     AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 206     AC_MSG_CHECKING([for iconv declaration])
 207     AC_CACHE_VAL(am_cv_proto_iconv, [
 208       AC_TRY_COMPILE([
 209 #include <stdlib.h>
 210 #include <iconv.h>
 211 extern
 212 #ifdef __cplusplus
 213 "C"
 214 #endif
 215 #if defined(__STDC__) || defined(__cplusplus)
 216 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 217 #else
 218 size_t iconv();
 219 #endif
 220 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
 221       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 222     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 223     AC_MSG_RESULT([$]{ac_t:-
 224          }[$]am_cv_proto_iconv)
 225     AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 226       [Define as const if the declaration of iconv() needs const.])
 227   fi
 228   LIBICONV=
 229   if test "$am_cv_lib_iconv" = yes; then
 230     LIBICONV="-liconv"
 231   fi
 232   AC_SUBST(LIBICONV)
 233 ])
 234
 235 dnl written by Guido Draheim <guidod@gmx.de>, original by Alexandre Oliva
 236 dnl Version 1.3 (2001/03/02)
 237 dnl source http://www.gnu.org/software/ac-archive/Miscellaneous/ac_define_dir.html
 238
 239 AC_DEFUN([AC_DEFINE_DIR], [
 240   test "x$prefix" = xNONE && prefix="$ac_default_prefix"
 241   test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 242   ac_define_dir=`eval echo [$]$2`
 243   ac_define_dir=`eval echo [$]ac_define_dir`
 244   ifelse($3, ,
 245     AC_DEFINE_UNQUOTED($1, "$ac_define_dir"),
 246     AC_DEFINE_UNQUOTED($1, "$ac_define_dir", $3))
 247 ])
 248
 249 dnl See whether we need a declaration for a function.
 250 dnl The result is highly dependent on the INCLUDES passed in, so make sure
 251 dnl to use a different cache variable name in this macro if it is invoked
 252 dnl in a different context somewhere else.
 253 dnl gcc_AC_CHECK_DECL(SYMBOL,
 254 dnl     [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND [, INCLUDES]]])
 255 AC_DEFUN([gcc_AC_CHECK_DECL],
 256 [AC_MSG_CHECKING([whether $1 is declared])
 257 AC_CACHE_VAL(gcc_cv_have_decl_$1,
 258 [AC_TRY_COMPILE([$4],
 259 [#ifndef $1
 260 char *(*pfn) = (char *(*)) $1 ;
 261 #endif], eval "gcc_cv_have_decl_$1=yes", eval "gcc_cv_have_decl_$1=no")])
 262 if eval "test \"`echo '$gcc_cv_have_decl_'$1`\" = yes"; then
 263   AC_MSG_RESULT(yes) ; ifelse([$2], , :, [$2])
 264 else
 265   AC_MSG_RESULT(no) ; ifelse([$3], , :, [$3])
 266 fi
 267 ])dnl
 268
 269 dnl Check multiple functions to see whether each needs a declaration.
 270 dnl Arrange to define HAVE_DECL_<FUNCTION> to 0 or 1 as appropriate.
 271 dnl gcc_AC_CHECK_DECLS(SYMBOLS,
 272 dnl     [ACTION-IF-NEEDED [, ACTION-IF-NOT-NEEDED [, INCLUDES]]])
 273 AC_DEFUN([gcc_AC_CHECK_DECLS],
 274 [for ac_func in $1
 275 do
 276 changequote(, )dnl
 277   ac_tr_decl=HAVE_DECL_`echo $ac_func | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 278 changequote([, ])dnl
 279 gcc_AC_CHECK_DECL($ac_func,
 280   [AC_DEFINE_UNQUOTED($ac_tr_decl, 1) $2],
 281   [AC_DEFINE_UNQUOTED($ac_tr_decl, 0) $3],
 282 dnl It is possible that the include files passed in here are local headers
 283 dnl which supply a backup declaration for the relevant prototype based on
 284 dnl the definition of (or lack of) the HAVE_DECL_ macro.  If so, this test
 285 dnl will always return success.  E.g. see libiberty.h's handling of
 286 dnl `basename'.  To avoid this, we define the relevant HAVE_DECL_ macro to
 287 dnl 1 so that any local headers used do not provide their own prototype
 288 dnl during this test.
 289 #undef $ac_tr_decl
 290 #define $ac_tr_decl 1
 291   $4
 292 )
 293 done
 294 dnl Automatically generate config.h entries via autoheader.
 295 if test x = y ; then
 296   patsubst(translit([$1], [a-z], [A-Z]), [\w+],
 297     [AC_DEFINE([HAVE_DECL_\&], 1,
 298       [Define to 1 if we found this declaration otherwise define to 0.])])dnl
 299 fi
 300 ])
 301
 302 dnl Find the location of the private Tcl headers
 303 dnl When Tcl is installed, this is TCL_INCLUDE_SPEC/tcl-private/generic
 304 dnl When Tcl is in the build tree, this is not needed.
 305 dnl
 306 dnl Note: you must use first use SC_LOAD_TCLCONFIG!
 307 AC_DEFUN([CY_AC_TCL_PRIVATE_HEADERS], [
 308   AC_MSG_CHECKING([for Tcl private headers])
 309   private_dir=""
 310   dir=`echo ${TCL_INCLUDE_SPEC}/tcl-private/generic | sed -e s/-I//`
 311   if test -f ${dir}/tclInt.h ; then
 312     private_dir=${dir}
 313   fi
 314
 315   if test x"${private_dir}" = x; then
 316     AC_ERROR(could not find private Tcl headers)
 317   else
 318     TCL_PRIVATE_INCLUDE="-I${private_dir}"
 319     AC_MSG_RESULT(${private_dir})
 320   fi
 321 ])
 322
 323 dnl Find the location of the private Tk headers
 324 dnl When Tk is installed, this is TK_INCLUDE_SPEC/tk-private/generic
 325 dnl When Tk is in the build tree, this not needed.
 326 dnl
 327 dnl Note: you must first use SC_LOAD_TKCONFIG
 328 AC_DEFUN([CY_AC_TK_PRIVATE_HEADERS], [
 329   AC_MSG_CHECKING([for Tk private headers])
 330   private_dir=""
 331   dir=`echo ${TK_INCLUDE_SPEC}/tk-private/generic | sed -e s/-I//`
 332   if test -f ${dir}/tkInt.h; then
 333     private_dir=${dir}
 334   fi
 335
 336   if test x"${private_dir}" = x; then
 337     AC_ERROR(could not find Tk private headers)
 338   else
 339     TK_PRIVATE_INCLUDE="-I${private_dir}"
 340     AC_MSG_RESULT(${private_dir})
 341   fi
 342 ])