gcc/configure.in

   1 # configure.in for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  22 #02111-1307, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.13)
  29 AC_INIT(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 # Determine the host, build, and target systems
  33 AC_CANONICAL_SYSTEM
  34
  35 # Determine the target- and build-specific subdirectories
  36 GCC_TOPLEV_SUBDIRS
  37
  38 # Set program_transform_name
  39 AC_ARG_PROGRAM
  40
  41 # Check for bogus environment variables.
  42 # Test if LIBRARY_PATH contains the notation for the current directory
  43 # since this would lead to problems installing/building glibc.
  44 # LIBRARY_PATH contains the current directory if one of the following
  45 # is true:
  46 # - one of the terminals (":" and ";") is the first or last sign
  47 # - two terminals occur directly after each other
  48 # - the path contains an element with a dot in it
  49 AC_MSG_CHECKING(LIBRARY_PATH variable)
  50 changequote(,)dnl
  51 case ${LIBRARY_PATH} in
  52   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  53     library_path_setting="contains current directory"
  54     ;;
  55   *)
  56     library_path_setting="ok"
  57     ;;
  58 esac
  59 changequote([,])dnl
  60 AC_MSG_RESULT($library_path_setting)
  61 if test "$library_path_setting" != "ok"; then
  62 AC_MSG_ERROR([
  63 *** LIBRARY_PATH shouldn't contain the current directory when
  64 *** building gcc. Please change the environment variable
  65 *** and run configure again.])
  66 fi
  67
  68 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  69 # since this would lead to problems installing/building glibc.
  70 # GCC_EXEC_PREFIX contains the current directory if one of the following
  71 # is true:
  72 # - one of the terminals (":" and ";") is the first or last sign
  73 # - two terminals occur directly after each other
  74 # - the path contains an element with a dot in it
  75 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  76 changequote(,)dnl
  77 case ${GCC_EXEC_PREFIX} in
  78   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  79     gcc_exec_prefix_setting="contains current directory"
  80     ;;
  81   *)
  82     gcc_exec_prefix_setting="ok"
  83     ;;
  84 esac
  85 changequote([,])dnl
  86 AC_MSG_RESULT($gcc_exec_prefix_setting)
  87 if test "$gcc_exec_prefix_setting" != "ok"; then
  88 AC_MSG_ERROR([
  89 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  90 *** building gcc. Please change the environment variable
  91 *** and run configure again.])
  92 fi
  93
  94 # -----------
  95 # Directories
  96 # -----------
  97
  98 # Specify the local prefix
  99 local_prefix=
 100 AC_ARG_WITH(local-prefix,
 101 [  --with-local-prefix=DIR specifies directory to put local include],
 102 [case "${withval}" in
 103 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 104 no)     ;;
 105 *)      local_prefix=$with_local_prefix ;;
 106 esac])
 107
 108 # Default local prefix if it is empty
 109 if test x$local_prefix = x; then
 110         local_prefix=/usr/local
 111 fi
 112
 113 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 114 # passed in by the toplevel make and thus we'd get different behavior
 115 # depending on where we built the sources.
 116 gcc_gxx_include_dir=
 117 # Specify the g++ header file directory
 118 AC_ARG_WITH(gxx-include-dir,
 119 [  --with-gxx-include-dir=DIR
 120                           specifies directory to put g++ header files],
 121 [case "${withval}" in
 122 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 123 no)     ;;
 124 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 125 esac])
 126
 127 if test x${gcc_gxx_include_dir} = x; then
 128   if test x${enable_version_specific_runtime_libs} = xyes; then
 129     gcc_gxx_include_dir='${libsubdir}/include/c++'
 130   else
 131     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 132 changequote(<<, >>)dnl
 133     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 134 changequote([, ])dnl
 135   fi
 136 fi
 137
 138 AC_ARG_WITH(cpp_install_dir,
 139 [  --with-cpp-install-dir=DIR
 140                           install the user visible C preprocessor in DIR
 141                           (relative to PREFIX) as well as PREFIX/bin],
 142 [if test x$withval = xyes; then
 143   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 144 elif test x$withval != xno; then
 145   cpp_install_dir=$withval
 146 fi])
 147
 148 # -------------------
 149 # Find default linker
 150 # -------------------
 151
 152 # With GNU ld
 153 AC_ARG_WITH(gnu-ld,
 154 [  --with-gnu-ld           arrange to work with GNU ld.],
 155 gnu_ld_flag="$with_gnu_ld",
 156 gnu_ld_flag=no)
 157
 158 # With pre-defined ld
 159 AC_ARG_WITH(ld,
 160 [  --with-ld               arrange to use the specified ld (full pathname)],
 161 DEFAULT_LINKER="$with_ld")
 162 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 163   if test ! -x "$DEFAULT_LINKER"; then
 164     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 165   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 166     gnu_ld_flag=yes
 167   fi
 168   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 169         [Define to enable the use of a default linker.])
 170 fi
 171
 172 AC_MSG_CHECKING([whether a default linker was specified])
 173 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 174   if test x"$gnu_ld_flag" = x"no"; then
 175     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 176   else
 177     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 178   fi
 179 else
 180   AC_MSG_RESULT(no)
 181 fi
 182
 183 # ----------------------
 184 # Find default assembler
 185 # ----------------------
 186
 187 # With GNU as
 188 AC_ARG_WITH(gnu-as,
 189 [  --with-gnu-as           arrange to work with GNU as],
 190 gas_flag="$with_gnu_as",
 191 gas_flag=no)
 192
 193 AC_ARG_WITH(as,
 194 [  --with-as               arrange to use the specified as (full pathname)],
 195 DEFAULT_ASSEMBLER="$with_as")
 196 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_ASSEMBLER"; then
 198     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 199   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gas_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 203         [Define to enable the use of a default assembler.])
 204 fi
 205
 206 AC_MSG_CHECKING([whether a default assembler was specified])
 207 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 208   if test x"$gas_flag" = x"no"; then
 209     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 210   else
 211     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 212   fi
 213 else
 214   AC_MSG_RESULT(no)
 215 fi
 216
 217 # ---------------
 218 # Find C compiler
 219 # ---------------
 220
 221 # Find the native compiler
 222 AC_PROG_CC
 223 AC_PROG_CC_C_O
 224 # autoconf is lame and doesn't give us any substitution variable for this.
 225 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 226   NO_MINUS_C_MINUS_O=yes
 227 else
 228   OUTPUT_OPTION='-o $@'
 229 fi
 230 AC_SUBST(NO_MINUS_C_MINUS_O)
 231 AC_SUBST(OUTPUT_OPTION)
 232
 233 # -------------------------
 234 # Check C compiler features
 235 # -------------------------
 236
 237 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
 238 ac_cv_prog_cc_no_long_long,
 239 [save_CFLAGS="$CFLAGS"
 240 CFLAGS="-Wno-long-long"
 241 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
 242                ac_cv_prog_cc_no_long_long=no)
 243 CFLAGS="$save_CFLAGS"])
 244
 245 AC_PROG_CPP
 246 AC_C_INLINE
 247
 248 gcc_AC_C_LONG_LONG
 249 gcc_AC_C__BOOL
 250
 251 # sizeof(char) is 1 by definition.
 252 AC_COMPILE_CHECK_SIZEOF(void *)
 253 AC_COMPILE_CHECK_SIZEOF(short)
 254 AC_COMPILE_CHECK_SIZEOF(int)
 255 AC_COMPILE_CHECK_SIZEOF(long)
 256 if test $ac_cv_c_long_long = yes; then
 257   AC_COMPILE_CHECK_SIZEOF(long long)
 258 fi
 259 if test $ac_cv_c___int64 = yes; then
 260   AC_COMPILE_CHECK_SIZEOF(__int64)
 261 fi
 262
 263 # -----------------
 264 # Find Ada compiler
 265 # -----------------
 266
 267 # See if GNAT has been installed
 268 gcc_AC_PROG_GNAT
 269
 270 if test x$have_gnat != xno ; then
 271 AC_CACHE_CHECK(whether ${ADAC} accepts -Wno-long-long,
 272 ac_cv_prog_adac_no_long_long,
 273 [cat >conftest.adb <<EOF
 274 procedure conftest is begin null; end conftest;
 275 EOF
 276 if $ADAC -Wno-long-long -c conftest.adb 1>&5 2>&5 ; then
 277   ac_cv_prog_adac_no_long_long=yes
 278 else
 279   ac_cv_prog_adac_no_long_long=no
 280 fi
 281 rm -f conftest*])
 282 else
 283   ac_cv_prog_adac_no_long_long=yes
 284 fi
 285
 286 # ---------------------
 287 # Warnings and checking
 288 # ---------------------
 289
 290 strict1_warn=
 291 if test $ac_cv_prog_cc_no_long_long = yes && \
 292     test $ac_cv_prog_adac_no_long_long = yes ; then
 293   strict1_warn="-pedantic -Wno-long-long"
 294 fi
 295 AC_SUBST(strict1_warn)
 296
 297 # If the native compiler is GCC, we can enable warnings even in stage1.
 298 # That's useful for people building cross-compilers, or just running a
 299 # quick `make'.
 300 warn_cflags=
 301 if test "x$GCC" = "xyes"; then
 302   warn_cflags='$(GCC_WARN_CFLAGS)'
 303 fi
 304 AC_SUBST(warn_cflags)
 305
 306 # Enable -Werror in bootstrap stage2 and later.
 307 # Change the default to "no" on release branches.
 308 AC_ARG_ENABLE(werror,
 309 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 310 [enable_werror=yes])
 311 if test x$enable_werror = xyes ; then
 312   WERROR=-Werror
 313 fi
 314 AC_SUBST(WERROR)
 315
 316 # Enable expensive internal checks
 317 AC_ARG_ENABLE(checking,
 318 [  --enable-checking[=LIST]
 319                           enable expensive run-time checks.  With LIST,
 320                           enable only specific categories of checks.
 321                           Categories are: misc,tree,rtl,rtlflag,gc,gcac;
 322                           default is misc,tree,gc,rtlflag],
 323 [ac_checking=
 324 ac_tree_checking=
 325 ac_rtl_checking=
 326 ac_rtlflag_checking=
 327 ac_gc_checking=
 328 ac_gc_always_collect=
 329 case "${enableval}" in
 330 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;
 331         ac_rtlflag_checking=1 ;;
 332 no)     ;;
 333 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 334         set fnord $enableval; shift
 335         IFS="$ac_save_IFS"
 336         for check
 337         do
 338                 case $check in
 339                 misc)   ac_checking=1 ;;
 340                 tree)   ac_tree_checking=1 ;;
 341                 rtlflag)        ac_rtlflag_checking=1 ;;
 342                 rtl)    ac_rtl_checking=1 ;;
 343                 gc)     ac_gc_checking=1 ;;
 344                 gcac)   ac_gc_always_collect=1 ;;
 345                 valgrind)       ac_checking_valgrind=1 ;;
 346                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 347                 esac
 348         done
 349         ;;
 350 esac
 351 ],
 352 # Enable some checks by default for development versions of GCC
 353 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1; ac_rtlflag_checking=1;])
 354 nocommon_flag=""
 355 if test x$ac_checking != x ; then
 356   AC_DEFINE(ENABLE_CHECKING, 1,
 357 [Define if you want more run-time sanity checks.  This one gets a grab
 358    bag of miscellaneous but relatively cheap checks.])
 359   nocommon_flag=-fno-common
 360 fi
 361 AC_SUBST(nocommon_flag)
 362 if test x$ac_tree_checking != x ; then
 363   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 364 [Define if you want all operations on trees (the basic data
 365    structure of the front ends) to be checked for dynamic type safety
 366    at runtime.  This is moderately expensive.])
 367 fi
 368 if test x$ac_rtl_checking != x ; then
 369   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 370 [Define if you want all operations on RTL (the basic data structure
 371    of the optimizer and back end) to be checked for dynamic type safety
 372    at runtime.  This is quite expensive.])
 373 fi
 374 if test x$ac_rtlflag_checking != x ; then
 375   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 376 [Define if you want RTL flag accesses to be checked against the RTL
 377    codes that are supported for each access macro.  This is relatively
 378    cheap.])
 379 fi
 380 if test x$ac_gc_checking != x ; then
 381   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 382 [Define if you want the garbage collector to do object poisoning and
 383    other memory allocation checks.  This is quite expensive.])
 384 fi
 385 if test x$ac_gc_always_collect != x ; then
 386   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 387 [Define if you want the garbage collector to operate in maximally
 388    paranoid mode, validating the entire heap and collecting garbage at
 389    every opportunity.  This is extremely expensive.])
 390 fi
 391 valgrind_path_defines=
 392 valgrind_command=
 393 if test x$ac_checking_valgrind != x ; then
 394   # It is certainly possible that there's valgrind but no valgrind.h.
 395   # GCC relies on making annotations so we must have both.
 396   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 397   AC_TRY_CPP(
 398     [#include <memcheck.h>
 399 #ifndef VALGRIND_DISCARD
 400 #error VALGRIND_DISCARD not defined
 401 #endif],
 402   [gcc_cv_header_memcheck_h=yes],
 403   gcc_cv_header_memcheck_h=no)
 404   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 405   AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 406   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 407         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 408   if test "x$valgrind_path" = "x" || (test $have_valgrind_h = no && test $gcc_cv_header_memcheck_h = no); then
 409         AC_MSG_ERROR([*** Can't find both valgrind and valgrind.h/memcheck.h])
 410   fi
 411   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 412   valgrind_command="$valgrind_path -q"
 413   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 414 [Define if you want to run subprograms and generated programs
 415    through valgrind (a memory checker).  This is extremely expensive.])
 416   if test $gcc_cv_header_memcheck_h = yes; then
 417     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 418         [Define if valgrind's memcheck.h header is installed.])
 419   fi
 420 fi
 421 AC_SUBST(valgrind_path_defines)
 422 AC_SUBST(valgrind_command)
 423
 424 # Enable code coverage collection
 425 AC_ARG_ENABLE(coverage,
 426 [  --enable-coverage[=LEVEL]
 427                           enable compiler\'s code coverage collection.
 428                           Use to measure compiler performance and locate
 429                           unused parts of the compiler. With LEVEL, specify
 430                           optimization. Values are opt, noopt,
 431                           default is noopt],
 432 [case "${enableval}" in
 433 yes|noopt)
 434         coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 435         ;;
 436 opt)
 437         coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 438         ;;
 439 *)
 440         AC_MSG_ERROR(unknown coverage setting $enableval)
 441         ;;
 442 esac],
 443 [coverage_flags=""])
 444 AC_SUBST(coverage_flags)
 445
 446 # -------------------------------
 447 # Miscenalleous configure options
 448 # -------------------------------
 449
 450 # With stabs
 451 AC_ARG_WITH(stabs,
 452 [  --with-stabs            arrange to use stabs instead of host debug format],
 453 stabs="$with_stabs",
 454 stabs=no)
 455
 456 # With ELF
 457 AC_ARG_WITH(elf,
 458 [  --with-elf              arrange to use ELF instead of host debug format],
 459 elf="$with_elf",
 460 elf=no)
 461
 462 # Determine whether or not multilibs are enabled.
 463 AC_ARG_ENABLE(multilib,
 464 [  --enable-multilib       enable library support for multiple ABIs],
 465 [], [enable_multilib=yes])
 466 AC_SUBST(enable_multilib)
 467
 468 # Enable __cxa_atexit for C++.
 469 AC_ARG_ENABLE(__cxa_atexit,
 470 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 471 [], [])
 472
 473 # Enable threads
 474 # Pass with no value to take the default
 475 # Pass with a value to specify a thread package
 476 AC_ARG_ENABLE(threads,
 477 [  --enable-threads        enable thread usage for target GCC
 478   --enable-threads=LIB    use LIB thread package for target GCC],,
 479 enable_threads='')
 480
 481 enable_threads_flag=$enable_threads
 482 # Check if a valid thread package
 483 case x${enable_threads_flag} in
 484         x | xno)
 485                 # No threads
 486                 target_thread_file='single'
 487                 ;;
 488         xyes)
 489                 # default
 490                 target_thread_file=''
 491                 ;;
 492         xdecosf1 | xirix | xmach | xos2 | xposix | xpthreads | xsingle | \
 493         xsolaris | xwin32 | xdce | xrtems| xvxworks | xaix | xgnat)
 494                 target_thread_file=$enable_threads_flag
 495                 ;;
 496         *)
 497                 echo "$enable_threads is an unknown thread package" 1>&2
 498                 exit 1
 499                 ;;
 500 esac
 501
 502 AC_ARG_ENABLE(objc-gc,
 503 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 504                           the GNU Objective-C runtime],
 505 if test x$enable_objc_gc = xno; then
 506         objc_boehm_gc=''
 507 else
 508         objc_boehm_gc=1
 509 fi,
 510 objc_boehm_gc='')
 511
 512 AC_ARG_WITH(dwarf2,
 513 [  --with-dwarf2           force the default debug format to be DWARF 2],
 514 dwarf2="$with_dwarf2",
 515 dwarf2=no)
 516
 517 AC_ARG_ENABLE(shared,
 518 [  --disable-shared        don't provide a shared libgcc],
 519 [
 520   case $enable_shared in
 521   yes | no) ;;
 522   *)
 523     enable_shared=no
 524     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 525     for pkg in $enableval; do
 526       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 527         enable_shared=yes
 528       fi
 529     done
 530     IFS="$ac_save_ifs"
 531     ;;
 532   esac
 533 ], [enable_shared=yes])
 534 AC_SUBST(enable_shared)
 535
 536 AC_ARG_WITH(sysroot,
 537 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 538 [
 539  case ${with_sysroot} in
 540  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
 541  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 542  esac
 543
 544  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 545  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 546
 547  if test "x$exec_prefix" = xNONE; then
 548   if test "x$prefix" = xNONE; then
 549    test_prefix=/usr/local
 550   else
 551    test_prefix=$prefix
 552   fi
 553  else
 554   test_prefix=$exec_prefix
 555  fi
 556  case ${TARGET_SYSTEM_ROOT} in
 557  "${test_prefix}"|"${test_prefix}/"*|\
 558  '${exec_prefix}'|'${exec_prefix}/'*)
 559    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 560    TARGET_SYSTEM_ROOT_DEFINE="$t"
 561    ;;
 562  esac
 563 ], [
 564  TARGET_SYSTEM_ROOT=
 565  TARGET_SYSTEM_ROOT_DEFINE=
 566  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 567 ])
 568 AC_SUBST(TARGET_SYSTEM_ROOT)
 569 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 570 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 571
 572 # Build with intermodule optimisations
 573 local_prefix=
 574 AC_ARG_ENABLE(intermodule,
 575 [  --enable-intermodule    build the compiler in one step],
 576 [case "${enable_intermodule}" in
 577   yes) onestep=-onestep : ;;
 578   *) onestep= : ;;
 579 esac])
 580 AC_SUBST(onestep)
 581
 582 # -------------------------
 583 # Checks for other programs
 584 # -------------------------
 585
 586 AC_PROG_MAKE_SET
 587
 588 # Find some useful tools
 589 AC_PROG_AWK
 590 gcc_AC_PROG_LN
 591 gcc_AC_PROG_LN_S
 592 AC_PROG_RANLIB
 593 gcc_AC_PROG_INSTALL
 594
 595 # See if we have the mktemp command.
 596 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 597
 598 # Do we have a single-tree copy of texinfo?
 599 if test -f $srcdir/../texinfo/Makefile.in; then
 600   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 601   gcc_cv_prog_makeinfo_modern=yes
 602   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 603 else
 604   # See if makeinfo has been installed and is modern enough
 605   # that we can use it.
 606   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 607   [GNU texinfo.* \([0-9][0-9.]*\)],
 608   [4.[2-9]*])
 609 fi
 610
 611 if test $gcc_cv_prog_makeinfo_modern = no; then
 612   AC_MSG_WARN([
 613 *** Makeinfo is missing or too old.
 614 *** Info documentation will not be built.])
 615   BUILD_INFO=
 616 else
 617   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 618 fi
 619
 620 # Is pod2man recent enough to regenerate manpages?
 621 AC_MSG_CHECKING([for recent Pod::Man])
 622 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 623   AC_MSG_RESULT(yes)
 624   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 625 else
 626   AC_MSG_RESULT(no)
 627   GENERATED_MANPAGES=
 628 fi
 629
 630 # 'make compare' can be significantly faster, if cmp itself can
 631 # skip bytes instead of using tail.  The test being performed is
 632 # "if cmp --ignore-initial=2 t1 t2 && ! cmp --ignore-initial=1 t1 t2"
 633 # but we need to sink errors and handle broken shells.
 634 AC_MSG_CHECKING([for cmp's capabilities])
 635 echo abfoo >t1
 636 echo cdfoo >t2
 637 if cmp --ignore-initial=2 t1 t2 > /dev/null 2>&1; then
 638   if cmp --ignore-initial=1 t1 t2 > /dev/null 2>&1; then
 639     make_compare_target=slowcompare
 640   else
 641     make_compare_target=gnucompare
 642   fi
 643 else
 644   make_compare_target=slowcompare
 645 fi
 646 rm t1 t2
 647 AC_SUBST(make_compare_target)
 648 AC_MSG_RESULT($make_compare_target)
 649
 650 # How about lex?
 651 dnl Don't use AC_PROG_LEX; we insist on flex.
 652 dnl LEXLIB is not useful in gcc.
 653 if test -f $srcdir/../flex/skel.c; then
 654   FLEX='$(objdir)/../flex/flex'
 655 else
 656   AC_CHECK_PROG(FLEX, flex, flex, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing flex)
 657 fi
 658
 659 # Bison?
 660 # The -L switch is so bison can find its skeleton file.
 661 if test -f $srcdir/../bison/bison.simple; then
 662   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 663 else
 664   AC_CHECK_PROG(BISON, bison, bison, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing bison)
 665 fi
 666
 667 # --------------------
 668 # Checks for C headers
 669 # --------------------
 670
 671 AC_MSG_CHECKING(for GNU C library)
 672 AC_CACHE_VAL(gcc_cv_glibc,
 673 [AC_TRY_COMPILE(
 674   [#include <features.h>],[
 675 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 676 #error Not a GNU C library system
 677 #endif],
 678   [gcc_cv_glibc=yes],
 679   gcc_cv_glibc=no)])
 680 AC_MSG_RESULT($gcc_cv_glibc)
 681 if test $gcc_cv_glibc = yes; then
 682   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 683 fi
 684
 685 AC_HEADER_STDC
 686 AC_HEADER_TIME
 687 gcc_AC_HEADER_STDBOOL
 688 gcc_AC_HEADER_STRING
 689 AC_HEADER_SYS_WAIT
 690 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 691                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 692                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 693                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 694
 695 # Check for thread headers.
 696 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 697 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 698
 699 # These tests can't be done till we know if we have limits.h.
 700 gcc_AC_C_CHAR_BIT
 701 AC_C_BIGENDIAN_CROSS
 702
 703 # --------
 704 # UNSORTED
 705 # --------
 706
 707 # Stage specific cflags for build.
 708 stage1_cflags=
 709 case $build in
 710 vax-*-*)
 711   if test x$GCC = xyes
 712   then
 713     stage1_cflags="-Wa,-J"
 714   else
 715     stage1_cflags="-J"
 716   fi
 717   ;;
 718 powerpc-*-darwin*)
 719   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 720   # sources; use -no-cpp-precomp to get to GNU cpp.
 721   # Apple's GCC has bugs in designated initializer handling, so disable
 722   # that too.
 723   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 724   ;;
 725 esac
 726 AC_SUBST(stage1_cflags)
 727
 728 # These libraries may be used by collect2.
 729 # We may need a special search path to get them linked.
 730 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 731 [save_LIBS="$LIBS"
 732 for libs in '' -lld -lmld \
 733                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 734                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 735 do
 736         LIBS="$libs"
 737         AC_TRY_LINK_FUNC(ldopen,
 738                 [gcc_cv_collect2_libs="$libs"; break])
 739 done
 740 LIBS="$save_LIBS"
 741 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 742 case $gcc_cv_collect2_libs in
 743         "none required")        ;;
 744         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 745 esac
 746 AC_SUBST(COLLECT2_LIBS)
 747
 748 # When building Ada code on Alpha, we need exc_resume which is usually in
 749 # -lexc.  So test for it.
 750 save_LIBS="$LIBS"
 751 LIBS=
 752 AC_SEARCH_LIBS(exc_resume, exc)
 753 GNAT_LIBEXC="$LIBS"
 754 LIBS="$save_LIBS"
 755 AC_SUBST(GNAT_LIBEXC)
 756
 757 # Some systems put ldexp and frexp in libm instead of libc; assume
 758 # they're both in the same place.  jcf-dump needs them.
 759 save_LIBS="$LIBS"
 760 LIBS=
 761 AC_SEARCH_LIBS(ldexp, m)
 762 LDEXP_LIB="$LIBS"
 763 LIBS="$save_LIBS"
 764 AC_SUBST(LDEXP_LIB)
 765
 766 # Use <inttypes.h> only if it exists,
 767 # doesn't clash with <sys/types.h>, and declares intmax_t.
 768 AC_MSG_CHECKING(for inttypes.h)
 769 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 770 [AC_TRY_COMPILE(
 771   [#include <sys/types.h>
 772 #include <inttypes.h>],
 773   [intmax_t i = -1;],
 774   [gcc_cv_header_inttypes_h=yes],
 775   gcc_cv_header_inttypes_h=no)])
 776 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 777 if test $gcc_cv_header_inttypes_h = yes; then
 778   AC_DEFINE(HAVE_INTTYPES_H, 1,
 779         [Define if you have a working <inttypes.h> header file.])
 780 fi
 781
 782 dnl Disabled until we have a complete test for buggy enum bitfields.
 783 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 784
 785 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 786         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
 787         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo lstat \
 788         scandir alphasort gettimeofday mbstowcs wcswidth mmap mincore \
 789         setlocale)
 790
 791 if test x$ac_cv_func_mbstowcs = xyes; then
 792   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 793 [    AC_TRY_RUN([#include <stdlib.h>
 794 int main()
 795 {
 796   mbstowcs(0, "", 0);
 797   return 0;
 798 }],
 799     gcc_cv_func_mbstowcs_works=yes,
 800     gcc_cv_func_mbstowcs_works=no,
 801     gcc_cv_func_mbstowcs_works=yes)])
 802   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 803     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
 804   [Define this macro if mbstowcs does not crash when its
 805    first argument is NULL.])
 806   fi
 807 fi
 808
 809 AC_CHECK_TYPE(ssize_t, int)
 810
 811 # Try to determine the array type of the second argument of getgroups
 812 # for the target system (int or gid_t).
 813 AC_TYPE_GETGROUPS
 814 if test "${target}" = "${build}"; then
 815   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 816 else
 817   case "${target}" in
 818         # This condition may need some tweaking.  It should include all
 819         # targets where the array type of the second argument of getgroups
 820         # is int and the type of gid_t is not equivalent to int.
 821         *-*-sunos* | *-*-ultrix*)
 822                 TARGET_GETGROUPS_T=int
 823                 ;;
 824         *)
 825                 TARGET_GETGROUPS_T=gid_t
 826                 ;;
 827   esac
 828 fi
 829 AC_SUBST(TARGET_GETGROUPS_T)
 830
 831 gcc_AC_FUNC_PRINTF_PTR
 832 gcc_AC_FUNC_MMAP_BLACKLIST
 833
 834 case "${host}" in
 835 *-*-uwin*)
 836   AC_MSG_ERROR([
 837 *** UWIN may not be used as a host platform because
 838 *** linking with posix.dll is not allowed by the GNU GPL])
 839   ;;
 840 *-*-*vms*)
 841   # Under VMS, vfork works very different than on Unix. The standard test
 842   # won't work, and it isn't easily adaptable. It makes more sense to
 843   # just force it.
 844   ac_cv_func_vfork_works=yes
 845   ;;
 846 esac
 847 AC_FUNC_VFORK
 848
 849 AM_ICONV
 850 # Until we have in-tree GNU iconv:
 851 LIBICONV_DEP=
 852 AC_SUBST(LIBICONV_DEP)
 853
 854 AM_LC_MESSAGES
 855
 856 # We will need to find libiberty.h and ansidecl.h
 857 saved_CFLAGS="$CFLAGS"
 858 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 859 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
 860         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
 861         fprintf_unlocked strstr errno vasprintf \
 862         malloc realloc calloc free basename getopt clock, , ,[
 863 #include "ansidecl.h"
 864 #include "system.h"])
 865
 866 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 867 #include "ansidecl.h"
 868 #include "system.h"
 869 #ifdef HAVE_SYS_RESOURCE_H
 870 #include <sys/resource.h>
 871 #endif
 872 ])
 873
 874 AC_TRY_COMPILE([
 875 #include "ansidecl.h"
 876 #include "system.h"
 877 #ifdef HAVE_SYS_RESOURCE_H
 878 #include <sys/resource.h>
 879 #endif
 880 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
 881 [Define to \`long' if <sys/resource.h> doesn't define.])])
 882
 883 gcc_AC_CHECK_DECLS(ldgetname, , ,[
 884 #include "ansidecl.h"
 885 #include "system.h"
 886 #ifdef HAVE_LDFCN_H
 887 #include <ldfcn.h>
 888 #endif
 889 ])
 890
 891 gcc_AC_CHECK_DECLS(times, , ,[
 892 #include "ansidecl.h"
 893 #include "system.h"
 894 #ifdef HAVE_SYS_TIMES_H
 895 #include <sys/times.h>
 896 #endif
 897 ])
 898
 899 # More time-related stuff.
 900 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
 901 AC_TRY_COMPILE([
 902 #include "ansidecl.h"
 903 #include "system.h"
 904 #ifdef HAVE_SYS_TIMES_H
 905 #include <sys/times.h>
 906 #endif
 907 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
 908 if test $ac_cv_struct_tms = yes; then
 909   AC_DEFINE(HAVE_STRUCT_TMS, 1,
 910   [Define if <sys/times.h> defines struct tms.])
 911 fi
 912
 913 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
 914 # revisit after autoconf 2.50.
 915 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
 916 AC_TRY_COMPILE([
 917 #include "ansidecl.h"
 918 #include "system.h"
 919 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
 920 if test $gcc_cv_type_clock_t = yes; then
 921   AC_DEFINE(HAVE_CLOCK_T, 1,
 922   [Define if <time.h> defines clock_t.])
 923 fi
 924
 925 AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
 926 [AC_TRY_COMPILE([
 927 #include "ansidecl.h"
 928 #include "system.h"
 929 ],
 930 [if ((uchar *)0) return 0;
 931  if (sizeof(uchar)) return 0;],
 932 ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
 933 if test $ac_cv_type_uchar = yes; then
 934   AC_DEFINE(HAVE_UCHAR, 1,
 935   [Define if <sys/types.h> defines \`uchar'.])
 936 fi
 937
 938 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 939 CFLAGS="$saved_CFLAGS"
 940
 941 gcc_AC_INITFINI_ARRAY
 942
 943 # mkdir takes a single argument on some systems.
 944 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 945
 946 # File extensions
 947 manext='.1'
 948 objext='.o'
 949 AC_SUBST(manext)
 950 AC_SUBST(objext)
 951
 952 # With Setjmp/Longjmp based exception handling.
 953 AC_ARG_ENABLE(sjlj-exceptions,
 954 [  --enable-sjlj-exceptions
 955                           arrange to use setjmp/longjmp exception handling],
 956 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
 957 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
 958   [Define 0/1 to force the choice for exception handling model.])])
 959
 960 AC_CHECK_LIB(unwind, main, use_libunwind_default=yes, use_libunwind_default=no)
 961 # Use libunwind based exception handling.
 962 AC_ARG_ENABLE(libunwind-exceptions,
 963 [  --enable-libunwind-exceptions  force use libunwind for exceptions],
 964 use_libunwind_exceptions=$enableval,
 965 use_libunwind_exceptions=$use_libunwind_default)
 966 if test x"$use_libunwind_exceptions" = xyes; then
 967    AC_DEFINE(USE_LIBUNWIND_EXCEPTIONS, 1,
 968         [Define if gcc should use -lunwind.])
 969 fi
 970
 971 # --------------------------------------------------------
 972 # Build, host, and target specific configuration fragments
 973 # --------------------------------------------------------
 974
 975 target_gtfiles=
 976 build_xm_file=
 977 build_xm_defines=
 978 build_install_headers_dir=install-headers-tar
 979 build_exeext=
 980 host_xm_file=
 981 host_xm_defines=
 982 host_xmake_file=
 983 host_exeext=
 984
 985 # Decode the host machine, then the target machine.
 986 # For the host machine, we save the xm_file variable as host_xm_file;
 987 # then we decode the target machine and forget everything else
 988 # that came from the host machine.
 989 for machine in $build $host $target; do
 990         . ${srcdir}/config.gcc
 991 done
 992
 993 extra_objs="${host_extra_objs} ${extra_objs}"
 994
 995 # Default the target-machine variables that were not explicitly set.
 996 if test x"$tm_file" = x
 997 then tm_file=$cpu_type/$cpu_type.h; fi
 998
 999 if test x"$extra_headers" = x
1000 then extra_headers=; fi
1001
1002 if test x$md_file = x
1003 then md_file=$cpu_type/$cpu_type.md; fi
1004
1005 if test x$out_file = x
1006 then out_file=$cpu_type/$cpu_type.c; fi
1007
1008 if test x"$tmake_file" = x
1009 then tmake_file=$cpu_type/t-$cpu_type
1010 fi
1011
1012 if test x"$dwarf2" = xyes
1013 then tm_file="$tm_file tm-dwarf2.h"
1014 fi
1015
1016 # Say what files are being used for the output code and MD file.
1017 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1018 echo "Using \`$srcdir/config/$md_file' as machine description file."
1019
1020 # If any of the xm_file variables contain nonexistent files, warn
1021 # about them and drop them.
1022
1023 bx=
1024 for x in $build_xm_file; do
1025   if    test -f $srcdir/config/$x
1026   then      bx="$bx $x"
1027   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1028   fi
1029 done
1030 build_xm_file="$bx"
1031
1032 hx=
1033 for x in $host_xm_file; do
1034   if    test -f $srcdir/config/$x
1035   then      hx="$hx $x"
1036   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1037   fi
1038 done
1039 host_xm_file="$hx"
1040
1041 tx=
1042 for x in $xm_file; do
1043   if    test -f $srcdir/config/$x
1044   then      tx="$tx $x"
1045   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1046   fi
1047 done
1048 xm_file="$tx"
1049
1050 count=a
1051 for f in $tm_file; do
1052         count=${count}x
1053 done
1054 if test $count = ax; then
1055         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1056 else
1057         echo "Using the following target machine macro files:"
1058         for f in $tm_file; do
1059                 echo "  $srcdir/config/$f"
1060         done
1061 fi
1062
1063 if test x$need_64bit_hwint = xyes; then
1064         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1065 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1066 fi
1067
1068 count=a
1069 for f in $host_xm_file; do
1070         count=${count}x
1071 done
1072 if test $count = a; then
1073         :
1074 elif test $count = ax; then
1075         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1076 else
1077         echo "Using the following host machine macro files:"
1078         for f in $host_xm_file; do
1079                 echo "  $srcdir/config/$f"
1080         done
1081 fi
1082 echo "Using ${out_host_hook_obj} for host machine hooks."
1083
1084 if test "$host_xm_file" != "$build_xm_file"; then
1085         count=a
1086         for f in $build_xm_file; do
1087                 count=${count}x
1088         done
1089         if test $count = a; then
1090                 :
1091         elif test $count = ax; then
1092                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1093         else
1094                 echo "Using the following build machine macro files:"
1095                 for f in $build_xm_file; do
1096                         echo "  $srcdir/config/$f"
1097                 done
1098         fi
1099 fi
1100
1101 if test x$thread_file = x; then
1102         if test x$target_thread_file != x; then
1103                 thread_file=$target_thread_file
1104         else
1105                 thread_file='single'
1106         fi
1107 fi
1108
1109 if test x$enable___cxa_atexit = xyes || \
1110    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1111   AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1112   [Define if you want to use __cxa_atexit, rather than atexit, to
1113    register C++ destructors for local statics and global objects.
1114    This is essential for fully standards-compliant handling of
1115    destructors, but requires __cxa_atexit in libc.])
1116 fi
1117
1118 # Look for a file containing extra machine modes.
1119 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1120   extra_modes_file='$(srcdir)'/config/${extra_modes}
1121   AC_SUBST(extra_modes_file)
1122   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "$extra_modes",
1123   [Define to the name of a file containing a list of extra machine modes
1124    for this architecture.])
1125   AC_DEFINE(EXTRA_CC_MODES, 1,
1126   [Define if the target architecture needs extra machine modes to represent
1127    the results of comparisons.])
1128 fi
1129
1130 # auto-host.h is the file containing items generated by autoconf and is
1131 # the first file included by config.h.
1132 # If host=build, it is correct to have bconfig include auto-host.h
1133 # as well.  If host!=build, we are in error and need to do more
1134 # work to find out the build config parameters.
1135 if test x$host = x$build
1136 then
1137         build_auto=auto-host.h
1138         FORBUILD=..
1139 else
1140         # We create a subdir, then run autoconf in the subdir.
1141         # To prevent recursion we set host and build for the new
1142         # invocation of configure to the build for this invocation
1143         # of configure.
1144         tempdir=build.$$
1145         rm -rf $tempdir
1146         mkdir $tempdir
1147         cd $tempdir
1148         case ${srcdir} in
1149         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1150         *) realsrcdir=../${srcdir};;
1151         esac
1152         saved_CFLAGS="${CFLAGS}"
1153         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1154         ${realsrcdir}/configure \
1155                 --target=$target_alias --host=$build_alias --build=$build_alias
1156         CFLAGS="${saved_CFLAGS}"
1157
1158         # We just finished tests for the build machine, so rename
1159         # the file auto-build.h in the gcc directory.
1160         mv auto-host.h ../auto-build.h
1161         cd ..
1162         rm -rf $tempdir
1163         build_auto=auto-build.h
1164         FORBUILD=../${build_subdir}
1165 fi
1166 AC_SUBST(FORBUILD)
1167
1168 tm_file="${tm_file} defaults.h"
1169 tm_p_file="${tm_p_file} tm-preds.h"
1170 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1171 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1172 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1173 # put this back in temporarily.
1174 xm_file="ansidecl.h ${xm_file}"
1175
1176 # --------
1177 # UNSORTED
1178 # --------
1179
1180 # Get the version trigger filename from the toplevel
1181 if test "${with_gcc_version_trigger+set}" = set; then
1182         gcc_version_trigger=$with_gcc_version_trigger
1183 else
1184         gcc_version_trigger=${srcdir}/version.c
1185 fi
1186 changequote(,)dnl
1187 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
1188 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1189
1190 # Compile in configure arguments.
1191 if test -f configargs.h ; then
1192         # Being re-configured.
1193         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1194         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1195 else
1196         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1197 fi
1198 cat > configargs.h <<EOF
1199 /* Generated automatically. */
1200 static const char configuration_arguments[] = "$gcc_config_arguments";
1201 static const char thread_model[] = "$thread_file";
1202
1203 static const struct {
1204   const char *name, *value;
1205 } configure_default_options[] = $configure_default_options;
1206 EOF
1207 changequote([,])dnl
1208
1209 # Internationalization
1210 PACKAGE=gcc
1211 VERSION="$gcc_version"
1212 AC_SUBST(PACKAGE)
1213 AC_SUBST(VERSION)
1214
1215 ZW_GNU_GETTEXT_SISTER_DIR
1216
1217 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1218 # -liconv on the link line twice.
1219 case "$LIBINTL" in *$LIBICONV*)
1220         LIBICONV= ;;
1221 esac
1222
1223 # Windows32 Registry support for specifying GCC installation paths.
1224 AC_ARG_ENABLE(win32-registry,
1225 [  --disable-win32-registry
1226                           disable lookup of installation paths in the
1227                           Registry on Windows hosts
1228   --enable-win32-registry enable registry lookup (default)
1229   --enable-win32-registry=KEY
1230                           use KEY instead of GCC version as the last portion
1231                           of the registry key],,)
1232 case $host_os in
1233         win32 | pe | cygwin* | mingw32* | uwin*)
1234 AC_MSG_CHECKING(whether windows registry support is requested)
1235 if test "x$enable_win32_registry" != xno; then
1236   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1237 [Define to 1 if installation paths should be looked up in Windows32
1238    Registry. Ignored on non windows32 hosts.])
1239   AC_MSG_RESULT(yes)
1240   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
1241 else
1242   AC_MSG_RESULT(no)
1243 fi
1244
1245 # Check if user specified a different registry key.
1246 case "x${enable_win32_registry}" in
1247 x | xyes)
1248   # default.
1249   gcc_cv_win32_registry_key="$VERSION"
1250   ;;
1251 xno)
1252   # no registry lookup.
1253   gcc_cv_win32_registry_key=''
1254   ;;
1255 *)
1256   # user-specified key.
1257   gcc_cv_win32_registry_key="$enable_win32_registry"
1258   ;;
1259 esac
1260
1261 if test "x$enable_win32_registry" != xno; then
1262   AC_MSG_CHECKING(registry key on windows hosts)
1263   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
1264         [Define to be the last portion of registry key on windows hosts.])
1265   AC_MSG_RESULT($gcc_cv_win32_registry_key)
1266 fi
1267 ;;
1268 esac
1269
1270 # Get an absolute path to the GCC top-level source directory
1271 holddir=`${PWDCMD-pwd}`
1272 cd $srcdir
1273 topdir=`${PWDCMD-pwd}`
1274 cd $holddir
1275
1276 # Conditionalize the makefile for this host machine.
1277 # Make-host contains the concatenation of all host makefile fragments
1278 # [there can be more than one].  This file is built by configure.frag.
1279 host_overrides=Make-host
1280 dep_host_xmake_file=
1281 for f in .. ${host_xmake_file}
1282 do
1283         if test -f ${srcdir}/config/$f
1284         then
1285                 dep_host_xmake_file="${dep_host_xmake_file} ${srcdir}/config/$f"
1286         fi
1287 done
1288
1289 # Conditionalize the makefile for this target machine.
1290 # Make-target contains the concatenation of all host makefile fragments
1291 # [there can be more than one].  This file is built by configure.frag.
1292 target_overrides=Make-target
1293 dep_tmake_file=
1294 for f in .. ${tmake_file}
1295 do
1296         if test -f ${srcdir}/config/$f
1297         then
1298                 dep_tmake_file="${dep_tmake_file} ${srcdir}/config/$f"
1299         fi
1300 done
1301
1302 symbolic_link='ln -s'
1303
1304 # If the host doesn't support symlinks, modify CC in
1305 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1306 # Otherwise, we can use "CC=$(CC)".
1307 rm -f symtest.tem
1308 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1309 then
1310         cc_set_by_configure="\$(CC)"
1311         quoted_cc_set_by_configure="\$(CC)"
1312         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1313         quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1314 else
1315         rm -f symtest.tem
1316         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1317         then
1318                 symbolic_link="cp -p"
1319         else
1320                 symbolic_link="cp"
1321         fi
1322         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1323         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1324         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1325         quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1326 fi
1327 rm -f symtest.tem
1328
1329 out_object_file=`basename $out_file .c`.o
1330
1331 tm_file_list=
1332 for f in $tm_file; do
1333   case $f in
1334     ansidecl.h )
1335        tm_file_list="${tm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1336     defaults.h )
1337        tm_file_list="${tm_file_list} \$(srcdir)/$f" ;;
1338     *) tm_file_list="${tm_file_list} \$(srcdir)/config/$f" ;;
1339   esac
1340 done
1341
1342 tm_p_file_list=
1343 for f in $tm_p_file; do
1344   case $f in
1345     tm-preds.h )
1346        tm_p_file_list="${tm_p_file_list} $f" ;;
1347     *) tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f" ;;
1348   esac
1349 done
1350
1351 host_xm_file_list=
1352 for f in $host_xm_file; do
1353   case $f in
1354     ansidecl.h )
1355        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1356     auto-host.h )
1357        host_xm_file_list="${host_xm_file_list} $f" ;;
1358     defaults.h )
1359        host_xm_file_list="${host_xm_file_list} \$(srcdir)/$f" ;;
1360     *) host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f" ;;
1361   esac
1362 done
1363
1364 build_xm_file_list=
1365 for f in $build_xm_file; do
1366   case $f in
1367     ansidecl.h )
1368        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1369     auto-build.h | auto-host.h )
1370        build_xm_file_list="${build_xm_file_list} $f" ;;
1371     defaults.h )
1372        host_xm_file_list="${host_xm_file_list} \$(srcdir)/$f" ;;
1373     *) build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f" ;;
1374   esac
1375 done
1376
1377 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1378 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1379 CROSS=                                          AC_SUBST(CROSS)
1380 ALL=all.internal                                AC_SUBST(ALL)
1381 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1382 if test x$host != x$target
1383 then
1384         CROSS="-DCROSS_COMPILE"
1385         ALL=all.cross
1386         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1387         case "$host","$target" in
1388             i?86-*-*,x86_64-*-* \
1389             | powerpc*-*-*,powerpc64*-*-*)
1390                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1391         esac
1392 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1393         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1394         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1395 fi
1396
1397 # If this is a cross-compiler that does not
1398 # have its own set of headers then define
1399 # inhibit_libc
1400
1401 # If this is using newlib, without having the headers available now,
1402 # then define inhibit_libc in LIBGCC2_CFLAGS.
1403 # This prevents libgcc2 from containing any code which requires libc
1404 # support.
1405 inhibit_libc=
1406 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1407        test x$with_newlib = xyes ; } &&
1408      test "x$with_headers" = x ; then
1409        inhibit_libc=-Dinhibit_libc
1410 fi
1411 AC_SUBST(inhibit_libc)
1412
1413 # When building gcc with a cross-compiler, we need to adjust things so
1414 # that the generator programs are still built with the native compiler.
1415 # Also, we cannot run fixincludes or fix-header.
1416
1417 # These are the normal (build=host) settings:
1418 BUILD_PREFIX=                   AC_SUBST(BUILD_PREFIX)
1419 BUILD_PREFIX_1=ignore-          AC_SUBST(BUILD_PREFIX_1)
1420 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1421 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1422
1423 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1424 STMP_FIXPROTO=stmp-fixproto     AC_SUBST(STMP_FIXPROTO)
1425
1426 # And these apply if build != host, or we are generating coverage data
1427 if test x$build != x$host || test "x$coverage_flags" != x
1428 then
1429     BUILD_PREFIX=build-
1430     BUILD_PREFIX_1=build-
1431     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1432
1433     if test "x$TARGET_SYSTEM_ROOT" = x; then
1434         STMP_FIXINC=
1435         STMP_FIXPROTO=
1436     fi
1437 fi
1438
1439 # Expand extra_headers to include complete path.
1440 # This substitutes for lots of t-* files.
1441 extra_headers_list=
1442 if test "x$extra_headers" = x
1443 then true
1444 else
1445         # Prepend ${srcdir}/config/${cpu_type}/ to every entry in extra_headers.
1446         for file in $extra_headers;
1447         do
1448                 extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1449         done
1450 fi
1451
1452 # Add a definition of USE_COLLECT2 if system wants one.
1453 case $use_collect2 in
1454   no) use_collect2= ;;
1455   "") ;;
1456   *)
1457     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1458     xm_defines="${xm_defines} USE_COLLECT2"
1459     ;;
1460 esac
1461
1462 # Identify the assembler which will work hand-in-glove with the newly
1463 # built GCC, so that we can examine its features.  This is the assembler
1464 # which will be driven by the driver program.
1465 #
1466 # If build != host, and we aren't building gas in-tree, we identify a
1467 # build->target assembler and hope that it will have the same features
1468 # as the host->target assembler we'll be using.
1469 AC_MSG_CHECKING(what assembler to use)
1470 in_tree_gas=no
1471 gcc_cv_as=
1472 gcc_cv_gas_major_version=
1473 gcc_cv_gas_minor_version=
1474 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1475 if test -x "$DEFAULT_ASSEMBLER"; then
1476         gcc_cv_as="$DEFAULT_ASSEMBLER"
1477 elif test -x "$AS"; then
1478         gcc_cv_as="$AS"
1479 elif test -x as$host_exeext; then
1480         # Build using assembler in the current directory.
1481         gcc_cv_as=./as$host_exeext
1482 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1483      && test -f ../gas/Makefile; then
1484   # Single tree build which includes gas.
1485   in_tree_gas=yes
1486   _gcc_COMPUTE_GAS_VERSION
1487   rm -f as$host_exeext
1488   $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1489   in_tree_gas_is_elf=no
1490   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1491      || (grep 'obj_format = multi' ../gas/Makefile \
1492          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1493   then
1494     in_tree_gas_is_elf=yes
1495   fi
1496 fi
1497
1498 if test "x$gcc_cv_as" = x; then
1499         # Search the same directories that the installed compiler will
1500         # search.  Else we may find the wrong assembler and lose.  If we
1501         # do not find a suitable assembler binary, then try the user's
1502         # path.
1503         #
1504         # Also note we have to check MD_EXEC_PREFIX before checking the
1505         # user's path.  Unfortunately, there is no good way to get at the
1506         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1507         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1508         # to be fixed as part of the make/configure rewrite too.
1509
1510         if test "x$exec_prefix" = xNONE; then
1511                 if test "x$prefix" = xNONE; then
1512                         test_prefix=/usr/local
1513                 else
1514                         test_prefix=$prefix
1515                 fi
1516         else
1517                 test_prefix=$exec_prefix
1518         fi
1519
1520         # If the loop below does not find an assembler, then use whatever
1521         # one we can find in the users's path.
1522         # user's path.
1523         if test "x$program_prefix" != xNONE; then
1524                 gcc_cv_as=${program_prefix}as$host_exeext
1525         else
1526                 gcc_cv_as=`echo as | sed ${program_transform_name}`$host_exeext
1527         fi
1528
1529         test_dirs="$test_prefix/lib/gcc-lib/$target_alias/$gcc_version \
1530                    $test_prefix/lib/gcc-lib/$target_alias \
1531                    /usr/lib/gcc/$target_alias/$gcc_version \
1532                    /usr/lib/gcc/$target_alias \
1533                    $test_prefix/$target_alias/bin/$target_alias/$gcc_version \
1534                    $test_prefix/$target_alias/bin"
1535
1536         if test x$host = x$target; then
1537             test_dirs="$test_dirs \
1538                    /usr/libexec \
1539                    /usr/ccs/gcc \
1540                    /usr/ccs/bin \
1541                    /udk/usr/ccs/bin \
1542                    /bsd43/usr/lib/cmplrs/cc \
1543                    /usr/cross64/usr/bin \
1544                    /usr/lib/cmplrs/cc \
1545                    /sysv/usr/lib/cmplrs/cc \
1546                    /svr4/usr/lib/cmplrs/cc \
1547                    /usr/bin"
1548         fi
1549
1550         for dir in $test_dirs; do
1551                 if test -x $dir/as$host_exeext; then
1552                         gcc_cv_as=$dir/as$host_exeext
1553                         break;
1554                 fi
1555         done
1556 fi
1557 case $in_tree_gas in
1558   yes)
1559     AC_MSG_RESULT("newly built gas")
1560     ;;
1561   no)
1562     AC_MSG_RESULT($gcc_cv_as)
1563     ;;
1564 esac
1565
1566 # Identify the linker which will work hand-in-glove with the newly
1567 # built GCC, so that we can examine its features.  This is the linker
1568 # which will be driven by the driver program.
1569 #
1570 # If build != host, and we aren't building gas in-tree, we identify a
1571 # build->target linker and hope that it will have the same features
1572 # as the host->target linker we'll be using.
1573 AC_MSG_CHECKING(what linker to use)
1574 in_tree_ld=no
1575 gcc_cv_ld=
1576 gcc_cv_gld_major_version=
1577 gcc_cv_gld_minor_version=
1578 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1579 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1580 if test -x "$DEFAULT_LINKER"; then
1581         gcc_cv_ld="$DEFAULT_LINKER"
1582 elif test -x "$LD"; then
1583         gcc_cv_ld="$LD"
1584 elif test -x collect-ld$host_exeext; then
1585         # Build using linker in the current directory.
1586         gcc_cv_ld=./collect-ld$host_exeext
1587 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1588      && test -f ../ld/Makefile; then
1589         # Single tree build which includes ld.
1590         in_tree_ld=yes
1591         in_tree_ld_is_elf=no
1592         if (grep 'EMUL = .*elf' ../ld/Makefile \
1593             || grep 'EMUL = .*linux' ../ld/Makefile) > /dev/null; then
1594           in_tree_ld_is_elf=yes
1595         fi
1596         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1597         do
1598 changequote(,)dnl
1599                 gcc_cv_gld_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1600 changequote([,])dnl
1601                 if test x$gcc_cv_gld_version != x; then
1602                         break
1603                 fi
1604         done
1605 changequote(,)dnl
1606         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1607         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1608 changequote([,])dnl
1609         rm -f collect-ld$host_exeext
1610         $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext \
1611                 2>/dev/null
1612 fi
1613
1614 if test "x$gcc_cv_ld" = x; then
1615         # Search the same directories that the installed compiler will
1616         # search.  Else we may find the wrong linker and lose.  If we
1617         # do not find a suitable linker binary, then try the user's
1618         # path.
1619         #
1620         # Also note we have to check MD_EXEC_PREFIX before checking the
1621         # user's path.  Unfortunately, there is no good way to get at the
1622         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1623         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1624         # to be fixed as part of the make/configure rewrite too.
1625
1626         if test "x$exec_prefix" = xNONE; then
1627                 if test "x$prefix" = xNONE; then
1628                         test_prefix=/usr/local
1629                 else
1630                         test_prefix=$prefix
1631                 fi
1632         else
1633                 test_prefix=$exec_prefix
1634         fi
1635
1636         # If the loop below does not find an linker, then use whatever
1637         # one we can find in the users's path.
1638         # user's path.
1639         if test "x$program_prefix" != xNONE; then
1640                 gcc_cv_ld=${program_prefix}ld$host_exeext
1641         else
1642                 gcc_cv_ld=`echo ld | sed ${program_transform_name}`$host_exeext
1643         fi
1644
1645         test_dirs="$test_prefix/lib/gcc-lib/$target_alias/$gcc_version \
1646                    $test_prefix/lib/gcc-lib/$target_alias \
1647                    /usr/lib/gcc/$target_alias/$gcc_version \
1648                    /usr/lib/gcc/$target_alias \
1649                    $test_prefix/$target_alias/bin/$target_alias/$gcc_version \
1650                    $test_prefix/$target_alias/bin"
1651
1652         if test x$host = x$target; then
1653             test_dirs="$test_dirs \
1654                    /usr/libexec \
1655                    /usr/ccs/gcc \
1656                    /usr/ccs/bin \
1657                    /udk/usr/ccs/bin \
1658                    /bsd43/usr/lib/cmplrs/cc \
1659                    /usr/cross64/usr/bin \
1660                    /usr/lib/cmplrs/cc \
1661                    /sysv/usr/lib/cmplrs/cc \
1662                    /svr4/usr/lib/cmplrs/cc \
1663                    /usr/bin"
1664         fi
1665
1666         for dir in $test_dirs; do
1667                 if test -x $dir/ld$host_exeext; then
1668                         gcc_cv_ld=$dir/ld$host_exeext
1669                         break;
1670                 fi
1671         done
1672 fi
1673 case $in_tree_ld in
1674   yes)
1675     AC_MSG_RESULT("newly built ld")
1676     ;;
1677   no)
1678     AC_MSG_RESULT($gcc_cv_ld)
1679     ;;
1680 esac
1681
1682 # Figure out what nm we will be using.
1683 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1684 AC_MSG_CHECKING(what nm to use)
1685 in_tree_nm=no
1686 if test -x nm$host_exeext; then
1687         gcc_cv_nm=./nm$host_exeext
1688 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1689      && test -f ../binutils/Makefile; then
1690         # Single tree build which includes binutils.
1691         in_tree_nm=yes
1692         gcc_cv_nm=./nm$host_exeext
1693         rm -f nm$host_exeext
1694         $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1695 elif test "x$program_prefix" != xNONE; then
1696         gcc_cv_nm=${program_prefix}nm$host_exeext
1697 else
1698         gcc_cv_nm=`echo nm | sed ${program_transform_name}`$host_exeext
1699 fi
1700 case $in_tree_nm in
1701   yes) AC_MSG_RESULT("newly built nm") ;;
1702   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
1703 esac
1704
1705 # Figure out what objdump we will be using.
1706 AC_MSG_CHECKING(what objdump to use)
1707 in_tree_objdump=no
1708 if test -x objdump$host_exeext; then
1709         gcc_cv_objdump=./objdump$host_exeext
1710 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1711      && test -f ../binutils/Makefile; then
1712         # Single tree build which includes binutils.
1713         in_tree_objdump=yes
1714         gcc_cv_objdump=./objdump$host_exeext
1715         rm -f objdump$host_exeext
1716         $symbolic_link ../binutils/objdump$host_exeext \
1717                 objdump$host_exeext 2>/dev/null
1718 elif test "x$program_prefix" != xNONE; then
1719         gcc_cv_objdump=${program_prefix}objdump$host_exeext
1720 else
1721         gcc_cv_objdump=`echo objdump | \
1722                 sed ${program_transform_name}`$host_exeext
1723 fi
1724 case $in_tree_objdump in
1725   yes) AC_MSG_RESULT("newly built objdump") ;;
1726   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
1727 esac
1728
1729 # Figure out what assembler alignment features are present.
1730 AC_MSG_CHECKING(assembler alignment features)
1731 gcc_cv_as_alignment_features=none
1732 if test $in_tree_gas = yes; then
1733   # Gas version 2.6 and later support for .balign and .p2align.
1734   gcc_GAS_VERSION_GTE_IFELSE(2,6,0,[
1735     gcc_cv_as_alignment_features=".balign and .p2align"
1736     AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1737   ])
1738   # Gas version 2.8 and later support specifying the maximum
1739   # bytes to skip when using .p2align.
1740   gcc_GAS_VERSION_GTE_IFELSE(2,8,0,[
1741     gcc_cv_as_alignment_features=".p2align including maximum skip"
1742     AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1743   ])
1744 elif test x$gcc_cv_as != x; then
1745         # Check if we have .balign and .p2align
1746         echo ".balign  4" > conftest.s
1747         echo ".p2align  2" >> conftest.s
1748         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1749                 gcc_cv_as_alignment_features=".balign and .p2align"
1750                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1751         fi
1752         rm -f conftest.s conftest.o
1753         # Check if specifying the maximum bytes to skip when
1754         # using .p2align is supported.
1755         echo ".p2align 4,,7" > conftest.s
1756         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1757                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1758                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1759         fi
1760         rm -f conftest.s conftest.o
1761 fi
1762 AC_MSG_RESULT($gcc_cv_as_alignment_features)
1763
1764 AC_MSG_CHECKING(assembler subsection support)
1765 gcc_cv_as_subsections=no
1766 if test $in_tree_gas = yes ; then
1767   gcc_GAS_VERSION_GTE_IFELSE(2,9,0,[
1768     test $in_tree_gas_is_elf = yes \
1769         && gcc_cv_as_subsections="working .subsection -1"
1770   ])
1771 elif test x$gcc_cv_as != x; then
1772         # Check if we have .subsection
1773         echo ".subsection 1" > conftest.s
1774         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1775                 gcc_cv_as_subsections=".subsection"
1776                 if test x$gcc_cv_nm != x; then
1777                         cat > conftest.s <<EOF
1778 conftest_label1: .word 0
1779 .subsection -1
1780 conftest_label2: .word 0
1781 .previous
1782 EOF
1783                         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1784                                 $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1785                                 $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1786                                 if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1; then
1787                                         :
1788                                 else
1789                                         gcc_cv_as_subsections="working .subsection -1"
1790                                 fi
1791                         fi
1792                 fi
1793         fi
1794         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1795 fi
1796 if test x"$gcc_cv_as_subsections" = x"working .subsection -1"; then
1797         AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1798 [Define if your assembler supports .subsection and .subsection -1 starts
1799    emitting at the beginning of your section.])
1800 fi
1801 AC_MSG_RESULT($gcc_cv_as_subsections)
1802
1803 AC_MSG_CHECKING(assembler weak support)
1804 gcc_cv_as_weak=no
1805 if test $in_tree_gas = yes ; then
1806   gcc_GAS_VERSION_GTE_IFELSE(2,2,0,[
1807     gcc_cv_as_weak="yes"
1808   ])
1809 elif test x$gcc_cv_as != x; then
1810         # Check if we have .weak
1811         echo "  .weak foobar" > conftest.s
1812         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1813                 gcc_cv_as_weak="yes"
1814         fi
1815         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1816 fi
1817 if test x"$gcc_cv_as_weak" = xyes; then
1818         AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])
1819 fi
1820 AC_MSG_RESULT($gcc_cv_as_weak)
1821
1822 AC_MSG_CHECKING(assembler hidden support)
1823 gcc_cv_as_hidden=no
1824 if test $in_tree_gas = yes ; then
1825   gcc_GAS_VERSION_GTE_IFELSE(2,12,1,[
1826     test $in_tree_gas_is_elf = yes && gcc_cv_as_hidden="yes"
1827   ])
1828 elif test x$gcc_cv_as != x; then
1829         # Check if we have .hidden
1830         echo "  .hidden foobar" > conftest.s
1831         echo "foobar:" >> conftest.s
1832         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1833                 gcc_cv_as_hidden="yes"
1834         fi
1835         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1836
1837         # GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
1838         # This is irritatingly difficult to feature test for.  Look for
1839         # the date string after the version number.
1840         ld_ver=`$gcc_cv_ld --version 2>/dev/null | head -1`
1841         if echo "$ld_ver" | grep GNU > /dev/null; then
1842 changequote(,)dnl
1843                ld_vers=`echo $ld_ver | sed -n \
1844                -e 's,^.*[        ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1845                -e 's,^.*[        ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1846                -e 's,^.*[        ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1847                -e 's,^.*[        ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
1848                -e 's,^.*[        ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
1849                -e 's,^.*[        ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[        ].*$,\1,p'`
1850                ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
1851                 if test 0"$ld_date" -lt 20020404; then
1852                         if test -n "$ld_date"; then
1853                                 # If there was date string, but was earlier than 2002-04-04, fail
1854                                 gcc_cv_as_hidden="no"
1855                         elif test -z "$ld_vers"; then
1856                                 # If there was no date string nor ld version number, something is wrong
1857                                 gcc_cv_as_hidden="no"
1858                         else
1859                                 ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
1860                                 ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
1861                                 ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
1862                                 test -z "$ld_vers_patch" && ld_vers_patch=0
1863                                 if test "$ld_vers_major" -lt 2; then
1864                                         gcc_cv_as_hidden="no"
1865                                 elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
1866                                         gcc_cv_as_hidden="no"
1867                                 elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 \
1868                                           -a "$ld_vers_patch" -eq 0; then
1869                                         gcc_cv_as_hidden="no"
1870                                 fi
1871                         fi
1872                 fi
1873 changequote([,])dnl
1874         fi
1875 fi
1876 case "$target" in
1877   mips-sgi-irix6*)
1878     if test x"$gnu_ld_flag" = x"no"; then
1879       # Even if using gas with .hidden support, the resulting object files
1880       # cannot be linked with the IRIX 6 O32 linker.  With the N32 and
1881       # N64 linkers, the problem is that the linker refuses to accept
1882       # -call_shared (passed by default to the linker) and -r (used to
1883       # link the object file generated without .hidden directives with
1884       # one that hides symbols), so we also lose.
1885       gcc_cv_as_hidden=no
1886     fi
1887     ;;
1888 esac
1889 if test x"$gcc_cv_as_hidden" = xyes; then
1890         AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1891                 [Define if your assembler supports .hidden.])
1892 fi
1893 AC_MSG_RESULT($gcc_cv_as_hidden)
1894 libgcc_visibility=$gcc_cv_as_hidden
1895 AC_SUBST(libgcc_visibility)
1896
1897 AC_MSG_CHECKING(assembler leb128 support)
1898 gcc_cv_as_leb128=no
1899 if test $in_tree_gas = yes ; then
1900   gcc_GAS_VERSION_GTE_IFELSE(2,11,0,[
1901     test $in_tree_gas_is_elf = yes && gcc_cv_as_leb128="yes"
1902   ])
1903 elif test x$gcc_cv_as != x; then
1904         # Check if we have .[us]leb128, and support symbol arithmetic with it.
1905         cat > conftest.s <<EOF
1906         .data
1907         .uleb128 L2 - L1
1908 L1:
1909         .uleb128 1280
1910         .sleb128 -1010
1911 L2:
1912 EOF
1913         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1914                 gcc_cv_as_leb128="yes"
1915
1916                 # GAS versions before 2.11 do not support uleb128,
1917                 # despite appearing to.
1918                 # ??? There exists an elf-specific test that will crash
1919                 # the assembler.  Perhaps it's better to figure out whether
1920                 # arbitrary sections are supported and try the test.
1921                 as_ver=`$gcc_cv_as --version 2>/dev/null | head -1`
1922                 if echo "$as_ver" | grep GNU > /dev/null; then
1923 changequote(,)dnl
1924                         as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
1925                         as_major=`echo $as_ver | sed 's/\..*//'`
1926                         as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
1927 changequote([,])dnl
1928                         if test $as_major -eq 2 -a $as_minor -lt 11; then
1929                                 gcc_cv_as_leb128="no"
1930                         fi
1931                 fi
1932         fi
1933         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1934 fi
1935 if test x"$gcc_cv_as_leb128" = xyes; then
1936         AC_DEFINE(HAVE_AS_LEB128, 1,
1937                 [Define if your assembler supports .uleb128.])
1938 fi
1939 AC_MSG_RESULT($gcc_cv_as_leb128)
1940
1941 AC_MSG_CHECKING(assembler eh_frame optimization)
1942 gcc_cv_as_eh_frame=no
1943 if test $in_tree_gas = yes ; then
1944   gcc_GAS_VERSION_GTE_IFELSE(2,12,0,[
1945     test $in_tree_gas_is_elf = yes && gcc_cv_as_eh_frame="yes"
1946   ])
1947 elif test x$gcc_cv_as != x; then
1948         # Check if this is GAS.
1949         as_ver=`$gcc_cv_as --version < /dev/null 2> /dev/null | head -1`
1950         rm -f a.out 2> /dev/null
1951         if echo "$as_ver" | grep GNU > /dev/null; then
1952                 # Versions up to and including 2.11.0 may mis-optimize
1953                 # .eh_frame data.  Try something.
1954                 cat > conftest.s <<EOF
1955         .text
1956 .LFB1:
1957         .4byte  0
1958 .L1:
1959         .4byte  0
1960 .LFE1:
1961         .section        .eh_frame,"aw",@progbits
1962 __FRAME_BEGIN__:
1963         .4byte  .LECIE1-.LSCIE1
1964 .LSCIE1:
1965         .4byte  0x0
1966         .byte   0x1
1967         .ascii "z\0"
1968         .byte   0x1
1969         .byte   0x78
1970         .byte   0x1a
1971         .byte   0x0
1972         .byte   0x4
1973         .4byte  1
1974         .p2align 1
1975 .LECIE1:
1976 .LSFDE1:
1977         .4byte  .LEFDE1-.LASFDE1
1978 .LASFDE1:
1979         .4byte  .LASFDE1-__FRAME_BEGIN__
1980         .4byte  .LFB1
1981         .4byte  .LFE1-.LFB1
1982         .byte   0x4
1983         .4byte  .LFE1-.LFB1
1984         .byte   0x4
1985         .4byte  .L1-.LFB1
1986 .LEFDE1:
1987 EOF
1988                 cat > conftest.lit <<EOF
1989  0000 10000000 00000000 017a0001 781a0004  .........z..x...
1990  0010 01000000 12000000 18000000 00000000  ................
1991  0020 08000000 04080000 0044               .........D
1992 EOF
1993                 cat > conftest.big <<EOF
1994  0000 00000010 00000000 017a0001 781a0004  .........z..x...
1995  0010 00000001 00000012 00000018 00000000  ................
1996  0020 00000008 04000000 0844               .........D
1997 EOF
1998                 # If the assembler didn't choke, and we can objdump,
1999                 # and we got the correct data, then succeed.
2000                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
2001                    && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2002                       | tail -3 > conftest.got \
2003                    && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
2004                         || cmp conftest.big conftest.got > /dev/null 2>&1; }
2005                 then
2006                         gcc_cv_as_eh_frame="yes"
2007                 else
2008                         gcc_cv_as_eh_frame="bad"
2009                         if $gcc_cv_as -o conftest.o --traditional-format /dev/null; then
2010                                 AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2011         [Define if your assembler mis-optimizes .eh_frame data.])
2012                         fi
2013                 fi
2014         fi
2015         rm -f conftest.*
2016 fi
2017 AC_MSG_RESULT($gcc_cv_as_eh_frame)
2018
2019 AC_MSG_CHECKING(assembler section merging support)
2020 gcc_cv_as_shf_merge=no
2021 if test $in_tree_gas = yes ; then
2022   gcc_GAS_VERSION_GTE_IFELSE(2,12,0,[
2023     test $in_tree_gas_is_elf = yes && gcc_cv_as_shf_merge="yes"
2024   ])
2025 elif test x$gcc_cv_as != x; then
2026         # Check if we support SHF_MERGE sections
2027         echo '.section .rodata.str, "aMS", @progbits, 1' > conftest.s
2028         if $gcc_cv_as --fatal-warnings -o conftest.o conftest.s > /dev/null 2>&1; then
2029                 gcc_cv_as_shf_merge=yes
2030         fi
2031         rm -f conftest.s conftest.o
2032 fi
2033 if test x"$gcc_cv_as_shf_merge" = xyes; then
2034         AC_DEFINE(HAVE_GAS_SHF_MERGE, 1,
2035 [Define if your assembler supports marking sections with SHF_MERGE flag.])
2036 fi
2037 AC_MSG_RESULT($gcc_cv_as_shf_merge)
2038
2039 AC_MSG_CHECKING(assembler thread-local storage support)
2040 gcc_cv_as_tls=no
2041 conftest_s=
2042 tls_first_major=
2043 tls_first_minor=
2044 tls_as_opt=
2045 case "$target" in
2046 changequote(,)dnl
2047   alpha*-*-*)
2048     conftest_s='
2049         .section ".tdata","awT",@progbits
2050 foo:    .long   25
2051         .text
2052         ldq     $27,__tls_get_addr($29)         !literal!1
2053         lda     $16,foo($29)                    !tlsgd!1
2054         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2055         ldq     $27,__tls_get_addr($29)         !literal!2
2056         lda     $16,foo($29)                    !tlsldm!2
2057         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2058         ldq     $1,foo($29)                     !gotdtprel
2059         ldah    $2,foo($29)                     !dtprelhi
2060         lda     $3,foo($2)                      !dtprello
2061         lda     $4,foo($29)                     !dtprel
2062         ldq     $1,foo($29)                     !gottprel
2063         ldah    $2,foo($29)                     !tprelhi
2064         lda     $3,foo($2)                      !tprello
2065         lda     $4,foo($29)                     !tprel'
2066         tls_first_major=2
2067         tls_first_minor=13
2068         ;;
2069   i[34567]86-*-*)
2070 changequote([,])dnl
2071     conftest_s='
2072         .section ".tdata","awT",@progbits
2073 foo:    .long   25
2074         .text
2075         movl    %gs:0, %eax
2076         leal    foo@TLSGD(,%ebx,1), %eax
2077         leal    foo@TLSLDM(%ebx), %eax
2078         leal    foo@DTPOFF(%eax), %edx
2079         movl    foo@GOTTPOFF(%ebx), %eax
2080         subl    foo@GOTTPOFF(%ebx), %eax
2081         addl    foo@GOTNTPOFF(%ebx), %eax
2082         movl    foo@INDNTPOFF, %eax
2083         movl    $foo@TPOFF, %eax
2084         subl    $foo@TPOFF, %eax
2085         leal    foo@NTPOFF(%ecx), %eax'
2086         tls_first_major=2
2087         tls_first_minor=14
2088         ;;
2089   x86_64-*-*)
2090     conftest_s='
2091         .section ".tdata","awT",@progbits
2092 foo:    .long   25
2093         .text
2094         movq    %fs:0, %rax
2095         leaq    foo@TLSGD(%rip), %rdi
2096         leaq    foo@TLSLD(%rip), %rdi
2097         leaq    foo@DTPOFF(%rax), %rdx
2098         movq    foo@GOTTPOFF(%rip), %rax
2099         movq    $foo@TPOFF, %rax'
2100         tls_first_major=2
2101         tls_first_minor=14
2102         ;;
2103   ia64-*-*)
2104     conftest_s='
2105         .section ".tdata","awT",@progbits
2106 foo:    data8   25
2107         .text
2108         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2109         addl    r17 = @ltoff(@dtprel(foo#)), gp
2110         addl    r18 = @ltoff(@tprel(foo#)), gp
2111         addl    r19 = @dtprel(foo#), gp
2112         adds    r21 = @dtprel(foo#), r13
2113         movl    r23 = @dtprel(foo#)
2114         addl    r20 = @tprel(foo#), gp
2115         adds    r22 = @tprel(foo#), r13
2116         movl    r24 = @tprel(foo#)'
2117         tls_first_major=2
2118         tls_first_minor=13
2119         ;;
2120   powerpc-*-*)
2121     conftest_s='
2122         .section ".tdata","awT",@progbits
2123         .align 2
2124 ld0:    .space 4
2125 ld1:    .space 4
2126 x1:     .space 4
2127 x2:     .space 4
2128 x3:     .space 4
2129         .text
2130         addi 3,31,ld0@got@tlsgd
2131         bl __tls_get_addr
2132         addi 3,31,x1@got@tlsld
2133         bl __tls_get_addr
2134         addi 9,3,x1@dtprel
2135         addis 9,3,x2@dtprel@ha
2136         addi 9,9,x2@dtprel@l
2137         lwz 9,x3@got@tprel(31)
2138         add 9,9,x@tls
2139         addi 9,2,x1@tprel
2140         addis 9,2,x2@tprel@ha
2141         addi 9,9,x2@tprel@l'
2142         tls_first_major=2
2143         tls_first_minor=14
2144         tls_as_opt=-a32
2145         ;;
2146   powerpc64-*-*)
2147     conftest_s='
2148         .section ".tdata","awT",@progbits
2149         .align 3
2150 ld0:    .space 8
2151 ld1:    .space 8
2152 x1:     .space 8
2153 x2:     .space 8
2154 x3:     .space 8
2155         .text
2156         addi 3,2,ld0@got@tlsgd
2157         bl .__tls_get_addr
2158         nop
2159         addi 3,2,ld1@toc
2160         bl .__tls_get_addr
2161         nop
2162         addi 3,2,x1@got@tlsld
2163         bl .__tls_get_addr
2164         nop
2165         addi 9,3,x1@dtprel
2166         bl .__tls_get_addr
2167         nop
2168         addis 9,3,x2@dtprel@ha
2169         addi 9,9,x2@dtprel@l
2170         bl .__tls_get_addr
2171         nop
2172         ld 9,x3@got@dtprel(2)
2173         add 9,9,3
2174         bl .__tls_get_addr
2175         nop'
2176         tls_first_major=2
2177         tls_first_minor=14
2178         tls_as_opt=-a64
2179         ;;
2180   s390-*-*)
2181     conftest_s='
2182         .section ".tdata","awT",@progbits
2183 foo:    .long   25
2184         .text
2185         .long   foo@TLSGD
2186         .long   foo@TLSLDM
2187         .long   foo@DTPOFF
2188         .long   foo@NTPOFF
2189         .long   foo@GOTNTPOFF
2190         .long   foo@INDNTPOFF
2191         l       %r1,foo@GOTNTPOFF(%r12)
2192         l       %r1,0(%r1):tls_load:foo
2193         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2194         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2195         tls_first_major=2
2196         tls_first_minor=14
2197         tls_as_opt=-m31
2198         ;;
2199   s390x-*-*)
2200     conftest_s='
2201         .section ".tdata","awT",@progbits
2202 foo:    .long   25
2203         .text
2204         .quad   foo@TLSGD
2205         .quad   foo@TLSLDM
2206         .quad   foo@DTPOFF
2207         .quad   foo@NTPOFF
2208         .quad   foo@GOTNTPOFF
2209         lg      %r1,foo@GOTNTPOFF(%r12)
2210         larl    %r1,foo@INDNTPOFF
2211         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2212         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2213         tls_first_major=2
2214         tls_first_minor=14
2215         tls_as_opt="-m64 -Aesame"
2216         ;;
2217 esac
2218 if test -z "$tls_first_major"; then
2219   :
2220 elif test $in_tree_gas = yes ; then
2221   gcc_GAS_VERSION_GTE_IFELSE($tls_first_major,$tls_first_minor,0,[
2222     gcc_cv_as_tls=yes
2223   ])
2224 elif test x$gcc_cv_as != x; then
2225   echo "$conftest_s" > conftest.s
2226   if $gcc_cv_as $tls_as_opt --fatal-warnings -o conftest.o conftest.s > /dev/null 2>&1
2227   then
2228     gcc_cv_as_tls=yes
2229   fi
2230   rm -f conftest.s conftest.o
2231 fi
2232 if test "$gcc_cv_as_tls" = yes; then
2233   AC_DEFINE(HAVE_AS_TLS, 1,
2234             [Define if your assembler supports thread-local storage.])
2235 fi
2236 AC_MSG_RESULT($gcc_cv_as_tls)
2237
2238 case "$target" in
2239   # All TARGET_ABI_OSF targets.
2240   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2241     AC_CACHE_CHECK([assembler supports explicit relocations],
2242         gcc_cv_as_explicit_relocs, [
2243         gcc_cv_as_explicit_relocs=unknown
2244         if test $in_tree_gas = yes ; then
2245            gcc_GAS_VERSION_GTE_IFELSE(2,12,0,[
2246               gcc_cv_as_explicit_relocs=yes
2247            ])
2248         elif test x$gcc_cv_as != x; then
2249             cat > conftest.s << 'EOF'
2250         .set nomacro
2251         .text
2252         extbl   $3, $2, $3      !lituse_bytoff!1
2253         ldq     $2, a($29)      !literal!1
2254         ldq     $4, b($29)      !literal!2
2255         ldq_u   $3, 0($2)       !lituse_base!1
2256         ldq     $27, f($29)     !literal!5
2257         jsr     $26, ($27), f   !lituse_jsr!5
2258         ldah    $29, 0($26)     !gpdisp!3
2259         lda     $0, c($29)      !gprel
2260         ldah    $1, d($29)      !gprelhigh
2261         lda     $1, d($1)       !gprellow
2262         lda     $29, 0($29)     !gpdisp!3
2263 EOF
2264             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
2265                 gcc_cv_as_explicit_relocs=yes
2266             else
2267                 gcc_cv_as_explicit_relocs=no
2268             fi
2269             rm -f conftest.s conftest.o
2270         fi
2271     ])
2272     if test "x$gcc_cv_as_explicit_relocs" = xyes; then
2273         AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2274                 [Define if your assembler supports explicit relocations.])
2275     fi
2276     ;;
2277   sparc*-*-*)
2278     AC_CACHE_CHECK([assembler .register pseudo-op support],
2279         gcc_cv_as_register_pseudo_op, [
2280         gcc_cv_as_register_pseudo_op=unknown
2281         if test x$gcc_cv_as != x; then
2282             # Check if we have .register
2283             echo ".register %g2, #scratch" > conftest.s
2284             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
2285                 gcc_cv_as_register_pseudo_op=yes
2286             else
2287                 gcc_cv_as_register_pseudo_op=no
2288             fi
2289             rm -f conftest.s conftest.o
2290         fi
2291     ])
2292     if test "x$gcc_cv_as_register_pseudo_op" = xyes; then
2293         AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2294                 [Define if your assembler supports .register.])
2295     fi
2296
2297     AC_CACHE_CHECK([assembler supports -relax],
2298         gcc_cv_as_relax_opt, [
2299         gcc_cv_as_relax_opt=unknown
2300         if test x$gcc_cv_as != x; then
2301             # Check if gas supports -relax
2302             echo ".text" > conftest.s
2303             if $gcc_cv_as -relax -o conftest.o conftest.s > /dev/null 2>&1; then
2304                 gcc_cv_as_relax_opt=yes
2305             else
2306                 gcc_cv_as_relax_opt=no
2307             fi
2308             rm -f conftest.s conftest.o
2309         fi
2310     ])
2311     if test "x$gcc_cv_as_relax_opt" = xyes; then
2312         AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2313                 [Define if your assembler supports -relax option.])
2314     fi
2315
2316     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
2317         gcc_cv_as_sparc_ua_pcrel, [
2318         gcc_cv_as_sparc_ua_pcrel=unknown
2319         if test x$gcc_cv_as != x -a x$gcc_cv_ld != x; then
2320             gcc_cv_as_sparc_ua_pcrel=no
2321             echo ".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo)" > conftest.s
2322             if $gcc_cv_as -K PIC -o conftest.o conftest.s > /dev/null 2>&1 \
2323                && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2324                 gcc_cv_as_sparc_ua_pcrel=yes
2325             fi
2326             rm -f conftest.s conftest.o conftest
2327         fi
2328     ])
2329     if test "x$gcc_cv_as_sparc_ua_pcrel" = xyes; then
2330         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2331                 [Define if your assembler and linker support unaligned PC relative relocs.])
2332     fi
2333
2334     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs against hidden symbols],
2335         gcc_cv_as_sparc_ua_pcrel_hidden, [
2336         if test "x$gcc_cv_as_sparc_ua_pcrel" = xyes; then
2337             gcc_cv_as_sparc_ua_pcrel_hidden=unknown
2338             if test x$gcc_cv_objdump != x; then
2339                 gcc_cv_as_sparc_ua_pcrel_hidden=no
2340                 echo ".data; .align 4; .byte 0x31; .uaword %r_disp32(foo)" > conftest.s
2341                 echo ".byte 0x32, 0x33, 0x34; .global foo; .hidden foo" >> conftest.s
2342                 echo "foo: .skip 4" >> conftest.s
2343                 if $gcc_cv_as -K PIC -o conftest.o conftest.s > /dev/null 2>&1 \
2344                    && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2345                    && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2346                       | grep ' 31000000 07323334' > /dev/null 2>&1; then
2347                     if $gcc_cv_objdump -R conftest 2> /dev/null \
2348                        | grep 'DISP32' > /dev/null 2>&1; then
2349                         :
2350                     else
2351                         gcc_cv_as_sparc_ua_pcrel_hidden=yes
2352                     fi
2353                 fi
2354             fi
2355             rm -f conftest.s conftest.o conftest
2356         else
2357             gcc_cv_as_sparc_ua_pcrel_hidden="$gcc_cv_as_sparc_ua_pcrel"
2358         fi
2359     ])
2360     if test "x$gcc_cv_as_sparc_ua_pcrel_hidden" = xyes; then
2361         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2362                 [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])
2363     fi
2364
2365     AC_CACHE_CHECK([for assembler offsetable %lo() support],
2366         gcc_cv_as_offsetable_lo10, [
2367         gcc_cv_as_offsetable_lo10=unknown
2368         if test "x$gcc_cv_as" != x; then
2369             # Check if assembler has offsetable %lo()
2370             echo "or %g1, %lo(ab) + 12, %g1" > conftest.s
2371             echo "or %g1, %lo(ab + 12), %g1" > conftest1.s
2372             if $gcc_cv_as -xarch=v9 -o conftest.o conftest.s \
2373                     > /dev/null 2>&1 &&
2374                $gcc_cv_as -xarch=v9 -o conftest1.o conftest1.s \
2375                     > /dev/null 2>&1; then
2376                 if cmp conftest.o conftest1.o > /dev/null 2>&1; then
2377                     gcc_cv_as_offsetable_lo10=no
2378                 else
2379                     gcc_cv_as_offsetable_lo10=yes
2380                 fi
2381             else
2382                 gcc_cv_as_offsetable_lo10=no
2383             fi
2384             rm -f conftest.s conftest.o conftest1.s conftest1.o
2385         fi
2386     ])
2387     if test "x$gcc_cv_as_offsetable_lo10" = xyes; then
2388         AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2389             [Define if your assembler supports offsetable %lo().])
2390     fi
2391
2392     ;;
2393
2394 changequote(,)dnl
2395   i[34567]86-*-* | x86_64-*-*)
2396 changequote([,])dnl
2397     AC_MSG_CHECKING(assembler instructions)
2398     gcc_cv_as_instructions=
2399     if test $in_tree_gas = yes ; then
2400       gcc_GAS_VERSION_GTE_IFELSE(2,9,0,[
2401         gcc_cv_as_instructions="filds fists"
2402       ])
2403     elif test x$gcc_cv_as != x; then
2404         set "filds fists" "filds mem; fists mem"
2405         while test $# -gt 0
2406         do
2407                 echo "$2" > conftest.s
2408                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
2409                         gcc_cv_as_instructions=${gcc_cv_as_instructions}$1" "
2410                 fi
2411                 shift 2
2412         done
2413         rm -f conftest.s conftest.o
2414     fi
2415     if test x"$gcc_cv_as_instructions" != x; then
2416         AC_DEFINE_UNQUOTED(HAVE_GAS_`echo "$gcc_cv_as_instructions" | sed -e 's/ $//' | tr '[a-z ]' '[A-Z_]'`)
2417     fi
2418     AC_MSG_RESULT($gcc_cv_as_instructions)
2419
2420     AC_MSG_CHECKING(assembler GOTOFF in data directives)
2421     gcc_cv_as_gotoff_in_data=no
2422     if test $in_tree_gas = yes ; then
2423       gcc_GAS_VERSION_GTE_IFELSE(2,11,0,[
2424         gcc_cv_as_gotoff_in_data=yes
2425       ])
2426     elif test x$gcc_cv_as != x; then
2427         cat > conftest.s <<EOF
2428         .text
2429 .L0:
2430         nop
2431         .data
2432         .long .L0@GOTOFF
2433 EOF
2434         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
2435           gcc_cv_as_gotoff_in_data=yes
2436         fi
2437     fi
2438     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2439       [`if test $gcc_cv_as_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2440       [Define true if the assembler supports '.long foo@GOTOFF'.])
2441     AC_MSG_RESULT($gcc_cv_as_gotoff_in_data)
2442     ;;
2443
2444   ia64*-*-*)
2445     AC_CACHE_CHECK([assembler supports ltoffx and ldxmov],
2446         gcc_cv_as_ltoffx_ldxmov_relocs, [
2447         gcc_cv_as_ltoffx_ldxmov_relocs=unknown
2448         if test $in_tree_gas = yes ; then
2449           gcc_GAS_VERSION_GTE_IFELSE(2,14,0,[
2450             gcc_cv_as_ltoffx_ldxmov_relocs=yes
2451           ])
2452         elif test x$gcc_cv_as != x; then
2453             cat > conftest.s << 'EOF'
2454 changequote(,)dnl
2455         .text
2456         addl r15 = @ltoffx(x#), gp
2457         ;;
2458         ld8.mov r16 = [r15], x#
2459 EOF
2460 changequote([,])dnl
2461             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
2462                 gcc_cv_as_ltoffx_ldxmov_relocs=yes
2463             else
2464                 gcc_cv_as_ltoffx_ldxmov_relocs=no
2465             fi
2466             rm -f conftest.s conftest.o
2467         fi
2468     ])
2469     if test "x$gcc_cv_as_ltoffx_ldxmov_relocs" = xyes; then
2470         AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2471           [Define if your assembler supports ltoffx and ldxmov relocations.])
2472     fi
2473     ;;
2474   powerpc*-*-*)
2475     AC_CACHE_CHECK([assembler supports mfcr field],
2476         gcc_cv_as_mfcrf, [
2477         gcc_cv_as_mfcrf=unknown
2478         if test $in_tree_gas = yes ; then
2479           gcc_GAS_VERSION_GTE_IFELSE(2,14,0,[
2480             gcc_cv_as_mfcrf=yes
2481           ])
2482         elif test x$gcc_cv_as != x; then
2483             cat > conftest.s << 'EOF'
2484               case "$target" in
2485 changequote(,)dnl
2486                 *-*-aix*)
2487         .csect .text[PR]
2488                 ;;
2489                 *)
2490         .text
2491                 ;;
2492               esac
2493         mfcr 3,128
2494 EOF
2495 changequote([,])dnl
2496             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
2497                 gcc_cv_as_mfcrf=yes
2498             else
2499                 gcc_cv_as_mfcrf=no
2500             fi
2501             rm -f conftest.s conftest.o
2502         fi
2503     ])
2504     if test "x$gcc_cv_as_mfcrf" = xyes; then
2505         AC_DEFINE(HAVE_AS_MFCRF, 1,
2506           [Define if your assembler supports mfcr field.])
2507     fi
2508     ;;
2509 esac
2510
2511 AC_MSG_CHECKING(assembler dwarf2 debug_line support)
2512 gcc_cv_as_dwarf2_debug_line=no
2513 # ??? Not all targets support dwarf2 debug_line, even within a version
2514 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2515 # info to the output file.  So, as supported targets are added to gas 2.11,
2516 # add some instruction here to (also) show we expect this might work.
2517 # ??? Once 2.11 is released, probably need to add first known working
2518 # version to the per-target configury.
2519 case "$target" in
2520   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2521   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2522   | xstormy16*-*-* | cris-*-*)
2523     insn="nop"
2524     ;;
2525   ia64*-*-*)
2526     insn="nop 0"
2527     ;;
2528   mmix-*-*)
2529     insn="swym 0"
2530     ;;
2531   esac
2532 if test $in_tree_gas = yes ; then
2533   gcc_GAS_VERSION_GTE_IFELSE(2,11,0,[
2534     test $in_tree_gas_is_elf = yes && test x"$insn" != x \
2535         && gcc_cv_as_dwarf2_debug_line="yes"
2536   ])
2537 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
2538         echo '  .file 1 "conftest.s"' > conftest.s
2539         echo '  .loc 1 3 0' >> conftest.s
2540         echo "  $insn" >> conftest.s
2541         # ??? This fails with non-gnu grep.
2542         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
2543            && grep debug_line conftest.o > /dev/null 2>&1 ; then
2544                 # The .debug_line file table must be in the exact order that
2545                 # we specified the files, since these indices are also used
2546                 # by DW_AT_decl_file.  Approximate this test by testing if
2547                 # the assembler bitches if the same index is assigned twice.
2548                 echo '  .file 1 "foo.s"' > conftest.s
2549                 echo '  .file 1 "bar.s"' >> conftest.s
2550                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1
2551                 then
2552                   gcc_cv_as_dwarf2_debug_line="no"
2553                 else
2554                   gcc_cv_as_dwarf2_debug_line="yes"
2555                 fi
2556         fi
2557         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
2558 fi
2559 if test x"$gcc_cv_as_dwarf2_debug_line" = xyes; then
2560         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2561 [Define if your assembler supports dwarf2 .file/.loc directives,
2562    and preserves file table indices exactly as given.])
2563 fi
2564 AC_MSG_RESULT($gcc_cv_as_dwarf2_debug_line)
2565
2566 AC_MSG_CHECKING(assembler --gdwarf2 support)
2567 gcc_cv_as_gdwarf2_flag=no
2568 if test $in_tree_gas = yes ; then
2569   gcc_GAS_VERSION_GTE_IFELSE(2,11,0,[
2570     test $in_tree_gas_is_elf = yes && test x"$insn" != x \
2571         && gcc_cv_as_gdwarf2_flag="yes"
2572   ])
2573 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
2574         echo '' > conftest.s
2575         # ??? This fails with non-gnu grep.
2576         if $gcc_cv_as --gdwarf2 -o conftest.o conftest.s > /dev/null 2>&1
2577           then
2578           gcc_cv_as_gdwarf2_flag="yes"
2579         fi
2580         rm -f conftest.s conftest.o
2581 fi
2582 if test x"$gcc_cv_as_gdwarf2_flag" = xyes; then
2583         AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2584 [Define if your assembler supports the --gdwarf2 option.])
2585 fi
2586 AC_MSG_RESULT($gcc_cv_as_gdwarf2_flag)
2587
2588 AC_MSG_CHECKING(assembler --gstabs support)
2589 gcc_cv_as_gstabs_flag=no
2590 if test $in_tree_gas = yes ; then
2591   gcc_GAS_VERSION_GTE_IFELSE(2,11,0,[
2592     test $in_tree_gas_is_elf = yes && test x"$insn" != x \
2593         && gcc_cv_as_gstabs_flag="yes"
2594   ])
2595 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
2596         echo '' > conftest.s
2597         # ??? This fails with non-gnu grep.
2598         if $gcc_cv_as --gstabs -o conftest.o conftest.s > /dev/null 2>&1 ; then
2599           gcc_cv_as_gstabs_flag="yes"
2600           # The native Solaris 9/Intel assembler doesn't understand --gstabs
2601           # and warns about it, but still exits successfully.  So check for
2602           # this.
2603           if $gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | \
2604                 grep -i warning > /dev/null ; then
2605             gcc_cv_as_gstabs_flag="no"
2606           fi
2607         fi
2608         rm -f conftest.s conftest.o
2609 fi
2610 if test x"$gcc_cv_as_gstabs_flag" = xyes; then
2611         AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2612 [Define if your assembler supports the --gstabs option.])
2613 fi
2614 AC_MSG_RESULT($gcc_cv_as_gstabs_flag)
2615
2616 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2617 gcc_cv_ld_ro_rw_mix=unknown
2618 if test $in_tree_ld = yes ; then
2619   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2620      && test $in_tree_ld_is_elf = yes; then
2621     gcc_cv_ld_ro_rw_mix=read-write
2622   fi
2623 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2624   echo '.section myfoosect, "a"' > conftest1.s
2625   echo '.section myfoosect, "aw"' > conftest2.s
2626   echo '.byte 1' >> conftest2.s
2627   echo '.section myfoosect, "a"' > conftest3.s
2628   echo '.byte 0' >> conftest3.s
2629   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2630      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2631      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2632      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2633         conftest2.o conftest3.o > /dev/null 2>&1; then
2634     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2635                          | sed -e '/myfoosect/!d' -e N`
2636     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2637       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2638         gcc_cv_ld_ro_rw_mix=read-only
2639       else
2640         gcc_cv_ld_ro_rw_mix=read-write
2641       fi
2642     fi
2643   fi
2644 changequote(,)dnl
2645   rm -f conftest.* conftest[123].*
2646 changequote([,])dnl
2647 fi
2648 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2649         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2650   [Define if your linker links a mix of read-only
2651    and read-write sections into a read-write section.])
2652 fi
2653 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2654
2655 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2656 gcc_cv_ld_eh_frame_hdr=no
2657 if test $in_tree_ld = yes ; then
2658   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2659      && test $in_tree_ld_is_elf = yes; then
2660     gcc_cv_ld_eh_frame_hdr=yes
2661   fi
2662 elif test x$gcc_cv_ld != x; then
2663         # Check if linker supports --eh-frame-hdr option
2664         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2665                 gcc_cv_ld_eh_frame_hdr=yes
2666         fi
2667 fi
2668 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2669         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2670 [Define if your linker supports --eh-frame-hdr option.])
2671 fi
2672 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2673
2674 AC_MSG_CHECKING(linker position independent executable support)
2675 gcc_cv_ld_pie=no
2676 if test $in_tree_ld = yes ; then
2677   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2678      && test $in_tree_ld_is_elf = yes; then
2679     gcc_cv_ld_pie=yes
2680   fi
2681 elif test x$gcc_cv_ld != x; then
2682         # Check if linker supports -pie option
2683         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2684                 gcc_cv_ld_pie=yes
2685         fi
2686 fi
2687 if test x"$gcc_cv_ld_pie" = xyes; then
2688         AC_DEFINE(HAVE_LD_PIE, 1,
2689 [Define if your linker supports -pie option.])
2690 fi
2691 AC_MSG_RESULT($gcc_cv_ld_pie)
2692
2693 # Miscellaneous target-specific checks.
2694 case "$target" in
2695   mips*-*-*)
2696     AC_MSG_CHECKING(whether libgloss uses STARTUP directives consistently)
2697     gcc_cv_mips_libgloss_startup=no
2698     gcc_cv_libgloss_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/libgloss
2699     if test "x$exec_prefix" = xNONE; then
2700       if test "x$prefix" = xNONE; then
2701         test_prefix=/usr/local
2702       else
2703         test_prefix=$prefix
2704       fi
2705     else
2706       test_prefix=$exec_prefix
2707     fi
2708     for f in $gcc_cv_libgloss_srcdir/mips/idt.ld $test_prefix/$target_alias/lib/idt.ld
2709     do
2710       if grep '^STARTUP' $f > /dev/null 2>&1; then
2711         gcc_cv_mips_libgloss_startup=yes
2712         break
2713       fi
2714     done
2715     if test x"$gcc_cv_mips_libgloss_startup" = xyes; then
2716       AC_DEFINE(HAVE_MIPS_LIBGLOSS_STARTUP_DIRECTIVES, 1,
2717         [Define if your MIPS libgloss linker scripts consistently include STARTUP directives.])
2718     fi
2719     AC_MSG_RESULT($gcc_cv_mips_libgloss_startup)
2720
2721     AC_MSG_CHECKING(whether the assembler has explicit relocation support)
2722     if test x$gcc_cv_mips_explicit_relocs = x; then
2723       gcc_cv_mips_explicit_relocs=no
2724       if test $in_tree_gas = yes; then
2725         gcc_GAS_VERSION_GTE_IFELSE(2,14,0,[
2726           gcc_cv_mips_explicit_relocs=yes
2727         ])
2728       elif test x$gcc_cv_as != x; then
2729         echo '  lw $4,%gp_rel(foo)($4)' > conftest.s
2730         if $gcc_cv_as conftest.s -o conftest.o > /dev/null 2>&1; then
2731           gcc_cv_mips_explicit_relocs=yes
2732         fi
2733         rm -f conftest.s conftest.o
2734       fi
2735     fi
2736     if test $gcc_cv_mips_explicit_relocs = yes; then
2737       test x$target_cpu_default != x || target_cpu_default=0
2738       target_cpu_default="(${target_cpu_default}|MASK_EXPLICIT_RELOCS)"
2739     fi
2740     AC_MSG_RESULT($gcc_cv_mips_explicit_relocs)
2741     ;;
2742 esac
2743
2744 if test x$with_sysroot = x && test x$host = x$target \
2745    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
2746   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include")
2747 fi
2748
2749 # Figure out what language subdirectories are present.
2750 # Look if the user specified --enable-languages="..."; if not, use
2751 # the environment variable $LANGUAGES if defined. $LANGUAGES might
2752 # go away some day.
2753 # NB:  embedded tabs in this IF block -- do not untabify
2754 if test x"${enable_languages+set}" != xset; then
2755         if test x"${LANGUAGES+set}" = xset; then
2756                 enable_languages="${LANGUAGES}"
2757                 AC_MSG_WARN([setting LANGUAGES is deprecated, use --enable-languages instead])
2758
2759         else
2760                 enable_languages=all
2761         fi
2762 else
2763         if test x"${enable_languages}" = x \
2764         || test x"${enable_languages}" = xyes;
2765         then
2766                 AC_MSG_ERROR([--enable-languages needs at least one language argument])
2767         fi
2768 fi
2769 enable_languages=`echo "${enable_languages}" | sed -e 's/[[     ,]][[   ,]]*/,/g' -e 's/,$//'`
2770
2771 # First scan to see if an enabled language requires some other language.
2772 # We assume that a given config-lang.in will list all the language
2773 # front ends it requires, even if some are required indirectly.
2774 for lang in ${srcdir}/*/config-lang.in ..
2775 do
2776    case $lang in
2777     ..)
2778        ;;
2779     # The odd quoting in the next line works around
2780     # an apparent bug in bash 1.12 on linux.
2781 changequote(,)dnl
2782     ${srcdir}/[*]/config-lang.in)
2783        ;;
2784     *)
2785        lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^      ]*\).*$,\1,p' $lang`
2786        this_lang_requires=`sed -n -e 's,^lang_requires=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^lang_requires=\([^    ]*\).*$,\1,p' $lang`
2787        for other in $this_lang_requires
2788        do
2789           case ,${enable_languages}, in
2790            *,$other,*)
2791               ;;
2792            *,all,*)
2793               ;;
2794            *,$lang_alias,*)
2795               enable_languages="$enable_languages,$other"
2796               ;;
2797           esac
2798        done
2799        ;;
2800 changequote([,])dnl
2801    esac
2802 done
2803
2804 expected_languages=`echo ,${enable_languages}, | sed -e 's:,: :g' -e 's:  *: :g' -e 's:  *: :g' -e 's:^ ::' -e 's: $::'`
2805 found_languages=
2806 subdirs=
2807 for lang in ${srcdir}/*/config-lang.in ..
2808 do
2809         case $lang in
2810         ..) ;;
2811         # The odd quoting in the next line works around
2812         # an apparent bug in bash 1.12 on linux.
2813 changequote(,)dnl
2814         ${srcdir}/[*]/config-lang.in) ;;
2815         *)
2816           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
2817           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
2818           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
2819           if test "x$lang_alias" = x
2820           then
2821                 echo "$lang doesn't set \$language." 1>&2
2822                 exit 1
2823           fi
2824           case ${build_by_default},${enable_languages}, in
2825           *,$lang_alias,*) add_this_lang=yes ;;
2826           no,*) add_this_lang=no ;;
2827           *,all,*) add_this_lang=yes ;;
2828           *) add_this_lang=no ;;
2829           esac
2830           found_languages="${found_languages} ${lang_alias}"
2831           if test x"${add_this_lang}" = xyes; then
2832                 case $lang in
2833                     ${srcdir}/ada/config-lang.in)
2834                         if test x$have_gnat = xyes ; then
2835                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2836                         fi
2837                         ;;
2838                     *)
2839                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2840                         ;;
2841                 esac
2842           fi
2843           ;;
2844 changequote([,])dnl
2845         esac
2846 done
2847
2848 missing_languages=
2849 for expected_language in ${expected_languages} ..
2850 do
2851     if test "${expected_language}" != ..; then
2852         missing_language="${expected_language}"
2853         if test "${expected_language}" = "c" \
2854            || test "${expected_language}" = "all"; then
2855                 missing_language=
2856         fi
2857         for found_language in ${found_languages} ..
2858         do
2859             if test "${found_language}" != ..; then
2860                 if test "${expected_language}" = "${found_language}"; then
2861                     missing_language=
2862                 fi
2863             fi
2864         done
2865         if test "x${missing_language}" != x; then
2866            missing_languages="${missing_languages} ${missing_language}"
2867         fi
2868     fi
2869 done
2870
2871 if test "x$missing_languages" != x; then
2872   AC_MSG_ERROR([
2873 The following requested languages were not found:${missing_languages}
2874 The following languages were available: c${found_languages}])
2875 fi
2876
2877 # Make gthr-default.h if we have a thread file.
2878 gthread_flags=
2879 if test $thread_file != single; then
2880     rm -f gthr-default.h
2881     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
2882     gthread_flags=-DHAVE_GTHR_DEFAULT
2883 fi
2884 AC_SUBST(gthread_flags)
2885
2886 # Find out what GC implementation we want, or may, use.
2887 AC_ARG_WITH(gc,
2888 [  --with-gc={simple,page} choose the garbage collection mechanism to use
2889                           with the compiler],
2890 [case "$withval" in
2891   simple | page)
2892     GGC=ggc-$withval
2893     ;;
2894   *)
2895     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2896     ;;
2897 esac],
2898 [GGC=ggc-page])
2899 AC_SUBST(GGC)
2900 echo "Using $GGC for garbage collection."
2901
2902 # Use the system's zlib library.
2903 zlibdir=-L../zlib
2904 zlibinc="-I\$(srcdir)/../zlib"
2905 AC_ARG_WITH(system-zlib,
2906 [  --with-system-zlib      use installed libz],
2907 zlibdir=
2908 zlibinc=
2909 )
2910 AC_SUBST(zlibdir)
2911 AC_SUBST(zlibinc)
2912
2913 dnl Very limited version of automake's enable-maintainer-mode
2914
2915 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2916   dnl maintainer-mode is disabled by default
2917   AC_ARG_ENABLE(maintainer-mode,
2918 [  --enable-maintainer-mode
2919                           enable make rules and dependencies not useful
2920                           (and sometimes confusing) to the casual installer],
2921       maintainer_mode=$enableval,
2922       maintainer_mode=no)
2923
2924 AC_MSG_RESULT($maintainer_mode)
2925
2926 if test "$maintainer_mode" = "yes"; then
2927   MAINT=''
2928 else
2929   MAINT='#'
2930 fi
2931 AC_SUBST(MAINT)dnl
2932
2933 # Make empty files to contain the specs and options for each language.
2934 # Then add #include lines to for a compiler that has specs and/or options.
2935
2936 lang_opt_files=
2937 lang_specs_files=
2938 lang_options_files=
2939 lang_tree_files=
2940 for subdir in . $subdirs
2941 do
2942         if test -f $srcdir/$subdir/lang.opt; then
2943             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
2944         fi
2945         if test -f $srcdir/$subdir/lang-specs.h; then
2946             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
2947         fi
2948         if test -f $srcdir/$subdir/lang-options.h; then
2949             lang_options_files="$lang_options_files $srcdir/$subdir/lang-options.h"
2950         fi
2951         if test -f $srcdir/$subdir/$subdir-tree.def; then
2952             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
2953         fi
2954 done
2955
2956 # These (without "all_") are set in each config-lang.in.
2957 # `language' must be a single word so is spelled singularly.
2958 all_languages=
2959 all_boot_languages=
2960 all_compilers=
2961 all_stagestuff=
2962 all_outputs='Makefile fixinc/Makefile gccbug mklibgcc mkheaders'
2963 # List of language makefile fragments.
2964 all_lang_makefiles=
2965 # Files for gengtype
2966 all_gtfiles="$target_gtfiles"
2967 # Files for gengtype with language
2968 all_gtfiles_files_langs=
2969 all_gtfiles_files_files=
2970
2971 # Add the language fragments.
2972 # Languages are added via two mechanisms.  Some information must be
2973 # recorded in makefile variables, these are defined in config-lang.in.
2974 # We accumulate them and plug them into the main Makefile.
2975 # The other mechanism is a set of hooks for each of the main targets
2976 # like `clean', `install', etc.
2977
2978 language_fragments="Make-lang"
2979 language_hooks="Make-hooks"
2980
2981 for s in .. $subdirs
2982 do
2983         if test $s != ".."
2984         then
2985                 language=
2986                 boot_language=
2987                 compilers=
2988                 stagestuff=
2989                 outputs=
2990                 gtfiles=
2991                 . ${srcdir}/$s/config-lang.in
2992                 if test "x$language" = x
2993                 then
2994                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
2995                         exit 1
2996                 fi
2997                 all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Make-lang.in"
2998                 if test -f ${srcdir}/$s/Makefile.in
2999                 then all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Makefile.in"
3000                 fi
3001                 all_languages="$all_languages $language"
3002                 if test "x$boot_language" = xyes
3003                 then
3004                         all_boot_languages="$all_boot_languages $language"
3005                 fi
3006                 all_compilers="$all_compilers $compilers"
3007                 all_stagestuff="$all_stagestuff $stagestuff"
3008                 all_outputs="$all_outputs $outputs"
3009                 all_gtfiles="$all_gtfiles $gtfiles"
3010                 for f in .. $gtfiles
3011                 do
3012                      if test $f != ".."
3013                      then
3014                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3015                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3016                      fi
3017                 done
3018         fi
3019 done
3020
3021 # Pick up gtfiles for c
3022 gtfiles=
3023 s="c"
3024 . ${srcdir}/c-config-lang.in
3025 all_gtfiles="$all_gtfiles $gtfiles"
3026 for f in .. $gtfiles
3027 do
3028      if test $f != ".."
3029      then
3030         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3031         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3032      fi
3033 done
3034
3035 check_languages=
3036 for language in .. $all_languages
3037 do
3038         if test $language != ".."
3039         then
3040                 check_languages="$check_languages check-$language"
3041         fi
3042 done
3043
3044 # Since we can't use `::' targets, we link each language in
3045 # with a set of hooks, reached indirectly via lang.${target}.
3046
3047 rm -f Make-hooks
3048 touch Make-hooks
3049 target_list="all.build all.cross start.encap rest.encap tags \
3050         info dvi generated-manpages \
3051         install-normal install-common install-info install-man \
3052         uninstall \
3053         mostlyclean clean distclean extraclean maintainer-clean \
3054         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
3055 for t in $target_list
3056 do
3057         x=
3058         for lang in .. $all_languages
3059         do
3060                 if test $lang != ".."; then
3061                         x="$x $lang.$t"
3062                 fi
3063         done
3064         echo "lang.$t: $x" >> Make-hooks
3065 done
3066
3067 # Create .gdbinit.
3068
3069 echo "dir ." > .gdbinit
3070 echo "dir ${srcdir}" >> .gdbinit
3071 if test x$gdb_needs_out_file_path = xyes
3072 then
3073         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3074 fi
3075 if test "x$subdirs" != x; then
3076         for s in $subdirs
3077         do
3078                 echo "dir ${srcdir}/$s" >> .gdbinit
3079         done
3080 fi
3081 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3082
3083 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
3084 # absolute path for gcc_tooldir based on inserting the number of up-directory
3085 # movements required to get from $(exec_prefix) to $(prefix) into the basic
3086 # $(libsubdir)/@(unlibsubdir) based path.
3087 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
3088 # make and thus we'd get different behavior depending on where we built the
3089 # sources.
3090 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
3091     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_alias)'
3092 else
3093 changequote(<<, >>)dnl
3094 # An explanation of the sed strings:
3095 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
3096 #  -e 's|/$||'            match a trailing forward slash and eliminates it
3097 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
3098 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
3099 #
3100 # (*) Note this pattern overwrites the first character of the string
3101 # with a forward slash if one is not already present.  This is not a
3102 # problem because the exact names of the sub-directories concerned is
3103 # unimportant, just the number of them matters.
3104 #
3105 # The practical upshot of these patterns is like this:
3106 #
3107 #  prefix     exec_prefix        result
3108 #  ------     -----------        ------
3109 #   /foo        /foo/bar          ../
3110 #   /foo/       /foo/bar          ../
3111 #   /foo        /foo/bar/         ../
3112 #   /foo/       /foo/bar/         ../
3113 #   /foo        /foo/bar/ugg      ../../
3114 #
3115     dollar='$$'
3116     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_alias)"
3117 changequote([, ])dnl
3118 fi
3119 AC_SUBST(gcc_tooldir)
3120 AC_SUBST(dollar)
3121
3122 # Find a directory in which to install a shared libgcc.
3123
3124 AC_ARG_ENABLE(version-specific-runtime-libs,
3125 [  --enable-version-specific-runtime-libs
3126                           specify that runtime libraries should be
3127                           installed in a compiler-specific directory])
3128
3129 AC_ARG_WITH(slibdir,
3130 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
3131 slibdir="$with_slibdir",
3132 if test "${enable_version_specific_runtime_libs+set}" = set; then
3133   slibdir='$(libsubdir)'
3134 elif test "$host" != "$target"; then
3135   slibdir='$(build_tooldir)/lib'
3136 else
3137   slibdir='$(libdir)'
3138 fi)
3139 AC_SUBST(slibdir)
3140
3141 objdir=`${PWDCMD-pwd}`
3142 AC_SUBST(objdir)
3143
3144 # Process the language and host/target makefile fragments.
3145 ${CONFIG_SHELL-/bin/sh} $srcdir/configure.frag $srcdir "$subdirs" "$dep_host_xmake_file" "$dep_tmake_file"
3146
3147 # Substitute configuration variables
3148 AC_SUBST(subdirs)
3149 AC_SUBST(srcdir)
3150 AC_SUBST(all_boot_languages)
3151 AC_SUBST(all_compilers)
3152 AC_SUBST(all_gtfiles)
3153 AC_SUBST(all_gtfiles_files_langs)
3154 AC_SUBST(all_gtfiles_files_files)
3155 AC_SUBST(all_lang_makefiles)
3156 AC_SUBST(all_languages)
3157 AC_SUBST(all_stagestuff)
3158 AC_SUBST(build_exeext)
3159 AC_SUBST(build_install_headers_dir)
3160 AC_SUBST(build_xm_file_list)
3161 AC_SUBST(build_xm_file)
3162 AC_SUBST(build_xm_defines)
3163 AC_SUBST(check_languages)
3164 AC_SUBST(cc_set_by_configure)
3165 AC_SUBST(quoted_cc_set_by_configure)
3166 AC_SUBST(cpp_install_dir)
3167 AC_SUBST(dep_host_xmake_file)
3168 AC_SUBST(dep_tmake_file)
3169 AC_SUBST(extra_headers_list)
3170 AC_SUBST(extra_objs)
3171 AC_SUBST(extra_parts)
3172 AC_SUBST(extra_passes)
3173 AC_SUBST(extra_programs)
3174 AC_SUBST(float_h_file)
3175 AC_SUBST(gcc_config_arguments)
3176 AC_SUBST(gcc_gxx_include_dir)
3177 AC_SUBST(libstdcxx_incdir)
3178 AC_SUBST(gcc_version)
3179 AC_SUBST(gcc_version_full)
3180 AC_SUBST(gcc_version_trigger)
3181 AC_SUBST(host_exeext)
3182 AC_SUBST(host_extra_gcc_objs)
3183 AC_SUBST(host_xm_file_list)
3184 AC_SUBST(host_xm_file)
3185 AC_SUBST(host_xm_defines)
3186 AC_SUBST(out_host_hook_obj)
3187 AC_SUBST(install)
3188 AC_SUBST(lang_opt_files)
3189 AC_SUBST(lang_options_files)
3190 AC_SUBST(lang_specs_files)
3191 AC_SUBST(lang_tree_files)
3192 AC_SUBST(local_prefix)
3193 AC_SUBST(md_file)
3194 AC_SUBST(objc_boehm_gc)
3195 AC_SUBST(out_file)
3196 AC_SUBST(out_object_file)
3197 AC_SUBST(stage_prefix_set_by_configure)
3198 AC_SUBST(quoted_stage_prefix_set_by_configure)
3199 AC_SUBST(symbolic_link)
3200 AC_SUBST(thread_file)
3201 AC_SUBST(tm_file_list)
3202 AC_SUBST(tm_file)
3203 AC_SUBST(tm_defines)
3204 AC_SUBST(tm_p_file_list)
3205 AC_SUBST(tm_p_file)
3206 AC_SUBST(xm_file)
3207 AC_SUBST(xm_defines)
3208 AC_SUBST(target_alias)
3209 AC_SUBST(c_target_objs)
3210 AC_SUBST(cxx_target_objs)
3211 AC_SUBST(target_cpu_default)
3212
3213 AC_SUBST_FILE(target_overrides)
3214 AC_SUBST_FILE(host_overrides)
3215 AC_SUBST_FILE(language_fragments)
3216 AC_SUBST_FILE(language_hooks)
3217
3218 # Echo that links are built
3219 if test x$host = x$target
3220 then
3221         str1="native "
3222 else
3223         str1="cross-"
3224         str2=" from $host"
3225 fi
3226
3227 if test x$host != x$build
3228 then
3229         str3=" on a $build system"
3230 fi
3231
3232 if test "x$str2" != x || test "x$str3" != x
3233 then
3234         str4=
3235 fi
3236
3237 echo "Links are now set up to build a ${str1}compiler for ${target}$str4" 1>&2
3238
3239 if test "x$str2" != x || test "x$str3" != x
3240 then
3241         echo " ${str2}${str3}." 1>&2
3242 fi
3243
3244 # Configure the subdirectories
3245 # AC_CONFIG_SUBDIRS($subdirs)
3246
3247 # Create the Makefile
3248 # and configure language subdirectories
3249 AC_OUTPUT($all_outputs,
3250 [
3251 case x$CONFIG_HEADERS in
3252 xauto-host.h:config.in)
3253 echo > cstamp-h ;;
3254 esac
3255 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3256 # bootstrapping and the installation procedure can still use
3257 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3258 # FLAGS_TO_PASS has been modified to solve the problem there.
3259 # This is virtually a duplicate of what happens in configure.lang; we do
3260 # an extra check to make sure this only happens if ln -s can be used.
3261 if test "$symbolic_link" = "ln -s"; then
3262  for d in .. ${subdirs} fixinc ; do
3263    if test $d != ..; then
3264         STARTDIR=`${PWDCMD-pwd}`
3265         cd $d
3266         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3267         do
3268                 rm -f $t
3269                 $symbolic_link ../$t $t 2>/dev/null
3270         done
3271         cd $STARTDIR
3272    fi
3273  done
3274 else true ; fi
3275 ],
3276 [subdirs='$subdirs'
3277 symbolic_link='$symbolic_link'
3278 ])