gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.13)
   9 AC_INIT(as.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_ISC_POSIX
  13
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  18
  19 AM_PROG_LIBTOOL
  20
  21 user_bfd_gas=
  22 AC_ARG_ENABLE(bfd-assembler,
  23 [  --enable-bfd-assembler  use BFD back end for writing object files],
  24 [case "${enableval}" in
  25   yes) need_bfd=yes user_bfd_gas=yes ;;
  26   no)  user_bfd_gas=no ;;
  27   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(targets,
  30 [    targets            alternative target configurations besides the primary],
  31 [case "${enableval}" in
  32   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  33             ;;
  34   no)       enable_targets= ;;
  35   *)        enable_targets=$enableval ;;
  36 esac])dnl
  37 AC_ARG_ENABLE(commonbfdlib,
  38 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  39 [case "${enableval}" in
  40   yes) commonbfdlib=true ;;
  41   no)  commonbfdlib=false ;;
  42   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  43 esac])dnl
  44
  45 using_cgen=no
  46
  47 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  48 AC_ARG_ENABLE(build-warnings,
  49 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  50 [case "${enableval}" in
  51   yes)  ;;
  52   no)   build_warnings="-w";;
  53   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  54         build_warnings="${build_warnings} ${t}";;
  55   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  56         build_warnings="${t} ${build_warnings}";;
  57   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  58 esac
  59 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  60   echo "Setting warning flags = $build_warnings" 6>&1
  61 fi])dnl
  62 WARN_CFLAGS=""
  63 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  64     WARN_CFLAGS="${build_warnings}"
  65 fi
  66 AC_SUBST(WARN_CFLAGS)
  67
  68 # Generate a header file
  69 AM_CONFIG_HEADER(config.h:config.in)
  70
  71 # If we are on a DOS filesystem, we must use gdb.ini rather than
  72 # .gdbinit.
  73 GDBINIT=".gdbinit"
  74 case "${host}" in
  75   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*)
  76     GDBINIT="gdb.ini"
  77     ;;
  78 esac
  79 AC_SUBST(GDBINIT)
  80
  81 te_file=generic
  82
  83 # Makefile target for installing gas in $(tooldir)/bin.
  84 install_tooldir=install-exec-tooldir
  85
  86 canon_targets=""
  87 all_targets=no
  88 if test -n "$enable_targets" ; then
  89   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  90     if test $t = "all"; then
  91       all_targets=yes
  92       continue
  93     fi
  94     result=`$ac_config_sub $t 2>/dev/null`
  95     if test -n "$result" ; then
  96       canon_targets="$canon_targets $result"
  97 #    else
  98 #      # Permit "all", etc.  We don't support it yet though.
  99 #      canon_targets="$canon_targets $t"
 100     fi
 101   done
 102   GAS_UNIQ(canon_targets)
 103 fi
 104
 105 emulations=""
 106
 107 for this_target in $target $canon_targets ; do
 108
 109 changequote(,)dnl
 110     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 111 changequote([,])dnl
 112
 113     # check for architecture variants
 114     arch=
 115     endian=
 116     case ${cpu} in
 117       alpha*)           cpu_type=alpha ;;
 118       armeb)            cpu_type=arm endian=big ;;
 119       arm*)             cpu_type=arm endian=little ;;
 120       armb*)            cpu_type=arm endian=little ;;
 121       armv*l)           cpu_type=arm endian=little ;;
 122       armv*b)           cpu_type=arm endian=big ;;
 123       xscale*)          cpu_type=arm endian=little ;;
 124       strongarm*)       cpu_type=arm endian=little ;;
 125       thumb*)           cpu_type=arm endian=little ;;
 126       hppa*)            cpu_type=hppa ;;
 127 changequote(,)dnl
 128       i[3456]86)        cpu_type=i386 arch=i386;;
 129       x86_64)           cpu_type=i386 arch=x86_64;;
 130       ia64)             cpu_type=ia64 ;;
 131       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 132       m680[012346]0)    cpu_type=m68k ;;
 133 changequote([,])dnl
 134       m68008)           cpu_type=m68k ;;
 135       m683??)           cpu_type=m68k ;;
 136       m5200)            cpu_type=m68k ;;
 137       m8*)              cpu_type=m88k ;;
 138       mips*el)          cpu_type=mips endian=little ;;
 139       mips*)            cpu_type=mips endian=big ;;
 140       or32*)            cpu_type=or32 endian=big ;;
 141       pjl*)             cpu_type=pj endian=little ;;
 142       pj*)              cpu_type=pj endian=big ;;
 143       powerpc*le*)      cpu_type=ppc endian=little ;;
 144       powerpc*)         cpu_type=ppc endian=big ;;
 145       rs6000*)          cpu_type=ppc ;;
 146       s390x*)           cpu_type=s390 arch=s390x ;;
 147       s390*)            cpu_type=s390 arch=s390 ;;
 148       sh*le)            cpu_type=sh endian=little ;;
 149       sh*)              cpu_type=sh endian=big ;;
 150       sparclite*)       cpu_type=sparc arch=sparclite ;;
 151       sparclet*)        cpu_type=sparc arch=sparclet ;;
 152       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 153       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 154       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 155       v850*)            cpu_type=v850 ;;
 156       *)                cpu_type=${cpu} ;;
 157     esac
 158
 159     if test ${this_target} = $target ; then
 160       target_cpu_type=${cpu_type}
 161     elif test ${target_cpu_type} != ${cpu_type} ; then
 162       continue
 163     fi
 164
 165     generic_target=${cpu_type}-$vendor-$os
 166     dev=no
 167     bfd_gas=no
 168     em=generic
 169     mips_stabs_elf=
 170
 171     # assign object format
 172     case ${generic_target} in
 173       a29k-*-coff)          fmt=coff ;;
 174       a29k-amd-udi)         fmt=coff ;;
 175       a29k-amd-ebmon)       fmt=coff ;;
 176       a29k-nyu-sym1)        fmt=coff ;;
 177       a29k-*-rtems*)        fmt=coff ;;
 178       a29k-*-vxworks*)      fmt=coff ;;
 179
 180       alpha*-*-*vms*)       fmt=evax ;;
 181       alpha*-*-netware*)    fmt=ecoff ;;
 182       alpha*-*-openbsd*)    fmt=ecoff ;;
 183       alpha*-*-osf*)        fmt=ecoff ;;
 184       alpha*-*-linuxecoff*) fmt=ecoff ;;
 185       alpha*-*-linux-gnu*)  fmt=elf em=linux ;;
 186       alpha*-*-netbsd*)     fmt=elf em=nbsd ;;
 187
 188       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 189
 190       arm-*-aout)                       fmt=aout ;;
 191       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 192       arm-*-rtems | thumb-*-rtems)      fmt=elf ;;
 193       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 194       arm*-*-conix*)                    fmt=elf ;;
 195       arm-*-linux*aout*)                fmt=aout em=linux ;;
 196       arm*-*-linux-gnu* | arm*-*-uclinux*)
 197                                         fmt=elf  em=linux ;;
 198       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 199       arm-*-netbsd* | arm-*-openbsd*)   fmt=aout em=nbsd ;;
 200       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 201       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 202       arm-*-wince)                      fmt=coff em=wince-pe ;;
 203       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 204       arm-*-riscix*)                    fmt=aout em=riscix ;;
 205       arm-*-vxworks)                    fmt=coff ;;
 206
 207       avr-*-*)              fmt=elf bfd_gas=yes ;;
 208
 209       cris-*-*)             fmt=multi bfd_gas=yes ;;
 210
 211       d10v-*-*)             fmt=elf bfd_gas=yes ;;
 212       d30v-*-*)             fmt=elf bfd_gas=yes ;;
 213
 214
 215       fr30-*-*)             fmt=elf bfd_gas=yes ;;
 216
 217       hppa-*-linux-gnu*)    case ${cpu} in
 218                                 hppa*64*)
 219                                         fmt=elf em=hppalinux64;;
 220                                 hppa*)
 221                                         fmt=elf em=linux;;
 222                             esac ;;
 223       hppa-*-*elf*)         fmt=elf em=hppa ;;
 224       hppa-*-lites*)        fmt=elf em=hppa ;;
 225       hppa-*-netbsd*)       fmt=elf em=nbsd ;;
 226       hppa-*-osf*)          fmt=som em=hppa ;;
 227       hppa-*-rtems*)        fmt=elf em=hppa ;;
 228       hppa-*-hpux11*)       case ${cpu} in
 229                                 hppa*64*)
 230                                         fmt=elf em=hppa64 ;;
 231                                 hppa*)
 232                                         fmt=som em=hppa ;;
 233                             esac ;;
 234       hppa-*-hpux*)         fmt=som em=hppa ;;
 235       hppa-*-mpeix*)        fmt=som em=hppa ;;
 236       hppa-*-bsd*)          fmt=som em=hppa ;;
 237       hppa-*-hiux*)         fmt=som em=hppa ;;
 238
 239       h8300-*-rtems*)       fmt=coff ;;
 240       h8300-*-coff)         fmt=coff ;;
 241       h8300-*-elf)          fmt=elf ;;
 242       h8500-*-rtems*)       fmt=coff ;;
 243       h8500-*-coff)         fmt=coff ;;
 244
 245       i370-*-elf* | i370-*-linux*) fmt=elf ;;
 246       i386-ibm-aix*)        fmt=coff em=i386aix ;;
 247       i386-sequent-bsd*)    fmt=aout em=dynix bfd_gas=yes ;;
 248       i386-*-beospe*)       fmt=coff em=pe bfd_gas=yes ;;
 249       i386-*-beoself* | i386-*-beos*) fmt=elf bfd_gas=yes ;;
 250       i386-*-bsd*)          fmt=aout em=386bsd ;;
 251       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 252       i386-*-netbsd*)       em=nbsd bfd_gas=yes
 253                             case ${cpu} in
 254                               x86_64)   fmt=elf ;;
 255                               *)        case ${os} in
 256                                           *elf*) fmt=elf ;;
 257                                           *)     fmt=aout ;;
 258                                         esac
 259                                         ;;
 260                             esac
 261                             ;;
 262       i386-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes;;
 263       i386-*-linux*aout* | i386-*-linux*oldld)   fmt=aout em=linux ;;
 264       i386-*-linux*coff*)   fmt=coff em=linux ;;
 265       i386-*-linux-gnu*)    fmt=elf em=linux bfd_gas=yes ;;
 266       x86_64-*-linux-gnu*)  fmt=elf em=linux bfd_gas=yes ;;
 267       i386-*-lynxos*)       fmt=coff em=lynx ;;
 268 changequote(,)dnl
 269       i386-*-sysv[45]* | i386-*-solaris* | i386-*-elf)
 270                             fmt=elf bfd_gas=yes ;;
 271       i386-*-freebsdaout* | i386-*-freebsd[12].* | i386-*-freebsd[12])
 272                             fmt=aout em=386bsd ;;
 273 changequote([,])dnl
 274       i386-*-coff | i386-*-sysv* | i386-*-sco3.2v5*coff | i386-*-isc*)
 275                           fmt=coff ;;
 276       i386-*-sco3.2v5*)      fmt=elf
 277                             if test ${this_target} = $target; then
 278                                 AC_DEFINE(SCO_ELF, 1,
 279                                     [Define if defaulting to ELF on SCO 5.])
 280                             fi
 281                             ;;
 282       i386-*-sco3.2*)       fmt=coff ;;
 283       i386-*-vsta)          fmt=aout ;;
 284       i386-*-msdosdjgpp* | i386-*-go32* | i386-go32-rtems*)
 285                             fmt=coff em=go32 bfd_gas=yes
 286                             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 287                             ;;
 288       i386-*-rtemself*)     fmt=elf ;;
 289       i386-*-rtemscoff*)    fmt=coff ;;
 290       i386-*-rtems*)        fmt=elf ;;
 291       i386-*-gnu*)          fmt=elf ;;
 292       i386-*-mach*)
 293                             fmt=aout em=mach bfd_gas=yes ;;
 294       i386-*-msdos*)        fmt=aout ;;
 295       i386-*-moss*)         fmt=elf ;;
 296       i386-*-pe)            fmt=coff em=pe bfd_gas=yes ;;
 297       i386-*-cygwin*)       fmt=coff em=pe bfd_gas=yes ;;
 298       i386-*-interix*)      fmt=coff em=interix bfd_gas=yes ;;
 299       i386-*-mingw32*)      fmt=coff em=pe bfd_gas=yes ;;
 300       i386-*-*nt*)          fmt=coff em=pe bfd_gas=yes ;;
 301       i386-*-vxworks*)      fmt=aout ;;
 302       i386-*-chaos)         fmt=elf ;;
 303       i860-stardent-sysv4* | i860-stardent-elf*)
 304                             fmt=elf bfd_gas=yes endian=little
 305                             AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 306       i960-*-bout)          fmt=bout ;;
 307       i960-*-coff)          fmt=coff em=ic960 ;;
 308       i960-*-rtems*)        fmt=coff em=ic960 ;;
 309       i960-*-nindy*)        fmt=bout ;;
 310       i960-*-vxworks4*)     fmt=bout ;;
 311       i960-*-vxworks5.0)    fmt=bout ;;
 312       i960-*-vxworks5.*)    fmt=coff em=ic960 ;;
 313       i960-*-vxworks*)      fmt=bout ;;
 314       i960-*-elf*)          fmt=elf ;;
 315
 316       ia64-*-elf*)          fmt=elf ;;
 317       ia64-*-aix*)          fmt=elf em=ia64aix ;;
 318       ia64-*-linux-gnu*)    fmt=elf em=linux ;;
 319       ia64-*-hpux*)         fmt=elf em=hpux ;;
 320       ia64-*-netbsd*)       fmt=elf em=nbsd ;;
 321
 322       m32r-*-*)             fmt=elf bfd_gas=yes ;;
 323
 324       m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)fmt=elf bfd_gas=yes ;;
 325
 326       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 327                             fmt=aout em=sun3 ;;
 328       m68k-motorola-sysv*)  fmt=coff em=delta ;;
 329       m68k-bull-sysv3*)     fmt=coff em=dpx2 ;;
 330       m68k-apollo-*)        fmt=coff em=apollo ;;
 331       m68k-*-sysv4*) # must be before -sysv*
 332                             fmt=elf em=svr4 ;;
 333       m68k-*-elf*)          fmt=elf ;;
 334       m68k-*-coff | m68k-*-sysv* | m68k-*-rtemscoff*)
 335                             fmt=coff ;;
 336       m68k-*-rtems*)        fmt=elf ;;
 337       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 338       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 339       m68k-*-linux-gnu*)    fmt=elf em=linux ;;
 340       m68k-*-gnu*)          fmt=elf ;;
 341       m68k-*-lynxos*)       fmt=coff em=lynx ;;
 342       m68k-*-netbsdelf*)    fmt=elf em=nbsd bfd_gas=yes ;;
 343       m68k-*-netbsdaout* | m68k-*-netbsd*)
 344                             fmt=aout em=nbsd bfd_gas=yes ;;
 345       m68k-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 346       m68k-apple-aux*)      fmt=coff em=aux ;;
 347       m68k-*-psos*)         fmt=elf em=psos;;
 348
 349       m88k-motorola-sysv3*) fmt=coff em=delt88 ;;
 350       m88k-*-coff*)         fmt=coff ;;
 351
 352       mcore-*-elf)          fmt=elf bfd_gas=yes ;;
 353       mcore-*-pe)           fmt=coff em=pe bfd_gas=yes ;;
 354
 355       # don't change em like *-*-bsd does
 356       mips-dec-openbsd*)    fmt=elf endian=little ;;
 357       mips-dec-bsd*)        fmt=aout endian=little ;;
 358       mips-sony-bsd*)       fmt=ecoff ;;
 359       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 360       mips-*-ultrix*)       fmt=ecoff endian=little ;;
 361       mips-*-osf*)          fmt=ecoff endian=little ;;
 362       mips-*-ecoff*)        fmt=ecoff ;;
 363       mips-*-pe*)           fmt=coff endian=little em=pe ;;
 364       mips-*-irix6*)        fmt=elf ;;
 365       mips-*-irix5*)        fmt=elf ;;
 366       mips-*-irix*)         fmt=ecoff ;;
 367       mips-*-lnews*)        fmt=ecoff em=lnews ;;
 368       mips-*-riscos*)       fmt=ecoff ;;
 369       mips*-*-linux*)       fmt=elf em=tmips mips_stabs_elf=y ;;
 370       mips-*-sysv4*MP* | mips-*-gnu*)
 371                             fmt=elf em=tmips ;;
 372       mips-*-sysv*)         fmt=ecoff ;;
 373       mips-*-elf* | mips-*-rtems* | mips-*-netbsd* | mips-*-openbsd*)
 374                             fmt=elf ;;
 375       mips-*-vxworks*)      fmt=elf mips_stabs_elf=y ;;
 376       mmix-*-*)             fmt=elf bfd_gas=yes ;;
 377       mn10200-*-*)          fmt=elf bfd_gas=yes ;;
 378       mn10300-*-*)          fmt=elf bfd_gas=yes ;;
 379       openrisc-*-*)         fmt=elf bfd_gas=yes ;;
 380       or32-*-rtems*)        fmt=coff ;;
 381       or32-*-coff)          fmt=coff ;;
 382       or32-*-elf)           fmt=elf ;;
 383       pj*)                  fmt=elf ;;
 384       ppc-*-pe | ppc-*-cygwin* | ppc-*-winnt*)
 385                             fmt=coff em=pe ;;
 386       ppc-*-aix*)           fmt=coff ;;
 387       ppc-*-beos*)          fmt=coff ;;
 388       ppc-*-*bsd* | ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 389                             fmt=elf ;;
 390       ppc-*-linux-gnu*)     fmt=elf
 391                             case "$endian" in
 392                             big)  ;;
 393                             *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 394                             esac
 395                             ;;
 396       ppc-*-solaris*)       fmt=elf
 397                             if test ${this_target} = $target; then
 398                                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 399                                 [Define if default target is PowerPC Solaris.])
 400                             fi
 401                             if test x${endian} = xbig; then
 402                                 AC_MSG_ERROR(Solaris must be configured little endian)
 403                             fi
 404                             ;;
 405       ppc-*-rtems*)         fmt=elf ;;
 406       ppc-*-macos* | ppc-*-mpw*)
 407                             fmt=coff em=macos ;;
 408       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 409       ppc-*-vxworks*)       fmt=elf ;;
 410
 411       s390x-*-linux-gnu*)   fmt=elf em=linux ;;
 412       s390-*-linux-gnu*)    fmt=elf em=linux ;;
 413
 414       sh*-*-linux*)         fmt=elf em=linux
 415                             case ${cpu} in
 416                                 sh*eb)
 417                                         endian=big ;;
 418                                 sh*)
 419                                         endian=little ;;
 420                             esac ;;
 421       sh*-*-netbsdelf*)     fmt=elf em=nbsd ;;
 422       sh-*-elf*)            fmt=elf ;;
 423       sh-*-coff*)           fmt=coff bfd_gas=yes;;
 424       sh-*-pe*)             fmt=coff em=pe bfd_gas=yes endian=little ;;
 425       sh-*-rtemself*)       fmt=elf ;;
 426       sh-*-rtems*)          fmt=coff bfd_gas=yes;;
 427
 428       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 429       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 430       ns32k-pc532-openbsd*) fmt=aout em=nbsd532 ;;
 431
 432       sparc-*-rtemsaout*)   fmt=aout ;;
 433       sparc-*-rtemself*)    fmt=elf ;;
 434       sparc-*-rtems*)       fmt=elf ;;
 435       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 436       sparc-*-aout | sparc*-*-vxworks*)
 437                             fmt=aout em=sparcaout ;;
 438       sparc-*-coff)         fmt=coff ;;
 439       sparc-*-linux*aout*)  fmt=aout em=linux ;;
 440       sparc-*-linux-gnu*)   fmt=elf em=linux ;;
 441       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 442       sparc-fujitsu-none)   fmt=aout ;;
 443       sparc-*-elf | sparc-*-sysv4* | sparc-*-solaris*)
 444                             fmt=elf ;;
 445       sparc-*-netbsd*)      em=nbsd bfd_gas=yes
 446                             case ${cpu} in
 447                                 sparc) case ${os} in
 448                                            *elf*) fmt=elf ;;
 449                                            *)     fmt=aout ;;
 450                                        esac ;;
 451                                 sparc64) fmt=elf ;;
 452                             esac
 453                             ;;
 454       sparc-*-openbsd*)     fmt=aout em=nbsd ;;
 455
 456       strongarm-*-coff)     fmt=coff ;;
 457       strongarm-*-elf)      fmt=elf ;;
 458       xscale-*-coff)     fmt=coff ;;
 459       xscale-*-elf)      fmt=elf ;;
 460
 461       tic30-*-*aout*)       fmt=aout bfd_gas=yes ;;
 462       tic30-*-*coff*)       fmt=coff bfd_gas=yes ;;
 463       tic54x-*-* | c54x*-*-*)
 464                             fmt=coff bfd_gas=yes need_libm=yes;;
 465       tic80-*-*)            fmt=coff ;;
 466
 467       v850-*-*)             fmt=elf bfd_gas=yes ;;
 468       v850e-*-*)            fmt=elf bfd_gas=yes ;;
 469       v850ea-*-*)           fmt=elf bfd_gas=yes ;;
 470
 471       vax-*-bsd* | vax-*-ultrix*)
 472                             fmt=aout ;;
 473       vax-*-vms)            fmt=vms ;;
 474
 475       w65-*-*)              fmt=coff ;;
 476
 477       xstormy16-*-*)        fmt=elf bfd_gas=yes ;;
 478
 479       z8k-*-coff | z8k-*-sim)
 480                             fmt=coff ;;
 481
 482       *-*-aout | *-*-scout)
 483                             fmt=aout ;;
 484       *-*-freebsd*)         fmt=elf em=freebsd bfd_gas=yes ;;
 485       *-*-nindy*)
 486                             fmt=bout ;;
 487       *-*-bsd*)
 488                             fmt=aout em=sun3 ;;
 489       *-*-generic)          fmt=generic ;;
 490       *-*-xray | *-*-hms)   fmt=coff ;;
 491       *-*-sim)              fmt=coff ;;
 492       *-*-elf | *-*-sysv4* | *-*-solaris*)
 493                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 494                             fmt=elf dev=yes ;;
 495       *-*-vxworks)          fmt=aout ;;
 496       *-*-netware)          fmt=elf ;;
 497     esac
 498
 499     if test ${this_target} = $target ; then
 500       endian_def=
 501       if test x${endian} = xbig; then
 502         endian_def=1
 503       elif test x${endian} = xlittle; then
 504         endian_def=0
 505       fi
 506       if test x${endian_def} != x; then
 507         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 508                            [Define as 1 if big endian.])
 509       fi
 510     fi
 511
 512     if test x${mips_stabs_elf} != x; then
 513       AC_DEFINE(MIPS_STABS_ELF, 1,
 514                 [Use ELF stabs for MIPS, not ECOFF stabs])
 515     fi
 516
 517     case ${cpu_type}-${fmt} in
 518       alpha*-*) bfd_gas=yes ;;
 519       arm-*)    bfd_gas=yes ;;
 520     # not yet
 521     # i386-aout)        bfd_gas=preferred ;;
 522       ia64*-*)  bfd_gas=yes ;;
 523       mips-*)   bfd_gas=yes ;;
 524       ns32k-*)  bfd_gas=yes ;;
 525       pdp11-*)  bfd_gas=yes ;;
 526       ppc-*)    bfd_gas=yes ;;
 527       sparc-*)  bfd_gas=yes ;;
 528       strongarm-*)      bfd_gas=yes ;;
 529       xscale-*) bfd_gas=yes ;;
 530       *-elf)    bfd_gas=yes ;;
 531       *-ecoff)  bfd_gas=yes ;;
 532       *-som)    bfd_gas=yes ;;
 533     #enable bfd for coff and aout to allow testing if a bfd target is
 534     #the primary target, but not for coff or aout as the primary target
 535       i386-coff)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 536       i386-aout)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 537       *)                ;;
 538     esac
 539
 540 # Other random stuff.
 541
 542     # Do we need the opcodes library?
 543     case ${cpu_type} in
 544       vax | i386 | tic30)
 545         ;;
 546
 547       *)
 548         need_opcodes=yes
 549
 550         case "${enable_shared}" in
 551         yes) shared_opcodes=true ;;
 552         *opcodes*) shared_opcodes=true ;;
 553         *) shared_opcodes=false ;;
 554         esac
 555         if test "${shared_opcodes}" = "true"; then
 556           # A shared libopcodes must be linked against libbfd.
 557           need_bfd=yes
 558         fi
 559         ;;
 560     esac
 561
 562     # Any other special object files needed ?
 563     case ${cpu_type} in
 564       fr30 | m32r | openrisc)
 565         using_cgen=yes
 566         ;;
 567
 568       m68k)
 569         case ${extra_objects} in
 570         *m68k-parse.o*) ;;
 571         *) extra_objects="$extra_objects m68k-parse.o" ;;
 572         esac
 573         ;;
 574
 575       mips)
 576         echo ${extra_objects} | grep -s "itbl-parse.o"
 577         if test $? -ne 0 ; then
 578           extra_objects="$extra_objects itbl-parse.o"
 579         fi
 580
 581         echo ${extra_objects} | grep -s "itbl-lex.o"
 582         if test $? -ne 0 ; then
 583           extra_objects="$extra_objects itbl-lex.o"
 584         fi
 585
 586         echo ${extra_objects} | grep -s "itbl-ops.o"
 587         if test $? -ne 0 ; then
 588           extra_objects="$extra_objects itbl-ops.o"
 589         fi
 590         ;;
 591
 592       i386 | s390 | sparc)
 593         if test $this_target = $target ; then
 594           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 595         fi
 596         ;;
 597
 598       xstormy16)
 599         using_cgen=yes
 600         ;;
 601
 602       *)
 603         ;;
 604     esac
 605
 606     if test $using_cgen = yes ; then
 607         case "x${extra_objects}" in
 608         *cgen.o*) ;;
 609         *) extra_objects="$extra_objects cgen.o" ;;
 610         esac
 611     fi
 612
 613 # See if we really can support this configuration with the emulation code.
 614
 615     if test $this_target = $target ; then
 616       primary_bfd_gas=$bfd_gas
 617       obj_format=$fmt
 618       te_file=$em
 619
 620       if test $bfd_gas = no ; then
 621         # Can't support other configurations this way.
 622         break
 623       fi
 624     elif test $bfd_gas = no ; then
 625       # Can't support this configuration.
 626       break
 627     fi
 628
 629 # From target name and format, produce a list of supported emulations.
 630
 631     case ${generic_target}-${fmt} in
 632       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 633       mips*-*-linux*-*) case "$endian" in
 634                         big)    emulation="mipsbelf mipslelf mipself" ;;
 635                         *)      emulation="mipslelf mipsbelf mipself" ;;
 636                         esac ;;
 637       mips-*-lnews*-ecoff) ;;
 638       mips-*-*-ecoff)   case "$endian" in
 639                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 640                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 641                         esac ;;
 642       mips-*-*-elf)     case "$endian" in
 643                         big)    emulation="mipsbelf mipslelf mipself" ;;
 644                         *)      emulation="mipslelf mipsbelf mipself" ;;
 645                         esac ;;
 646       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 647       # i386-pc-pe-coff != i386-pc-coff.
 648       i386-*-pe-coff)   ;;
 649       # Uncommenting the next line will turn on support for i386 AOUT
 650       # for the default linux configuration
 651       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 652       #
 653       i386-*-aout)      emulation="i386aout" ;;
 654       i386-*-coff)      emulation="i386coff" ;;
 655       i386-*-elf)       emulation="i386elf" ;;
 656
 657       # Always all formats.  The first stated emulation becomes the default.
 658       cris-*-*aout*)    emulation="crisaout criself" ;;
 659       cris-*-*)         emulation="criself crisaout" ;;
 660     esac
 661
 662     emulations="$emulations $emulation"
 663
 664 done
 665
 666 # Turn on all targets if possible
 667 if test ${all_targets} = "yes"; then
 668   case ${target_cpu_type} in
 669   i386)
 670     case ${obj_format} in
 671     aout)
 672       emulations="$emulations i386coff i386elf"
 673       ;;
 674     coff)
 675       emulations="$emulations i386aout i386elf"
 676     ;;
 677     elf)
 678       emulations="$emulations i386aout i386coff"
 679       ;;
 680     esac
 681   ;;
 682   esac
 683 fi
 684
 685 # Assign floating point type.  Most processors with FP support
 686 # IEEE FP.  On those that don't support FP at all, usually IEEE
 687 # is emulated.
 688 case ${target_cpu} in
 689   vax | tahoe ) atof=${target_cpu} ;;
 690   pdp11)        atof=vax ;;
 691   *)            atof=ieee ;;
 692 esac
 693
 694 case "${obj_format}" in
 695   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 696 esac
 697
 698 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 699 cgen_cpu_prefix=""
 700 if test $using_cgen = yes ; then
 701   case ${target_cpu} in
 702     *) cgen_cpu_prefix=${target_cpu} ;;
 703   esac
 704   AC_SUBST(cgen_cpu_prefix)
 705   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 706 fi
 707
 708 dnl
 709 dnl Make sure the desired support files exist.
 710 dnl
 711
 712 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 713   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 714 fi
 715
 716 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 717   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 718 fi
 719
 720 case ${user_bfd_gas}-${primary_bfd_gas} in
 721   yes-yes | no-no)
 722     # We didn't override user's choice.
 723     ;;
 724   no-yes)
 725     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 726     ;;
 727   no-preferred)
 728     primary_bfd_gas=no
 729     ;;
 730   *-preferred)
 731     primary_bfd_gas=yes
 732     ;;
 733   yes-*)
 734     primary_bfd_gas=yes
 735     ;;
 736   -*)
 737     # User specified nothing.
 738     ;;
 739 esac
 740
 741 # Some COFF configurations want these random other flags set.
 742 case ${obj_format} in
 743   coff)
 744     case ${target_cpu_type} in
 745       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 746       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 747       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 748     esac
 749     ;;
 750 esac
 751
 752 # Getting this done right is going to be a bitch.  Each configuration specified
 753 # with --enable-targets=... should be checked for environment, format, cpu, and
 754 # bfd_gas setting.
 755 #
 756 # For each configuration, the necessary object file support code must be linked
 757 # in.  This might be only one, it might be up to four.  The necessary emulation
 758 # code needs to be provided, too.
 759 #
 760 # And then there's "--enable-targets=all"....
 761 #
 762 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 763
 764 formats="${obj_format}"
 765 emfiles=""
 766 EMULATIONS=""
 767 GAS_UNIQ(emulations)
 768 for em in . $emulations ; do
 769   case $em in
 770     .)  continue ;;
 771     mipsbelf | mipslelf | mipself)
 772         fmt=elf   file=mipself ;;
 773     mipsbecoff | mipslecoff | mipsecoff)
 774         fmt=ecoff file=mipsecoff ;;
 775     *coff)
 776         fmt=coff  file=$em ;;
 777     *aout)
 778         fmt=aout file=$em ;;
 779     *elf)
 780         fmt=elf file=$em ;;
 781   esac
 782   formats="$formats $fmt"
 783   emfiles="$emfiles e-$file.o"
 784   EMULATIONS="$EMULATIONS &$em,"
 785 done
 786 GAS_UNIQ(formats)
 787 GAS_UNIQ(emfiles)
 788 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 789   for fmt in $formats ; do
 790     case $fmt in
 791       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 792       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 793       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 794       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 795       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 796       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 797       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 798       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 799       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 800       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 801     esac
 802     extra_objects="$extra_objects obj-$fmt.o"
 803   done
 804   obj_format=multi
 805 fi
 806 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 807   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 808   # e-mips* has more than one emulation per file, e-i386* has just one at the
 809   # moment.  If only one emulation is specified, then don't define
 810   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 811   case "${obj_format}${emfiles}" in
 812     multi* | *mips*)
 813       extra_objects="$extra_objects $emfiles"
 814       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 815   esac
 816 fi
 817 AC_SUBST(extra_objects)
 818 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 819 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 820                    [Default emulation.])
 821
 822 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 823   yes-*-coff)   need_bfd=yes ;;
 824   no-*-coff)    need_bfd=yes
 825                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 826 esac
 827
 828 reject_dev_configs=yes
 829
 830 case ${reject_dev_configs}-${dev} in
 831   yes-yes) # Oops.
 832     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 833     ;;
 834 esac
 835
 836 AC_SUBST(target_cpu_type)
 837 AC_SUBST(obj_format)
 838 AC_SUBST(te_file)
 839 AC_SUBST(install_tooldir)
 840 AC_SUBST(atof)
 841 dnl AC_SUBST(emulation)
 842
 843 case "${primary_bfd_gas}" in
 844   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 845         need_bfd=yes ;;
 846 esac
 847
 848 # do we need the opcodes library?
 849 case "${need_opcodes}" in
 850 yes)
 851   OPCODES_LIB=../opcodes/libopcodes.la
 852   ;;
 853 esac
 854
 855 case "${need_bfd}" in
 856 yes)
 857   BFDLIB=../bfd/libbfd.la
 858   ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 859   ;;
 860 esac
 861
 862 AC_SUBST(BFDLIB)
 863 AC_SUBST(OPCODES_LIB)
 864
 865 AC_SUBST(ALL_OBJ_DEPS)
 866
 867 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 868 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 869 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 870 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 871 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 872
 873 AC_PROG_CC
 874
 875 AC_PROG_YACC
 876 AM_PROG_LEX
 877
 878 ALL_LINGUAS="fr tr"
 879 CY_GNU_GETTEXT
 880
 881 AM_MAINTAINER_MODE
 882 AC_EXEEXT
 883
 884 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 885
 886 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 887 # people who are not cross-compiling but are compiling cross-assemblers.
 888 AC_MSG_CHECKING(whether compiling a cross-assembler)
 889 if test "${host}" = "${target}"; then
 890   cross_gas=no
 891 else
 892   cross_gas=yes
 893   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 894 fi
 895 AC_MSG_RESULT($cross_gas)
 896
 897 dnl ansidecl.h will deal with const
 898 dnl AC_CONST
 899 AC_FUNC_ALLOCA
 900 AC_C_INLINE
 901
 902 # VMS doesn't have unlink.
 903 AC_CHECK_FUNCS(unlink remove, break)
 904
 905 # Some systems don't have sbrk().
 906 AC_CHECK_FUNCS(sbrk)
 907
 908 # do we need the math library?
 909 case "${need_libm}" in
 910 yes)
 911   AC_CHECK_LIBM
 912   AC_SUBST(LIBM)
 913   ;;
 914 esac
 915
 916 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 917 # enough, but on some of those systems, the assert macro relies on requoting
 918 # working properly!
 919 GAS_WORKING_ASSERT
 920
 921 # On some systems, the system header files may not declare malloc, realloc,
 922 # and free.  There are places where gas needs these functions to have been
 923 # declared -- such as when taking their addresses.
 924 gas_test_headers="
 925 #ifdef HAVE_MEMORY_H
 926 #include <memory.h>
 927 #endif
 928 #ifdef HAVE_STRING_H
 929 #include <string.h>
 930 #else
 931 #ifdef HAVE_STRINGS_H
 932 #include <strings.h>
 933 #endif
 934 #endif
 935 #ifdef HAVE_STDLIB_H
 936 #include <stdlib.h>
 937 #endif
 938 #ifdef HAVE_UNISTD_H
 939 #include <unistd.h>
 940 #endif
 941 "
 942 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 943 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 944 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 945 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 946 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 947
 948 # Does errno.h declare errno, or do we have to add a separate declaration
 949 # for it?
 950 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 951 #ifdef HAVE_ERRNO_H
 952 #include <errno.h>
 953 #endif
 954 ])
 955
 956 dnl This must come last.
 957
 958 dnl We used to make symlinks to files in the source directory, but now
 959 dnl we just use the right name for .c files, and create .h files in
 960 dnl the build directory which include the right .h file.  Make sure
 961 dnl the old symlinks don't exist, so that a reconfigure in an existing
 962 dnl directory behaves reasonably.
 963
 964 AC_OUTPUT(Makefile doc/Makefile ${GDBINIT}:gdbinit.in po/Makefile.in:po/Make-in,
 965 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 966  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 967  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 968  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 969  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 970  if test "x$cgen_cpu_prefix" != x ; then
 971    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 972  fi
 973
 974  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
 975 [target_cpu_type=${target_cpu_type}
 976  cgen_cpu_prefix=${cgen_cpu_prefix}
 977  obj_format=${obj_format}
 978  te_file=${te_file}])