gas/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl   Copyright (C) 2012-2018 Free Software Foundation, Inc.
   7 dnl
   8 dnl This file is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; see the file COPYING3.  If not see
  20 dnl <http://www.gnu.org/licenses/>.
  21 dnl
  22 dnl v2.5 needed for --bindir et al
  23 m4_include([../bfd/version.m4])
  24 AC_INIT([gas], BFD_VERSION)
  25 AC_CONFIG_SRCDIR(as.h)
  26
  27 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  28 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  29 dnl gas/ instead of gas/../.
  30 AC_CONFIG_AUX_DIR(..)
  31 AC_CANONICAL_TARGET
  32 AC_ISC_POSIX
  33
  34 AM_INIT_AUTOMAKE
  35
  36 AC_PROG_CC
  37 AC_GNU_SOURCE
  38 AC_USE_SYSTEM_EXTENSIONS
  39
  40 LT_INIT
  41 ACX_LARGEFILE
  42 ACX_PROG_CMP_IGNORE_INITIAL
  43
  44 AC_ARG_ENABLE(targets,
  45 [  --enable-targets        alternative target configurations besides the primary],
  46 [case "${enableval}" in
  47   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  48             ;;
  49   no)       enable_targets= ;;
  50   *)        enable_targets=$enableval ;;
  51 esac])dnl
  52
  53 ac_checking=yes
  54 if grep '^RELEASE=y' ${srcdir}/../bfd/Makefile.am >/dev/null 2>/dev/null ; then
  55   ac_checking=
  56 fi
  57 AC_ARG_ENABLE(checking,
  58 [  --enable-checking       enable run-time checks],
  59 [case "${enableval}" in
  60   no|none)  ac_checking= ;;
  61   *)        ac_checking=yes ;;
  62 esac])dnl
  63 if test x$ac_checking != x ; then
  64   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  65 fi
  66
  67 # PR gas/19109
  68 # Decide the default method for compressing debug sections.
  69 ac_default_compressed_debug_sections=unset
  70 # Provide a configure time option to override our default.
  71 AC_ARG_ENABLE(compressed_debug_sections,
  72               AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,none}],
  73               [compress debug sections by default]),
  74 [case ,"${enableval}", in
  75   ,yes, | ,all, | *,gas,*) ac_default_compressed_debug_sections=yes ;;
  76   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
  77   *)   ac_default_compressed_debug_sections=unset ;;
  78 esac])dnl
  79
  80 # PR gas/19520
  81 # Decide if x86 assembler should generate relax relocations.
  82 ac_default_x86_relax_relocations=unset
  83 # Provide a configure time option to override our default.
  84 AC_ARG_ENABLE(x86_relax_relocations,
  85               AS_HELP_STRING([--enable-x86-relax-relocations],
  86               [generate x86 relax relocations by default]),
  87 [case "${enableval}" in
  88   no)  ac_default_x86_relax_relocations=0 ;;
  89 esac])dnl
  90
  91 # Decide if ELF assembler should generate common symbols with the
  92 # STT_COMMON type.
  93 ac_default_elf_stt_common=unset
  94 # Provide a configure time option to override our default.
  95 AC_ARG_ENABLE(elf_stt_common,
  96               AS_HELP_STRING([--enable-elf-stt-common],
  97               [generate ELF common symbols with STT_COMMON type by default]),
  98 [case "${enableval}" in
  99   yes)  ac_default_elf_stt_common=1 ;;
 100 esac])dnl
 101
 102
 103 # Decide if the ELF assembler should default to generating
 104 # GNU Build notes if none are provided by the input.
 105 ac_default_generate_build_notes=0
 106 # Provide a configuration option to override the default.
 107 AC_ARG_ENABLE(generate_build_notes,
 108               AS_HELP_STRING([--enable-generate-build-notes],
 109               [generate GNU Build notes if none are provided by the input]),
 110 [case "${enableval}" in
 111   yes)  ac_default_generate_build_notes=1 ;;
 112   no)   ac_default_generate_build_notes=0 ;;
 113 esac])dnl
 114
 115
 116 # Decide if the x86 ELF assembler should default to generating GNU x86
 117 # used ISA and feature properties.
 118 ac_default_generate_x86_used_note=unset
 119 # Provide a configuration option to override the default.
 120 AC_ARG_ENABLE(x86-used-note,
 121               AS_HELP_STRING([--enable-x86-used-note],
 122               [generate GNU x86 used ISA and feature properties]),
 123 [case "${enableval}" in
 124   yes)  ac_default_generate_x86_used_note=1 ;;
 125   no)   ac_default_generate_x86_used_note=0 ;;
 126 esac])dnl
 127
 128
 129 using_cgen=no
 130
 131 AM_BINUTILS_WARNINGS
 132
 133 # Generate a header file
 134 AC_CONFIG_HEADERS(config.h:config.in)
 135
 136 dnl Option --with-cpu=TYPE allows configure type control of the default
 137 dnl cpu type within the assembler.  Currently only the ARC target
 138 dnl supports this feature, but others may be added in the future.
 139 AC_ARG_WITH(cpu,
 140             AS_HELP_STRING([--with-cpu=CPU],
 141             [default cpu variant is CPU (currently only supported on ARC)]),
 142             [AC_DEFINE_UNQUOTED(TARGET_WITH_CPU,
 143                                 "${with_cpu}",
 144                                 [Target specific CPU.])],
 145             [])
 146
 147 # PR 14072
 148 AH_VERBATIM([00_CONFIG_H_CHECK],
 149 [/* Check that config.h is #included before system headers
 150    (this works only for glibc, but that should be enough).  */
 151 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 152 #  error config.h must be #included before system headers
 153 #endif
 154 #define __CONFIG_H__ 1])
 155
 156 # If we are on a DOS filesystem, we must use gdb.ini rather than
 157 # .gdbinit.
 158 case "${host}" in
 159   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
 160     GDBINIT="gdb.ini"
 161     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
 162     ;;
 163   *)
 164     GDBINIT=".gdbinit"
 165     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
 166     ;;
 167 esac
 168 AC_SUBST(GDBINIT)
 169
 170 #We need this for the host.
 171 AC_C_BIGENDIAN
 172
 173 te_file=generic
 174
 175 # Makefile target for installing gas in $(tooldir)/bin.
 176 install_tooldir=install-exec-tooldir
 177
 178 canon_targets=""
 179 all_targets=no
 180 if test -n "$enable_targets" ; then
 181   for t in `echo $enable_targets | sed 's/,/ /g'`; do
 182     if test $t = "all"; then
 183       all_targets=yes
 184       continue
 185     fi
 186     result=`$ac_config_sub $t 2>/dev/null`
 187     if test -n "$result" ; then
 188       canon_targets="$canon_targets $result"
 189 #    else
 190 #      # Permit "all", etc.  We don't support it yet though.
 191 #      canon_targets="$canon_targets $t"
 192     fi
 193   done
 194   GAS_UNIQ(canon_targets)
 195 fi
 196
 197 emulations=""
 198
 199 for this_target in $target $canon_targets ; do
 200
 201     targ=${this_target}
 202     . ${srcdir}/configure.tgt
 203
 204     case ${target_cpu} in
 205       crisv32)
 206         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 207                            [Default CRIS architecture.])
 208         ;;
 209     esac
 210
 211     if test ${this_target} = $target ; then
 212       target_cpu_type=${cpu_type}
 213     elif test ${target_cpu_type} != ${cpu_type} ; then
 214       continue
 215     fi
 216
 217     generic_target=${cpu_type}-${target_vendor}-${target_os}
 218     case ${generic_target} in
 219       i386-*-msdosdjgpp* \
 220       | i386-*-go32* \
 221       | i386-go32-rtems*)
 222         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 223         ;;
 224
 225       i386-*-solaris2 \
 226       | x86_64-*-solaris2 \
 227       | i386-*-solaris2.[[0-9]] \
 228       | i386-*-solaris2.1[[01]] \
 229       | x86_64-*-solaris2.1[[01]])
 230         if test ${this_target} = $target \
 231            && test ${ac_default_x86_relax_relocations} = unset; then
 232           ac_default_x86_relax_relocations=0
 233         fi
 234         ;;
 235
 236       microblaze*)
 237         ;;
 238
 239 changequote(,)dnl
 240       ppc-*-aix[5-9].*)
 241 changequote([,])dnl
 242         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 243                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 244         ;;
 245       ppc-*-solaris*)
 246         if test ${this_target} = $target; then
 247           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 248                     [Define if default target is PowerPC Solaris.])
 249         fi
 250         if test x${endian} = xbig; then
 251           AC_MSG_ERROR(Solaris must be configured little endian)
 252         fi
 253         ;;
 254     esac
 255
 256     if test ${this_target} = $target ; then
 257       endian_def=
 258       if test x${endian} = xbig; then
 259         endian_def=1
 260       elif test x${endian} = xlittle; then
 261         endian_def=0
 262       fi
 263       if test x${endian_def} != x; then
 264         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 265                            [Define as 1 if big endian.])
 266       fi
 267     fi
 268
 269 # Other random stuff.
 270
 271     case ${cpu_type} in
 272       mips)
 273         # Set mips_cpu to the name of the default CPU.
 274         case ${target_cpu} in
 275           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 276             mips_cpu=from-abi
 277             ;;
 278           mipsisa32 | mipsisa32el)
 279             mips_cpu=mips32
 280             ;;
 281           mipsisa32r2 | mipsisa32r2el)
 282             mips_cpu=mips32r2
 283             ;;
 284           mipsisa32r3 | mipsisa32r3el)
 285             mips_cpu=mips32r3
 286             ;;
 287           mipsisa32r5 | mipsisa32r5el)
 288             mips_cpu=mips32r5
 289             ;;
 290           mipsisa32r6 | mipsisa32r6el)
 291             mips_cpu=mips32r6
 292             ;;
 293           mipsisa64 | mipsisa64el)
 294             mips_cpu=mips64
 295             ;;
 296           mipsisa64r2 | mipsisa64r2el)
 297             mips_cpu=mips64r2
 298             ;;
 299           mipsisa64r3 | mipsisa64r3el)
 300             mips_cpu=mips64r3
 301             ;;
 302           mipsisa64r5 | mipsisa64r5el)
 303             mips_cpu=mips64r5
 304             ;;
 305           mipsisa64r6 | mipsisa64r6el)
 306             mips_cpu=mips64r6
 307             ;;
 308           mipstx39 | mipstx39el)
 309             mips_cpu=r3900
 310             ;;
 311           mips64vr | mips64vrel)
 312             mips_cpu=vr4100
 313             ;;
 314           mipsisa32r2* | mipsisa64r2*)
 315 changequote(,)dnl
 316             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 317 changequote([,])dnl
 318             ;;
 319           mipsisa32r6* | mipsisa64r6*)
 320 changequote(,)dnl
 321             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r6//' -e 's/el$//'`
 322 changequote([,])dnl
 323             ;;
 324           mips64* | mipsisa64* | mipsisa32*)
 325 changequote(,)dnl
 326             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 327 changequote([,])dnl
 328             ;;
 329           mips*)
 330 changequote(,)dnl
 331             mips_cpu=`echo $target_cpu | sed -e 's/^mips//' -e 's/el$//'`
 332 changequote([,])dnl
 333             ;;
 334           *)
 335             AC_MSG_ERROR($target_cpu isn't a supported MIPS CPU name)
 336             ;;
 337         esac
 338         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 339         # binaries.  It's a GNU extension that some OSes don't understand.
 340         case ${target} in
 341           *-*-irix*)
 342             use_e_mips_abi_o32=0
 343             ;;
 344           *)
 345             use_e_mips_abi_o32=1
 346             ;;
 347         esac
 348         # Decide whether to generate 32-bit or 64-bit code by default.
 349         # Used to resolve -march=from-abi when an embedded ABI is selected.
 350         case ${target} in
 351           mips64*-*-* | mipsisa64*-*-*)
 352             mips_default_64bit=1
 353             ;;
 354           *)
 355             mips_default_64bit=0
 356             ;;
 357         esac
 358         # Decide which ABI to target by default.
 359         case ${target} in
 360           mips64*-linux* | mips-sgi-irix6* | mips64*-freebsd* \
 361           | mips64*-kfreebsd*-gnu | mips64*-ps2-elf*)
 362             mips_default_abi=N32_ABI
 363             ;;
 364           mips*-linux* | mips*-freebsd* | mips*-kfreebsd*-gnu)
 365             mips_default_abi=O32_ABI
 366             ;;
 367           mips64*-openbsd*)
 368             mips_default_abi=N64_ABI
 369             ;;
 370           *)
 371             mips_default_abi=NO_ABI
 372             ;;
 373         esac
 374         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 375                            [Default CPU for MIPS targets. ])
 376         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 377                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 378         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 379                            [Generate 64-bit code by default on MIPS targets. ])
 380         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 381                            [Choose a default ABI for MIPS targets. ])
 382         ;;
 383     esac
 384
 385     # Do we need the opcodes library?
 386     case ${cpu_type} in
 387       vax | tic30)
 388         ;;
 389
 390       *)
 391         need_opcodes=yes
 392
 393         case "${enable_shared}" in
 394         yes) shared_opcodes=true ;;
 395         *opcodes*) shared_opcodes=true ;;
 396         *) shared_opcodes=false ;;
 397         esac
 398         ;;
 399     esac
 400
 401     # Any other special object files needed ?
 402     case ${cpu_type} in
 403
 404       bfin)
 405         for f in bfin-parse.o bfin-lex-wrapper.o; do
 406           case " $extra_objects " in
 407             *" $f "*) ;;
 408             *) extra_objects="$extra_objects $f" ;;
 409           esac
 410         done
 411         ;;
 412
 413       epiphany | fr30 | ip2k | iq2000 | lm32 | m32r | or1k)
 414         using_cgen=yes
 415         ;;
 416
 417       m32c)
 418         using_cgen=yes
 419         ;;
 420       frv)
 421         using_cgen=yes
 422         ;;
 423       m68k)
 424         f=m68k-parse.o
 425         case " $extra_objects " in
 426           *" $f "*) ;;
 427           *) extra_objects="$extra_objects $f" ;;
 428         esac
 429         ;;
 430
 431       mep)
 432         using_cgen=yes
 433         ;;
 434
 435       mips)
 436         for f in itbl-parse.o itbl-lex-wrapper.o itbl-ops.o; do
 437           case " $extra_objects " in
 438             *" $f "*) ;;
 439             *) extra_objects="$extra_objects $f" ;;
 440           esac
 441         done
 442         ;;
 443
 444       mt)
 445         using_cgen=yes
 446         ;;
 447
 448       nds32)
 449         # Decide BASELINE, REDUCED_REGS, FPU_DP_EXT, FPU_SP_EXT features
 450         # based on arch_name.
 451         AC_MSG_CHECKING(for default configuration of --with-arch)
 452         if test "x${with_arch}" != x; then
 453           case ${with_arch} in
 454             v2j | v2s | v2f | v2 | v3m | v3j | v3s | v3f | v3 )
 455               AC_DEFINE_UNQUOTED(NDS32_DEFAULT_ARCH_NAME, "$with_arch",
 456                                  [Define value for nds32_arch_name])
 457               ;;
 458             *)
 459               AC_MSG_ERROR(This kind of arch name does *NOT* exist!)
 460               ;;
 461           esac
 462         fi
 463         AC_MSG_RESULT($with_arch)
 464
 465         # Decide features one by one.
 466         AC_MSG_CHECKING(for default configuration of --enable-dx-regs)
 467         if test "x${enable_dx_regs}" = xyes; then
 468           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 1,
 469                     [Define value for nds32_dx_regs])
 470         else
 471           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 0,
 472                     [Define default value for nds32_dx_regs])
 473         fi
 474         AC_MSG_RESULT($enable_dx_regs)
 475
 476         AC_MSG_CHECKING(for default configuration of --enable-perf-ext)
 477         if test "x${enable_perf_ext}" = xno; then
 478           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 0,
 479                     [Define value for nds32_perf_ext])
 480         else
 481           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 1,
 482                     [Define default value for nds32_perf_ext])
 483         fi
 484         AC_MSG_RESULT($enable_perf_ext)
 485
 486         AC_MSG_CHECKING(for default configuration of --enable-perf-ext2)
 487         if test "x${enable_perf_ext2}" = xno; then
 488           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 0,
 489                     [Define value for nds32_perf_ext2])
 490         else
 491           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 1,
 492                     [Define default value for nds32_perf_ext2])
 493         fi
 494         AC_MSG_RESULT($enable_perf_ext2)
 495
 496         AC_MSG_CHECKING(for default configuration of --enable-string-ext)
 497         if test "x${enable_string_ext}" = xno; then
 498           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 0,
 499                     [Define value for nds32_string_ext])
 500         else
 501           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 1,
 502                     [Define default value for nds32_string_ext])
 503         fi
 504         AC_MSG_RESULT($enable_string_ext)
 505
 506         AC_MSG_CHECKING(for default configuration of --enable-audio-ext)
 507         if test "x${enable_audio_ext}" = xno; then
 508           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 0,
 509                     [Define value for nds32_audio_ext])
 510         else
 511           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 1,
 512                     [Define default value for nds32_audio_ext])
 513         fi
 514         AC_MSG_RESULT($enable_audio_ext)
 515         ;;
 516
 517       aarch64 | i386 | riscv | s390 | sparc)
 518         if test $this_target = $target ; then
 519           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 520         fi
 521         ;;
 522
 523       rl78)
 524         f=rl78-parse.o
 525         case " $extra_objects " in
 526           *" $f "*) ;;
 527           *) extra_objects="$extra_objects $f" ;;
 528         esac
 529         ;;
 530
 531       rx)
 532         f=rx-parse.o
 533         case " $extra_objects " in
 534           *" $f "*) ;;
 535           *) extra_objects="$extra_objects $f" ;;
 536         esac
 537         ;;
 538
 539       xstormy16)
 540         using_cgen=yes
 541         ;;
 542
 543       xc16x)
 544         using_cgen=yes
 545         ;;
 546
 547       xtensa)
 548         f=config/xtensa-relax.o
 549         case " $extra_objects " in
 550           *" $f "*) ;;
 551           *) extra_objects="$extra_objects $f" ;;
 552         esac
 553         ;;
 554
 555       *)
 556         ;;
 557     esac
 558
 559     if test $using_cgen = yes ; then
 560         f=cgen.o
 561         case " $extra_objects " in
 562           *" $f "*) ;;
 563           *) extra_objects="$extra_objects $f" ;;
 564         esac
 565     fi
 566
 567 # See if we really can support this configuration with the emulation code.
 568
 569     if test $this_target = $target ; then
 570       obj_format=$fmt
 571       te_file=$em
 572     fi
 573
 574     case ${te_file} in
 575       vms)
 576         f=config/te-vms.o
 577         case " $extra_objects " in
 578           *" $f "*) ;;
 579           *) extra_objects="$extra_objects $f" ;;
 580         esac ;;
 581     esac
 582
 583 # From target name and format, produce a list of supported emulations.
 584
 585     case ${generic_target}-${fmt} in
 586       mips-*-*-*)       case "$endian" in
 587                         big)    emulation="mipsbelf mipslelf mipself" ;;
 588                         *)      emulation="mipslelf mipsbelf mipself" ;;
 589                         esac ;;
 590       # i386-pc-pe-coff != i386-pc-coff.
 591       i386-*-pe-coff)   ;;
 592       # Uncommenting the next line will turn on support for i386 AOUT
 593       # for the default linux configuration
 594       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 595       #
 596       i386-*-aout)      emulation="i386aout" ;;
 597       i386-*-coff)      emulation="i386coff" ;;
 598       i386-*-elf)       emulation="i386elf" ;;
 599
 600       # Always all formats.  The first stated emulation becomes the default.
 601       cris-*-*aout*)    emulation="crisaout criself" ;;
 602       cris-*-*)         emulation="criself crisaout" ;;
 603     esac
 604
 605     emulations="$emulations $emulation"
 606
 607 done
 608
 609 if test ${ac_default_x86_relax_relocations} = unset; then
 610   ac_default_x86_relax_relocations=1
 611 fi
 612 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_X86_RELAX_RELOCATIONS,
 613   $ac_default_x86_relax_relocations,
 614   [Define to 1 if you want to generate x86 relax relocations by default.])
 615
 616 if test ${ac_default_elf_stt_common} = unset; then
 617   ac_default_elf_stt_common=0
 618 fi
 619 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_ELF_STT_COMMON,
 620   $ac_default_elf_stt_common,
 621   [Define to 1 if you want to generate ELF common symbols with the
 622    STT_COMMON type by default.])
 623
 624 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_BUILD_NOTES,
 625   $ac_default_generate_build_notes,
 626   [Define to 1 if you want to generate GNU Build attribute notes
 627    by default, if none are contained in the input.])
 628
 629 if test ${ac_default_generate_x86_used_note} = unset; then
 630   ac_default_generate_x86_used_note=0
 631 fi
 632 AC_DEFINE_UNQUOTED(DEFAULT_X86_USED_NOTE,
 633   $ac_default_generate_x86_used_note,
 634   [Define to 1 if you want to generate GNU x86 used ISA and feature
 635    properties by default.])
 636
 637 if test x$ac_default_compressed_debug_sections = xyes ; then
 638   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 639 fi
 640
 641 # Turn on all targets if possible
 642 if test ${all_targets} = "yes"; then
 643   case ${target_cpu_type} in
 644   i386)
 645     case ${obj_format} in
 646     aout)
 647       emulations="$emulations i386coff i386elf"
 648       ;;
 649     coff)
 650       emulations="$emulations i386aout i386elf"
 651     ;;
 652     elf)
 653       emulations="$emulations i386aout i386coff"
 654       ;;
 655     esac
 656   ;;
 657   x86_64)
 658     case ${obj_format} in
 659     aout)
 660       emulations="$emulations i386coff i386elf"
 661       ;;
 662     coff)
 663       emulations="$emulations i386aout i386elf"
 664     ;;
 665     elf)
 666       emulations="$emulations i386aout i386coff"
 667       ;;
 668     esac
 669   ;;
 670   esac
 671 fi
 672
 673 # PE code has way too many macros tweaking behaviour
 674 case ${te_file} in
 675   pe*) emulations="" ;;
 676 esac
 677
 678 # Assign floating point type.  Most processors with FP support
 679 # IEEE FP.  On those that don't support FP at all, usually IEEE
 680 # is emulated.
 681 case ${target_cpu} in
 682   vax | pdp11 ) atof=vax ;;
 683   *)            atof=ieee ;;
 684 esac
 685
 686 case "${obj_format}" in
 687   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 688 esac
 689
 690 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 691 cgen_cpu_prefix=""
 692 if test $using_cgen = yes ; then
 693   case ${target_cpu} in
 694     or1knd)
 695        cgen_cpu_prefix=or1k ;;
 696     *) cgen_cpu_prefix=${target_cpu} ;;
 697   esac
 698   AC_SUBST(cgen_cpu_prefix)
 699   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 700 fi
 701
 702 dnl
 703 dnl Make sure the desired support files exist.
 704 dnl
 705
 706 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 707   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 708 fi
 709
 710 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 711   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 712 fi
 713
 714 # Some COFF configurations want these random other flags set.
 715 case ${obj_format} in
 716   coff)
 717     case ${target_cpu_type} in
 718       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 719       x86_64) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 720     esac
 721     ;;
 722 esac
 723
 724 # Getting this done right is going to be a bitch.  Each configuration specified
 725 # with --enable-targets=... should be checked for environment, format, cpu
 726 # setting.
 727 #
 728 # For each configuration, the necessary object file support code must be linked
 729 # in.  This might be only one, it might be up to four.  The necessary emulation
 730 # code needs to be provided, too.
 731 #
 732 # And then there's "--enable-targets=all"....
 733 #
 734 # For now, just always do it for MIPS ELF configurations.  Sigh.
 735
 736 formats="${obj_format}"
 737 emfiles=""
 738 EMULATIONS=""
 739 GAS_UNIQ(emulations)
 740 for em in . $emulations ; do
 741   case $em in
 742     .)  continue ;;
 743     mipsbelf | mipslelf | mipself)
 744         fmt=elf   file=mipself ;;
 745     *coff)
 746         fmt=coff  file=$em ;;
 747     *aout)
 748         fmt=aout file=$em ;;
 749     *elf)
 750         fmt=elf file=$em ;;
 751   esac
 752   formats="$formats $fmt"
 753   emfiles="$emfiles config/e-$file.o"
 754   EMULATIONS="$EMULATIONS &$em,"
 755 done
 756 GAS_UNIQ(formats)
 757 GAS_UNIQ(emfiles)
 758 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 759   for fmt in $formats ; do
 760     case $fmt in
 761       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 762       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 763       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 764       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 765       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 766       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 767     esac
 768     extra_objects="$extra_objects config/obj-$fmt.o"
 769   done
 770   obj_format=multi
 771 fi
 772 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 773   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 774   # e-mipself has more than one emulation per file, e-i386* has just one at the
 775   # moment.  If only one emulation is specified, then don't define
 776   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 777   case "${obj_format}${emfiles}" in
 778     multi* | *mipself*)
 779       extra_objects="$extra_objects $emfiles"
 780       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 781   esac
 782 fi
 783 AC_SUBST(extra_objects)
 784 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 785 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 786                    [Default emulation.])
 787
 788 reject_dev_configs=yes
 789
 790 case ${reject_dev_configs}-${dev} in
 791   yes-yes) # Oops.
 792     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 793     ;;
 794 esac
 795
 796 AC_SUBST(target_cpu_type)
 797 AC_SUBST(obj_format)
 798 AC_SUBST(te_file)
 799 AC_SUBST(install_tooldir)
 800 AC_SUBST(atof)
 801 dnl AC_SUBST(emulation)
 802
 803 # do we need the opcodes library?
 804 case "${need_opcodes}" in
 805 yes)
 806   OPCODES_LIB=../opcodes/libopcodes.la
 807   ;;
 808 esac
 809
 810 AC_SUBST(OPCODES_LIB)
 811
 812 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 813 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 814 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 815 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 816 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 817
 818 AC_PROG_YACC
 819 AM_PROG_LEX
 820
 821 ALL_LINGUAS="es fi fr id ja ru rw sv tr uk zh_CN"
 822 ZW_GNU_GETTEXT_SISTER_DIR
 823 AM_PO_SUBDIRS
 824
 825 AM_MAINTAINER_MODE
 826 AM_CONDITIONAL(GENINSRC_NEVER, false)
 827 AC_EXEEXT
 828
 829 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h errno.h sys/types.h limits.h locale.h time.h sys/stat.h)
 830 ACX_HEADER_STRING
 831
 832 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 833 # people who are not cross-compiling but are compiling cross-assemblers.
 834 AC_MSG_CHECKING(whether compiling a cross-assembler)
 835 if test "${host}" = "${target}"; then
 836   cross_gas=no
 837 else
 838   cross_gas=yes
 839   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 840 fi
 841 AC_MSG_RESULT($cross_gas)
 842
 843 dnl ansidecl.h will deal with const
 844 dnl AC_C_CONST
 845 AC_FUNC_ALLOCA
 846 AC_C_INLINE
 847
 848 # VMS doesn't have unlink.
 849 AC_CHECK_FUNCS(unlink remove, break)
 850 AC_CHECK_FUNCS(sbrk setlocale)
 851 AC_CHECK_FUNCS(strsignal)
 852
 853 AM_LC_MESSAGES
 854
 855 # do we need the math library?
 856 case "${need_libm}" in
 857 yes)
 858   LT_LIB_M
 859   AC_SUBST(LIBM)
 860   ;;
 861 esac
 862
 863 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 864 # enough, but on some of those systems, the assert macro relies on requoting
 865 # working properly!
 866 GAS_WORKING_ASSERT
 867
 868 # On some systems, the system header files may not declare malloc, realloc,
 869 # and free.  There are places where gas needs these functions to have been
 870 # declared -- such as when taking their addresses.
 871 gas_test_headers="
 872 #ifdef HAVE_MEMORY_H
 873 #include <memory.h>
 874 #endif
 875 #ifdef HAVE_STRING_H
 876 #include <string.h>
 877 #else
 878 #ifdef HAVE_STRINGS_H
 879 #include <strings.h>
 880 #endif
 881 #endif
 882 #ifdef HAVE_STDLIB_H
 883 #include <stdlib.h>
 884 #endif
 885 #ifdef HAVE_UNISTD_H
 886 #include <unistd.h>
 887 #endif
 888 "
 889
 890 # Does errno.h declare errno, or do we have to add a separate declaration
 891 # for it?
 892 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 893 #ifdef HAVE_ERRNO_H
 894 #include <errno.h>
 895 #endif
 896 ])
 897
 898 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 899 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
 900 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 901 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
 902 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
 903 if test $gas_cv_decl_getopt_unistd_h = yes; then
 904   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 905             [Is the prototype for getopt in <unistd.h> in the expected format?])
 906 fi
 907
 908 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 909 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
 910 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 911 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 912 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 913 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 914
 915 AC_CHECK_DECLS([free, getenv, malloc, mempcpy, realloc, stpcpy, strstr, vsnprintf, asprintf])
 916
 917 BFD_BINARY_FOPEN
 918
 919 # Link in zlib if we can.  This allows us to write compressed debug sections.
 920 AM_ZLIB
 921
 922 # Support for VMS timestamps via cross compile
 923
 924 if test "$ac_cv_header_time_h" = yes; then
 925   GAS_HAVE_TIME_TYPE_MEMBER(struct tm, tm_gmtoff)
 926 fi
 927
 928 if test "$ac_cv_header_sys_stat_h" = yes; then
 929     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_sec)
 930     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_nsec)
 931 fi
 932
 933
 934 dnl Required for html, pdf, install-pdf and install-html targets.
 935 AC_SUBST(datarootdir)
 936 AC_SUBST(docdir)
 937 AC_SUBST(htmldir)
 938 AC_SUBST(pdfdir)
 939
 940 dnl This must come last.
 941
 942 dnl We used to make symlinks to files in the source directory, but now
 943 dnl we just use the right name for .c files, and create .h files in
 944 dnl the build directory which include the right .h file.  Make sure
 945 dnl the old symlinks don't exist, so that a reconfigure in an existing
 946 dnl directory behaves reasonably.
 947
 948 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 949 AC_CONFIG_COMMANDS([default],
 950 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 951  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 952  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 953  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 954  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 955  if test "x$cgen_cpu_prefix" != x ; then
 956    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 957  fi],
 958 [target_cpu_type=${target_cpu_type}
 959  cgen_cpu_prefix=${cgen_cpu_prefix}
 960  obj_format=${obj_format}
 961  te_file=${te_file}])
 962
 963 AC_OUTPUT