gas/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl   Copyright (C) 2012-2019 Free Software Foundation, Inc.
   7 dnl
   8 dnl This file is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; see the file COPYING3.  If not see
  20 dnl <http://www.gnu.org/licenses/>.
  21 dnl
  22 dnl v2.5 needed for --bindir et al
  23 m4_include([../bfd/version.m4])
  24 AC_INIT([gas], BFD_VERSION)
  25 AC_CONFIG_SRCDIR(as.h)
  26
  27 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  28 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  29 dnl gas/ instead of gas/../.
  30 AC_CONFIG_AUX_DIR(..)
  31 AC_CANONICAL_TARGET
  32 AC_ISC_POSIX
  33
  34 AM_INIT_AUTOMAKE
  35
  36 AC_PROG_CC
  37 AC_GNU_SOURCE
  38 AC_USE_SYSTEM_EXTENSIONS
  39
  40 LT_INIT
  41 ACX_LARGEFILE
  42 ACX_PROG_CMP_IGNORE_INITIAL
  43
  44 AC_ARG_ENABLE(targets,
  45 [  --enable-targets        alternative target configurations besides the primary],
  46 [case "${enableval}" in
  47   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  48             ;;
  49   no)       enable_targets= ;;
  50   *)        enable_targets=$enableval ;;
  51 esac])dnl
  52
  53 ac_checking=
  54 . ${srcdir}/../bfd/development.sh
  55 test "$development" = true && ac_checking=yes
  56 AC_ARG_ENABLE(checking,
  57 [  --enable-checking       enable run-time checks],
  58 [case "${enableval}" in
  59   no|none)  ac_checking= ;;
  60   *)        ac_checking=yes ;;
  61 esac])dnl
  62 if test x$ac_checking != x ; then
  63   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  64 fi
  65
  66 # PR gas/19109
  67 # Decide the default method for compressing debug sections.
  68 ac_default_compressed_debug_sections=unset
  69 # Provide a configure time option to override our default.
  70 AC_ARG_ENABLE(compressed_debug_sections,
  71               AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,none}],
  72               [compress debug sections by default]),
  73 [case ,"${enableval}", in
  74   ,yes, | ,all, | *,gas,*) ac_default_compressed_debug_sections=yes ;;
  75   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
  76   *)   ac_default_compressed_debug_sections=unset ;;
  77 esac])dnl
  78
  79 # PR gas/19520
  80 # Decide if x86 assembler should generate relax relocations.
  81 ac_default_x86_relax_relocations=unset
  82 # Provide a configure time option to override our default.
  83 AC_ARG_ENABLE(x86_relax_relocations,
  84               AS_HELP_STRING([--enable-x86-relax-relocations],
  85               [generate x86 relax relocations by default]),
  86 [case "${enableval}" in
  87   no)  ac_default_x86_relax_relocations=0 ;;
  88 esac])dnl
  89
  90 # Decide if ELF assembler should generate common symbols with the
  91 # STT_COMMON type.
  92 ac_default_elf_stt_common=unset
  93 # Provide a configure time option to override our default.
  94 AC_ARG_ENABLE(elf_stt_common,
  95               AS_HELP_STRING([--enable-elf-stt-common],
  96               [generate ELF common symbols with STT_COMMON type by default]),
  97 [case "${enableval}" in
  98   yes)  ac_default_elf_stt_common=1 ;;
  99 esac])dnl
 100
 101
 102 # Decide if the ELF assembler should default to generating
 103 # GNU Build notes if none are provided by the input.
 104 ac_default_generate_build_notes=0
 105 # Provide a configuration option to override the default.
 106 AC_ARG_ENABLE(generate_build_notes,
 107               AS_HELP_STRING([--enable-generate-build-notes],
 108               [generate GNU Build notes if none are provided by the input]),
 109 [case "${enableval}" in
 110   yes)  ac_default_generate_build_notes=1 ;;
 111   no)   ac_default_generate_build_notes=0 ;;
 112 esac])dnl
 113
 114
 115 # Decide if the x86 ELF assembler should default to generating GNU x86
 116 # used ISA and feature properties.
 117 ac_default_generate_x86_used_note=unset
 118 # Provide a configuration option to override the default.
 119 AC_ARG_ENABLE(x86-used-note,
 120               AS_HELP_STRING([--enable-x86-used-note],
 121               [generate GNU x86 used ISA and feature properties]),
 122 [case "${enableval}" in
 123   yes)  ac_default_generate_x86_used_note=1 ;;
 124   no)   ac_default_generate_x86_used_note=0 ;;
 125 esac])dnl
 126
 127 # Decide if the RISC-V ELF assembler should default to generating attribute.
 128 ac_default_generate_riscv_attr=unset
 129 # Provide a configuration option to override the default.
 130 AC_ARG_ENABLE(default-riscv-attribute,
 131               AS_HELP_STRING([--enable-default-riscv-attribute],
 132               [generate RISC-V arch attribute by default]),
 133 [case "${enableval}" in
 134   yes)  ac_default_generate_riscv_attr=1 ;;
 135   no)   ac_default_generate_riscv_attr=0 ;;
 136 esac])dnl
 137
 138 using_cgen=no
 139
 140 AM_BINUTILS_WARNINGS
 141
 142 # Generate a header file
 143 AC_CONFIG_HEADERS(config.h:config.in)
 144
 145 dnl Option --with-cpu=TYPE allows configure type control of the default
 146 dnl cpu type within the assembler.  Currently only the ARC target
 147 dnl supports this feature, but others may be added in the future.
 148 AC_ARG_WITH(cpu,
 149             AS_HELP_STRING([--with-cpu=CPU],
 150             [default cpu variant is CPU (currently only supported on ARC)]),
 151             [AC_DEFINE_UNQUOTED(TARGET_WITH_CPU,
 152                                 "${with_cpu}",
 153                                 [Target specific CPU.])],
 154             [])
 155
 156 # PR 14072
 157 AH_VERBATIM([00_CONFIG_H_CHECK],
 158 [/* Check that config.h is #included before system headers
 159    (this works only for glibc, but that should be enough).  */
 160 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 161 #  error config.h must be #included before system headers
 162 #endif
 163 #define __CONFIG_H__ 1])
 164
 165 # If we are on a DOS filesystem, we must use gdb.ini rather than
 166 # .gdbinit.
 167 case "${host}" in
 168   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
 169     GDBINIT="gdb.ini"
 170     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
 171     ;;
 172   *)
 173     GDBINIT=".gdbinit"
 174     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
 175     ;;
 176 esac
 177 AC_SUBST(GDBINIT)
 178
 179 #We need this for the host.
 180 AC_C_BIGENDIAN
 181
 182 te_file=generic
 183
 184 # Makefile target for installing gas in $(tooldir)/bin.
 185 install_tooldir=install-exec-tooldir
 186
 187 canon_targets=""
 188 all_targets=no
 189 if test -n "$enable_targets" ; then
 190   for t in `echo $enable_targets | sed 's/,/ /g'`; do
 191     if test $t = "all"; then
 192       all_targets=yes
 193       continue
 194     fi
 195     result=`$ac_config_sub $t 2>/dev/null`
 196     if test -n "$result" ; then
 197       canon_targets="$canon_targets $result"
 198 #    else
 199 #      # Permit "all", etc.  We don't support it yet though.
 200 #      canon_targets="$canon_targets $t"
 201     fi
 202   done
 203   GAS_UNIQ(canon_targets)
 204 fi
 205
 206 emulations=""
 207
 208 for this_target in $target $canon_targets ; do
 209
 210     targ=${this_target}
 211     . ${srcdir}/configure.tgt
 212
 213     case ${target_cpu} in
 214       crisv32)
 215         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 216                            [Default CRIS architecture.])
 217         ;;
 218     esac
 219
 220     if test ${this_target} = $target ; then
 221       target_cpu_type=${cpu_type}
 222     elif test ${target_cpu_type} != ${cpu_type} ; then
 223       continue
 224     fi
 225
 226     generic_target=${cpu_type}-${target_vendor}-${target_os}
 227     case ${generic_target} in
 228       i386-*-msdosdjgpp* \
 229       | i386-*-go32* \
 230       | i386-go32-rtems*)
 231         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 232         ;;
 233
 234       i386-*-solaris2 \
 235       | x86_64-*-solaris2 \
 236       | i386-*-solaris2.[[0-9]] \
 237       | i386-*-solaris2.1[[01]] \
 238       | x86_64-*-solaris2.1[[01]])
 239         if test ${this_target} = $target \
 240            && test ${ac_default_x86_relax_relocations} = unset; then
 241           ac_default_x86_relax_relocations=0
 242         fi
 243         ;;
 244
 245       microblaze*)
 246         ;;
 247
 248 changequote(,)dnl
 249       ppc-*-aix[5-9].*)
 250 changequote([,])dnl
 251         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 252                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 253         ;;
 254       ppc-*-solaris*)
 255         if test ${this_target} = $target; then
 256           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 257                     [Define if default target is PowerPC Solaris.])
 258         fi
 259         if test x${endian} = xbig; then
 260           AC_MSG_ERROR(Solaris must be configured little endian)
 261         fi
 262         ;;
 263     esac
 264
 265     if test ${this_target} = $target ; then
 266       endian_def=
 267       if test x${endian} = xbig; then
 268         endian_def=1
 269       elif test x${endian} = xlittle; then
 270         endian_def=0
 271       fi
 272       if test x${endian_def} != x; then
 273         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 274                            [Define as 1 if big endian.])
 275       fi
 276     fi
 277
 278 # Other random stuff.
 279
 280     case ${cpu_type} in
 281       mips)
 282         # Set mips_cpu to the name of the default CPU.
 283         case ${target_cpu} in
 284           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 285             mips_cpu=from-abi
 286             ;;
 287           mipsisa32 | mipsisa32el)
 288             mips_cpu=mips32
 289             ;;
 290           mipsisa32r2 | mipsisa32r2el)
 291             mips_cpu=mips32r2
 292             ;;
 293           mipsisa32r3 | mipsisa32r3el)
 294             mips_cpu=mips32r3
 295             ;;
 296           mipsisa32r5 | mipsisa32r5el)
 297             mips_cpu=mips32r5
 298             ;;
 299           mipsisa32r6 | mipsisa32r6el)
 300             mips_cpu=mips32r6
 301             ;;
 302           mipsisa64 | mipsisa64el)
 303             mips_cpu=mips64
 304             ;;
 305           mipsisa64r2 | mipsisa64r2el)
 306             mips_cpu=mips64r2
 307             ;;
 308           mipsisa64r3 | mipsisa64r3el)
 309             mips_cpu=mips64r3
 310             ;;
 311           mipsisa64r5 | mipsisa64r5el)
 312             mips_cpu=mips64r5
 313             ;;
 314           mipsisa64r6 | mipsisa64r6el)
 315             mips_cpu=mips64r6
 316             ;;
 317           mipstx39 | mipstx39el)
 318             mips_cpu=r3900
 319             ;;
 320           mips64vr | mips64vrel)
 321             mips_cpu=vr4100
 322             ;;
 323           mipsisa32r2* | mipsisa64r2*)
 324 changequote(,)dnl
 325             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 326 changequote([,])dnl
 327             ;;
 328           mipsisa32r6* | mipsisa64r6*)
 329 changequote(,)dnl
 330             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r6//' -e 's/el$//'`
 331 changequote([,])dnl
 332             ;;
 333           mips64* | mipsisa64* | mipsisa32*)
 334 changequote(,)dnl
 335             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 336 changequote([,])dnl
 337             ;;
 338           mips*)
 339 changequote(,)dnl
 340             mips_cpu=`echo $target_cpu | sed -e 's/^mips//' -e 's/el$//'`
 341 changequote([,])dnl
 342             ;;
 343           *)
 344             AC_MSG_ERROR($target_cpu isn't a supported MIPS CPU name)
 345             ;;
 346         esac
 347         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 348         # binaries.  It's a GNU extension that some OSes don't understand.
 349         case ${target} in
 350           *-*-irix*)
 351             use_e_mips_abi_o32=0
 352             ;;
 353           *)
 354             use_e_mips_abi_o32=1
 355             ;;
 356         esac
 357         # Decide whether to generate 32-bit or 64-bit code by default.
 358         # Used to resolve -march=from-abi when an embedded ABI is selected.
 359         case ${target} in
 360           mips64*-*-* | mipsisa64*-*-*)
 361             mips_default_64bit=1
 362             ;;
 363           *)
 364             mips_default_64bit=0
 365             ;;
 366         esac
 367         # Decide which ABI to target by default.
 368         case ${target} in
 369           mips64*-linux* | mips-sgi-irix6* | mips64*-freebsd* \
 370           | mips64*-kfreebsd*-gnu | mips64*-ps2-elf*)
 371             mips_default_abi=N32_ABI
 372             ;;
 373           mips*-linux* | mips*-freebsd* | mips*-kfreebsd*-gnu)
 374             mips_default_abi=O32_ABI
 375             ;;
 376           mips64*-openbsd*)
 377             mips_default_abi=N64_ABI
 378             ;;
 379           *)
 380             mips_default_abi=NO_ABI
 381             ;;
 382         esac
 383         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 384                            [Default CPU for MIPS targets. ])
 385         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 386                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 387         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 388                            [Generate 64-bit code by default on MIPS targets. ])
 389         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 390                            [Choose a default ABI for MIPS targets. ])
 391         ;;
 392     esac
 393
 394     # Do we need the opcodes library?
 395     case ${cpu_type} in
 396       vax | tic30)
 397         ;;
 398
 399       *)
 400         need_opcodes=yes
 401
 402         case "${enable_shared}" in
 403         yes) shared_opcodes=true ;;
 404         *opcodes*) shared_opcodes=true ;;
 405         *) shared_opcodes=false ;;
 406         esac
 407         ;;
 408     esac
 409
 410     # Any other special object files needed ?
 411     case ${cpu_type} in
 412
 413       bfin)
 414         for f in bfin-parse.o bfin-lex-wrapper.o; do
 415           case " $extra_objects " in
 416             *" $f "*) ;;
 417             *) extra_objects="$extra_objects $f" ;;
 418           esac
 419         done
 420         ;;
 421
 422       epiphany | fr30 | ip2k | iq2000 | lm32 | m32r | or1k)
 423         using_cgen=yes
 424         ;;
 425
 426       m32c)
 427         using_cgen=yes
 428         ;;
 429       frv)
 430         using_cgen=yes
 431         ;;
 432       m68k)
 433         f=m68k-parse.o
 434         case " $extra_objects " in
 435           *" $f "*) ;;
 436           *) extra_objects="$extra_objects $f" ;;
 437         esac
 438         ;;
 439
 440       mep)
 441         using_cgen=yes
 442         ;;
 443
 444       mips)
 445         for f in itbl-parse.o itbl-lex-wrapper.o itbl-ops.o; do
 446           case " $extra_objects " in
 447             *" $f "*) ;;
 448             *) extra_objects="$extra_objects $f" ;;
 449           esac
 450         done
 451         ;;
 452
 453       mt)
 454         using_cgen=yes
 455         ;;
 456
 457       nds32)
 458         # setup NDS32_LINUX_TOOLCHAIN definition
 459         if test "linux" = $em; then
 460           AC_DEFINE(NDS32_LINUX_TOOLCHAIN, 1,
 461             [Define value for nds32_linux_toolchain])
 462         else
 463           AC_DEFINE(NDS32_LINUX_TOOLCHAIN, 0,
 464             [Define default value for nds32_linux_toolchain])
 465         fi
 466
 467         # Decide BASELINE, REDUCED_REGS, FPU_DP_EXT, FPU_SP_EXT features
 468         # based on arch_name.
 469         AC_MSG_CHECKING(for default configuration of --with-arch)
 470         if test "x${with_arch}" != x; then
 471           case ${with_arch} in
 472             v2j | v2s | v2f | v2 | v3m | v3j | v3s | v3f | v3 )
 473               AC_DEFINE_UNQUOTED(NDS32_DEFAULT_ARCH_NAME, "$with_arch",
 474                                  [Define value for nds32_arch_name])
 475               ;;
 476             *)
 477               AC_MSG_ERROR(This kind of arch name does *NOT* exist!)
 478               ;;
 479           esac
 480         fi
 481         AC_MSG_RESULT($with_arch)
 482
 483         # Decide features one by one.
 484         AC_MSG_CHECKING(for default configuration of --enable-dx-regs)
 485         if test "x${enable_dx_regs}" = xyes; then
 486           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 1,
 487                     [Define value for nds32_dx_regs])
 488         else
 489           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 0,
 490                     [Define default value for nds32_dx_regs])
 491         fi
 492         AC_MSG_RESULT($enable_dx_regs)
 493
 494         AC_MSG_CHECKING(for default configuration of --enable-perf-ext)
 495         if test "x${enable_perf_ext}" = xno; then
 496           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 0,
 497                     [Define value for nds32_perf_ext])
 498         else
 499           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 1,
 500                     [Define default value for nds32_perf_ext])
 501         fi
 502         AC_MSG_RESULT($enable_perf_ext)
 503
 504         AC_MSG_CHECKING(for default configuration of --enable-perf-ext2)
 505         if test "x${enable_perf_ext2}" = xno; then
 506           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 0,
 507                     [Define value for nds32_perf_ext2])
 508         else
 509           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 1,
 510                     [Define default value for nds32_perf_ext2])
 511         fi
 512         AC_MSG_RESULT($enable_perf_ext2)
 513
 514         AC_MSG_CHECKING(for default configuration of --enable-string-ext)
 515         if test "x${enable_string_ext}" = xno; then
 516           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 0,
 517                     [Define value for nds32_string_ext])
 518         else
 519           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 1,
 520                     [Define default value for nds32_string_ext])
 521         fi
 522         AC_MSG_RESULT($enable_string_ext)
 523
 524         AC_MSG_CHECKING(for default configuration of --enable-audio-ext)
 525         if test "x${enable_audio_ext}" = xno; then
 526           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 0,
 527                     [Define value for nds32_audio_ext])
 528         else
 529           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 1,
 530                     [Define default value for nds32_audio_ext])
 531         fi
 532         AC_MSG_RESULT($enable_audio_ext)
 533
 534         AC_MSG_CHECKING(for default configuration of --enable-dsp-ext)
 535         if test "x${enable_dsp_ext}" = xno; then
 536           AC_DEFINE(NDS32_DEFAULT_DSP_EXT, 0,
 537                     [Define value for nds32_dsp_ext])
 538         else
 539           AC_DEFINE(NDS32_DEFAULT_DSP_EXT, 1,
 540                     [Define default value for nds32_dsp_ext])
 541         fi
 542         AC_MSG_RESULT($enable_dsp_ext)
 543
 544         AC_MSG_CHECKING(for default configuration of --enable-zol-ext)
 545         if test "x${enable_zol_ext}" = xno; then
 546           AC_DEFINE(NDS32_DEFAULT_ZOL_EXT, 0,
 547                     [Define value for nds32_zol_ext])
 548         else
 549           AC_DEFINE(NDS32_DEFAULT_ZOL_EXT, 1,
 550                     [Define default value for nds32_zol_ext])
 551         fi
 552         AC_MSG_RESULT($enable_zol_ext)
 553         ;;
 554
 555       aarch64 | i386 | riscv | s390 | sparc)
 556         if test $this_target = $target ; then
 557           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 558         fi
 559         ;;
 560
 561       rl78)
 562         f=rl78-parse.o
 563         case " $extra_objects " in
 564           *" $f "*) ;;
 565           *) extra_objects="$extra_objects $f" ;;
 566         esac
 567         ;;
 568
 569       rx)
 570         f=rx-parse.o
 571         case " $extra_objects " in
 572           *" $f "*) ;;
 573           *) extra_objects="$extra_objects $f" ;;
 574         esac
 575         ;;
 576
 577       xstormy16)
 578         using_cgen=yes
 579         ;;
 580
 581       xc16x)
 582         using_cgen=yes
 583         ;;
 584
 585       xtensa)
 586         f=config/xtensa-relax.o
 587         case " $extra_objects " in
 588           *" $f "*) ;;
 589           *) extra_objects="$extra_objects $f" ;;
 590         esac
 591         ;;
 592
 593       *)
 594         ;;
 595     esac
 596
 597     if test $using_cgen = yes ; then
 598         f=cgen.o
 599         case " $extra_objects " in
 600           *" $f "*) ;;
 601           *) extra_objects="$extra_objects $f" ;;
 602         esac
 603     fi
 604
 605 # See if we really can support this configuration with the emulation code.
 606
 607     if test $this_target = $target ; then
 608       obj_format=$fmt
 609       te_file=$em
 610     fi
 611
 612     case ${te_file} in
 613       vms)
 614         f=config/te-vms.o
 615         case " $extra_objects " in
 616           *" $f "*) ;;
 617           *) extra_objects="$extra_objects $f" ;;
 618         esac ;;
 619     esac
 620
 621 # From target name and format, produce a list of supported emulations.
 622
 623     case ${generic_target}-${fmt} in
 624       mips-*-*-*)       case "$endian" in
 625                         big)    emulation="mipsbelf mipslelf mipself" ;;
 626                         *)      emulation="mipslelf mipsbelf mipself" ;;
 627                         esac ;;
 628       # i386-pc-pe-coff != i386-pc-coff.
 629       i386-*-pe-coff)   ;;
 630       # Uncommenting the next line will turn on support for i386 AOUT
 631       # for the default linux configuration
 632       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 633       #
 634       i386-*-aout)      emulation="i386aout" ;;
 635       i386-*-coff)      emulation="i386coff" ;;
 636       i386-*-elf)       emulation="i386elf" ;;
 637
 638       # Always all formats.  The first stated emulation becomes the default.
 639       cris-*-*aout*)    emulation="crisaout criself" ;;
 640       cris-*-*)         emulation="criself crisaout" ;;
 641     esac
 642
 643     emulations="$emulations $emulation"
 644
 645 done
 646
 647 if test ${ac_default_x86_relax_relocations} = unset; then
 648   ac_default_x86_relax_relocations=1
 649 fi
 650 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_X86_RELAX_RELOCATIONS,
 651   $ac_default_x86_relax_relocations,
 652   [Define to 1 if you want to generate x86 relax relocations by default.])
 653
 654 if test ${ac_default_elf_stt_common} = unset; then
 655   ac_default_elf_stt_common=0
 656 fi
 657 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_ELF_STT_COMMON,
 658   $ac_default_elf_stt_common,
 659   [Define to 1 if you want to generate ELF common symbols with the
 660    STT_COMMON type by default.])
 661
 662 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_BUILD_NOTES,
 663   $ac_default_generate_build_notes,
 664   [Define to 1 if you want to generate GNU Build attribute notes
 665    by default, if none are contained in the input.])
 666
 667 if test ${ac_default_generate_x86_used_note} = unset; then
 668   ac_default_generate_x86_used_note=0
 669 fi
 670 AC_DEFINE_UNQUOTED(DEFAULT_X86_USED_NOTE,
 671   $ac_default_generate_x86_used_note,
 672   [Define to 1 if you want to generate GNU x86 used ISA and feature
 673    properties by default.])
 674
 675 if test ${ac_default_generate_riscv_attr} = unset; then
 676     case ${target_os} in
 677       elf)
 678         ac_default_generate_riscv_attr=1
 679         ;;
 680       *)
 681         ac_default_generate_riscv_attr=0
 682         ;;
 683   esac
 684 fi
 685
 686 AC_DEFINE_UNQUOTED(DEFAULT_RISCV_ATTR,
 687   $ac_default_generate_riscv_attr,
 688   [Define to 1 if you want to generate RISC-V arch attribute by default.])
 689
 690 if test x$ac_default_compressed_debug_sections = xyes ; then
 691   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 692 fi
 693
 694 # Turn on all targets if possible
 695 if test ${all_targets} = "yes"; then
 696   case ${target_cpu_type} in
 697   i386)
 698     case ${obj_format} in
 699     aout)
 700       emulations="$emulations i386coff i386elf"
 701       ;;
 702     coff)
 703       emulations="$emulations i386aout i386elf"
 704     ;;
 705     elf)
 706       emulations="$emulations i386aout i386coff"
 707       ;;
 708     esac
 709   ;;
 710   x86_64)
 711     case ${obj_format} in
 712     aout)
 713       emulations="$emulations i386coff i386elf"
 714       ;;
 715     coff)
 716       emulations="$emulations i386aout i386elf"
 717     ;;
 718     elf)
 719       emulations="$emulations i386aout i386coff"
 720       ;;
 721     esac
 722   ;;
 723   esac
 724 fi
 725
 726 # PE code has way too many macros tweaking behaviour
 727 case ${te_file} in
 728   pe*) emulations="" ;;
 729 esac
 730
 731 # Assign floating point type.  Most processors with FP support
 732 # IEEE FP.  On those that don't support FP at all, usually IEEE
 733 # is emulated.
 734 case ${target_cpu} in
 735   vax | pdp11 ) atof=vax ;;
 736   *)            atof=ieee ;;
 737 esac
 738
 739 case "${obj_format}" in
 740   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 741 esac
 742
 743 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 744 cgen_cpu_prefix=""
 745 if test $using_cgen = yes ; then
 746   case ${target_cpu} in
 747     or1knd)
 748        cgen_cpu_prefix=or1k ;;
 749     *) cgen_cpu_prefix=${target_cpu} ;;
 750   esac
 751   AC_SUBST(cgen_cpu_prefix)
 752   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 753 fi
 754
 755 dnl
 756 dnl Make sure the desired support files exist.
 757 dnl
 758
 759 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 760   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 761 fi
 762
 763 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 764   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 765 fi
 766
 767 # Some COFF configurations want these random other flags set.
 768 case ${obj_format} in
 769   coff)
 770     case ${target_cpu_type} in
 771       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 772       x86_64) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 773     esac
 774     ;;
 775 esac
 776
 777 # Getting this done right is going to be a bitch.  Each configuration specified
 778 # with --enable-targets=... should be checked for environment, format, cpu
 779 # setting.
 780 #
 781 # For each configuration, the necessary object file support code must be linked
 782 # in.  This might be only one, it might be up to four.  The necessary emulation
 783 # code needs to be provided, too.
 784 #
 785 # And then there's "--enable-targets=all"....
 786 #
 787 # For now, just always do it for MIPS ELF configurations.  Sigh.
 788
 789 formats="${obj_format}"
 790 emfiles=""
 791 EMULATIONS=""
 792 GAS_UNIQ(emulations)
 793 for em in . $emulations ; do
 794   case $em in
 795     .)  continue ;;
 796     mipsbelf | mipslelf | mipself)
 797         fmt=elf   file=mipself ;;
 798     *coff)
 799         fmt=coff  file=$em ;;
 800     *aout)
 801         fmt=aout file=$em ;;
 802     *elf)
 803         fmt=elf file=$em ;;
 804   esac
 805   formats="$formats $fmt"
 806   emfiles="$emfiles config/e-$file.o"
 807   EMULATIONS="$EMULATIONS &$em,"
 808 done
 809 GAS_UNIQ(formats)
 810 GAS_UNIQ(emfiles)
 811 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 812   for fmt in $formats ; do
 813     case $fmt in
 814       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 815       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 816       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 817       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 818       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 819       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 820     esac
 821     extra_objects="$extra_objects config/obj-$fmt.o"
 822   done
 823   obj_format=multi
 824 fi
 825 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 826   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 827   # e-mipself has more than one emulation per file, e-i386* has just one at the
 828   # moment.  If only one emulation is specified, then don't define
 829   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 830   case "${obj_format}${emfiles}" in
 831     multi* | *mipself*)
 832       extra_objects="$extra_objects $emfiles"
 833       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 834   esac
 835 fi
 836 AC_SUBST(extra_objects)
 837 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 838 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 839                    [Default emulation.])
 840
 841 reject_dev_configs=yes
 842
 843 case ${reject_dev_configs}-${dev} in
 844   yes-yes) # Oops.
 845     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 846     ;;
 847 esac
 848
 849 AC_SUBST(target_cpu_type)
 850 AC_SUBST(obj_format)
 851 AC_SUBST(te_file)
 852 AC_SUBST(install_tooldir)
 853 AC_SUBST(atof)
 854 dnl AC_SUBST(emulation)
 855
 856 # do we need the opcodes library?
 857 case "${need_opcodes}" in
 858 yes)
 859   OPCODES_LIB=../opcodes/libopcodes.la
 860   ;;
 861 esac
 862
 863 AC_SUBST(OPCODES_LIB)
 864
 865 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 866 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 867 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 868 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 869 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 870
 871 AC_PROG_YACC
 872 AM_PROG_LEX
 873
 874 ALL_LINGUAS="es fi fr id ja ru rw sv tr uk zh_CN"
 875 ZW_GNU_GETTEXT_SISTER_DIR
 876 AM_PO_SUBDIRS
 877
 878 AM_MAINTAINER_MODE
 879 AM_CONDITIONAL(GENINSRC_NEVER, false)
 880 AC_EXEEXT
 881
 882 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h errno.h sys/types.h limits.h locale.h time.h sys/stat.h)
 883 ACX_HEADER_STRING
 884
 885 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 886 # people who are not cross-compiling but are compiling cross-assemblers.
 887 AC_MSG_CHECKING(whether compiling a cross-assembler)
 888 if test "${host}" = "${target}"; then
 889   cross_gas=no
 890 else
 891   cross_gas=yes
 892   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 893 fi
 894 AC_MSG_RESULT($cross_gas)
 895
 896 dnl ansidecl.h will deal with const
 897 dnl AC_C_CONST
 898 AC_FUNC_ALLOCA
 899 AC_C_INLINE
 900
 901 # VMS doesn't have unlink.
 902 AC_CHECK_FUNCS(unlink remove, break)
 903 AC_CHECK_FUNCS(sbrk setlocale)
 904 AC_CHECK_FUNCS(strsignal)
 905
 906 AM_LC_MESSAGES
 907
 908 # do we need the math library?
 909 case "${need_libm}" in
 910 yes)
 911   LT_LIB_M
 912   AC_SUBST(LIBM)
 913   ;;
 914 esac
 915
 916 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 917 # enough, but on some of those systems, the assert macro relies on requoting
 918 # working properly!
 919 GAS_WORKING_ASSERT
 920
 921 # On some systems, the system header files may not declare malloc, realloc,
 922 # and free.  There are places where gas needs these functions to have been
 923 # declared -- such as when taking their addresses.
 924 gas_test_headers="
 925 #ifdef HAVE_MEMORY_H
 926 #include <memory.h>
 927 #endif
 928 #ifdef HAVE_STRING_H
 929 #include <string.h>
 930 #else
 931 #ifdef HAVE_STRINGS_H
 932 #include <strings.h>
 933 #endif
 934 #endif
 935 #ifdef HAVE_STDLIB_H
 936 #include <stdlib.h>
 937 #endif
 938 #ifdef HAVE_UNISTD_H
 939 #include <unistd.h>
 940 #endif
 941 "
 942
 943 # Does errno.h declare errno, or do we have to add a separate declaration
 944 # for it?
 945 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 946 #ifdef HAVE_ERRNO_H
 947 #include <errno.h>
 948 #endif
 949 ])
 950
 951 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 952 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
 953 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 954 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
 955 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
 956 if test $gas_cv_decl_getopt_unistd_h = yes; then
 957   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 958             [Is the prototype for getopt in <unistd.h> in the expected format?])
 959 fi
 960
 961 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 962 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
 963 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 964 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 965 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 966 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 967
 968 AC_CHECK_DECLS([free, getenv, malloc, mempcpy, realloc, stpcpy, strstr, vsnprintf, asprintf])
 969
 970 BFD_BINARY_FOPEN
 971
 972 # Link in zlib if we can.  This allows us to write compressed debug sections.
 973 AM_ZLIB
 974
 975 # Support for VMS timestamps via cross compile
 976
 977 if test "$ac_cv_header_time_h" = yes; then
 978   GAS_HAVE_TIME_TYPE_MEMBER(struct tm, tm_gmtoff)
 979 fi
 980
 981 if test "$ac_cv_header_sys_stat_h" = yes; then
 982     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_sec)
 983     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_nsec)
 984 fi
 985
 986
 987 dnl Required for html, pdf, install-pdf and install-html targets.
 988 AC_SUBST(datarootdir)
 989 AC_SUBST(docdir)
 990 AC_SUBST(htmldir)
 991 AC_SUBST(pdfdir)
 992
 993 dnl This must come last.
 994
 995 dnl We used to make symlinks to files in the source directory, but now
 996 dnl we just use the right name for .c files, and create .h files in
 997 dnl the build directory which include the right .h file.  Make sure
 998 dnl the old symlinks don't exist, so that a reconfigure in an existing
 999 dnl directory behaves reasonably.
1000
1001 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
1002 AC_CONFIG_COMMANDS([default],
1003 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1004  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1005  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1006  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1007  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1008  if test "x$cgen_cpu_prefix" != x ; then
1009    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1010  fi],
1011 [target_cpu_type=${target_cpu_type}
1012  cgen_cpu_prefix=${cgen_cpu_prefix}
1013  obj_format=${obj_format}
1014  te_file=${te_file}])
1015
1016 AC_OUTPUT