gas/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl   Copyright (C) 2012-2018 Free Software Foundation, Inc.
   7 dnl
   8 dnl This file is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; see the file COPYING3.  If not see
  20 dnl <http://www.gnu.org/licenses/>.
  21 dnl
  22 dnl v2.5 needed for --bindir et al
  23 m4_include([../bfd/version.m4])
  24 AC_INIT([gas], BFD_VERSION)
  25 AC_CONFIG_SRCDIR(as.h)
  26
  27 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  28 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  29 dnl gas/ instead of gas/../.
  30 AC_CONFIG_AUX_DIR(..)
  31 AC_CANONICAL_TARGET
  32 AC_ISC_POSIX
  33
  34 AM_INIT_AUTOMAKE
  35
  36 AC_PROG_CC
  37 AC_GNU_SOURCE
  38 AC_USE_SYSTEM_EXTENSIONS
  39
  40 LT_INIT
  41 ACX_LARGEFILE
  42 ACX_PROG_CMP_IGNORE_INITIAL
  43
  44 AC_ARG_ENABLE(targets,
  45 [  --enable-targets        alternative target configurations besides the primary],
  46 [case "${enableval}" in
  47   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  48             ;;
  49   no)       enable_targets= ;;
  50   *)        enable_targets=$enableval ;;
  51 esac])dnl
  52
  53 ac_checking=yes
  54 if grep '^RELEASE=y' ${srcdir}/../bfd/Makefile.am >/dev/null 2>/dev/null ; then
  55   ac_checking=
  56 fi
  57 AC_ARG_ENABLE(checking,
  58 [  --enable-checking       enable run-time checks],
  59 [case "${enableval}" in
  60   no|none)  ac_checking= ;;
  61   *)        ac_checking=yes ;;
  62 esac])dnl
  63 if test x$ac_checking != x ; then
  64   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  65 fi
  66
  67 # PR gas/19109
  68 # Decide the default method for compressing debug sections.
  69 ac_default_compressed_debug_sections=unset
  70 # Provide a configure time option to override our default.
  71 AC_ARG_ENABLE(compressed_debug_sections,
  72               AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,none}],
  73               [compress debug sections by default]),
  74 [case ,"${enableval}", in
  75   ,yes, | ,all, | *,gas,*) ac_default_compressed_debug_sections=yes ;;
  76   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
  77   *)   ac_default_compressed_debug_sections=unset ;;
  78 esac])dnl
  79
  80 # PR gas/19520
  81 # Decide if x86 assembler should generate relax relocations.
  82 ac_default_x86_relax_relocations=unset
  83 # Provide a configure time option to override our default.
  84 AC_ARG_ENABLE(x86_relax_relocations,
  85               AS_HELP_STRING([--enable-x86-relax-relocations],
  86               [generate x86 relax relocations by default]),
  87 [case "${enableval}" in
  88   no)  ac_default_x86_relax_relocations=0 ;;
  89 esac])dnl
  90
  91 # Decide if ELF assembler should generate common symbols with the
  92 # STT_COMMON type.
  93 ac_default_elf_stt_common=unset
  94 # Provide a configure time option to override our default.
  95 AC_ARG_ENABLE(elf_stt_common,
  96               AS_HELP_STRING([--enable-elf-stt-common],
  97               [generate ELF common symbols with STT_COMMON type by default]),
  98 [case "${enableval}" in
  99   yes)  ac_default_elf_stt_common=1 ;;
 100 esac])dnl
 101
 102
 103 # Decide if the ELF assembler should default to generating
 104 # GNU Build notes if none are provided by the input.
 105 ac_default_generate_build_notes=0
 106 # Provide a configuration option to override the default.
 107 AC_ARG_ENABLE(generate_build_notes,
 108               AS_HELP_STRING([--enable-generate-build-notes],
 109               [generate GNU Build notes if none are provided by the input]),
 110 [case "${enableval}" in
 111   yes)  ac_default_generate_build_notes=1 ;;
 112   no)   ac_default_generate_build_notes=0 ;;
 113 esac])dnl
 114
 115
 116 # Decide if the x86 ELF assembler should default to generating GNU x86
 117 # used ISA and feature properties.
 118 ac_default_generate_x86_used_note=unset
 119 # Provide a configuration option to override the default.
 120 AC_ARG_ENABLE(x86-used-note,
 121               AS_HELP_STRING([--enable-x86-used-note],
 122               [generate GNU x86 used ISA and feature properties]),
 123 [case "${enableval}" in
 124   yes)  ac_default_generate_x86_used_note=1 ;;
 125   no)   ac_default_generate_x86_used_note=0 ;;
 126 esac])dnl
 127
 128
 129 using_cgen=no
 130
 131 AM_BINUTILS_WARNINGS
 132
 133 # Generate a header file
 134 AC_CONFIG_HEADERS(config.h:config.in)
 135
 136 dnl Option --with-cpu=TYPE allows configure type control of the default
 137 dnl cpu type within the assembler.  Currently only the ARC target
 138 dnl supports this feature, but others may be added in the future.
 139 AC_ARG_WITH(cpu,
 140             AS_HELP_STRING([--with-cpu=CPU],
 141             [default cpu variant is CPU (currently only supported on ARC)]),
 142             [AC_DEFINE_UNQUOTED(TARGET_WITH_CPU,
 143                                 "${with_cpu}",
 144                                 [Target specific CPU.])],
 145             [])
 146
 147 # PR 14072
 148 AH_VERBATIM([00_CONFIG_H_CHECK],
 149 [/* Check that config.h is #included before system headers
 150    (this works only for glibc, but that should be enough).  */
 151 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 152 #  error config.h must be #included before system headers
 153 #endif
 154 #define __CONFIG_H__ 1])
 155
 156 # If we are on a DOS filesystem, we must use gdb.ini rather than
 157 # .gdbinit.
 158 case "${host}" in
 159   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
 160     GDBINIT="gdb.ini"
 161     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
 162     ;;
 163   *)
 164     GDBINIT=".gdbinit"
 165     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
 166     ;;
 167 esac
 168 AC_SUBST(GDBINIT)
 169
 170 #We need this for the host.
 171 AC_C_BIGENDIAN
 172
 173 te_file=generic
 174
 175 # Makefile target for installing gas in $(tooldir)/bin.
 176 install_tooldir=install-exec-tooldir
 177
 178 canon_targets=""
 179 all_targets=no
 180 if test -n "$enable_targets" ; then
 181   for t in `echo $enable_targets | sed 's/,/ /g'`; do
 182     if test $t = "all"; then
 183       all_targets=yes
 184       continue
 185     fi
 186     result=`$ac_config_sub $t 2>/dev/null`
 187     if test -n "$result" ; then
 188       canon_targets="$canon_targets $result"
 189 #    else
 190 #      # Permit "all", etc.  We don't support it yet though.
 191 #      canon_targets="$canon_targets $t"
 192     fi
 193   done
 194   GAS_UNIQ(canon_targets)
 195 fi
 196
 197 emulations=""
 198
 199 for this_target in $target $canon_targets ; do
 200
 201     targ=${this_target}
 202     . ${srcdir}/configure.tgt
 203
 204     case ${target_cpu} in
 205       crisv32)
 206         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 207                            [Default CRIS architecture.])
 208         ;;
 209     esac
 210
 211     if test ${this_target} = $target ; then
 212       target_cpu_type=${cpu_type}
 213     elif test ${target_cpu_type} != ${cpu_type} ; then
 214       continue
 215     fi
 216
 217     generic_target=${cpu_type}-${target_vendor}-${target_os}
 218     case ${generic_target} in
 219       i386-*-msdosdjgpp* \
 220       | i386-*-go32* \
 221       | i386-go32-rtems*)
 222         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 223         ;;
 224
 225       i386-*-solaris2 \
 226       | x86_64-*-solaris2 \
 227       | i386-*-solaris2.[[0-9]] \
 228       | i386-*-solaris2.1[[01]] \
 229       | x86_64-*-solaris2.1[[01]])
 230         if test ${this_target} = $target \
 231            && test ${ac_default_x86_relax_relocations} = unset; then
 232           ac_default_x86_relax_relocations=0
 233         fi
 234         ;;
 235
 236       microblaze*)
 237         ;;
 238
 239 changequote(,)dnl
 240       ppc-*-aix[5-9].*)
 241 changequote([,])dnl
 242         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 243                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 244         ;;
 245       ppc-*-solaris*)
 246         if test ${this_target} = $target; then
 247           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 248                     [Define if default target is PowerPC Solaris.])
 249         fi
 250         if test x${endian} = xbig; then
 251           AC_MSG_ERROR(Solaris must be configured little endian)
 252         fi
 253         ;;
 254     esac
 255
 256     if test ${this_target} = $target ; then
 257       endian_def=
 258       if test x${endian} = xbig; then
 259         endian_def=1
 260       elif test x${endian} = xlittle; then
 261         endian_def=0
 262       fi
 263       if test x${endian_def} != x; then
 264         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 265                            [Define as 1 if big endian.])
 266       fi
 267     fi
 268
 269 # Other random stuff.
 270
 271     case ${cpu_type} in
 272       mips)
 273         # Set mips_cpu to the name of the default CPU.
 274         case ${target_cpu} in
 275           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 276             mips_cpu=from-abi
 277             ;;
 278           mipsisa32 | mipsisa32el)
 279             mips_cpu=mips32
 280             ;;
 281           mipsisa32r2 | mipsisa32r2el)
 282             mips_cpu=mips32r2
 283             ;;
 284           mipsisa32r3 | mipsisa32r3el)
 285             mips_cpu=mips32r3
 286             ;;
 287           mipsisa32r5 | mipsisa32r5el)
 288             mips_cpu=mips32r5
 289             ;;
 290           mipsisa32r6 | mipsisa32r6el)
 291             mips_cpu=mips32r6
 292             ;;
 293           mipsisa64 | mipsisa64el)
 294             mips_cpu=mips64
 295             ;;
 296           mipsisa64r2 | mipsisa64r2el)
 297             mips_cpu=mips64r2
 298             ;;
 299           mipsisa64r3 | mipsisa64r3el)
 300             mips_cpu=mips64r3
 301             ;;
 302           mipsisa64r5 | mipsisa64r5el)
 303             mips_cpu=mips64r5
 304             ;;
 305           mipsisa64r6 | mipsisa64r6el)
 306             mips_cpu=mips64r6
 307             ;;
 308           mipstx39 | mipstx39el)
 309             mips_cpu=r3900
 310             ;;
 311           mips64vr | mips64vrel)
 312             mips_cpu=vr4100
 313             ;;
 314           mipsisa32r2* | mipsisa64r2*)
 315 changequote(,)dnl
 316             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 317 changequote([,])dnl
 318             ;;
 319           mipsisa32r6* | mipsisa64r6*)
 320 changequote(,)dnl
 321             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r6//' -e 's/el$//'`
 322 changequote([,])dnl
 323             ;;
 324           mips64* | mipsisa64* | mipsisa32*)
 325 changequote(,)dnl
 326             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 327 changequote([,])dnl
 328             ;;
 329           mips*)
 330 changequote(,)dnl
 331             mips_cpu=`echo $target_cpu | sed -e 's/^mips//' -e 's/el$//'`
 332 changequote([,])dnl
 333             ;;
 334           *)
 335             AC_MSG_ERROR($target_cpu isn't a supported MIPS CPU name)
 336             ;;
 337         esac
 338         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 339         # binaries.  It's a GNU extension that some OSes don't understand.
 340         case ${target} in
 341           *-*-irix*)
 342             use_e_mips_abi_o32=0
 343             ;;
 344           *)
 345             use_e_mips_abi_o32=1
 346             ;;
 347         esac
 348         # Decide whether to generate 32-bit or 64-bit code by default.
 349         # Used to resolve -march=from-abi when an embedded ABI is selected.
 350         case ${target} in
 351           mips64*-*-* | mipsisa64*-*-*)
 352             mips_default_64bit=1
 353             ;;
 354           *)
 355             mips_default_64bit=0
 356             ;;
 357         esac
 358         # Decide which ABI to target by default.
 359         case ${target} in
 360           mips64*-linux* | mips-sgi-irix6* | mips64*-freebsd* \
 361           | mips64*-kfreebsd*-gnu | mips64*-ps2-elf*)
 362             mips_default_abi=N32_ABI
 363             ;;
 364           mips*-linux* | mips*-freebsd* | mips*-kfreebsd*-gnu)
 365             mips_default_abi=O32_ABI
 366             ;;
 367           mips64*-openbsd*)
 368             mips_default_abi=N64_ABI
 369             ;;
 370           *)
 371             mips_default_abi=NO_ABI
 372             ;;
 373         esac
 374         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 375                            [Default CPU for MIPS targets. ])
 376         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 377                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 378         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 379                            [Generate 64-bit code by default on MIPS targets. ])
 380         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 381                            [Choose a default ABI for MIPS targets. ])
 382         ;;
 383     esac
 384
 385     # Do we need the opcodes library?
 386     case ${cpu_type} in
 387       vax | tic30)
 388         ;;
 389
 390       *)
 391         need_opcodes=yes
 392
 393         case "${enable_shared}" in
 394         yes) shared_opcodes=true ;;
 395         *opcodes*) shared_opcodes=true ;;
 396         *) shared_opcodes=false ;;
 397         esac
 398         ;;
 399     esac
 400
 401     # Any other special object files needed ?
 402     case ${cpu_type} in
 403
 404       bfin)
 405         for f in bfin-parse.o bfin-lex-wrapper.o; do
 406           case " $extra_objects " in
 407             *" $f "*) ;;
 408             *) extra_objects="$extra_objects $f" ;;
 409           esac
 410         done
 411         ;;
 412
 413       epiphany | fr30 | ip2k | iq2000 | lm32 | m32r | or1k)
 414         using_cgen=yes
 415         ;;
 416
 417       m32c)
 418         using_cgen=yes
 419         ;;
 420       frv)
 421         using_cgen=yes
 422         ;;
 423       m68k)
 424         f=m68k-parse.o
 425         case " $extra_objects " in
 426           *" $f "*) ;;
 427           *) extra_objects="$extra_objects $f" ;;
 428         esac
 429         ;;
 430
 431       mep)
 432         using_cgen=yes
 433         ;;
 434
 435       mips)
 436         for f in itbl-parse.o itbl-lex-wrapper.o itbl-ops.o; do
 437           case " $extra_objects " in
 438             *" $f "*) ;;
 439             *) extra_objects="$extra_objects $f" ;;
 440           esac
 441         done
 442         ;;
 443
 444       mt)
 445         using_cgen=yes
 446         ;;
 447
 448       nds32)
 449         # setup NDS32_LINUX_TOOLCHAIN definition
 450         if test "linux" = $em; then
 451           AC_DEFINE(NDS32_LINUX_TOOLCHAIN, 1,
 452             [Define value for nds32_linux_toolchain])
 453         else
 454           AC_DEFINE(NDS32_LINUX_TOOLCHAIN, 0,
 455             [Define default value for nds32_linux_toolchain])
 456         fi
 457
 458         # Decide BASELINE, REDUCED_REGS, FPU_DP_EXT, FPU_SP_EXT features
 459         # based on arch_name.
 460         AC_MSG_CHECKING(for default configuration of --with-arch)
 461         if test "x${with_arch}" != x; then
 462           case ${with_arch} in
 463             v2j | v2s | v2f | v2 | v3m | v3j | v3s | v3f | v3 )
 464               AC_DEFINE_UNQUOTED(NDS32_DEFAULT_ARCH_NAME, "$with_arch",
 465                                  [Define value for nds32_arch_name])
 466               ;;
 467             *)
 468               AC_MSG_ERROR(This kind of arch name does *NOT* exist!)
 469               ;;
 470           esac
 471         fi
 472         AC_MSG_RESULT($with_arch)
 473
 474         # Decide features one by one.
 475         AC_MSG_CHECKING(for default configuration of --enable-dx-regs)
 476         if test "x${enable_dx_regs}" = xyes; then
 477           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 1,
 478                     [Define value for nds32_dx_regs])
 479         else
 480           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 0,
 481                     [Define default value for nds32_dx_regs])
 482         fi
 483         AC_MSG_RESULT($enable_dx_regs)
 484
 485         AC_MSG_CHECKING(for default configuration of --enable-perf-ext)
 486         if test "x${enable_perf_ext}" = xno; then
 487           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 0,
 488                     [Define value for nds32_perf_ext])
 489         else
 490           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 1,
 491                     [Define default value for nds32_perf_ext])
 492         fi
 493         AC_MSG_RESULT($enable_perf_ext)
 494
 495         AC_MSG_CHECKING(for default configuration of --enable-perf-ext2)
 496         if test "x${enable_perf_ext2}" = xno; then
 497           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 0,
 498                     [Define value for nds32_perf_ext2])
 499         else
 500           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 1,
 501                     [Define default value for nds32_perf_ext2])
 502         fi
 503         AC_MSG_RESULT($enable_perf_ext2)
 504
 505         AC_MSG_CHECKING(for default configuration of --enable-string-ext)
 506         if test "x${enable_string_ext}" = xno; then
 507           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 0,
 508                     [Define value for nds32_string_ext])
 509         else
 510           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 1,
 511                     [Define default value for nds32_string_ext])
 512         fi
 513         AC_MSG_RESULT($enable_string_ext)
 514
 515         AC_MSG_CHECKING(for default configuration of --enable-audio-ext)
 516         if test "x${enable_audio_ext}" = xno; then
 517           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 0,
 518                     [Define value for nds32_audio_ext])
 519         else
 520           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 1,
 521                     [Define default value for nds32_audio_ext])
 522         fi
 523         AC_MSG_RESULT($enable_audio_ext)
 524
 525         AC_MSG_CHECKING(for default configuration of --enable-dsp-ext)
 526         if test "x${enable_dsp_ext}" = xno; then
 527           AC_DEFINE(NDS32_DEFAULT_DSP_EXT, 0,
 528                     [Define value for nds32_dsp_ext])
 529         else
 530           AC_DEFINE(NDS32_DEFAULT_DSP_EXT, 1,
 531                     [Define default value for nds32_dsp_ext])
 532         fi
 533         AC_MSG_RESULT($enable_dsp_ext)
 534
 535         AC_MSG_CHECKING(for default configuration of --enable-zol-ext)
 536         if test "x${enable_zol_ext}" = xno; then
 537           AC_DEFINE(NDS32_DEFAULT_ZOL_EXT, 0,
 538                     [Define value for nds32_zol_ext])
 539         else
 540           AC_DEFINE(NDS32_DEFAULT_ZOL_EXT, 1,
 541                     [Define default value for nds32_zol_ext])
 542         fi
 543         AC_MSG_RESULT($enable_zol_ext)
 544         ;;
 545
 546       aarch64 | i386 | riscv | s390 | sparc)
 547         if test $this_target = $target ; then
 548           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 549         fi
 550         ;;
 551
 552       rl78)
 553         f=rl78-parse.o
 554         case " $extra_objects " in
 555           *" $f "*) ;;
 556           *) extra_objects="$extra_objects $f" ;;
 557         esac
 558         ;;
 559
 560       rx)
 561         f=rx-parse.o
 562         case " $extra_objects " in
 563           *" $f "*) ;;
 564           *) extra_objects="$extra_objects $f" ;;
 565         esac
 566         ;;
 567
 568       xstormy16)
 569         using_cgen=yes
 570         ;;
 571
 572       xc16x)
 573         using_cgen=yes
 574         ;;
 575
 576       xtensa)
 577         f=config/xtensa-relax.o
 578         case " $extra_objects " in
 579           *" $f "*) ;;
 580           *) extra_objects="$extra_objects $f" ;;
 581         esac
 582         ;;
 583
 584       *)
 585         ;;
 586     esac
 587
 588     if test $using_cgen = yes ; then
 589         f=cgen.o
 590         case " $extra_objects " in
 591           *" $f "*) ;;
 592           *) extra_objects="$extra_objects $f" ;;
 593         esac
 594     fi
 595
 596 # See if we really can support this configuration with the emulation code.
 597
 598     if test $this_target = $target ; then
 599       obj_format=$fmt
 600       te_file=$em
 601     fi
 602
 603     case ${te_file} in
 604       vms)
 605         f=config/te-vms.o
 606         case " $extra_objects " in
 607           *" $f "*) ;;
 608           *) extra_objects="$extra_objects $f" ;;
 609         esac ;;
 610     esac
 611
 612 # From target name and format, produce a list of supported emulations.
 613
 614     case ${generic_target}-${fmt} in
 615       mips-*-*-*)       case "$endian" in
 616                         big)    emulation="mipsbelf mipslelf mipself" ;;
 617                         *)      emulation="mipslelf mipsbelf mipself" ;;
 618                         esac ;;
 619       # i386-pc-pe-coff != i386-pc-coff.
 620       i386-*-pe-coff)   ;;
 621       # Uncommenting the next line will turn on support for i386 AOUT
 622       # for the default linux configuration
 623       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 624       #
 625       i386-*-aout)      emulation="i386aout" ;;
 626       i386-*-coff)      emulation="i386coff" ;;
 627       i386-*-elf)       emulation="i386elf" ;;
 628
 629       # Always all formats.  The first stated emulation becomes the default.
 630       cris-*-*aout*)    emulation="crisaout criself" ;;
 631       cris-*-*)         emulation="criself crisaout" ;;
 632     esac
 633
 634     emulations="$emulations $emulation"
 635
 636 done
 637
 638 if test ${ac_default_x86_relax_relocations} = unset; then
 639   ac_default_x86_relax_relocations=1
 640 fi
 641 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_X86_RELAX_RELOCATIONS,
 642   $ac_default_x86_relax_relocations,
 643   [Define to 1 if you want to generate x86 relax relocations by default.])
 644
 645 if test ${ac_default_elf_stt_common} = unset; then
 646   ac_default_elf_stt_common=0
 647 fi
 648 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_ELF_STT_COMMON,
 649   $ac_default_elf_stt_common,
 650   [Define to 1 if you want to generate ELF common symbols with the
 651    STT_COMMON type by default.])
 652
 653 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_BUILD_NOTES,
 654   $ac_default_generate_build_notes,
 655   [Define to 1 if you want to generate GNU Build attribute notes
 656    by default, if none are contained in the input.])
 657
 658 if test ${ac_default_generate_x86_used_note} = unset; then
 659   ac_default_generate_x86_used_note=0
 660 fi
 661 AC_DEFINE_UNQUOTED(DEFAULT_X86_USED_NOTE,
 662   $ac_default_generate_x86_used_note,
 663   [Define to 1 if you want to generate GNU x86 used ISA and feature
 664    properties by default.])
 665
 666 if test x$ac_default_compressed_debug_sections = xyes ; then
 667   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 668 fi
 669
 670 # Turn on all targets if possible
 671 if test ${all_targets} = "yes"; then
 672   case ${target_cpu_type} in
 673   i386)
 674     case ${obj_format} in
 675     aout)
 676       emulations="$emulations i386coff i386elf"
 677       ;;
 678     coff)
 679       emulations="$emulations i386aout i386elf"
 680     ;;
 681     elf)
 682       emulations="$emulations i386aout i386coff"
 683       ;;
 684     esac
 685   ;;
 686   x86_64)
 687     case ${obj_format} in
 688     aout)
 689       emulations="$emulations i386coff i386elf"
 690       ;;
 691     coff)
 692       emulations="$emulations i386aout i386elf"
 693     ;;
 694     elf)
 695       emulations="$emulations i386aout i386coff"
 696       ;;
 697     esac
 698   ;;
 699   esac
 700 fi
 701
 702 # PE code has way too many macros tweaking behaviour
 703 case ${te_file} in
 704   pe*) emulations="" ;;
 705 esac
 706
 707 # Assign floating point type.  Most processors with FP support
 708 # IEEE FP.  On those that don't support FP at all, usually IEEE
 709 # is emulated.
 710 case ${target_cpu} in
 711   vax | pdp11 ) atof=vax ;;
 712   *)            atof=ieee ;;
 713 esac
 714
 715 case "${obj_format}" in
 716   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 717 esac
 718
 719 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 720 cgen_cpu_prefix=""
 721 if test $using_cgen = yes ; then
 722   case ${target_cpu} in
 723     or1knd)
 724        cgen_cpu_prefix=or1k ;;
 725     *) cgen_cpu_prefix=${target_cpu} ;;
 726   esac
 727   AC_SUBST(cgen_cpu_prefix)
 728   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 729 fi
 730
 731 dnl
 732 dnl Make sure the desired support files exist.
 733 dnl
 734
 735 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 736   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 737 fi
 738
 739 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 740   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 741 fi
 742
 743 # Some COFF configurations want these random other flags set.
 744 case ${obj_format} in
 745   coff)
 746     case ${target_cpu_type} in
 747       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 748       x86_64) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 749     esac
 750     ;;
 751 esac
 752
 753 # Getting this done right is going to be a bitch.  Each configuration specified
 754 # with --enable-targets=... should be checked for environment, format, cpu
 755 # setting.
 756 #
 757 # For each configuration, the necessary object file support code must be linked
 758 # in.  This might be only one, it might be up to four.  The necessary emulation
 759 # code needs to be provided, too.
 760 #
 761 # And then there's "--enable-targets=all"....
 762 #
 763 # For now, just always do it for MIPS ELF configurations.  Sigh.
 764
 765 formats="${obj_format}"
 766 emfiles=""
 767 EMULATIONS=""
 768 GAS_UNIQ(emulations)
 769 for em in . $emulations ; do
 770   case $em in
 771     .)  continue ;;
 772     mipsbelf | mipslelf | mipself)
 773         fmt=elf   file=mipself ;;
 774     *coff)
 775         fmt=coff  file=$em ;;
 776     *aout)
 777         fmt=aout file=$em ;;
 778     *elf)
 779         fmt=elf file=$em ;;
 780   esac
 781   formats="$formats $fmt"
 782   emfiles="$emfiles config/e-$file.o"
 783   EMULATIONS="$EMULATIONS &$em,"
 784 done
 785 GAS_UNIQ(formats)
 786 GAS_UNIQ(emfiles)
 787 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 788   for fmt in $formats ; do
 789     case $fmt in
 790       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 791       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 792       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 793       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 794       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 795       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 796     esac
 797     extra_objects="$extra_objects config/obj-$fmt.o"
 798   done
 799   obj_format=multi
 800 fi
 801 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 802   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 803   # e-mipself has more than one emulation per file, e-i386* has just one at the
 804   # moment.  If only one emulation is specified, then don't define
 805   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 806   case "${obj_format}${emfiles}" in
 807     multi* | *mipself*)
 808       extra_objects="$extra_objects $emfiles"
 809       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 810   esac
 811 fi
 812 AC_SUBST(extra_objects)
 813 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 814 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 815                    [Default emulation.])
 816
 817 reject_dev_configs=yes
 818
 819 case ${reject_dev_configs}-${dev} in
 820   yes-yes) # Oops.
 821     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 822     ;;
 823 esac
 824
 825 AC_SUBST(target_cpu_type)
 826 AC_SUBST(obj_format)
 827 AC_SUBST(te_file)
 828 AC_SUBST(install_tooldir)
 829 AC_SUBST(atof)
 830 dnl AC_SUBST(emulation)
 831
 832 # do we need the opcodes library?
 833 case "${need_opcodes}" in
 834 yes)
 835   OPCODES_LIB=../opcodes/libopcodes.la
 836   ;;
 837 esac
 838
 839 AC_SUBST(OPCODES_LIB)
 840
 841 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 842 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 843 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 844 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 845 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 846
 847 AC_PROG_YACC
 848 AM_PROG_LEX
 849
 850 ALL_LINGUAS="es fi fr id ja ru rw sv tr uk zh_CN"
 851 ZW_GNU_GETTEXT_SISTER_DIR
 852 AM_PO_SUBDIRS
 853
 854 AM_MAINTAINER_MODE
 855 AM_CONDITIONAL(GENINSRC_NEVER, false)
 856 AC_EXEEXT
 857
 858 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h errno.h sys/types.h limits.h locale.h time.h sys/stat.h)
 859 ACX_HEADER_STRING
 860
 861 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 862 # people who are not cross-compiling but are compiling cross-assemblers.
 863 AC_MSG_CHECKING(whether compiling a cross-assembler)
 864 if test "${host}" = "${target}"; then
 865   cross_gas=no
 866 else
 867   cross_gas=yes
 868   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 869 fi
 870 AC_MSG_RESULT($cross_gas)
 871
 872 dnl ansidecl.h will deal with const
 873 dnl AC_C_CONST
 874 AC_FUNC_ALLOCA
 875 AC_C_INLINE
 876
 877 # VMS doesn't have unlink.
 878 AC_CHECK_FUNCS(unlink remove, break)
 879 AC_CHECK_FUNCS(sbrk setlocale)
 880 AC_CHECK_FUNCS(strsignal)
 881
 882 AM_LC_MESSAGES
 883
 884 # do we need the math library?
 885 case "${need_libm}" in
 886 yes)
 887   LT_LIB_M
 888   AC_SUBST(LIBM)
 889   ;;
 890 esac
 891
 892 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 893 # enough, but on some of those systems, the assert macro relies on requoting
 894 # working properly!
 895 GAS_WORKING_ASSERT
 896
 897 # On some systems, the system header files may not declare malloc, realloc,
 898 # and free.  There are places where gas needs these functions to have been
 899 # declared -- such as when taking their addresses.
 900 gas_test_headers="
 901 #ifdef HAVE_MEMORY_H
 902 #include <memory.h>
 903 #endif
 904 #ifdef HAVE_STRING_H
 905 #include <string.h>
 906 #else
 907 #ifdef HAVE_STRINGS_H
 908 #include <strings.h>
 909 #endif
 910 #endif
 911 #ifdef HAVE_STDLIB_H
 912 #include <stdlib.h>
 913 #endif
 914 #ifdef HAVE_UNISTD_H
 915 #include <unistd.h>
 916 #endif
 917 "
 918
 919 # Does errno.h declare errno, or do we have to add a separate declaration
 920 # for it?
 921 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 922 #ifdef HAVE_ERRNO_H
 923 #include <errno.h>
 924 #endif
 925 ])
 926
 927 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 928 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
 929 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 930 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
 931 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
 932 if test $gas_cv_decl_getopt_unistd_h = yes; then
 933   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 934             [Is the prototype for getopt in <unistd.h> in the expected format?])
 935 fi
 936
 937 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 938 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
 939 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 940 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 941 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 942 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 943
 944 AC_CHECK_DECLS([free, getenv, malloc, mempcpy, realloc, stpcpy, strstr, vsnprintf, asprintf])
 945
 946 BFD_BINARY_FOPEN
 947
 948 # Link in zlib if we can.  This allows us to write compressed debug sections.
 949 AM_ZLIB
 950
 951 # Support for VMS timestamps via cross compile
 952
 953 if test "$ac_cv_header_time_h" = yes; then
 954   GAS_HAVE_TIME_TYPE_MEMBER(struct tm, tm_gmtoff)
 955 fi
 956
 957 if test "$ac_cv_header_sys_stat_h" = yes; then
 958     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_sec)
 959     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_nsec)
 960 fi
 961
 962
 963 dnl Required for html, pdf, install-pdf and install-html targets.
 964 AC_SUBST(datarootdir)
 965 AC_SUBST(docdir)
 966 AC_SUBST(htmldir)
 967 AC_SUBST(pdfdir)
 968
 969 dnl This must come last.
 970
 971 dnl We used to make symlinks to files in the source directory, but now
 972 dnl we just use the right name for .c files, and create .h files in
 973 dnl the build directory which include the right .h file.  Make sure
 974 dnl the old symlinks don't exist, so that a reconfigure in an existing
 975 dnl directory behaves reasonably.
 976
 977 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 978 AC_CONFIG_COMMANDS([default],
 979 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 980  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 981  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 982  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 983  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 984  if test "x$cgen_cpu_prefix" != x ; then
 985    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 986  fi],
 987 [target_cpu_type=${target_cpu_type}
 988  cgen_cpu_prefix=${cgen_cpu_prefix}
 989  obj_format=${obj_format}
 990  te_file=${te_file}])
 991
 992 AC_OUTPUT