fuzz/CMakeLists.txt

   1 if(NOT ENABLE_STATIC)
   2   message(FATAL_ERROR "Fuzz targets require static libraries.")
   3 endif()
   4 if(NOT WITH_TURBOJPEG)
   5   message(FATAL_ERROR "Fuzz targets require the TurboJPEG API library.")
   6 endif()
   7
   8 set(FUZZ_BINDIR "" CACHE PATH
   9   "Directory into which fuzz targets should be installed")
  10 if(NOT FUZZ_BINDIR)
  11   message(FATAL_ERROR "FUZZ_BINDIR must be specified.")
  12 endif()
  13 message(STATUS "FUZZ_BINDIR = ${FUZZ_BINDIR}")
  14
  15 set(FUZZ_LIBRARY "" CACHE STRING
  16   "Path to fuzzer library or flags necessary to link with it")
  17 if(NOT FUZZ_LIBRARY)
  18   message(FATAL_ERROR "FUZZ_LIBRARY must be specified.")
  19 endif()
  20 message(STATUS "FUZZ_LIBRARY = ${FUZZ_LIBRARY}")
  21
  22 enable_language(CXX)
  23
  24 set(EFFECTIVE_CXX_FLAGS
  25   "${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
  26 message(STATUS "C++ Compiler flags = ${EFFECTIVE_CXX_FLAGS}")
  27
  28 add_executable(cjpeg_fuzzer${FUZZER_SUFFIX} cjpeg.cc ../cdjpeg.c ../rdbmp.c
  29   ../rdgif.c ../rdppm.c ../rdswitch.c ../rdtarga.c)
  30 set_property(TARGET cjpeg_fuzzer${FUZZER_SUFFIX} PROPERTY COMPILE_FLAGS
  31   ${COMPILE_FLAGS})
  32 target_link_libraries(cjpeg_fuzzer${FUZZER_SUFFIX} ${FUZZ_LIBRARY} jpeg-static)
  33 install(TARGETS cjpeg_fuzzer${FUZZER_SUFFIX} RUNTIME DESTINATION
  34   ${FUZZ_BINDIR})
  35
  36 macro(add_fuzz_target target source_file)
  37   add_executable(${target}_fuzzer${FUZZER_SUFFIX} ${source_file})
  38   target_link_libraries(${target}_fuzzer${FUZZER_SUFFIX} ${FUZZ_LIBRARY}
  39     turbojpeg-static)
  40   install(TARGETS ${target}_fuzzer${FUZZER_SUFFIX} RUNTIME DESTINATION
  41     ${FUZZ_BINDIR})
  42 endmacro()
  43
  44 add_fuzz_target(compress compress.cc)
  45
  46 add_fuzz_target(compress_yuv compress_yuv.cc)
  47
  48 # NOTE: This target is named libjpeg_turbo_fuzzer instead of decompress_fuzzer
  49 # in order to preserve the corpora from Google's OSS-Fuzz target for
  50 # libjpeg-turbo, which this target replaces.
  51 add_fuzz_target(libjpeg_turbo decompress.cc)
  52
  53 add_fuzz_target(decompress_yuv decompress_yuv.cc)
  54
  55 add_fuzz_target(transform transform.cc)