fo/block.xsl

   1 <?xml version='1.0'?>
   2 <xsl:stylesheet exclude-result-prefixes="d"
   3                 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   4                 xmlns:d="http://docbook.org/ns/docbook"
   5                 xmlns:fo="http://www.w3.org/1999/XSL/Format"
   6                 version='1.0'>
   7
   8 <!-- ********************************************************************
   9
  10      This file is part of the XSL DocBook Stylesheet distribution.
  11      See ../README or http://cdn.docbook.org/release/xsl/current/ for
  12      copyright and other information.
  13
  14      ******************************************************************** -->
  15
  16 <!-- ==================================================================== -->
  17
  18 <xsl:template match="d:blockinfo|d:info">
  19   <!-- suppress -->
  20 </xsl:template>
  21
  22 <!-- ==================================================================== -->
  23
  24 <xsl:template name="block.object">
  25   <xsl:variable name="keep.together">
  26     <xsl:call-template name="pi.dbfo_keep-together"/>
  27   </xsl:variable>
  28   <fo:block>
  29     <xsl:if test="$keep.together != ''">
  30       <xsl:attribute name="keep-together.within-column"><xsl:value-of
  31                       select="$keep.together"/></xsl:attribute>
  32     </xsl:if>
  33     <xsl:call-template name="anchor"/>
  34     <xsl:apply-templates/>
  35   </fo:block>
  36 </xsl:template>
  37
  38 <!-- ==================================================================== -->
  39
  40 <xsl:template match="d:para">
  41   <xsl:variable name="keep.together">
  42     <xsl:call-template name="pi.dbfo_keep-together"/>
  43   </xsl:variable>
  44   <fo:block xsl:use-attribute-sets="para.properties">
  45     <xsl:if test="$keep.together != ''">
  46       <xsl:attribute name="keep-together.within-column"><xsl:value-of
  47                       select="$keep.together"/></xsl:attribute>
  48     </xsl:if>
  49     <xsl:call-template name="anchor"/>
  50     <xsl:apply-templates/>
  51   </fo:block>
  52 </xsl:template>
  53
  54 <xsl:template match="d:simpara">
  55   <xsl:variable name="keep.together">
  56     <xsl:call-template name="pi.dbfo_keep-together"/>
  57   </xsl:variable>
  58   <fo:block xsl:use-attribute-sets="normal.para.spacing">
  59     <xsl:if test="$keep.together != ''">
  60       <xsl:attribute name="keep-together.within-column"><xsl:value-of
  61                       select="$keep.together"/></xsl:attribute>
  62     </xsl:if>
  63     <xsl:call-template name="anchor"/>
  64     <xsl:apply-templates/>
  65   </fo:block>
  66 </xsl:template>
  67
  68 <xsl:template match="d:formalpara">
  69   <xsl:variable name="keep.together">
  70     <xsl:call-template name="pi.dbfo_keep-together"/>
  71   </xsl:variable>
  72   <fo:block xsl:use-attribute-sets="normal.para.spacing">
  73     <xsl:if test="$keep.together != ''">
  74       <xsl:attribute name="keep-together.within-column"><xsl:value-of
  75                       select="$keep.together"/></xsl:attribute>
  76     </xsl:if>
  77     <xsl:call-template name="anchor"/>
  78     <xsl:apply-templates/>
  79   </fo:block>
  80 </xsl:template>
  81
  82 <!-- Only use title from info -->
  83 <xsl:template match="d:formalpara/d:info">
  84   <xsl:apply-templates select="d:title"/>
  85 </xsl:template>
  86
  87 <xsl:template match="d:formalpara/d:title|d:formalpara/d:info/d:title">
  88   <xsl:variable name="titleStr">
  89       <xsl:apply-templates/>
  90   </xsl:variable>
  91   <xsl:variable name="lastChar">
  92     <xsl:if test="$titleStr != ''">
  93       <xsl:value-of select="substring($titleStr,string-length($titleStr),1)"/>
  94     </xsl:if>
  95   </xsl:variable>
  96
  97   <fo:inline font-weight="bold"
  98              keep-with-next.within-line="always"
  99              padding-end="1em">
 100     <xsl:copy-of select="$titleStr"/>
 101     <xsl:if test="$lastChar != ''
 102                   and not(contains($runinhead.title.end.punct, $lastChar))">
 103       <xsl:value-of select="$runinhead.default.title.end.punct"/>
 104     </xsl:if>
 105     <xsl:text>&#160;</xsl:text>
 106   </fo:inline>
 107 </xsl:template>
 108
 109 <xsl:template match="d:formalpara/d:para">
 110   <xsl:apply-templates/>
 111 </xsl:template>
 112
 113 <!-- ==================================================================== -->
 114
 115 <xsl:template match="d:blockquote">
 116   <xsl:variable name="keep.together">
 117     <xsl:call-template name="pi.dbfo_keep-together"/>
 118   </xsl:variable>
 119   <fo:block xsl:use-attribute-sets="blockquote.properties">
 120     <xsl:if test="$keep.together != ''">
 121       <xsl:attribute name="keep-together.within-column"><xsl:value-of
 122                       select="$keep.together"/></xsl:attribute>
 123     </xsl:if>
 124     <xsl:call-template name="anchor"/>
 125     <fo:block>
 126       <xsl:if test="d:title|d:info/d:title">
 127         <fo:block xsl:use-attribute-sets="formal.title.properties">
 128           <xsl:apply-templates select="." mode="object.title.markup"/>
 129         </fo:block>
 130       </xsl:if>
 131       <xsl:apply-templates select="*[local-name(.) != 'title'
 132                                    and local-name(.) != 'attribution']"/>
 133     </fo:block>
 134     <xsl:if test="d:attribution">
 135       <fo:block text-align="right">
 136         <!-- mdash -->
 137         <xsl:text>&#x2014;</xsl:text>
 138         <xsl:apply-templates select="d:attribution"/>
 139       </fo:block>
 140     </xsl:if>
 141   </fo:block>
 142 </xsl:template>
 143
 144 <!-- Use an em dash per Chicago Manual of Style and https://sourceforge.net/tracker/index.php?func=detail&aid=2793878&group_id=21935&atid=373747 -->
 145 <xsl:template match="d:epigraph">
 146   <fo:block>
 147     <xsl:call-template name="anchor"/>
 148     <xsl:apply-templates select="child::*[local-name(.)!='attribution']"/>
 149     <xsl:if test="d:attribution">
 150       <fo:inline>
 151         <xsl:text>&#x2014;</xsl:text>
 152         <xsl:apply-templates select="d:attribution"/>
 153       </fo:inline>
 154     </xsl:if>
 155   </fo:block>
 156 </xsl:template>
 157
 158 <xsl:template match="d:attribution">
 159   <fo:inline><xsl:apply-templates/></fo:inline>
 160 </xsl:template>
 161
 162 <!-- ==================================================================== -->
 163
 164 <xsl:template name="floater">
 165   <xsl:param name="position" select="'none'"/>
 166   <xsl:param name="clear" select="'both'"/>
 167   <xsl:param name="width"/>
 168   <xsl:param name="content"/>
 169   <xsl:param name="start.indent">0pt</xsl:param>
 170   <xsl:param name="end.indent">0pt</xsl:param>
 171
 172   <xsl:choose>
 173     <xsl:when test="not($fop.extensions = 0)">
 174       <!-- fop 0.20.5 does not support floats -->
 175       <xsl:copy-of select="$content"/>
 176     </xsl:when>
 177     <xsl:when test="$position = 'none'">
 178       <xsl:copy-of select="$content"/>
 179     </xsl:when>
 180     <xsl:when test="$position = 'before'">
 181       <fo:float float="before">
 182         <xsl:copy-of select="$content"/>
 183       </fo:float>
 184     </xsl:when>
 185     <xsl:when test="$position = 'left' or
 186                     $position = 'start' or
 187                     $position = 'right' or
 188                     $position = 'end' or
 189                     $position = 'inside' or
 190                     $position = 'outside'">
 191       <xsl:variable name="float">
 192         <fo:float float="{$position}"
 193                   clear="{$clear}">
 194           <fo:block-container
 195                     start-indent="{$start.indent}"
 196                     end-indent="{$end.indent}">
 197             <xsl:if test="$width != ''">
 198               <xsl:attribute name="inline-progression-dimension">
 199                 <xsl:value-of select="$width"/>
 200               </xsl:attribute>
 201             </xsl:if>
 202             <fo:block>
 203               <xsl:copy-of select="$content"/>
 204             </fo:block>
 205           </fo:block-container>
 206         </fo:float>
 207       </xsl:variable>
 208       <xsl:choose>
 209         <xsl:when test="$axf.extensions != 0 and self::d:sidebar">
 210           <fo:block xsl:use-attribute-sets="normal.para.spacing"
 211                     space-after="0pt"
 212                     space-after.precedence="force"
 213                     start-indent="0pt" end-indent="0pt">
 214             <xsl:copy-of select="$float"/>
 215           </fo:block>
 216         </xsl:when>
 217         <xsl:when test="$axf.extensions != 0 and
 218                         ($position = 'left' or $position = 'start')">
 219           <fo:float float="{$position}"
 220                     clear="{$clear}">
 221             <fo:block-container
 222                       inline-progression-dimension=".001mm"
 223                       end-indent="{$start.indent} + {$width} + {$end.indent}">
 224               <xsl:attribute name="start-indent">
 225                 <xsl:choose>
 226                   <xsl:when test="ancestor::d:para">
 227                     <!-- Special case for handling inline floats
 228                          in Antenna House-->
 229                     <xsl:value-of select="concat('-', $body.start.indent)"/>
 230                   </xsl:when>
 231                   <xsl:otherwise>0pt</xsl:otherwise>
 232                 </xsl:choose>
 233               </xsl:attribute>
 234               <fo:block start-indent="{$start.indent}"
 235                         end-indent="-{$start.indent} - {$width}">
 236                 <xsl:copy-of select="$content"/>
 237               </fo:block>
 238             </fo:block-container>
 239           </fo:float>
 240
 241         </xsl:when>
 242         <xsl:when test="$axf.extensions != 0 and
 243                         ($position = 'right' or $position = 'end')">
 244           <!-- Special case for handling inline floats in Antenna House-->
 245           <fo:float float="{$position}"
 246                     clear="{$clear}">
 247             <fo:block-container
 248                       inline-progression-dimension=".001mm"
 249                       end-indent="-{$body.end.indent}"
 250                       start-indent="{$start.indent} + {$width} + {$end.indent}">
 251               <fo:block end-indent="{$end.indent}"
 252                         start-indent="-{$end.indent} - {$width}">
 253                 <xsl:copy-of select="$content"/>
 254               </fo:block>
 255             </fo:block-container>
 256           </fo:float>
 257
 258         </xsl:when>
 259         <xsl:when test="$xep.extensions != 0 and self::d:sidebar">
 260           <!-- float needs some space above  to line up with following para -->
 261           <fo:block xsl:use-attribute-sets="normal.para.spacing">
 262             <xsl:copy-of select="$float"/>
 263           </fo:block>
 264         </xsl:when>
 265         <xsl:when test="$xep.extensions != 0">
 266           <xsl:copy-of select="$float"/>
 267         </xsl:when>
 268         <xsl:otherwise>
 269           <xsl:copy-of select="$float"/>
 270         </xsl:otherwise>
 271       </xsl:choose>
 272     </xsl:when>
 273     <xsl:otherwise>
 274       <xsl:copy-of select="$content"/>
 275     </xsl:otherwise>
 276   </xsl:choose>
 277 </xsl:template>
 278
 279 <xsl:template match="d:sidebar" name="sidebar">
 280   <!-- Also does margin notes -->
 281   <xsl:variable name="pi-type">
 282     <xsl:call-template name="pi.dbfo_float-type"/>
 283   </xsl:variable>
 284
 285   <xsl:variable name="id">
 286     <xsl:call-template name="object.id"/>
 287   </xsl:variable>
 288
 289   <xsl:choose>
 290     <xsl:when test="$pi-type = 'margin.note'">
 291       <xsl:call-template name="margin.note"/>
 292     </xsl:when>
 293     <xsl:otherwise>
 294       <xsl:variable name="content">
 295         <fo:block xsl:use-attribute-sets="sidebar.properties"
 296                   id="{$id}">
 297           <xsl:call-template name="sidebar.titlepage"/>
 298           <xsl:apply-templates select="node()[not(self::d:title) and
 299                                          not(self::d:info) and
 300                                          not(self::d:sidebarinfo)]"/>
 301         </fo:block>
 302       </xsl:variable>
 303
 304       <xsl:variable name="pi-width">
 305         <xsl:call-template name="pi.dbfo_sidebar-width"/>
 306       </xsl:variable>
 307
 308       <xsl:variable name="position">
 309         <xsl:choose>
 310           <xsl:when test="$pi-type != ''">
 311             <xsl:value-of select="$pi-type"/>
 312           </xsl:when>
 313           <xsl:otherwise>
 314             <xsl:value-of select="$sidebar.float.type"/>
 315           </xsl:otherwise>
 316         </xsl:choose>
 317       </xsl:variable>
 318
 319       <xsl:call-template name="floater">
 320         <xsl:with-param name="content" select="$content"/>
 321         <xsl:with-param name="position" select="$position"/>
 322         <xsl:with-param name="width">
 323           <xsl:choose>
 324             <xsl:when test="$pi-width != ''">
 325               <xsl:value-of select="$pi-width"/>
 326             </xsl:when>
 327             <xsl:otherwise>
 328               <xsl:value-of select="$sidebar.float.width"/>
 329             </xsl:otherwise>
 330           </xsl:choose>
 331         </xsl:with-param>
 332         <xsl:with-param name="start.indent">
 333           <xsl:choose>
 334             <xsl:when test="$position = 'start' or
 335                             $position = 'left'">0pt</xsl:when>
 336             <xsl:when test="$position = 'end' or
 337                             $position = 'right'">0.5em</xsl:when>
 338             <xsl:otherwise>0pt</xsl:otherwise>
 339           </xsl:choose>
 340         </xsl:with-param>
 341         <xsl:with-param name="end.indent">
 342           <xsl:choose>
 343             <xsl:when test="$position = 'start' or
 344                             $position = 'left'">0.5em</xsl:when>
 345             <xsl:when test="$position = 'end' or
 346                             $position = 'right'">0pt</xsl:when>
 347             <xsl:otherwise>0pt</xsl:otherwise>
 348           </xsl:choose>
 349         </xsl:with-param>
 350       </xsl:call-template>
 351     </xsl:otherwise>
 352   </xsl:choose>
 353
 354 </xsl:template>
 355
 356 <xsl:template match="d:sidebar/d:title|d:sidebarinfo|d:sidebar/d:info"/>
 357
 358 <xsl:template match="d:sidebar/d:title|d:sidebarinfo/d:title|d:sidebar/d:info/d:title"
 359               mode="titlepage.mode" priority="1">
 360   <fo:block xsl:use-attribute-sets="sidebar.title.properties">
 361     <xsl:apply-templates/>
 362   </fo:block>
 363 </xsl:template>
 364
 365 <!-- Turn off para space-before if sidebar starts with a para, not title -->
 366 <xsl:template match="d:sidebar/*[1][self::d:para]">
 367   <xsl:variable name="keep.together">
 368     <xsl:call-template name="pi.dbfo_keep-together"/>
 369   </xsl:variable>
 370   <fo:block xsl:use-attribute-sets="para.properties">
 371     <xsl:attribute name="space-before.maximum">0pt</xsl:attribute>
 372     <xsl:attribute name="space-before.minimum">0pt</xsl:attribute>
 373     <xsl:attribute name="space-before.optimum">0pt</xsl:attribute>
 374     <xsl:if test="$keep.together != ''">
 375       <xsl:attribute name="keep-together.within-column"><xsl:value-of
 376                       select="$keep.together"/></xsl:attribute>
 377     </xsl:if>
 378     <xsl:call-template name="anchor"/>
 379     <xsl:apply-templates/>
 380   </fo:block>
 381
 382 </xsl:template>
 383
 384 <xsl:template name="margin.note">
 385   <xsl:param name="content">
 386     <fo:block xsl:use-attribute-sets="margin.note.properties">
 387       <xsl:if test="./d:title">
 388         <fo:block xsl:use-attribute-sets="margin.note.title.properties">
 389           <xsl:apply-templates select="./d:title" mode="margin.note.title.mode"/>
 390         </fo:block>
 391       </xsl:if>
 392       <xsl:apply-templates/>
 393     </fo:block>
 394   </xsl:param>
 395
 396   <xsl:variable name="pi-width">
 397     <xsl:call-template name="pi.dbfo_sidebar-width"/>
 398   </xsl:variable>
 399
 400   <xsl:variable name="position" select="$margin.note.float.type"/>
 401
 402   <xsl:call-template name="floater">
 403     <xsl:with-param name="content" select="$content"/>
 404     <xsl:with-param name="position" select="$position"/>
 405     <xsl:with-param name="width" >
 406       <xsl:choose>
 407         <xsl:when test="$pi-width != ''">
 408           <xsl:value-of select="$pi-width"/>
 409         </xsl:when>
 410         <xsl:otherwise>
 411           <xsl:value-of select="$margin.note.width"/>
 412         </xsl:otherwise>
 413       </xsl:choose>
 414     </xsl:with-param>
 415     <xsl:with-param name="start.indent">
 416       <xsl:choose>
 417         <xsl:when test="$position = 'start' or
 418                         $position = 'left'">0pt</xsl:when>
 419         <xsl:when test="$position = 'end' or
 420                         $position = 'right'">0.5em</xsl:when>
 421         <xsl:otherwise>0pt</xsl:otherwise>
 422       </xsl:choose>
 423     </xsl:with-param>
 424     <xsl:with-param name="end.indent">
 425       <xsl:choose>
 426         <xsl:when test="$position = 'start' or
 427                         $position = 'left'">0.5em</xsl:when>
 428         <xsl:when test="$position = 'end' or
 429                         $position = 'right'">0pt</xsl:when>
 430         <xsl:otherwise>0pt</xsl:otherwise>
 431       </xsl:choose>
 432     </xsl:with-param>
 433   </xsl:call-template>
 434 </xsl:template>
 435
 436 <xsl:template match="d:sidebar/d:title" mode="margin.note.title.mode">
 437   <xsl:apply-templates/>
 438 </xsl:template>
 439
 440 <!-- ==================================================================== -->
 441
 442 <xsl:template match="d:abstract">
 443   <xsl:variable name="keep.together">
 444     <xsl:call-template name="pi.dbfo_keep-together"/>
 445   </xsl:variable>
 446   <fo:block xsl:use-attribute-sets="abstract.properties">
 447     <xsl:if test="$keep.together != ''">
 448       <xsl:attribute name="keep-together.within-column"><xsl:value-of
 449                       select="$keep.together"/></xsl:attribute>
 450     </xsl:if>
 451     <xsl:call-template name="anchor"/>
 452     <xsl:apply-templates/>
 453   </fo:block>
 454 </xsl:template>
 455
 456 <xsl:template match="d:abstract/d:title|d:abstract/d:info/d:title">
 457   <fo:block xsl:use-attribute-sets="abstract.title.properties">
 458     <xsl:apply-templates/>
 459   </fo:block>
 460 </xsl:template>
 461
 462 <!-- ==================================================================== -->
 463
 464 <xsl:template match="d:msgset">
 465   <xsl:apply-templates/>
 466 </xsl:template>
 467
 468 <xsl:template match="d:msgentry">
 469   <xsl:call-template name="block.object"/>
 470 </xsl:template>
 471
 472 <xsl:template match="d:simplemsgentry">
 473   <xsl:call-template name="block.object"/>
 474 </xsl:template>
 475
 476 <xsl:template match="d:msg">
 477   <xsl:call-template name="block.object"/>
 478 </xsl:template>
 479
 480 <xsl:template match="d:msgmain">
 481   <xsl:apply-templates/>
 482 </xsl:template>
 483
 484 <xsl:template match="d:msgsub">
 485   <xsl:apply-templates/>
 486 </xsl:template>
 487
 488 <xsl:template match="d:msgrel">
 489   <xsl:apply-templates/>
 490 </xsl:template>
 491
 492 <xsl:template match="d:msgtext">
 493   <xsl:apply-templates/>
 494 </xsl:template>
 495
 496 <xsl:template match="d:msginfo">
 497   <xsl:call-template name="block.object"/>
 498 </xsl:template>
 499
 500 <xsl:template match="d:msglevel">
 501   <fo:block>
 502     <fo:inline font-weight="bold"
 503                keep-with-next.within-line="always">
 504       <xsl:call-template name="gentext.template">
 505         <xsl:with-param name="context" select="'msgset'"/>
 506         <xsl:with-param name="name" select="'MsgLevel'"/>
 507       </xsl:call-template>
 508     </fo:inline>
 509     <xsl:apply-templates/>
 510   </fo:block>
 511 </xsl:template>
 512
 513 <xsl:template match="d:msgorig">
 514   <fo:block>
 515     <fo:inline font-weight="bold"
 516                keep-with-next.within-line="always">
 517       <xsl:call-template name="gentext.template">
 518         <xsl:with-param name="context" select="'msgset'"/>
 519         <xsl:with-param name="name" select="'MsgOrig'"/>
 520       </xsl:call-template>
 521     </fo:inline>
 522     <xsl:apply-templates/>
 523   </fo:block>
 524 </xsl:template>
 525
 526 <xsl:template match="d:msgaud">
 527   <fo:block>
 528     <fo:inline font-weight="bold"
 529                keep-with-next.within-line="always">
 530       <xsl:call-template name="gentext.template">
 531         <xsl:with-param name="context" select="'msgset'"/>
 532         <xsl:with-param name="name" select="'MsgAud'"/>
 533       </xsl:call-template>
 534     </fo:inline>
 535     <xsl:apply-templates/>
 536   </fo:block>
 537 </xsl:template>
 538
 539 <xsl:template match="d:msgexplan">
 540   <xsl:call-template name="block.object"/>
 541 </xsl:template>
 542
 543 <xsl:template match="d:msgexplan/d:title">
 544   <fo:block font-weight="bold"
 545             keep-with-next.within-column="always"
 546             hyphenate="false">
 547     <xsl:apply-templates/>
 548   </fo:block>
 549 </xsl:template>
 550
 551 <!-- ==================================================================== -->
 552 <!-- For better or worse, revhistory is allowed in content... -->
 553
 554 <xsl:template match="d:revhistory">
 555   <fo:table table-layout="fixed" xsl:use-attribute-sets="revhistory.table.properties">
 556     <xsl:call-template name="anchor"/>
 557     <fo:table-column column-number="1" column-width="proportional-column-width(1)"/>
 558     <fo:table-column column-number="2" column-width="proportional-column-width(1)"/>
 559     <fo:table-column column-number="3" column-width="proportional-column-width(1)"/>
 560     <fo:table-body start-indent="0pt" end-indent="0pt">
 561       <fo:table-row>
 562         <fo:table-cell number-columns-spanned="3" xsl:use-attribute-sets="revhistory.table.cell.properties">
 563           <fo:block xsl:use-attribute-sets="revhistory.title.properties">
 564             <xsl:choose>
 565               <xsl:when test="d:title|d:info/d:title">
 566                 <xsl:apply-templates select="d:title|d:info/d:title" mode="titlepage.mode"/>
 567               </xsl:when>
 568               <xsl:otherwise>
 569                 <xsl:call-template name="gentext">
 570                   <xsl:with-param name="key" select="'RevHistory'"/>
 571                 </xsl:call-template>
 572               </xsl:otherwise>
 573             </xsl:choose>
 574           </fo:block>
 575         </fo:table-cell>
 576       </fo:table-row>
 577       <xsl:apply-templates/>
 578     </fo:table-body>
 579   </fo:table>
 580 </xsl:template>
 581
 582 <xsl:template match="d:revhistory/d:title">
 583   <!-- Handled in titlepage.mode -->
 584 </xsl:template>
 585
 586 <xsl:template match="d:revhistory/d:revision">
 587   <xsl:variable name="revnumber" select="d:revnumber"/>
 588   <xsl:variable name="revdate"   select="d:date"/>
 589   <xsl:variable name="revauthor" select="d:authorinitials|d:author"/>
 590   <xsl:variable name="revremark" select="d:revremark|d:revdescription"/>
 591   <fo:table-row>
 592     <fo:table-cell xsl:use-attribute-sets="revhistory.table.cell.properties">
 593       <fo:block>
 594         <xsl:call-template name="anchor"/>
 595         <xsl:if test="$revnumber">
 596           <xsl:call-template name="gentext">
 597             <xsl:with-param name="key" select="'Revision'"/>
 598           </xsl:call-template>
 599           <xsl:call-template name="gentext.space"/>
 600           <xsl:apply-templates select="$revnumber[1]"/>
 601         </xsl:if>
 602       </fo:block>
 603     </fo:table-cell>
 604     <fo:table-cell xsl:use-attribute-sets="revhistory.table.cell.properties">
 605       <fo:block>
 606         <xsl:apply-templates select="$revdate[1]"/>
 607       </fo:block>
 608     </fo:table-cell>
 609     <fo:table-cell xsl:use-attribute-sets="revhistory.table.cell.properties">
 610       <fo:block>
 611         <xsl:for-each select="$revauthor">
 612           <xsl:apply-templates select="."/>
 613           <xsl:if test="position() != last()">
 614             <xsl:text>, </xsl:text>
 615           </xsl:if>
 616         </xsl:for-each>
 617       </fo:block>
 618     </fo:table-cell>
 619   </fo:table-row>
 620   <xsl:if test="$revremark">
 621     <fo:table-row>
 622       <fo:table-cell number-columns-spanned="3" xsl:use-attribute-sets="revhistory.table.cell.properties">
 623         <fo:block>
 624           <xsl:apply-templates select="$revremark[1]"/>
 625         </fo:block>
 626       </fo:table-cell>
 627     </fo:table-row>
 628   </xsl:if>
 629 </xsl:template>
 630
 631 <xsl:template match="d:revision/d:revnumber">
 632   <xsl:apply-templates/>
 633 </xsl:template>
 634
 635 <xsl:template match="d:revision/d:date">
 636   <xsl:apply-templates/>
 637 </xsl:template>
 638
 639 <xsl:template match="d:revision/d:authorinitials">
 640   <xsl:apply-templates/>
 641 </xsl:template>
 642
 643 <xsl:template match="d:revision/d:author">
 644   <xsl:apply-templates/>
 645 </xsl:template>
 646
 647 <xsl:template match="d:revision/d:revremark">
 648   <xsl:apply-templates/>
 649 </xsl:template>
 650
 651 <xsl:template match="d:revision/d:revdescription">
 652   <xsl:apply-templates/>
 653 </xsl:template>
 654
 655 <!-- ==================================================================== -->
 656
 657 <xsl:template match="d:ackno|d:acknowledgements[parent::d:article]">
 658   <fo:block xsl:use-attribute-sets="normal.para.spacing">
 659     <xsl:call-template name="anchor"/>
 660     <xsl:apply-templates/>
 661   </fo:block>
 662 </xsl:template>
 663
 664 <!-- ==================================================================== -->
 665
 666 <xsl:template match="d:highlights">
 667   <xsl:call-template name="block.object"/>
 668 </xsl:template>
 669
 670 <!-- ==================================================================== -->
 671
 672 </xsl:stylesheet>