ext/gtk/meson.build

   1 gtk_sources = [
   2   'gstgtkbasesink.c',
   3   'gstgtksink.c',
   4   'gstgtkutils.c',
   5   'gstplugin.c',
   6   'gtkgstbasewidget.c',
   7   'gtkgstwidget.c',
   8 ]
   9
  10 gtk_defines = []
  11 optional_deps = []
  12
  13 gtk_dep = dependency('gtk+-3.0', required : false)
  14 if gtk_dep.found()
  15   if build_gstgl and gstgl_dep.found() and gtk_dep.version().version_compare('>=3.15.0')
  16     have_gtk3_gl_windowing = false
  17
  18     if gst_gl_have_window_x11 and gst_gl_have_platform_glx
  19       gtk_x11_dep = dependency('gtk+-x11-3.0', required : false)
  20       if gtk_x11_dep.found()
  21         optional_deps += gtk_x11_dep
  22         have_gtk3_gl_windowing = true
  23       endif
  24     endif
  25
  26     if gst_gl_have_window_wayland and gst_gl_have_platform_egl
  27       gtk_wayland_dep = dependency('gtk+-wayland-3.0', required : false)
  28       if gtk_wayland_dep.found()
  29         optional_deps += gtk_wayland_dep
  30         have_gtk3_gl_windowing = true
  31       endif
  32     endif
  33
  34     if have_gtk3_gl_windowing
  35       gtk_sources += [
  36         'gstgtkglsink.c',
  37         'gtkgstglwidget.c',
  38       ]
  39       optional_deps += gstgl_dep
  40       gtk_defines += ['-DGST_USE_UNSTABLE_API', '-DHAVE_GTK3_GL']
  41     endif
  42   endif
  43
  44   gstgtk = library('gstgtk',
  45     gtk_sources,
  46     c_args : gst_plugins_bad_args + gtk_defines,
  47     link_args : noseh_link_args,
  48     include_directories : [configinc],
  49     dependencies : [gtk_dep, gstvideo_dep, gstbase_dep, libm] + optional_deps,
  50     install : true,
  51     install_dir : plugins_install_dir,
  52   )
  53 endif
  54