examples/tutorials/gettingStartedQml/parts/part2/MenuBar.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the QtDeclarative module of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42
  43 Rectangle {
  44     id: menuBar
  45     width: 1000
  46     height:300
  47
  48     property color fileColor: "thistle"
  49     property color editColor: "powderblue"
  50
  51     //container for the header and the buttons
  52     Rectangle{
  53
  54         id: labelList
  55         height:parent.height/10
  56         width: parent.width
  57         color: "steelblue"
  58
  59         //default z is 0, items with higher z values are shown on top of items with lower z values
  60         z: 1
  61
  62         //row displays its children in a vertical row
  63         Row{
  64             anchors.centerIn: parent
  65             spacing:40
  66             Button{
  67                 height: 20
  68                 width: 50
  69                 label: "File"
  70                 id: fileButton
  71                 buttonColor : menuListView.currentIndex == 0? fileColor : Qt.darker(fileColor, 1.5)
  72                 scale: menuListView.currentIndex == 0? 1.25: 1
  73                 radius: 1
  74
  75                 //on a button click, change the list's currently selected item to FileMenu
  76                 onButtonClick: {
  77                     menuListView.currentIndex = 0
  78                 }
  79             }
  80             Button{
  81                 height: 20
  82                 width: 50
  83                 id: editButton
  84                 buttonColor : menuListView.currentIndex == 1?  editColor : Qt.darker(editColor, 1.5)
  85                 scale: menuListView.currentIndex == 1? 1.25: 1
  86                 label: "Edit"
  87                 radius: 1
  88
  89                 //on a button click, change the list's currently selected item to EditMenu
  90                 onButtonClick: {
  91                     menuListView.currentIndex = 1
  92                 }
  93
  94
  95             }
  96
  97
  98         }
  99     }
 100
 101     //a list of visual items already have delegates handling their display
 102     VisualItemModel{
 103         id: menuListModel
 104
 105         FileMenu{
 106             width: menuListView.width
 107             height: menuBar.height
 108             color: fileColor
 109         }
 110         EditMenu{
 111             color: editColor
 112             width:  menuListView.width
 113             height: menuBar.height
 114
 115         }
 116     }
 117
 118     //list view will display a model according to a delegate
 119     ListView{
 120         id: menuListView
 121         anchors.fill:parent
 122         anchors.bottom: parent.bottom
 123         width:parent.width
 124         height: parent.height
 125
 126         //the model contains the data
 127         model: menuListModel
 128
 129         //control the movement of the menu switching
 130         snapMode: ListView.SnapOneItem
 131         orientation: ListView.Horizontal
 132         boundsBehavior: Flickable.StopAtBounds
 133         flickDeceleration: 5000
 134         highlightFollowsCurrentItem: true
 135         highlightMoveDuration:240
 136         highlightRangeMode: ListView.StrictlyEnforceRange
 137     }
 138
 139
 140 }