examples/tutorials/gettingStarted/gsQml/parts/part5/TextEditor.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the QtDeclarative module of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 1.0
  42 import "core"
  43
  44 Rectangle {
  45     id: screen
  46     width: 1000; height: 1000
  47     property int partition: height/3
  48     state: "DRAWER_CLOSED"
  49
  50     //Item 1: MenuBar on the top portion of the screen
  51     MenuBar{
  52         id:menuBar
  53         height: screen.partition; width: screen.width
  54         z:1
  55     }
  56     //Item 2: The editable text area
  57     TextArea{
  58         id:textArea
  59         y:drawer.height
  60         color: "#3F3F3F"
  61         fontColor: "#DCDCCC"
  62          height: partition*2; width:parent.width
  63     }
  64     //Item 3: The drawer handle
  65     Rectangle{
  66         id:drawer
  67         height:15; width: parent.width
  68         border.color : "#6A6D6A"
  69         border.width: 1
  70         z:1
  71         gradient: Gradient {
  72                 GradientStop { position: 0.0; color: "#8C8F8C" }
  73                 GradientStop { position: 0.17; color: "#6A6D6A" }
  74                 GradientStop { position: 0.77; color: "#3F3F3F" }
  75                 GradientStop { position: 1.0; color: "#6A6D6A" }
  76             }
  77         Image{
  78             id: arrowIcon
  79             source: "images/arrow.png"
  80             anchors.horizontalCenter: parent.horizontalCenter
  81
  82             Behavior{NumberAnimation{property: "rotation";easing.type: Easing.OutExpo }}
  83         }
  84
  85         MouseArea{
  86             id: drawerMouseArea
  87             anchors.fill:parent
  88             hoverEnabled: true
  89             onEntered: parent.border.color = Qt.lighter("#6A6D6A")
  90             onExited:  parent.border.color = "#6A6D6A"
  91             onClicked:{
  92                 if (screen.state == "DRAWER_CLOSED"){
  93                     screen.state = "DRAWER_OPEN"
  94                 }
  95                 else if (screen.state == "DRAWER_OPEN"){
  96                     screen.state = "DRAWER_CLOSED"
  97                 }
  98             }
  99         }
 100     }
 101
 102     states:[
 103         State{
 104             name: "DRAWER_OPEN"
 105             PropertyChanges { target: menuBar; y: 0}
 106             PropertyChanges { target: textArea; y: partition + drawer.height}
 107             PropertyChanges { target: drawer; y: partition}
 108             PropertyChanges { target: arrowIcon; rotation: 180}
 109         },
 110         State{
 111             name: "DRAWER_CLOSED"
 112             PropertyChanges { target: menuBar; y:-height; }
 113             PropertyChanges { target: textArea; y: drawer.height; height: screen.height - drawer.height}
 114             PropertyChanges { target: drawer; y: 0}
 115             PropertyChanges { target: arrowIcon; rotation: 0}
 116         }
 117     ]
 118
 119     transitions: [
 120         Transition{
 121             to: "*"
 122             NumberAnimation { target: textArea; properties: "y, height"; duration: 100; easing.type:Easing.OutExpo }
 123             NumberAnimation { target: menuBar; properties: "y"; duration: 100;easing.type: Easing.OutExpo }
 124             NumberAnimation { target: drawer; properties: "y"; duration: 100;easing.type: Easing.OutExpo }
 125         }
 126     ]
 127 }