examples/standalone/ppc_setjmp.S

   1 /* SPDX-License-Identifier: LGPL-2.1+ */
   2 /* setjmp for PowerPC.
   3    Copyright (C) 1995, 1996, 1997, 1999, 2000 Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5  */
   6
   7 #include <ppc_asm.tmpl>
   8
   9 # define JB_GPR1   0  /* Also known as the stack pointer */
  10 # define JB_GPR2   1
  11 # define JB_LR     2  /* The address we will return to */
  12 # define JB_GPRS   3  /* GPRs 14 through 31 are saved, 18 in total */
  13 # define JB_CR     21 /* Condition code registers. */
  14 # define JB_FPRS   22 /* FPRs 14 through 31 are saved, 18*2 words total */
  15 # define JB_SIZE   (58*4)
  16
  17 #define FP(x...) x
  18
  19 .globl      setctxsp;
  20 setctxsp:
  21         mr  r1, r3
  22         blr
  23
  24 .globl      ppc_setjmp;
  25 ppc_setjmp:
  26         stw  r1,(JB_GPR1*4)(3)
  27         mflr r0
  28         stw  r2,(JB_GPR2*4)(3)
  29         stw  r14,((JB_GPRS+0)*4)(3)
  30 FP(     stfd 14,((JB_FPRS+0*2)*4)(3))
  31         stw  r0,(JB_LR*4)(3)
  32         stw  r15,((JB_GPRS+1)*4)(3)
  33 FP(     stfd 15,((JB_FPRS+1*2)*4)(3))
  34         mfcr r0
  35         stw  r16,((JB_GPRS+2)*4)(3)
  36 FP(     stfd 16,((JB_FPRS+2*2)*4)(3))
  37         stw  r0,(JB_CR*4)(3)
  38         stw  r17,((JB_GPRS+3)*4)(3)
  39 FP(     stfd 17,((JB_FPRS+3*2)*4)(3))
  40         stw  r18,((JB_GPRS+4)*4)(3)
  41 FP(     stfd 18,((JB_FPRS+4*2)*4)(3))
  42         stw  r19,((JB_GPRS+5)*4)(3)
  43 FP(     stfd 19,((JB_FPRS+5*2)*4)(3))
  44         stw  r20,((JB_GPRS+6)*4)(3)
  45 FP(     stfd 20,((JB_FPRS+6*2)*4)(3))
  46         stw  r21,((JB_GPRS+7)*4)(3)
  47 FP(     stfd 21,((JB_FPRS+7*2)*4)(3))
  48         stw  r22,((JB_GPRS+8)*4)(3)
  49 FP(     stfd 22,((JB_FPRS+8*2)*4)(3))
  50         stw  r23,((JB_GPRS+9)*4)(3)
  51 FP(     stfd 23,((JB_FPRS+9*2)*4)(3))
  52         stw  r24,((JB_GPRS+10)*4)(3)
  53 FP(     stfd 24,((JB_FPRS+10*2)*4)(3))
  54         stw  r25,((JB_GPRS+11)*4)(3)
  55 FP(     stfd 25,((JB_FPRS+11*2)*4)(3))
  56         stw  r26,((JB_GPRS+12)*4)(3)
  57 FP(     stfd 26,((JB_FPRS+12*2)*4)(3))
  58         stw  r27,((JB_GPRS+13)*4)(3)
  59 FP(     stfd 27,((JB_FPRS+13*2)*4)(3))
  60         stw  r28,((JB_GPRS+14)*4)(3)
  61 FP(     stfd 28,((JB_FPRS+14*2)*4)(3))
  62         stw  r29,((JB_GPRS+15)*4)(3)
  63 FP(     stfd 29,((JB_FPRS+15*2)*4)(3))
  64         stw  r30,((JB_GPRS+16)*4)(3)
  65 FP(     stfd 30,((JB_FPRS+16*2)*4)(3))
  66         stw  r31,((JB_GPRS+17)*4)(3)
  67 FP(     stfd 31,((JB_FPRS+17*2)*4)(3))
  68
  69         li 3, 0
  70         blr