examples/quick/modelviews/listview/highlight.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 // This example shows how to create your own highlight delegate for a ListView
  42 // that uses a SpringAnimation to provide custom movement when the
  43 // highlight bar is moved between items.
  44
  45 import QtQuick 2.0
  46 import "content"
  47
  48 Rectangle {
  49     width: 200; height: 300
  50
  51     // Define a delegate component.  A component will be
  52     // instantiated for each visible item in the list.
  53     Component {
  54         id: petDelegate
  55         Item {
  56             id: wrapper
  57             width: 200; height: 55
  58             Column {
  59                 SmallText { text: 'Name: ' + name }
  60                 SmallText { text: 'Type: ' + type }
  61                 SmallText { text: 'Age: ' + age }
  62             }
  63             // indent the item if it is the current item
  64             states: State {
  65                 name: "Current"
  66                 when: wrapper.ListView.isCurrentItem
  67                 PropertyChanges { target: wrapper; x: 20 }
  68             }
  69             transitions: Transition {
  70                 NumberAnimation { properties: "x"; duration: 200 }
  71             }
  72             MouseArea {
  73                 anchors.fill: parent
  74                 onClicked: wrapper.ListView.view.currentIndex = index
  75             }
  76         }
  77     }
  78
  79 //! [0]
  80     // Define a highlight with customized movement between items.
  81     Component {
  82         id: highlightBar
  83         Rectangle {
  84             width: 200; height: 50
  85             color: "#FFFF88"
  86             y: listView.currentItem.y;
  87             Behavior on y { SpringAnimation { spring: 2; damping: 0.1 } }
  88         }
  89     }
  90
  91     ListView {
  92         id: listView
  93         width: 200; height: parent.height
  94
  95         model: PetsModel {}
  96         delegate: petDelegate
  97         focus: true
  98
  99         // Set the highlight delegate. Note we must also set highlightFollowsCurrentItem
 100         // to false so the highlight delegate can control how the highlight is moved.
 101         highlight: highlightBar
 102         highlightFollowsCurrentItem: false
 103     }
 104 //! [0]
 105 }