examples/quick/draganddrop/views/gridview.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42
  43 GridView {
  44     id: root
  45     width: 320; height: 480
  46     cellWidth: 80; cellHeight: 80
  47
  48     displaced: Transition {
  49         NumberAnimation { properties: "x,y"; easing.type: Easing.OutQuad }
  50     }
  51
  52 //! [0]
  53     model: VisualDataModel {
  54 //! [0]
  55         id: visualModel
  56         model: ListModel {
  57             id: colorModel
  58             ListElement { color: "blue" }
  59             ListElement { color: "green" }
  60             ListElement { color: "red" }
  61             ListElement { color: "yellow" }
  62             ListElement { color: "orange" }
  63             ListElement { color: "purple" }
  64             ListElement { color: "cyan" }
  65             ListElement { color: "magenta" }
  66             ListElement { color: "chartreuse" }
  67             ListElement { color: "aquamarine" }
  68             ListElement { color: "indigo" }
  69             ListElement { color: "black" }
  70             ListElement { color: "lightsteelblue" }
  71             ListElement { color: "violet" }
  72             ListElement { color: "grey" }
  73             ListElement { color: "springgreen" }
  74             ListElement { color: "salmon" }
  75             ListElement { color: "blanchedalmond" }
  76             ListElement { color: "forestgreen" }
  77             ListElement { color: "pink" }
  78             ListElement { color: "navy" }
  79             ListElement { color: "goldenrod" }
  80             ListElement { color: "crimson" }
  81             ListElement { color: "teal" }
  82         }
  83 //! [1]
  84         delegate: MouseArea {
  85             id: delegateRoot
  86
  87             property int visualIndex: VisualDataModel.itemsIndex
  88
  89             width: 80; height: 80
  90             drag.target: icon
  91
  92             Rectangle {
  93                 id: icon
  94                 width: 72; height: 72
  95                 anchors {
  96                     horizontalCenter: parent.horizontalCenter;
  97                     verticalCenter: parent.verticalCenter
  98                 }
  99                 color: model.color
 100                 radius: 3
 101
 102                 Drag.active: delegateRoot.drag.active
 103                 Drag.source: delegateRoot
 104                 Drag.hotSpot.x: 36
 105                 Drag.hotSpot.y: 36
 106
 107                 states: [
 108                     State {
 109                         when: icon.Drag.active
 110                         ParentChange {
 111                             target: icon
 112                             parent: root
 113                         }
 114
 115                         AnchorChanges {
 116                             target: icon;
 117                             anchors.horizontalCenter: undefined;
 118                             anchors.verticalCenter: undefined
 119                         }
 120                     }
 121                 ]
 122             }
 123
 124             DropArea {
 125                 anchors { fill: parent; margins: 15 }
 126
 127                 onEntered: visualModel.items.move(drag.source.visualIndex, delegateRoot.visualIndex)
 128             }
 129         }
 130 //! [1]
 131     }
 132 }