examples/qml-compositor/main.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Digia Plc and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/legal
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Digia Plc and its Subsidiary(-ies) nor the names
  21 **     of its contributors may be used to endorse or promote products derived
  22 **     from this software without specific prior written permission.
  23 **
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42 import "compositor.js" as CompositorLogic
  43
  44 Item {
  45     id: root
  46
  47     property variant selectedWindow: null
  48     property bool hasFullscreenWindow: typeof compositor != "undefined" && compositor.fullscreenSurface !== null
  49
  50     onHasFullscreenWindowChanged: console.log("has fullscreen window: " + hasFullscreenWindow);
  51
  52     Image {
  53         id: background
  54         Behavior on opacity {
  55             NumberAnimation { easing.type: Easing.InCubic; duration: 400; }
  56         }
  57         anchors.fill: parent
  58         fillMode: Image.Tile
  59         source: "background.jpg"
  60         smooth: true
  61     }
  62
  63     MouseArea {
  64         anchors.fill: parent
  65         onClicked: {
  66             root.selectedWindow = null
  67             root.focus = true
  68         }
  69     }
  70
  71     MouseArea {
  72         anchors.right: parent.right
  73         anchors.bottom: parent.bottom
  74         width: 2
  75         height: 2
  76         hoverEnabled: true
  77         onEntered: {
  78             root.selectedWindow = null
  79             root.focus = true
  80         }
  81         z: 10
  82     }
  83
  84     function windowAdded(window) {
  85         var windowContainerComponent = Qt.createComponent("WindowContainer.qml");
  86         var windowContainer = windowContainerComponent.createObject(root);
  87
  88         window.parent = windowContainer;
  89
  90         windowContainer.targetWidth = window.width;
  91         windowContainer.targetHeight = window.height;
  92         windowContainer.child = window;
  93
  94         var windowChromeComponent = Qt.createComponent("WindowChrome.qml");
  95         var windowChrome = windowChromeComponent.createObject(window);
  96
  97         CompositorLogic.addWindow(windowContainer);
  98
  99         windowContainer.opacity = 1
 100         windowContainer.animationsEnabled = true;
 101         windowContainer.chrome = windowChrome;
 102     }
 103
 104     function windowResized(window) {
 105         var windowContainer = window.parent;
 106         windowContainer.width = window.width;
 107         windowContainer.height = window.height;
 108
 109         CompositorLogic.relayout();
 110     }
 111
 112     function windowDestroyed(window) {
 113         var windowContainer = window.parent;
 114         if (windowContainer.runDestroyAnimation)
 115             windowContainer.runDestroyAnimation();
 116     }
 117
 118     function removeWindow(window) {
 119         var windowContainer = window.parent;
 120         CompositorLogic.removeWindow(windowContainer);
 121         windowContainer.chrome.destroy();
 122         windowContainer.destroy();
 123         compositor.destroyWindow(window);
 124     }
 125
 126     onHeightChanged: CompositorLogic.relayout();
 127     onWidthChanged: CompositorLogic.relayout();
 128 }