examples/qml/samegame/content/BoomBlock.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the QtQml module of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:LGPL$
   9 ** GNU Lesser General Public License Usage
  10 ** This file may be used under the terms of the GNU Lesser General Public
  11 ** License version 2.1 as published by the Free Software Foundation and
  12 ** appearing in the file LICENSE.LGPL included in the packaging of this
  13 ** file. Please review the following information to ensure the GNU Lesser
  14 ** General Public License version 2.1 requirements will be met:
  15 ** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  16 **
  17 ** In addition, as a special exception, Nokia gives you certain additional
  18 ** rights. These rights are described in the Nokia Qt LGPL Exception
  19 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  20 **
  21 ** GNU General Public License Usage
  22 ** Alternatively, this file may be used under the terms of the GNU General
  23 ** Public License version 3.0 as published by the Free Software Foundation
  24 ** and appearing in the file LICENSE.GPL included in the packaging of this
  25 ** file. Please review the following information to ensure the GNU General
  26 ** Public License version 3.0 requirements will be met:
  27 ** http://www.gnu.org/copyleft/gpl.html.
  28 **
  29 ** Other Usage
  30 ** Alternatively, this file may be used in accordance with the terms and
  31 ** conditions contained in a signed written agreement between you and Nokia.
  32 **
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41
  42 import QtQuick 2.0
  43 import QtQuick.Particles 2.0
  44
  45 Item {
  46     id: block
  47     property bool dying: false
  48     property bool spawned: false
  49     property int type: 0
  50     property ParticleSystem particleSystem
  51
  52     Behavior on x {
  53         enabled: spawned;
  54         SpringAnimation{ spring: 2; damping: 0.2 }
  55     }
  56     Behavior on y {
  57         SpringAnimation{ spring: 2; damping: 0.2 }
  58     }
  59
  60     Image {
  61         id: img
  62         source: {
  63             if(type == 0){
  64                 "pics/redStone.png";
  65             } else if(type == 1) {
  66                 "pics/blueStone.png";
  67             } else {
  68                 "pics/greenStone.png";
  69             }
  70         }
  71         opacity: 0
  72         Behavior on opacity { NumberAnimation { duration: 200 } }
  73         anchors.fill: parent
  74     }
  75     Emitter {
  76         id: particles
  77         system: particleSystem
  78         group: {
  79             if(type == 0){
  80                 "red";
  81             } else if (type == 1) {
  82                 "blue";
  83             } else {
  84                 "green";
  85             }
  86         }
  87         anchors.fill: parent
  88
  89         speed: TargetDirection{targetX: block.width/2; targetY: block.height/2; magnitude: -60; magnitudeVariation: 60}
  90         shape: EllipseShape{fill:true}
  91         enabled: false;
  92         lifeSpan: 700; lifeSpanVariation: 100
  93         emitRate: 1000
  94         maximumEmitted: 100 //only fires 0.1s bursts (still 2x old number)
  95         size: 28
  96         endSize: 14
  97     }
  98
  99     states: [
 100         State {
 101             name: "AliveState"; when: spawned == true && dying == false
 102             PropertyChanges { target: img; opacity: 1 }
 103         },
 104
 105         State {
 106             name: "DeathState"; when: dying == true
 107             StateChangeScript { script: {particleSystem.paused = false; particles.pulse(100);} }
 108             PropertyChanges { target: img; opacity: 0 }
 109             StateChangeScript { script: block.destroy(1000); }
 110         }
 111     ]
 112 }