examples/qml/animation/pathinterpolator/pathinterpolator.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42
  43 Rectangle {
  44     id: window
  45     width: 400
  46     height: 400
  47
  48     Canvas {
  49         id: canvas
  50         anchors.fill: parent
  51         smooth: true
  52
  53         onPaint: {
  54             context.clearRect(0, 0, width, height)
  55             context.strokeStyle = "black"
  56             context.path = motionPath.path
  57             context.stroke()
  58         }
  59     }
  60
  61     PathInterpolator {
  62         id: motionPath
  63
  64         path: Path {
  65             startX: 50; startY: 50
  66
  67             PathCubic {
  68                 x: window.width - 50
  69                 y: window.height - 50
  70
  71                 control1X: x; control1Y: 50
  72                 control2X: 50; control2Y: y
  73             }
  74
  75             onChanged: canvas.requestPaint()
  76         }
  77
  78         NumberAnimation on progress {
  79             id: progressAnim
  80             running: false
  81             from: 0; to: 1
  82             duration: 2000
  83             easing.type: Easing.InQuad
  84         }
  85     }
  86
  87     Rectangle {
  88         id: box
  89
  90         width: 50; height: 50
  91         border.width: 1
  92         smooth: true
  93
  94         //bind our attributes to follow the path as progress changes
  95         x: motionPath.x
  96         y: motionPath.y
  97         rotation: motionPath.angle
  98         transform: Translate { x: -box.width/2; y: -box.height/2 }
  99
 100         Text {
 101             anchors.centerIn: parent
 102             text: "Box"
 103         }
 104     }
 105
 106     MouseArea {
 107         anchors.fill: parent
 108         onClicked: progressAnim.restart()
 109     }
 110
 111     Text {
 112         text: "Click anywhere to animate along the path"
 113         anchors.horizontalCenter: parent.horizontalCenter
 114     }
 115 }