examples/particles/system/content/timedgroupchanges.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Digia Plc and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/legal
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Digia Plc and its Subsidiary(-ies) nor the names
  21 **     of its contributors may be used to endorse or promote products derived
  22 **     from this software without specific prior written permission.
  23 **
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42 import QtQuick.Particles 2.0
  43
  44 Rectangle {
  45     width: 360
  46     height: 600
  47     color: "black"
  48     ParticleSystem {
  49         anchors.fill: parent
  50         id: syssy
  51         //! [0]
  52         ParticleGroup {
  53             name: "fire"
  54             duration: 2000
  55             durationVariation: 2000
  56             to: {"splode":1}
  57         }
  58         //! [0]
  59         //! [1]
  60         ParticleGroup {
  61             name: "splode"
  62             duration: 400
  63             to: {"dead":1}
  64             TrailEmitter {
  65                 group: "works"
  66                 emitRatePerParticle: 100
  67                 lifeSpan: 1000
  68                 maximumEmitted: 1200
  69                 size: 8
  70                 velocity: AngleDirection {angle: 270; angleVariation: 45; magnitude: 20; magnitudeVariation: 20;}
  71                 acceleration: PointDirection {y:100; yVariation: 20}
  72             }
  73         }
  74         //! [1]
  75         //! [2]
  76         ParticleGroup {
  77             name: "dead"
  78             duration: 1000
  79             Affector {
  80                 once: true
  81                 onAffected: worksEmitter.burst(400,x,y)
  82             }
  83         }
  84         //! [2]
  85
  86         Timer {
  87             interval: 6000
  88             running: true
  89             triggeredOnStart: true
  90             repeat: true
  91             onTriggered:startingEmitter.pulse(100);
  92         }
  93         Emitter {
  94             id: startingEmitter
  95             group: "fire"
  96             width: parent.width
  97             y: parent.height
  98             enabled: false
  99             emitRate: 80
 100             lifeSpan: 6000
 101             velocity: PointDirection {y:-100;}
 102             size: 32
 103         }
 104
 105         Emitter {
 106             id: worksEmitter
 107             group: "works"
 108             enabled: false
 109             emitRate: 100
 110             lifeSpan: 1600
 111             maximumEmitted: 6400
 112             size: 8
 113             velocity: CumulativeDirection {
 114                 PointDirection {y:-100}
 115                 AngleDirection {angleVariation: 360; magnitudeVariation: 80;}
 116             }
 117             acceleration: PointDirection {y:100; yVariation: 20}
 118         }
 119
 120         ImageParticle {
 121             groups: ["works", "fire", "splode"]
 122             source: "../../images/particle.png"
 123             entryEffect: ImageParticle.Scale
 124         }
 125     }
 126 }
 127