examples/particles/system/content/dynamiccomparison.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42 import QtQuick.Particles 2.0
  43
  44 Rectangle {
  45     id: root
  46     color: "black"
  47     width: 640
  48     height: 480
  49     ParticleSystem {
  50         id: sys
  51     }
  52
  53     ImageParticle {
  54         system: sys
  55         source: "../../images/particle.png"
  56         color: "white"
  57         colorVariation: 1.0
  58         alpha: 0.1
  59         entryEffect: ImageParticle.None
  60     }
  61
  62     Emitter {
  63         id: emitter
  64         system: sys
  65         width: parent.width/2
  66         velocity: PointDirection {y: 72; yVariation: 24}
  67         lifeSpan: 10000
  68         emitRate: 1000
  69         enabled: false
  70         size: 32
  71     }
  72
  73     //! [fake]
  74     Item {
  75         id: fakeEmitter
  76         function burst(number) {
  77             while (number > 0) {
  78                 var item = fakeParticle.createObject(root);
  79                 item.lifeSpan = Math.random() * 5000 + 5000;
  80                 item.x = Math.random() * (root.width/2) + (root.width/2);
  81                 item.y = 0;
  82                 number--;
  83             }
  84         }
  85
  86         Component {
  87             id: fakeParticle
  88             Image {
  89                 id: container
  90                 property int lifeSpan: 10000
  91                 width: 32
  92                 height: 32
  93                 source: "../../images/particle.png"
  94                 y: 0
  95                 PropertyAnimation on y {from: -16; to: root.height-16; duration: container.lifeSpan; running: true}
  96                 SequentialAnimation on opacity {
  97                     running: true
  98                     NumberAnimation { from:0; to: 1; duration: 500}
  99                     PauseAnimation { duration: container.lifeSpan - 1000}
 100                     NumberAnimation { from:1; to: 0; duration: 500}
 101                     ScriptAction { script: container.destroy(); }
 102                 }
 103             }
 104         }
 105     }
 106     //! [fake]
 107
 108     //Hooked to a timer, but click for extra bursts that really stress performance
 109     Timer {
 110         interval: 10000
 111         triggeredOnStart: true
 112         repeat: true
 113         running: true
 114         onTriggered: {
 115             emitter.burst(1000);
 116             fakeEmitter.burst(1000);
 117         }
 118     }
 119     Text {
 120         anchors.left: parent.left
 121         anchors.bottom: parent.bottom
 122         text: "1000 particles"
 123         color: "white"
 124         MouseArea {
 125             anchors.fill: parent
 126             onClicked: emitter.burst(1000);
 127         }
 128     }
 129     Text {
 130         anchors.right: parent.right
 131         anchors.bottom: parent.bottom
 132         text: "1000 items"
 133         color: "white"
 134         MouseArea {
 135             anchors.fill: parent
 136             onClicked: fakeEmitter.burst(1000);
 137         }
 138     }
 139 }