examples/particles/imageparticle/content/sharing.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 // This example shows how to create your own highlight delegate for a ListView
  42 // that uses a SpringAnimation to provide custom movement when the
  43 // highlight bar is moved between items.
  44
  45 import QtQuick 2.0
  46 import QtQuick.Particles 2.0
  47
  48 Rectangle {
  49     property real delegateHeight: 65
  50     width: 200; height: 300
  51     gradient: Gradient {
  52         GradientStop { position: 0.0; color: "#EEEEFF" }
  53         GradientStop { position: 1.0; color: "lightblue" }
  54     }
  55
  56     // Define a delegate component.  A component will be
  57     // instantiated for each visible item in the list.
  58     Component {
  59         id: petDelegate
  60         Item {
  61             id: wrapper
  62             width: 200; height: delegateHeight
  63             z: 10
  64             Column {
  65                 Text {color: "white"; text: name; font.pixelSize: 18 }
  66                 Text {color: "white"; text: 'Type: ' + type; font.pixelSize: 14 }
  67                 Text {color: "white"; text: 'Age: ' + age; font.pixelSize: 14 }
  68             }
  69             // indent the item if it is the current item
  70             states: State {
  71                 name: "Current"
  72                 when: wrapper.ListView.isCurrentItem
  73                 PropertyChanges { target: wrapper; x: 20 }
  74             }
  75             transitions: Transition {
  76                 NumberAnimation { properties: "x"; duration: 200 }
  77             }
  78         }
  79     }
  80
  81     // Define a highlight with customized movement between items.
  82     Component {
  83         id: highlightBar
  84         Rectangle {
  85             z: 0
  86             width: 200; height: delegateHeight
  87             gradient: Gradient {
  88                 GradientStop { position: 0.0; color: "#99FF99" }
  89                 GradientStop { position: 1.0; color: "#88FF88" }
  90             }
  91             y: listView.currentItem.y;
  92             Behavior on y { SpringAnimation { spring: 2; damping: 0.2 } }
  93             //! [1]
  94             ImageParticle {
  95                 anchors.fill: parent
  96                 system: particles
  97                 source: "../../images/flower.png"
  98                 color: "red"
  99                 clip: true
 100                 alpha: 1.0
 101             }
 102             //! [1]
 103         }
 104     }
 105
 106     ListView {
 107         id: listView
 108         width: 200; height: parent.height
 109
 110         model: petsModel
 111         delegate: petDelegate
 112         focus: true
 113
 114         // Set the highlight delegate. Note we must also set highlightFollowsCurrentItem
 115         // to false so the highlight delegate can control how the highlight is moved.
 116         highlight: highlightBar
 117         highlightFollowsCurrentItem: false
 118
 119         ParticleSystem { id: particles }
 120         Emitter {
 121             system: particles
 122             anchors.fill: parent
 123             emitRate: 1
 124             lifeSpan: 10000
 125             size: 24
 126             sizeVariation: 8
 127             velocity: AngleDirection { angleVariation: 360; magnitude: 3 }
 128             maximumEmitted: 10
 129             startTime: 5000
 130         }
 131
 132         //! [0]
 133         ImageParticle {
 134             anchors.fill: parent
 135             system: particles
 136             source: "../../images/flower.png"
 137             alpha: 0.1
 138             color: "white"
 139             rotationVariation: 180
 140             z: -1
 141         }
 142         //! [0]
 143     }
 144
 145     ListModel {
 146         id: petsModel
 147         ListElement {
 148             name: "Polly"
 149             type: "Parrot"
 150             age: 12
 151             size: "Small"
 152         }
 153         ListElement {
 154             name: "Penny"
 155             type: "Turtle"
 156             age: 4
 157             size: "Small"
 158         }
 159         ListElement {
 160             name: "Warren"
 161             type: "Rabbit"
 162             age: 2
 163             size: "Small"
 164         }
 165         ListElement {
 166             name: "Spot"
 167             type: "Dog"
 168             age: 9
 169             size: "Medium"
 170         }
 171         ListElement {
 172             name: "Schrödinger"
 173             type: "Cat"
 174             age: 2
 175             size: "Medium"
 176         }
 177         ListElement {
 178             name: "Joey"
 179             type: "Kangaroo"
 180             age: 1
 181             size: "Medium"
 182         }
 183         ListElement {
 184             name: "Kimba"
 185             type: "Bunny"
 186             age: 65
 187             size: "Large"
 188         }
 189         ListElement {
 190             name: "Rover"
 191             type: "Dog"
 192             age: 5
 193             size: "Large"
 194         }
 195         ListElement {
 196             name: "Tiny"
 197             type: "Elephant"
 198             age: 15
 199             size: "Large"
 200         }
 201     }
 202
 203 }