examples/particles/affectors/content/customaffector.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42 import QtQuick.Particles 2.0
  43
  44 Item {
  45     width: 360
  46     height: 600
  47
  48     Image {
  49         source: "../../images/backgroundLeaves.jpg"
  50         anchors.fill: parent
  51     }
  52     ParticleSystem {
  53         anchors.fill: parent
  54         Emitter {
  55             width: parent.width
  56             emitRate: 4
  57             lifeSpan: 14000
  58             size: 80
  59             velocity: PointDirection { y: 60 }
  60         }
  61         Wander {
  62             anchors.fill: parent
  63             anchors.bottomMargin: 100
  64             xVariance: 60
  65             pace: 60
  66         }
  67
  68         //! [0]
  69         Affector {
  70             property real coefficient: 0.1
  71             property real velocity: 1.5
  72             width: parent.width
  73             height: parent.height - 100
  74             onAffectParticles: {
  75             /*  //Linear movement
  76                 if (particle.r == 0) {
  77                     particle.r = Math.random() > 0.5 ? -1 : 1;
  78                 } else if (particle.r == 1) {
  79                     particle.rotation += velocity * dt;
  80                     if (particle.rotation >= maxAngle)
  81                         particle.r = -1;
  82                 } else if (particle.r == -1) {
  83                     particle.rotation -= velocity * dt;
  84                     if (particle.rotation <= -1 * maxAngle)
  85                         particle.r = 1;
  86                 }
  87             */
  88                 //Wobbly movement
  89                 for (var i=0; i<particles.length; i++) {
  90                     var particle = particles[i];
  91                     if (particle.r == 0.0) {
  92                         particle.r = Math.random() + 0.01;
  93                     }
  94                     particle.rotation += velocity * particle.r * dt;
  95                     particle.r -= particle.rotation * coefficient;
  96                     if (particle.r == 0.0)
  97                         particle.r -= particle.rotation * 0.000001;
  98                     particle.update = 1;
  99                 }
 100             }
 101         }
 102         //! [0]
 103
 104         //! [1]
 105         Affector {//Custom Friction, adds some 'randomness'
 106             x: -60
 107             width: parent.width + 120
 108             height: 100
 109             anchors.bottom: parent.bottom
 110             onAffectParticles: {
 111                 for (var i=0; i<particles.length; i++) {
 112                     var particle = particles[i];
 113                     var pseudoRand = (Math.floor(particle.t*1327) % 10) + 1;
 114                     var yslow = dt * pseudoRand * 0.5 + 1;
 115                     var xslow = dt * pseudoRand * 0.05 + 1;
 116                     if (particle.vy < 1)
 117                         particle.vy = 0;
 118                     else
 119                         particle.vy = (particle.vy / yslow);
 120                     if (particle.vx < 1)
 121                         particle.vx = 0;
 122                     else
 123                         particle.vx = (particle.vx / xslow);
 124                     particle.update = true;
 125                 }
 126             }
 127         }
 128         //! [1]
 129
 130         ImageParticle {
 131             anchors.fill: parent
 132             id: particles
 133             sprites: [Sprite {
 134                     source: "../../images/realLeaf1.png"
 135                     frameCount: 1
 136                     frameDuration: 1
 137                     to: {"a":1, "b":1, "c":1, "d":1}
 138                 }, Sprite {
 139                     name: "a"
 140                     source: "../../images/realLeaf1.png"
 141                     frameCount: 1
 142                     frameDuration: 10000
 143                 },
 144                 Sprite {
 145                     name: "b"
 146                     source: "../../images/realLeaf2.png"
 147                     frameCount: 1
 148                     frameDuration: 10000
 149                 },
 150                 Sprite {
 151                     name: "c"
 152                     source: "../../images/realLeaf3.png"
 153                     frameCount: 1
 154                     frameDuration: 10000
 155                 },
 156                 Sprite {
 157                     name: "d"
 158                     source: "../../images/realLeaf4.png"
 159                     frameCount: 1
 160                     frameDuration: 10000
 161                 }
 162             ]
 163
 164             z:4
 165         }
 166     }
 167 }