examples/p5solv

   1 #!/usr/bin/perl -w
   2
   3 use POSIX;
   4 use Fcntl;
   5 use Config::IniFiles;
   6 use File::FnMatch;
   7 use Data::Dumper;
   8 use solv;
   9 use Devel::Peek;
  10 use FileHandle;
  11 use File::Temp ();
  12 use strict;
  13
  14 package Repo::generic;
  15
  16 sub new {
  17   my ($class, $alias, $type, $attr) = @_;
  18   my $r = { %{$attr || {}} };
  19   $r->{'alias'} = $alias;
  20   $r->{'type'} = $type;
  21   return bless $r, $class;
  22 }
  23
  24 sub calc_cookie_fp {
  25   my ($self, $fp) = @_;
  26   my $chksum = solv::Chksum->new($solv::REPOKEY_TYPE_SHA256);
  27   $chksum->add_fp($fp);
  28   return $chksum->raw();
  29 }
  30
  31 sub calc_cookie_file {
  32   my ($self, $filename) = @_;
  33   my $chksum = solv::Chksum->new($solv::REPOKEY_TYPE_SHA256);
  34   $chksum->add("1.1");
  35   $chksum->add_stat($filename);
  36   return $chksum->raw();
  37 }
  38
  39 sub cachepath {
  40   my ($self, $ext) = @_;
  41   my $path = $self->{'alias'};
  42   $path =~ s/^\./_/s;
  43   $path .= $ext ? "_$ext.solvx" : '.solv';
  44   $path =~ s/\//_/gs;
  45   return "/var/cache/solv/$path";
  46 }
  47
  48 sub load {
  49   my ($self, $pool) = @_;
  50   $self->{'handle'} = $pool->add_repo($self->{'alias'});
  51   $self->{'handle'}->{'appdata'} = $self;
  52   $self->{'handle'}->{'priority'} = 99 - $self->{'priority'};
  53   my $dorefresh = $self->{'autorefresh'};
  54   if ($dorefresh) {
  55     my @s = stat($self->cachepath());
  56     $dorefresh = 0 if @s && time() - $s[9] < $self->{'metadata_expire'};
  57   }
  58   $self->{'cookie'} = '';
  59   if (!$dorefresh && $self->usecachedrepo()) {
  60     print "repo: '$self->{'alias'}' cached\n";
  61     return 1;
  62   }
  63   return $self->load_if_changed();
  64 }
  65
  66 sub load_if_changed {
  67   return 0;
  68 }
  69
  70 sub load_ext {
  71   return 0;
  72 }
  73
  74 sub download {
  75   my ($self, $file, $uncompress, $chksum, $markincomplete) = @_;
  76   if (!$self->{'baseurl'}) {
  77     print "$self->{'alias'}: no baseurl\n";
  78     return undef;
  79   }
  80   my $url = $self->{'baseurl'};
  81   $url =~ s/\/$//;
  82   $url .= "/$file";
  83   open(my $f, '+>', undef) || die;
  84   fcntl($f, Fcntl::F_SETFD, 0);
  85   my $st = system('curl', '-f', '-s', '-L', '-o', "/dev/fd/".fileno($f), '--', $url);
  86   if (POSIX::lseek(fileno($f), 0, POSIX::SEEK_END) == 0 && ($st == 0 || !$chksum)) {
  87     return undef;
  88   }
  89   POSIX::lseek(fileno($f), 0, POSIX::SEEK_SET);
  90   if ($st) {
  91     print "$file: download error #$st\n";
  92     $self->{'incomplete'} = 1 if $markincomplete;
  93     return undef;
  94   }
  95   if ($chksum) {
  96     my $fchksum = solv::Chksum->new($chksum->{'type'});
  97     $fchksum->add_fd(fileno($f));
  98     if (!$fchksum->matches($chksum)) {
  99       print "$file: checksum error\n";
 100       $self->{'incomplete'} = 1 if $markincomplete;
 101       return undef;
 102     }
 103   }
 104   if ($uncompress) {
 105     return solv::xfopen_fd($file, POSIX::dup(fileno($f)));
 106   } else {
 107     return solv::xfopen_fd('', POSIX::dup(fileno($f)));
 108   }
 109 }
 110
 111 sub usecachedrepo {
 112   my ($self, $ext, $mark) = @_;
 113   my $cookie = $ext ? $self->{'extcookie'} : $self->{'cookie'};
 114   my $handle = $self->{'handle'};
 115   my $cachepath = $self->cachepath($ext);
 116   my $fextcookie;
 117   if (sysopen(my $f, $cachepath, POSIX::O_RDONLY)) {
 118     sysseek($f, -32, Fcntl::SEEK_END);
 119     my $fcookie = '';
 120     return undef if sysread($f, $fcookie, 32) != 32;
 121     return undef if $cookie && $fcookie ne $cookie;
 122     if ($self->{'type'} ne 'system' && !$ext) {
 123       sysseek($f, -32 * 2, Fcntl::SEEK_END);
 124       return undef if sysread($f, $fextcookie, 32) != 32;
 125     }
 126     sysseek($f, 0, Fcntl::SEEK_SET);
 127     $f = solv::xfopen_fd('', POSIX::dup(fileno($f)));
 128     my $flags = $ext ? $solv::Repo::REPO_USE_LOADING|$solv::Repo::REPO_EXTEND_SOLVABLES : 0;
 129     $flags |= $solv::Repo::REPO_LOCALPOOL if $ext && $ext ne 'DL';
 130     if (!$self->{'handle'}->add_solv($f, $flags)) {
 131       solv::xfclose($f);
 132       return undef;
 133     }
 134     solv::xfclose($f);
 135     $self->{'cookie'} = $fcookie unless $ext;
 136     $self->{'extcookie'} = $fextcookie if $fextcookie;
 137     utime undef, undef, $f if $mark;
 138     return 1;
 139   }
 140   return undef;
 141 }
 142
 143 sub genextcookie {
 144   my ($self, $f) = @_;
 145   my $chksum = solv::Chksum->new($solv::REPOKEY_TYPE_SHA256);
 146   $chksum->add($self->{'cookie'});
 147   if ($f) {
 148     my @s = stat($f);
 149     $chksum->add("@s");
 150   }
 151   my $extcookie = $chksum->raw();
 152   substr($extcookie, 0, 1) = chr(1) if ord(substr($extcookie, 0, 1)) == 0;
 153   $self->{'extcookie'} = $extcookie;
 154 }
 155
 156 sub writecachedrepo {
 157   my ($self, $ext, $info) = @_;
 158   mkdir("/var/cache/solv", 0755) unless -d "/var/cache/solv";
 159   my ($f, $tmpname);
 160   eval {
 161     ($f, $tmpname) = File::Temp::tempfile(".newsolv-XXXXXX", 'DIR' => '/var/cache/solv');
 162   };
 163   return unless $f;
 164   chmod 0444, $f;
 165   my $ff = solv::xfopen_fd('', POSIX::dup(fileno($f)));
 166   if (!$info) {
 167     $self->{'handle'}->write($ff);
 168   } elsif ($ext) {
 169     $info->write($ff);
 170   } else {
 171      $self->{'handle'}->write_first_repodata($ff);
 172   }
 173   solv::xfclose($ff);
 174   if ($self->{'type'} ne 'system' && !$ext) {
 175     $self->genextcookie($f) unless $self->{'extcookie'};
 176     syswrite($f, $self->{'extcookie'});
 177   }
 178   syswrite($f, $ext ? $self->{'extcookie'} : $self->{'cookie'});
 179   close($f);
 180   if ($self->{'handle'}->iscontiguous()) {
 181     $f = solv::xfopen($tmpname);
 182     if ($f) {
 183       if (!$ext) {
 184         $self->{'handle'}->empty();
 185         die("internal error, cannot reload solv file\n") unless $self->{'handle'}->add_solv($f, $solv::Repo::SOLV_ADD_NO_STUBS);
 186       } else {
 187         $info->extend_to_repo();
 188         $info->read_solv_flags($f, $solv::Repo::REPO_EXTEND_SOLVABLES);
 189       }
 190       solv::xfclose($f);
 191     }
 192   }
 193   rename($tmpname, $self->cachepath($ext));
 194 }
 195
 196 package Repo::rpmmd;
 197
 198 our @ISA = ('Repo::generic');
 199
 200 sub find {
 201   my ($self, $what) = @_;
 202   my $di = $self->{'handle'}->Dataiterator($solv::SOLVID_META, $solv::REPOSITORY_REPOMD_TYPE, $what, $solv::Dataiterator::SEARCH_STRING);
 203   $di->prepend_keyname($solv::REPOSITORY_REPOMD);
 204   for my $d (@$di) {
 205     $d->setpos_parent();
 206     my $filename = $d->{'pool'}->lookup_str($solv::SOLVID_POS, $solv::REPOSITORY_REPOMD_LOCATION);
 207     next unless $filename;
 208     my $chksum = $d->{'pool'}->lookup_checksum($solv::SOLVID_POS, $solv::REPOSITORY_REPOMD_CHECKSUM);
 209     if (!$chksum) {
 210       print "no $filename file checksum!\n";
 211       return (undef, undef);
 212     }
 213     return ($filename, $chksum);
 214   }
 215   return (undef, undef);
 216 }
 217
 218 sub add_ext {
 219   my ($self, $repodata, $what, $ext) = @_;
 220   my ($filename, $chksum) = $self->find($what);
 221   ($filename, $chksum) = $self->find('prestodelta') if !$filename && $what eq 'deltainfo';
 222   return unless $filename;
 223   my $handle = $repodata->new_handle();
 224   $repodata->set_poolstr($handle, $solv::REPOSITORY_REPOMD_TYPE, $what);
 225   $repodata->set_str($handle, $solv::REPOSITORY_REPOMD_LOCATION, $filename);
 226   $repodata->set_checksum($handle, $solv::REPOSITORY_REPOMD_CHECKSUM, $chksum);
 227   if ($ext eq 'DL') {
 228     $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $solv::REPOSITORY_DELTAINFO);
 229     $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $solv::REPOKEY_TYPE_FLEXARRAY);
 230   } elsif ($ext eq 'FL') {
 231     $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $solv::SOLVABLE_FILELIST);
 232     $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $solv::REPOKEY_TYPE_DIRSTRARRAY);
 233   }
 234   $repodata->add_flexarray($solv::SOLVID_META, $solv::REPOSITORY_EXTERNAL, $handle);
 235 }
 236
 237 sub add_exts {
 238   my ($self) = @_;
 239   my $repodata = $self->{'handle'}->add_repodata(0);
 240   $self->add_ext($repodata, 'deltainfo', 'DL');
 241   $self->add_ext($repodata, 'filelists', 'FL');
 242   $repodata->internalize();
 243 }
 244
 245 sub load_ext {
 246   my ($self, $repodata) = @_;
 247   my $repomdtype = $repodata->lookup_str($solv::SOLVID_META, $solv::REPOSITORY_REPOMD_TYPE);
 248   my $ext;
 249   if ($repomdtype eq 'filelists') {
 250     $ext = 'FL';
 251   } elsif ($repomdtype eq 'deltainfo') {
 252     $ext = 'DL';
 253   } else {
 254     return 0;
 255   }
 256   print("[$self->{'alias'}:$ext: ");
 257   STDOUT->flush();
 258   if ($self->usecachedrepo($ext)) {
 259     print "cached]\n";
 260     return 1;
 261   }
 262   print "fetching]\n";
 263   my $filename = $repodata->lookup_str($solv::SOLVID_META, $solv::REPOSITORY_REPOMD_LOCATION);
 264   my $filechksum = $repodata->lookup_checksum($solv::SOLVID_META, $solv::REPOSITORY_REPOMD_CHECKSUM);
 265   my $f = $self->download($filename, 1, $filechksum);
 266   return 0 unless $f;
 267   if ($ext eq 'FL') {
 268     $self->{'handle'}->add_rpmmd($f, 'FL', $solv::Repo::REPO_USE_LOADING|$solv::Repo::REPO_EXTEND_SOLVABLES);
 269   } elsif ($ext eq 'FL') {
 270     $self->{'handle'}->add_deltainfoxml($f, $solv::Repo::REPO_USE_LOADING);
 271   }
 272   solv::xfclose($f);
 273   $self->writecachedrepo($ext, $repodata);
 274   return 1;
 275 }
 276
 277 sub load_if_changed {
 278   my ($self) = @_;
 279   print "rpmmd repo '$self->{'alias'}': ";
 280   STDOUT->flush();
 281   my $f = $self->download("repodata/repomd.xml");
 282   if (!$f) {
 283     print "no repomd.xml file, skipped\n";
 284     $self->{'handle'}->free(1);
 285     delete $self->{'handle'};
 286     return undef;
 287   }
 288   $self->{'cookie'} = $self->calc_cookie_fp($f);
 289   if ($self->usecachedrepo(undef, 1)) {
 290     print "cached\n";
 291     solv::xfclose($f);
 292     return 1;
 293   }
 294   $self->{'handle'}->add_repomdxml($f, 0);
 295   solv::xfclose($f);
 296   print "fetching\n";
 297   my ($filename, $filechksum) = $self->find('primary');
 298   if ($filename) {
 299     $f = $self->download($filename, 1, $filechksum, 1);
 300     if ($f) {
 301       $self->{'handle'}->add_rpmmd($f, undef, 0);
 302       solv::xfclose($f);
 303     }
 304     return undef if $self->{'incomplete'};
 305   }
 306   ($filename, $filechksum) = $self->find('updateinfo');
 307   if ($filename) {
 308     $f = $self->download($filename, 1, $filechksum, 1);
 309     if ($f) {
 310       $self->{'handle'}->add_updateinfoxml($f, 0);
 311       solv::xfclose($f);
 312     }
 313   }
 314   $self->add_exts();
 315   $self->writecachedrepo() unless $self->{'incomplete'};
 316   $self->{'handle'}->create_stubs();
 317   return 1;
 318 }
 319
 320 package Repo::susetags;
 321
 322 our @ISA = ('Repo::generic');
 323
 324 sub find {
 325   my ($self, $what) = @_;
 326
 327   my $di = $self->{'handle'}->Dataiterator($solv::SOLVID_META, $solv::SUSETAGS_FILE_NAME, $what, $solv::Dataiterator::SEARCH_STRING);
 328   $di->prepend_keyname($solv::SUSETAGS_FILE);
 329   for my $d (@$di) {
 330     $d->setpos_parent();
 331     my $chksum = $d->{'pool'}->lookup_checksum($solv::SOLVID_POS, $solv::SUSETAGS_FILE_CHECKSUM);
 332     return ($what, $chksum);
 333   }
 334   return (undef, undef);
 335 }
 336
 337 my %langtags = (
 338   $solv::SOLVABLE_SUMMARY     => $solv::REPOKEY_TYPE_STR,
 339   $solv::SOLVABLE_DESCRIPTION => $solv::REPOKEY_TYPE_STR,
 340   $solv::SOLVABLE_EULA        => $solv::REPOKEY_TYPE_STR,
 341   $solv::SOLVABLE_MESSAGEINS  => $solv::REPOKEY_TYPE_STR,
 342   $solv::SOLVABLE_MESSAGEDEL  => $solv::REPOKEY_TYPE_STR,
 343   $solv::SOLVABLE_CATEGORY    => $solv::REPOKEY_TYPE_ID,
 344 );
 345
 346 sub add_ext {
 347   my ($self, $repodata, $what, $ext) = @_;
 348   my ($filename, $chksum) = $self->find($what);
 349   my $handle = $repodata->new_handle();
 350   $repodata->set_str($handle, $solv::SUSETAGS_FILE_NAME, $filename);
 351   $repodata->set_checksum($handle, $solv::SUSETAGS_FILE_CHECKSUM, $chksum);
 352   if ($ext eq 'DL') {
 353     $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $solv::REPOSITORY_DELTAINFO);
 354     $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $solv::REPOKEY_TYPE_FLEXARRAY);
 355   } elsif ($ext eq 'DU') {
 356     $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $solv::SOLVABLE_DISKUSAGE);
 357     $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $solv::REPOKEY_TYPE_DIRNUMNUMARRAY);
 358   } elsif ($ext eq 'FL') {
 359     $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $solv::SOLVABLE_FILELIST);
 360     $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $solv::REPOKEY_TYPE_DIRSTRARRAY);
 361   } else {
 362     for my $langid (sort {$a <=> $b} keys %langtags) {
 363       $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $self->{'handle'}->{'pool'}->id2langid($langid, $ext, 1));
 364       $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $langtags{$langid});
 365     }
 366   }
 367   $repodata->add_flexarray($solv::SOLVID_META, $solv::REPOSITORY_EXTERNAL, $handle);
 368 }
 369
 370 sub add_exts {
 371   my ($self) = @_;
 372   my $repodata = $self->{'handle'}->add_repodata(0);
 373   my $di = $self->{'handle'}->Dataiterator($solv::SOLVID_META, $solv::SUSETAGS_FILE_NAME, undef, 0);
 374   $di->prepend_keyname($solv::SUSETAGS_FILE);
 375   for my $d (@$di) {
 376     my $filename = $d->match_str();
 377     next unless $filename && $filename =~ /^packages\.(..)(?:\..*)$/;
 378     next if $1 eq 'en' || $1 eq 'gz';
 379     $self->add_ext($repodata, $filename, $1);
 380   }
 381   $repodata->internalize();
 382 }
 383
 384 sub load_ext {
 385   my ($self, $repodata) = @_;
 386   my $filename = $repodata->lookup_str($solv::SOLVID_META, $solv::SUSETAGS_FILE_NAME);
 387   my $ext = substr($filename, 9, 2);
 388   print("[$self->{'alias'}:$ext: ");
 389   STDOUT->flush();
 390   if ($self->usecachedrepo($ext)) {
 391     print "cached]\n";
 392     return 1;
 393   }
 394   print "fetching]\n";
 395   my $defvendorid = $self->{'handle'}->lookup_id($solv::SOLVID_META, $solv::SUSETAGS_DEFAULTVENDOR);
 396   my $descrdir = $self->{'handle'}->lookup_str($solv::SOLVID_META, $solv::SUSETAGS_DESCRDIR) || 'suse/setup/descr';
 397   my $filechksum = $repodata->lookup_checksum($solv::SOLVID_META, $solv::SUSETAGS_FILE_CHECKSUM);
 398   my $f = $self->download("$descrdir/$filename", 1, $filechksum);
 399   return 0 unless $f;
 400   $self->{'handle'}->add_susetags($f, $defvendorid, $ext, $solv::Repo::REPO_USE_LOADING|$solv::Repo::REPO_EXTEND_SOLVABLES);
 401   solv::xfclose($f);
 402   $self->writecachedrepo($ext, $repodata);
 403   return 1;
 404 }
 405
 406 sub load_if_changed {
 407   my ($self) = @_;
 408   print "susetags repo '$self->{'alias'}': ";
 409   STDOUT->flush();
 410   my $f = $self->download("content");
 411   if (!$f) {
 412     print "no content file, skipped\n";
 413     $self->{'handle'}->free(1);
 414     delete $self->{'handle'};
 415     return undef;
 416   }
 417   $self->{'cookie'} = $self->calc_cookie_fp($f);
 418   if ($self->usecachedrepo(undef, 1)) {
 419     print "cached\n";
 420     solv::xfclose($f);
 421     return 1;
 422   }
 423   $self->{'handle'}->add_content($f, 0);
 424   solv::xfclose($f);
 425   print "fetching\n";
 426   my $defvendorid = $self->{'handle'}->lookup_id($solv::SOLVID_META, $solv::SUSETAGS_DEFAULTVENDOR);
 427   my $descrdir = $self->{'handle'}->lookup_str($solv::SOLVID_META, $solv::SUSETAGS_DESCRDIR) || 'suse/setup/descr';
 428   my ($filename, $filechksum) = $self->find('packages.gz');
 429   ($filename, $filechksum) = $self->find('packages') unless $filename;
 430   if ($filename) {
 431     $f = $self->download("$descrdir/$filename", 1, $filechksum, 1);
 432     if ($f) {
 433       $self->{'handle'}->add_susetags($f, $defvendorid, undef, $solv::Repo::REPO_NO_INTERNALIZE|$solv::Repo::SUSETAGS_RECORD_SHARES);
 434       solv::xfclose($f);
 435       ($filename, $filechksum) = $self->find('packages.en.gz');
 436       ($filename, $filechksum) = $self->find('packages.en') unless $filename;
 437       if ($filename) {
 438         $f = $self->download("$descrdir/$filename", 1, $filechksum, 1);
 439         if ($f) {
 440           $self->{'handle'}->add_susetags($f, $defvendorid, undef, $solv::Repo::REPO_NO_INTERNALIZE|$solv::Repo::REPO_REUSE_REPODATA|$solv::Repo::REPO_EXTEND_SOLVABLES);
 441           solv::xfclose($f);
 442         }
 443       }
 444       $self->{'handle'}->internalize();
 445     }
 446   }
 447   $self->add_exts();
 448   $self->writecachedrepo() unless $self->{'incomplete'};
 449   $self->{'handle'}->create_stubs();
 450   return undef;
 451 }
 452
 453 package Repo::unknown;
 454
 455 our @ISA = ('Repo::generic');
 456
 457 sub load {
 458   my ($self, $pool) = @_;
 459   print "unsupported repo '$self->{'alias'}': skipped\n";
 460   return 0;
 461 }
 462
 463 package Repo::system;
 464
 465 our @ISA = ('Repo::generic');
 466
 467 sub load {
 468   my ($self, $pool) = @_;
 469
 470   $self->{'handle'} = $pool->add_repo($self->{'alias'});
 471   $self->{'handle'}->{'appdata'} = $self;
 472   $pool->{'installed'} = $self->{'handle'};
 473   print "rpm database: ";
 474   $self->{'cookie'} = $self->calc_cookie_file('/var/lib/rpm/Packages');
 475   if ($self->usecachedrepo()) {
 476     print "cached\n";
 477     return 1;
 478   }
 479   print "reading\n";
 480   $self->{'handle'}->add_products("/etc/products.d", $solv::Repo::REPO_NO_INTERNALIZE);
 481   $self->{'handle'}->add_rpmdb(undef, $solv::Repo::REPO_REUSE_REPODATA);
 482   return 1;
 483 }
 484
 485 package main;
 486
 487 sub validarch {
 488   my ($pool, $arch) = @_;
 489   return undef unless $arch;
 490   my $id = $pool->str2id($arch, 0);
 491   return $id && $pool->isknownarch($id) ? 1 : undef;
 492 }
 493
 494 sub depglob {
 495   my ($pool, $name, $globname, $globdep) = @_;
 496   my $id = $pool->str2id($name, 0);
 497   if ($id) {
 498     my $match;
 499     for my $s ($pool->providers($id)) {
 500       return $pool->Job($solv::Job::SOLVER_SOLVABLE_NAME, $id) if $globname && $s->{'nameid'} == $id;
 501       $match = 1;
 502     }
 503     if ($match) {
 504       print "[using capability match for '$name']\n" if $globname && $globdep;
 505       return $pool->Job($solv::Job::SOLVER_SOLVABLE_PROVIDES, $id);
 506     }
 507   }
 508   return unless $name =~ /[[*?]/;
 509   if ($globname) {
 510     my %idmatches;
 511     for my $d (@{$pool->Dataiterator(0, $solv::SOLVABLE_NAME, $name, $solv::Dataiterator::SEARCH_GLOB)}) {
 512       my $s = $d->{'solvable'};
 513       $idmatches{$s->{'nameid'}} = 1 if $s->installable();
 514     }
 515     if (%idmatches) {
 516       return map {$pool->Job($solv::Job::SOLVER_SOLVABLE_NAME, $_)} sort(keys %idmatches);
 517     }
 518   }
 519   if ($globdep) {
 520     my @idmatches = $pool->matchprovidingids($name, $solv::Dataiterator::SEARCH_GLOB);
 521     if (@idmatches) {
 522       print "[using capability match for '$name']\n";
 523       return map {$pool->Job($solv::Job::SOLVER_SOLVABLE_PROVIDES, $_)} sort(@idmatches);
 524     }
 525   }
 526   return;
 527 }
 528
 529 sub limitjobs {
 530   my ($pool, $jobs, $flags, $evrstr) = @_;
 531   my @jobs;
 532   my $evr = $pool->str2id($evrstr);
 533   for my $j (@$jobs) {
 534     my $how = $j->{'how'};
 535     my $sel = $how & $solv::Job::SOLVER_SELECTMASK;
 536     my $what = $pool->rel2id($j->{'what'}, $evr, $flags);
 537     if ($flags == $solv::REL_ARCH) {
 538       $how |= $solv::Job::SOLVER_SETARCH;
 539     } elsif ($flags == $solv::REL_EQ && $sel == $solv::Job::SOLVER_SOLVABLE_NAME) {
 540       $how |= $evrstr =~ /-/ ? $solv::Job::SOLVER_SETEVR : $solv::Job::SOLVER_SETEV;
 541     }
 542     push @jobs, $pool->Job($how, $what);
 543   }
 544   return @jobs;
 545 }
 546
 547 sub limitjobs_evrarch {
 548   my ($pool, $jobs, $flags, $evrstr) = @_;
 549   if ($evrstr =~ /^(.+)\.(.+?)$/ && validarch($pool, $2)) {
 550     $evrstr = $1;
 551     $jobs = [ limitjobs($pool, $jobs, $solv::REL_ARCH, $2) ];
 552   }
 553   return limitjobs($pool, $jobs, $flags, $evrstr);
 554 }
 555
 556 sub mkjobs_rel {
 557   my ($pool, $cmd, $name, $rel, $evr) = @_;
 558   my $flags = 0;
 559   $flags |= $solv::REL_LT if $rel =~ /</;
 560   $flags |= $solv::REL_EQ if $rel =~ /=/;
 561   $flags |= $solv::REL_GT if $rel =~ />/;
 562   my @jobs = depglob($pool, $name, 1, 1);
 563   return limitjobs($pool, \@jobs, $flags, $evr) if @jobs;
 564   if (($name =~ /^(.+)\.(.+?)$/s) && validarch($pool, $2)) {
 565     my $arch = $2;
 566     @jobs = depglob($pool, $1, 1, 1);
 567     if (@jobs) {
 568       @jobs = limitjobs($pool, \@jobs, $solv::REL_ARCH, $arch);
 569       return limitjobs($pool, \@jobs, $flags, $evr);
 570     }
 571   }
 572   return ();
 573 }
 574
 575 sub mkjobs_nevra {
 576   my ($pool, $cmd, $arg) = @_;
 577   my @jobs = depglob($pool, $arg, 1, 1);
 578   return @jobs if @jobs;
 579   if (($arg =~ /^(.+)\.(.+?)$/s) && validarch($pool, $2)) {
 580     my $arch = $2;
 581     @jobs = depglob($pool, $1, 1, 1);
 582     return limitjobs($pool, \@jobs, $solv::REL_ARCH, $arch) if @jobs;
 583   }
 584   if ($arg =~ /^(.+)-(.+?)$/s) {
 585     my $evr = $2;
 586     @jobs = depglob($pool, $1, 1, 0);
 587     return limitjobs_evrarch($pool, \@jobs, $solv::REL_EQ, $evr) if @jobs;
 588   }
 589   if ($arg =~ /^(.+)-(.+?-.+?)$/s) {
 590     my $evr = $2;
 591     @jobs = depglob($pool, $1, 1, 0);
 592     return limitjobs_evrarch($pool, \@jobs, $solv::REL_EQ, $evr) if @jobs;
 593   }
 594   return ();
 595 }
 596
 597 sub mkjobs_filelist {
 598   my ($pool, $cmd, $arg) = @_;
 599   my $type = ($arg =~ /[[*?]/) ? $solv::Dataiterator::SEARCH_GLOB : $solv::Dataiterator::SEARCH_STRING;
 600   $type |= $solv::Dataiterator::SEARCH_FILES | $solv::Dataiterator::SEARCH_COMPLETE_FILELIST;
 601   my $di;
 602   if ($cmd eq 'erase') {
 603     $di = $pool->{'installed'}->Dataiterator(0, $solv::SOLVABLE_FILELIST, $arg, $type);
 604   } else {
 605     $di = $pool->Dataiterator(0, $solv::SOLVABLE_FILELIST, $arg, $type);
 606   }
 607   my @matches;
 608   for my $d (@$di) {
 609     my $s = $d->{'solvable'};
 610     next unless $s && $s->installable();
 611     push @matches, $s->{'id'};
 612     $di->skip_solvable();
 613   }
 614   return () unless @matches;
 615   print "[using file list match for '$arg']\n";
 616   if (@matches > 1) {
 617     return $pool->Job($solv::Job::SOLVER_SOLVABLE_ONE_OF, $pool->towhatprovides(\@matches));
 618   } else {
 619     return $pool->Job($solv::Job::SOLVER_SOLVABLE | $solv::Job::SOLVER_NOAUTOSET, $matches[0]);
 620   }
 621 }
 622
 623 sub mkjobs {
 624   my ($pool, $cmd, $arg) = @_;
 625   if ($arg && $arg =~ /^\//) {
 626     my @jobs = mkjobs_filelist($pool, $cmd, $arg);
 627     return @jobs if @jobs;
 628   }
 629   if ($arg =~ /^(.+?)\s*([<=>]+)\s*(.+?)$/s) {
 630     return mkjobs_rel($pool, $cmd, $1, $2, $3);
 631   } else {
 632     return mkjobs_nevra($pool, $cmd, $arg);
 633   }
 634 }
 635
 636 sub load_stub {
 637   my ($repodata) = @_;
 638   my $repo = $repodata->{'repo'}->{'appdata'};
 639   return $repo ? $repo->load_ext($repodata) : 0;
 640 }
 641
 642 die("Usage: p5solv COMMAND [ARGS]\n") unless @ARGV;
 643 my $cmd = shift @ARGV;
 644 $cmd = 'list' if $cmd eq 'li';
 645 $cmd = 'install' if $cmd eq 'in';
 646 $cmd = 'erase' if $cmd eq 'rm';
 647 $cmd = 'verify' if $cmd eq 've';
 648 $cmd = 'search' if $cmd eq 'se';
 649
 650 my @repos;
 651 for my $reposdir ('/etc/zypp/repos.d') {
 652   next unless -d $reposdir;
 653   next unless opendir(DIR, $reposdir);
 654   for my $reponame (sort(grep {/\.repo$/} readdir(DIR))) {
 655     my $cfg = new Config::IniFiles('-file' => "$reposdir/$reponame");
 656     for my $alias ($cfg->Sections()) {
 657       my $repoattr = {'alias' => $alias, 'enabled' => 0, 'priority' => 99, 'autorefresh' => 1, 'type' => 'rpm-md', 'metadata_expire' => 900};
 658       for my $p ($cfg->Parameters($alias)) {
 659         $repoattr->{$p} = $cfg->val($alias, $p);
 660       }
 661       my $repo;
 662       if ($repoattr->{'type'} eq 'rpm-md') {
 663         $repo = Repo::rpmmd->new($alias, 'repomd', $repoattr);
 664       } elsif ($repoattr->{'type'} eq 'yast2') {
 665         $repo = Repo::susetags->new($alias, 'susetags', $repoattr);
 666       } else {
 667         $repo = Repo::unknown->new($alias, 'unknown', $repoattr);
 668       }
 669       push @repos, $repo;
 670     }
 671   }
 672 }
 673
 674 my $pool = solv::Pool->new();
 675 $pool->setarch((POSIX::uname())[4]);
 676 $pool->set_loadcallback(\&load_stub);
 677
 678 my $sysrepo = Repo::system->new('@System', 'system');
 679 $sysrepo->load($pool);
 680 for my $repo (@repos) {
 681   $repo->load($pool) if $repo->{'enabled'};
 682 }
 683
 684 if ($cmd eq 'search') {
 685   my %matches;
 686   my $di = $pool->Dataiterator(0, $solv::SOLVABLE_NAME, $ARGV[0], $solv::Dataiterator::SEARCH_SUBSTRING | $solv::Dataiterator::SEARCH_NOCASE);
 687   for my $d (@$di) {
 688     $matches{$d->{'solvid'}} = 1;
 689   }
 690   for my $solvid (sort keys %matches) {
 691     my $s = $pool->{'solvables'}->[$solvid];
 692     print "- ".$s->str()." [$s->{'repo'}->{'name'}] ".$s->lookup_str($solv::SOLVABLE_SUMMARY)."\n";
 693   }
 694   exit(0);
 695 }
 696
 697 my @addedprovides =  $pool->addfileprovides_ids();
 698 $pool->createwhatprovides();
 699
 700 my @jobs;
 701 for my $arg (@ARGV) {
 702   my @njobs = mkjobs($pool, $cmd, $arg);
 703   die("nothing matches '$arg'\n") unless @njobs;
 704   push @jobs, @njobs;
 705 }
 706
 707 if ($cmd eq 'list' || $cmd eq 'info') {
 708   die("no package matched.\n") unless @jobs;
 709   for my $job (@jobs) {
 710     for my $s ($job->solvables()) {
 711       if ($cmd eq 'info') {
 712         printf "Name:        %s\n", $s->str();
 713         printf "Repo:        %s\n", $s->{'repo'}->{'name'};
 714         printf "Summary:     %s\n", $s->lookup_str($solv::SOLVABLE_SUMMARY);
 715         my $str = $s->lookup_str($solv::SOLVABLE_URL);
 716         printf "Url:         %s\n", $str if $str;
 717         $str = $s->lookup_str($solv::SOLVABLE_LICENSE);
 718         printf "License:     %s\n", $str if $str;
 719         printf "Description:\n%s\n", $s->lookup_str($solv::SOLVABLE_DESCRIPTION);
 720       } else {
 721         printf "  - %s [%s]\n", $s->str(), $s->{'repo'}->{'name'};
 722         printf "    %s\n", $s->lookup_str($solv::SOLVABLE_SUMMARY);
 723       }
 724     }
 725   }
 726   exit 0;
 727 }
 728
 729 if ($cmd eq 'install' || $cmd eq 'erase' || $cmd eq 'up' || $cmd eq 'dup' || $cmd eq 'verify') {
 730   if (!@jobs) {
 731     if ($cmd eq 'up' || $cmd eq 'verify') {
 732       push @jobs, $pool->Job($solv::Job::SOLVER_SOLVABLE_ALL, 0);
 733     } elsif ($cmd ne 'dup') {
 734       die("no package matched.\n");
 735     }
 736   }
 737   for my $job (@jobs) {
 738     if ($cmd eq 'up') {
 739       if ($job->{'how'} == $solv::Job::SOLVER_SOLVABLE_ALL || grep {$_->isinstalled()} $job->solvables()) {
 740         $job->{'how'} |= $solv::Job::SOLVER_UPDATE;
 741       } else {
 742         $job->{'how'} |= $solv::Job::SOLVER_INSTALL;
 743       }
 744     } elsif ($cmd eq 'install') {
 745         $job->{'how'} |= $solv::Job::SOLVER_INSTALL;
 746     } elsif ($cmd eq 'erase') {
 747         $job->{'how'} |= $solv::Job::SOLVER_ERASE;
 748     } elsif ($cmd eq 'dup') {
 749         $job->{'how'} |= $solv::Job::SOLVER_DISTUPGRADE;
 750     } elsif ($cmd eq 'verify') {
 751         $job->{'how'} |= $solv::Job::SOLVER_VERIFY;
 752     }
 753   }
 754   my $solver;
 755   while (1) {
 756     $solver = $pool->Solver();
 757     $solver->{'ignorealreadyrecommended'} = 1;
 758     $solver->{'allowuninstall'} = 1 if $cmd eq 'erase';
 759     if ($cmd eq 'dup' && !@jobs) {
 760       $solver->{'distupgrade'} = 1;
 761       $solver->{'updatesystem'} = 1;
 762       $solver->{'allowdowngrade'} = 1;
 763       $solver->{'allowvendorchange'} = 1;
 764       $solver->{'allowarchchange'} = 1;
 765       $solver->{'dosplitprovides'} = 1;
 766     } elsif ($cmd eq 'up' and @jobs == 1 and $jobs[0]->{'how'} == ($solv::Job::SOLVER_UPDATE | $solv::Job::SOLVER_SOLVABLE_ALL)) {
 767       $solver->{'dosplitprovides'} = 1;
 768     }
 769     my @problems = $solver->solve(\@jobs);
 770     last unless @problems;
 771     for my $problem (@problems) {
 772       print "Problem $problem->{'id'}/".@problems.":\n";
 773       my $r = $problem->findproblemrule();
 774       my $ri = $r->info();
 775       print $ri->problemstr()."\n";
 776       my @solutions = $problem->solutions();
 777       for my $solution (@solutions) {
 778         print "  Solution $solution->{'id'}:\n";
 779         for my $element ($solution->elements()) {
 780           my $etype = $element->{'type'};
 781           if ($etype == $solv::Solver::SOLVER_SOLUTION_JOB) {
 782             print "  - do not ask to ".$jobs[$element->{'jobidx'}]->str()."\n";
 783           } elsif ($etype == $solv::Solver::SOLVER_SOLUTION_INFARCH) {
 784             if ($element->{'solvable'}->isinstalled()) {
 785               print "  - keep ".$element->{'solvable'}->str()." despite the inferior architecture\n";
 786             } else {
 787               print "  - install ".$element->{'solvable'}->str()." despite the inferior architecture\n";
 788             }
 789           } elsif ($etype == $solv::Solver::SOLVER_SOLUTION_DISTUPGRADE) {
 790             if ($element->{'solvable'}->isinstalled()) {
 791               print "  - keep obsolete ".$element->{'solvable'}->str()."\n";
 792             } else {
 793               print "  - install ".$element->{'solvable'}->str()." from excluded repository\n";
 794             }
 795           } elsif ($etype == $solv::Solver::SOLVER_SOLUTION_REPLACE) {
 796             print "  - allow replacement of ".$element->{'solvable'}->str()." with ".$element->{'replacement'}->str()."\n";
 797           } elsif ($etype == $solv::Solver::SOLVER_SOLUTION_ERASE) {
 798             print "  - allow deinstallation of ".$element->{'solvable'}->str()."\n";
 799           } else {
 800             print "  - allow something else\n";
 801           }
 802         }
 803       }
 804       my $sol;
 805       while (1) {
 806         print "Please choose a solution: ";
 807         $sol = <STDIN>;
 808         chomp $sol;
 809         last if $sol eq 's' || $sol eq 'q' || ($sol =~ /^\d+$/ && $sol >= 1 && $sol <= @solutions);
 810       }
 811       next if $sol eq 's';
 812       exit(1) if $sol eq 'q';
 813       my $solution = $solutions[$sol - 1];
 814       for my $element ($solution->elements()) {
 815         my $etype = $element->{'type'};
 816         if ($etype == $solv::Solver::SOLVER_SOLUTION_JOB) {
 817           $jobs[$element->{'jobidx'}] = $pool->Job($solv::Job::SOLVER_NOOP, 0);
 818         } else {
 819           my $newjob = $element->Job();
 820           push @jobs, $newjob if $newjob && !grep {$_->{'how'} == $newjob->{'how'} && $_->{'what'} == $newjob->{'what'}} @jobs;
 821         }
 822       }
 823     }
 824   }
 825   my $trans = $solver->transaction();
 826   undef $solver;
 827   if ($trans->isempty()) {
 828     print "Nothing to do.\n";
 829     exit 0;
 830   }
 831   print "\nTransaction summary:\n\n";
 832   for my $c ($trans->classify()) {
 833     if ($c->{'type'} == $solv::Transaction::SOLVER_TRANSACTION_ERASE) {
 834       print "$c->{'count'} erased packages:\n";
 835     } elsif ($c->{'type'} == $solv::Transaction::SOLVER_TRANSACTION_INSTALL) {
 836       print "$c->{'count'} installed packages:\n";
 837     } elsif ($c->{'type'} == $solv::Transaction::SOLVER_TRANSACTION_REINSTALLED) {
 838       print "$c->{'count'} reinstalled packages:\n";
 839     } elsif ($c->{'type'} == $solv::Transaction::SOLVER_TRANSACTION_DOWNGRADED) {
 840       print "$c->{'count'} downgraded packages:\n";
 841     } elsif ($c->{'type'} == $solv::Transaction::SOLVER_TRANSACTION_CHANGED) {
 842       print "$c->{'count'} changed packages:\n";
 843     } elsif ($c->{'type'} == $solv::Transaction::SOLVER_TRANSACTION_UPGRADED) {
 844       print "$c->{'count'} upgraded packages:\n";
 845     } elsif ($c->{'type'} == $solv::Transaction::SOLVER_TRANSACTION_VENDORCHANGE) {
 846       printf "$c->{'count'} vendor changes from '%s' to '%s':\n", $pool->id2str($c->{'fromid'}), $pool->id2str($c->{'toid'});
 847     } elsif ($c->{'type'} == $solv::Transaction::SOLVER_TRANSACTION_ARCHCHANGE) {
 848       printf "$c->{'count'} arch changes from '%s' to '%s':\n", $pool->id2str($c->{'fromid'}), $pool->id2str($c->{'toid'});
 849     } else {
 850       next;
 851     }
 852     for my $p ($c->solvables()) {
 853       if ($c->{'type'} == $solv::Transaction::SOLVER_TRANSACTION_UPGRADED || $c->{'type'} == $solv::Transaction::SOLVER_TRANSACTION_DOWNGRADED) {
 854         my $other = $trans->othersolvable($p);
 855         printf "  - %s -> %s\n", $p->str(), $other->str();
 856       } else {
 857         printf "  - %s\n", $p->str();
 858       }
 859     }
 860     print "\n";
 861   }
 862   printf "install size change: %d K\n\n", $trans->calc_installsizechange();
 863   while (1) {
 864     print("OK to continue (y/n)? ");
 865     my $yn = <STDIN>;
 866     chomp $yn;
 867     last if $yn eq 'y';
 868     exit(1) if $yn eq 'n';
 869   }
 870   my @newpkgs = $trans->newpackages();
 871   my %newpkgsfps;
 872   if (@newpkgs) {
 873     my $downloadsize = 0;
 874     $downloadsize += $_->lookup_num($solv::SOLVABLE_DOWNLOADSIZE) for @newpkgs;
 875     printf "Downloading %d packages, %d K\n", scalar(@newpkgs), $downloadsize;
 876     for my $p (@newpkgs) {
 877       my $repo = $p->{'repo'}->{'appdata'};
 878       my ($location, $medianr) = $p->lookup_location();
 879       next unless $location;
 880       if ($repo->{'type'} eq 'susetags') {
 881         $location = ($repo->{'handle'}->lookup_str($solv::SOLVID_META, $solv::SUSETAGS_DATADIR) || 'suse') ."/$location";
 882       }
 883       my $chksum = $p->lookup_checksum($solv::SOLVABLE_CHECKSUM);
 884       my $f = $repo->download($location, 0, $chksum);
 885       die("\n$repo->{'alias'}: $location not found in repository\n") unless $f;
 886       $newpkgsfps{$p->{'id'}} = $f;
 887       print ".";
 888       STDOUT->flush();
 889     }
 890     print "\n";
 891   }
 892   print "Committing transaction:\n\n";
 893   $trans->order(0);
 894   for my $p ($trans->steps()) {
 895     my $steptype = $trans->steptype($p, $solv::Transaction::SOLVER_TRANSACTION_RPM_ONLY);
 896     if ($steptype == $solv::Transaction::SOLVER_TRANSACTION_ERASE) {
 897       print "erase ".$p->str()."\n";
 898       next unless $p->lookup_num($solv::RPM_RPMDBID);
 899       my $evr = $p->{'evr'};
 900       $evr =~ s/^[0-9]+://;     # strip epoch
 901       system('rpm', '-e', '--nodeps', '--nodigest', '--nosignature', "$p->{'name'}-$evr.$p->{'arch'}") && die("rpm failed: $?\n");
 902     } elsif ($steptype == $solv::Transaction::SOLVER_TRANSACTION_INSTALL || $steptype == $solv::Transaction::SOLVER_TRANSACTION_MULTIINSTALL) {
 903       print "install ".$p->str()."\n";
 904       my $f = $newpkgsfps{$p->{'id'}};
 905       my $mode = $steptype == $solv::Transaction::SOLVER_TRANSACTION_INSTALL ? '-U' : '-i';
 906       system('rpm', $mode, '--force', '--nodeps', '--nodigest', '--nosignature', "/dev/fd/".solv::xfileno($f)) && die("rpm failed: $?\n");
 907       solv::xfclose($f);
 908       delete $newpkgsfps{$p->{'id'}};
 909     }
 910   }
 911 }
 912
 913 exit 0;