examples/p5solv

   1 #!/usr/bin/perl -w
   2
   3 use POSIX;
   4 use Fcntl;
   5 use Config::IniFiles;
   6 use Data::Dumper;
   7 use solv;
   8 use Devel::Peek;
   9 use FileHandle;
  10 use File::Temp ();
  11 use strict;
  12
  13 package Repo::generic;
  14
  15 sub new {
  16   my ($class, $alias, $type, $attr) = @_;
  17   my $r = { %{$attr || {}} };
  18   $r->{'alias'} = $alias;
  19   $r->{'type'} = $type;
  20   return bless $r, $class;
  21 }
  22
  23 sub calc_cookie_fp {
  24   my ($self, $fp) = @_;
  25   my $chksum = solv::Chksum->new($solv::REPOKEY_TYPE_SHA256);
  26   $chksum->add("1.1");
  27   $chksum->add_fp($fp);
  28   return $chksum->raw();
  29 }
  30
  31 sub calc_cookie_file {
  32   my ($self, $filename) = @_;
  33   my $chksum = solv::Chksum->new($solv::REPOKEY_TYPE_SHA256);
  34   $chksum->add("1.1");
  35   $chksum->add_stat($filename);
  36   return $chksum->raw();
  37 }
  38
  39 sub calc_cookie_ext {
  40   my ($self, $f, $cookie) = @_;
  41   my $chksum = solv::Chksum->new($solv::REPOKEY_TYPE_SHA256);
  42   $chksum->add("1.1");
  43   $chksum->add($cookie);
  44   $chksum->add_fstat(fileno($f));
  45   my $extcookie = $chksum->raw();
  46   substr($extcookie, 0, 1) = chr(1) if ord(substr($extcookie, 0, 1)) == 0;
  47   return $extcookie;
  48 }
  49
  50 sub cachepath {
  51   my ($self, $ext) = @_;
  52   my $path = $self->{'alias'};
  53   $path =~ s/^\./_/s;
  54   $path .= $ext ? "_$ext.solvx" : '.solv';
  55   $path =~ s/\//_/gs;
  56   return "/var/cache/solv/$path";
  57 }
  58
  59 sub load {
  60   my ($self, $pool) = @_;
  61   $self->{'handle'} = $pool->add_repo($self->{'alias'});
  62   $self->{'handle'}->{'appdata'} = $self;
  63   $self->{'handle'}->{'priority'} = 99 - $self->{'priority'};
  64   my $dorefresh = $self->{'autorefresh'};
  65   if ($dorefresh) {
  66     my @s = stat($self->cachepath());
  67     $dorefresh = 0 if @s && ($self->{'metadata_expire'} == -1 || time() - $s[9] < $self->{'metadata_expire'});
  68   }
  69   $self->{'cookie'} = '';
  70   if (!$dorefresh && $self->usecachedrepo()) {
  71     print "repo: '$self->{'alias'}' cached\n";
  72     return 1;
  73   }
  74   return $self->load_if_changed();
  75 }
  76
  77 sub load_if_changed {
  78   return 0;
  79 }
  80
  81 sub load_ext {
  82   return 0;
  83 }
  84
  85 sub download {
  86   my ($self, $file, $uncompress, $chksum, $markincomplete) = @_;
  87   if (!$self->{'baseurl'}) {
  88     print "$self->{'alias'}: no baseurl\n";
  89     return undef;
  90   }
  91   my $url = $self->{'baseurl'};
  92   $url =~ s/\/$//;
  93   $url .= "/$file";
  94   open(my $f, '+>', undef) || die;
  95   fcntl($f, Fcntl::F_SETFD, 0);
  96   my $st = system('curl', '-f', '-s', '-L', '-o', "/dev/fd/".fileno($f), '--', $url);
  97   if (POSIX::lseek(fileno($f), 0, POSIX::SEEK_END) == 0 && ($st == 0 || !$chksum)) {
  98     return undef;
  99   }
 100   POSIX::lseek(fileno($f), 0, POSIX::SEEK_SET);
 101   if ($st) {
 102     print "$file: download error #$st\n";
 103     $self->{'incomplete'} = 1 if $markincomplete;
 104     return undef;
 105   }
 106   if ($chksum) {
 107     my $fchksum = solv::Chksum->new($chksum->{'type'});
 108     $fchksum->add_fd(fileno($f));
 109     if ($fchksum != $chksum) {
 110       print "$file: checksum error\n";
 111       $self->{'incomplete'} = 1 if $markincomplete;
 112       return undef;
 113     }
 114   }
 115   if ($uncompress) {
 116     return solv::xfopen_dup($file, fileno($f));
 117   } else {
 118     return solv::xfopen_dup(undef, fileno($f));
 119   }
 120 }
 121
 122 sub usecachedrepo {
 123   my ($self, $ext, $mark) = @_;
 124   my $cookie = $ext ? $self->{'extcookie'} : $self->{'cookie'};
 125   my $handle = $self->{'handle'};
 126   my $cachepath = $self->cachepath($ext);
 127   my $fextcookie;
 128   if (sysopen(my $f, $cachepath, POSIX::O_RDONLY)) {
 129     sysseek($f, -32, Fcntl::SEEK_END);
 130     my $fcookie = '';
 131     return undef if sysread($f, $fcookie, 32) != 32;
 132     return undef if $cookie && $fcookie ne $cookie;
 133     if ($self->{'type'} ne 'system' && !$ext) {
 134       sysseek($f, -32 * 2, Fcntl::SEEK_END);
 135       return undef if sysread($f, $fextcookie, 32) != 32;
 136     }
 137     sysseek($f, 0, Fcntl::SEEK_SET);
 138     my $fd = solv::xfopen_dup(undef, fileno($f));
 139     my $flags = $ext ? $solv::Repo::REPO_USE_LOADING|$solv::Repo::REPO_EXTEND_SOLVABLES : 0;
 140     $flags |= $solv::Repo::REPO_LOCALPOOL if $ext && $ext ne 'DL';
 141     if (!$self->{'handle'}->add_solv($fd, $flags)) {
 142       solv::xfclose($fd);
 143       return undef;
 144     }
 145     solv::xfclose($fd);
 146     $self->{'cookie'} = $fcookie unless $ext;
 147     $self->{'extcookie'} = $fextcookie if $fextcookie;
 148     utime undef, undef, $f if $mark;
 149     return 1;
 150   }
 151   return undef;
 152 }
 153
 154 sub writecachedrepo {
 155   my ($self, $ext, $info) = @_;
 156   mkdir("/var/cache/solv", 0755) unless -d "/var/cache/solv";
 157   my ($f, $tmpname);
 158   eval {
 159     ($f, $tmpname) = File::Temp::tempfile(".newsolv-XXXXXX", 'DIR' => '/var/cache/solv');
 160   };
 161   return unless $f;
 162   chmod 0444, $f;
 163   my $ff = solv::xfopen_dup(undef, fileno($f));
 164   if (!$info) {
 165     $self->{'handle'}->write($ff);
 166   } elsif ($ext) {
 167     $info->write($ff);
 168   } else {
 169      $self->{'handle'}->write_first_repodata($ff);
 170   }
 171   solv::xfclose($ff);
 172   if ($self->{'type'} ne 'system' && !$ext) {
 173     $self->{'extcookie'} ||= $self->calc_cookie_ext($f, $self->{'cookie'});
 174     syswrite($f, $self->{'extcookie'});
 175   }
 176   syswrite($f, $ext ? $self->{'extcookie'} : $self->{'cookie'});
 177   close($f);
 178   if ($self->{'handle'}->iscontiguous()) {
 179     $f = solv::xfopen($tmpname);
 180     if ($f) {
 181       if (!$ext) {
 182         $self->{'handle'}->empty();
 183         die("internal error, cannot reload solv file\n") unless $self->{'handle'}->add_solv($f, $solv::Repo::SOLV_ADD_NO_STUBS);
 184       } else {
 185         $info->extend_to_repo();
 186         $info->add_solv($f, $solv::Repo::REPO_EXTEND_SOLVABLES);
 187       }
 188       solv::xfclose($f);
 189     }
 190   }
 191   rename($tmpname, $self->cachepath($ext));
 192 }
 193
 194 sub packagespath {
 195   my ($self) = @_;
 196   return '';
 197 }
 198
 199 package Repo::rpmmd;
 200
 201 our @ISA = ('Repo::generic');
 202
 203 sub find {
 204   my ($self, $what) = @_;
 205   my $di = $self->{'handle'}->Dataiterator($solv::SOLVID_META, $solv::REPOSITORY_REPOMD_TYPE, $what, $solv::Dataiterator::SEARCH_STRING);
 206   $di->prepend_keyname($solv::REPOSITORY_REPOMD);
 207   for my $d (@$di) {
 208     my $dp = $d->parentpos();
 209     my $filename = $dp->lookup_str($solv::REPOSITORY_REPOMD_LOCATION);
 210     next unless $filename;
 211     my $chksum = $dp->lookup_checksum($solv::REPOSITORY_REPOMD_CHECKSUM);
 212     if (!$chksum) {
 213       print "no $filename file checksum!\n";
 214       return (undef, undef);
 215     }
 216     return ($filename, $chksum);
 217   }
 218   return (undef, undef);
 219 }
 220
 221 sub add_ext {
 222   my ($self, $repodata, $what, $ext) = @_;
 223   my ($filename, $chksum) = $self->find($what);
 224   ($filename, $chksum) = $self->find('prestodelta') if !$filename && $what eq 'deltainfo';
 225   return unless $filename;
 226   my $handle = $repodata->new_handle();
 227   $repodata->set_poolstr($handle, $solv::REPOSITORY_REPOMD_TYPE, $what);
 228   $repodata->set_str($handle, $solv::REPOSITORY_REPOMD_LOCATION, $filename);
 229   $repodata->set_checksum($handle, $solv::REPOSITORY_REPOMD_CHECKSUM, $chksum);
 230   if ($ext eq 'DL') {
 231     $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $solv::REPOSITORY_DELTAINFO);
 232     $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $solv::REPOKEY_TYPE_FLEXARRAY);
 233   } elsif ($ext eq 'FL') {
 234     $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $solv::SOLVABLE_FILELIST);
 235     $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $solv::REPOKEY_TYPE_DIRSTRARRAY);
 236   }
 237   $repodata->add_flexarray($solv::SOLVID_META, $solv::REPOSITORY_EXTERNAL, $handle);
 238 }
 239
 240 sub add_exts {
 241   my ($self) = @_;
 242   my $repodata = $self->{'handle'}->add_repodata(0);
 243   $self->add_ext($repodata, 'deltainfo', 'DL');
 244   $self->add_ext($repodata, 'filelists', 'FL');
 245   $repodata->internalize();
 246 }
 247
 248 sub load_ext {
 249   my ($self, $repodata) = @_;
 250   my $repomdtype = $repodata->lookup_str($solv::SOLVID_META, $solv::REPOSITORY_REPOMD_TYPE);
 251   my $ext;
 252   if ($repomdtype eq 'filelists') {
 253     $ext = 'FL';
 254   } elsif ($repomdtype eq 'deltainfo') {
 255     $ext = 'DL';
 256   } else {
 257     return 0;
 258   }
 259   print("[$self->{'alias'}:$ext: ");
 260   STDOUT->flush();
 261   if ($self->usecachedrepo($ext)) {
 262     print "cached]\n";
 263     return 1;
 264   }
 265   print "fetching]\n";
 266   my $filename = $repodata->lookup_str($solv::SOLVID_META, $solv::REPOSITORY_REPOMD_LOCATION);
 267   my $filechksum = $repodata->lookup_checksum($solv::SOLVID_META, $solv::REPOSITORY_REPOMD_CHECKSUM);
 268   my $f = $self->download($filename, 1, $filechksum);
 269   return 0 unless $f;
 270   if ($ext eq 'FL') {
 271     $self->{'handle'}->add_rpmmd($f, 'FL', $solv::Repo::REPO_USE_LOADING|$solv::Repo::REPO_EXTEND_SOLVABLES);
 272   } elsif ($ext eq 'FL') {
 273     $self->{'handle'}->add_deltainfoxml($f, $solv::Repo::REPO_USE_LOADING);
 274   }
 275   solv::xfclose($f);
 276   $self->writecachedrepo($ext, $repodata);
 277   return 1;
 278 }
 279
 280 sub load_if_changed {
 281   my ($self) = @_;
 282   print "rpmmd repo '$self->{'alias'}': ";
 283   STDOUT->flush();
 284   my $f = $self->download("repodata/repomd.xml");
 285   if (!$f) {
 286     print "no repomd.xml file, skipped\n";
 287     $self->{'handle'}->free(1);
 288     delete $self->{'handle'};
 289     return undef;
 290   }
 291   $self->{'cookie'} = $self->calc_cookie_fp($f);
 292   if ($self->usecachedrepo(undef, 1)) {
 293     print "cached\n";
 294     solv::xfclose($f);
 295     return 1;
 296   }
 297   $self->{'handle'}->add_repomdxml($f, 0);
 298   solv::xfclose($f);
 299   print "fetching\n";
 300   my ($filename, $filechksum) = $self->find('primary');
 301   if ($filename) {
 302     $f = $self->download($filename, 1, $filechksum, 1);
 303     if ($f) {
 304       $self->{'handle'}->add_rpmmd($f, undef, 0);
 305       solv::xfclose($f);
 306     }
 307     return undef if $self->{'incomplete'};
 308   }
 309   ($filename, $filechksum) = $self->find('updateinfo');
 310   if ($filename) {
 311     $f = $self->download($filename, 1, $filechksum, 1);
 312     if ($f) {
 313       $self->{'handle'}->add_updateinfoxml($f, 0);
 314       solv::xfclose($f);
 315     }
 316   }
 317   $self->add_exts();
 318   $self->writecachedrepo() unless $self->{'incomplete'};
 319   $self->{'handle'}->create_stubs();
 320   return 1;
 321 }
 322
 323 package Repo::susetags;
 324
 325 our @ISA = ('Repo::generic');
 326
 327 sub find {
 328   my ($self, $what) = @_;
 329
 330   my $di = $self->{'handle'}->Dataiterator($solv::SOLVID_META, $solv::SUSETAGS_FILE_NAME, $what, $solv::Dataiterator::SEARCH_STRING);
 331   $di->prepend_keyname($solv::SUSETAGS_FILE);
 332   for my $d (@$di) {
 333     my $dp = $d->parentpos();
 334     my $chksum = $dp->lookup_checksum($solv::SUSETAGS_FILE_CHECKSUM);
 335     return ($what, $chksum);
 336   }
 337   return (undef, undef);
 338 }
 339
 340 my %langtags = (
 341   $solv::SOLVABLE_SUMMARY     => $solv::REPOKEY_TYPE_STR,
 342   $solv::SOLVABLE_DESCRIPTION => $solv::REPOKEY_TYPE_STR,
 343   $solv::SOLVABLE_EULA        => $solv::REPOKEY_TYPE_STR,
 344   $solv::SOLVABLE_MESSAGEINS  => $solv::REPOKEY_TYPE_STR,
 345   $solv::SOLVABLE_MESSAGEDEL  => $solv::REPOKEY_TYPE_STR,
 346   $solv::SOLVABLE_CATEGORY    => $solv::REPOKEY_TYPE_ID,
 347 );
 348
 349 sub add_ext {
 350   my ($self, $repodata, $what, $ext) = @_;
 351   my ($filename, $chksum) = $self->find($what);
 352   my $handle = $repodata->new_handle();
 353   $repodata->set_str($handle, $solv::SUSETAGS_FILE_NAME, $filename);
 354   $repodata->set_checksum($handle, $solv::SUSETAGS_FILE_CHECKSUM, $chksum);
 355   if ($ext eq 'DL') {
 356     $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $solv::REPOSITORY_DELTAINFO);
 357     $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $solv::REPOKEY_TYPE_FLEXARRAY);
 358   } elsif ($ext eq 'DU') {
 359     $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $solv::SOLVABLE_DISKUSAGE);
 360     $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $solv::REPOKEY_TYPE_DIRNUMNUMARRAY);
 361   } elsif ($ext eq 'FL') {
 362     $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $solv::SOLVABLE_FILELIST);
 363     $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $solv::REPOKEY_TYPE_DIRSTRARRAY);
 364   } else {
 365     for my $langid (sort {$a <=> $b} keys %langtags) {
 366       $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $self->{'handle'}->{'pool'}->id2langid($langid, $ext, 1));
 367       $repodata->add_idarray($handle, $solv::REPOSITORY_KEYS, $langtags{$langid});
 368     }
 369   }
 370   $repodata->add_flexarray($solv::SOLVID_META, $solv::REPOSITORY_EXTERNAL, $handle);
 371 }
 372
 373 sub add_exts {
 374   my ($self) = @_;
 375   my $repodata = $self->{'handle'}->add_repodata(0);
 376   my $di = $self->{'handle'}->Dataiterator($solv::SOLVID_META, $solv::SUSETAGS_FILE_NAME, undef, 0);
 377   $di->prepend_keyname($solv::SUSETAGS_FILE);
 378   for my $d (@$di) {
 379     my $filename = $d->str();
 380     next unless $filename && $filename =~ /^packages\.(..)(?:\..*)$/;
 381     next if $1 eq 'en' || $1 eq 'gz';
 382     $self->add_ext($repodata, $filename, $1);
 383   }
 384   $repodata->internalize();
 385 }
 386
 387 sub load_ext {
 388   my ($self, $repodata) = @_;
 389   my $filename = $repodata->lookup_str($solv::SOLVID_META, $solv::SUSETAGS_FILE_NAME);
 390   my $ext = substr($filename, 9, 2);
 391   print("[$self->{'alias'}:$ext: ");
 392   STDOUT->flush();
 393   if ($self->usecachedrepo($ext)) {
 394     print "cached]\n";
 395     return 1;
 396   }
 397   print "fetching]\n";
 398   my $defvendorid = $self->{'handle'}->lookup_id($solv::SOLVID_META, $solv::SUSETAGS_DEFAULTVENDOR);
 399   my $descrdir = $self->{'handle'}->lookup_str($solv::SOLVID_META, $solv::SUSETAGS_DESCRDIR) || 'suse/setup/descr';
 400   my $filechksum = $repodata->lookup_checksum($solv::SOLVID_META, $solv::SUSETAGS_FILE_CHECKSUM);
 401   my $f = $self->download("$descrdir/$filename", 1, $filechksum);
 402   return 0 unless $f;
 403   $self->{'handle'}->add_susetags($f, $defvendorid, $ext, $solv::Repo::REPO_USE_LOADING|$solv::Repo::REPO_EXTEND_SOLVABLES);
 404   solv::xfclose($f);
 405   $self->writecachedrepo($ext, $repodata);
 406   return 1;
 407 }
 408
 409 sub load_if_changed {
 410   my ($self) = @_;
 411   print "susetags repo '$self->{'alias'}': ";
 412   STDOUT->flush();
 413   my $f = $self->download("content");
 414   if (!$f) {
 415     print "no content file, skipped\n";
 416     $self->{'handle'}->free(1);
 417     delete $self->{'handle'};
 418     return undef;
 419   }
 420   $self->{'cookie'} = $self->calc_cookie_fp($f);
 421   if ($self->usecachedrepo(undef, 1)) {
 422     print "cached\n";
 423     solv::xfclose($f);
 424     return 1;
 425   }
 426   $self->{'handle'}->add_content($f, 0);
 427   solv::xfclose($f);
 428   print "fetching\n";
 429   my $defvendorid = $self->{'handle'}->lookup_id($solv::SOLVID_META, $solv::SUSETAGS_DEFAULTVENDOR);
 430   my $descrdir = $self->{'handle'}->lookup_str($solv::SOLVID_META, $solv::SUSETAGS_DESCRDIR) || 'suse/setup/descr';
 431   my ($filename, $filechksum) = $self->find('packages.gz');
 432   ($filename, $filechksum) = $self->find('packages') unless $filename;
 433   if ($filename) {
 434     $f = $self->download("$descrdir/$filename", 1, $filechksum, 1);
 435     if ($f) {
 436       $self->{'handle'}->add_susetags($f, $defvendorid, undef, $solv::Repo::REPO_NO_INTERNALIZE|$solv::Repo::SUSETAGS_RECORD_SHARES);
 437       solv::xfclose($f);
 438       ($filename, $filechksum) = $self->find('packages.en.gz');
 439       ($filename, $filechksum) = $self->find('packages.en') unless $filename;
 440       if ($filename) {
 441         $f = $self->download("$descrdir/$filename", 1, $filechksum, 1);
 442         if ($f) {
 443           $self->{'handle'}->add_susetags($f, $defvendorid, undef, $solv::Repo::REPO_NO_INTERNALIZE|$solv::Repo::REPO_REUSE_REPODATA|$solv::Repo::REPO_EXTEND_SOLVABLES);
 444           solv::xfclose($f);
 445         }
 446       }
 447       $self->{'handle'}->internalize();
 448     }
 449   }
 450   $self->add_exts();
 451   $self->writecachedrepo() unless $self->{'incomplete'};
 452   $self->{'handle'}->create_stubs();
 453   return undef;
 454 }
 455
 456 sub packagespath {
 457   my ($self) = @_;
 458   return ($self->{'handle'}->lookup_str($solv::SOLVID_META, $solv::SUSETAGS_DATADIR) || 'suse') . '/';
 459 }
 460
 461 package Repo::unknown;
 462
 463 our @ISA = ('Repo::generic');
 464
 465 sub load {
 466   my ($self, $pool) = @_;
 467   print "unsupported repo '$self->{'alias'}': skipped\n";
 468   return 0;
 469 }
 470
 471 package Repo::system;
 472
 473 our @ISA = ('Repo::generic');
 474
 475 sub load {
 476   my ($self, $pool) = @_;
 477
 478   $self->{'handle'} = $pool->add_repo($self->{'alias'});
 479   $self->{'handle'}->{'appdata'} = $self;
 480   $pool->{'installed'} = $self->{'handle'};
 481   print "rpm database: ";
 482   $self->{'cookie'} = $self->calc_cookie_file('/var/lib/rpm/Packages');
 483   if ($self->usecachedrepo()) {
 484     print "cached\n";
 485     return 1;
 486   }
 487   print "reading\n";
 488   if (defined(&solv::Repo::add_products)) {
 489     $self->{'handle'}->add_products("/etc/products.d", $solv::Repo::REPO_NO_INTERNALIZE);
 490   }
 491   $self->{'handle'}->add_rpmdb(undef, $solv::Repo::REPO_REUSE_REPODATA);
 492   $self->writecachedrepo();
 493   return 1;
 494 }
 495
 496 package main;
 497
 498 sub load_stub {
 499   my ($repodata) = @_;
 500   my $repo = $repodata->{'repo'}->{'appdata'};
 501   return $repo ? $repo->load_ext($repodata) : 0;
 502 }
 503
 504 die("Usage: p5solv COMMAND [ARGS]\n") unless @ARGV;
 505 my $cmd = shift @ARGV;
 506 $cmd = 'list' if $cmd eq 'li';
 507 $cmd = 'install' if $cmd eq 'in';
 508 $cmd = 'erase' if $cmd eq 'rm';
 509 $cmd = 'verify' if $cmd eq 've';
 510 $cmd = 'search' if $cmd eq 'se';
 511
 512 my @repos;
 513 my @reposdirs;
 514 if (-d '/etc/zypp/repos.d') {
 515   @reposdirs = ( '/etc/zypp/repos.d' );
 516 } else {
 517   @reposdirs = ( '/etc/yum/repos.d' );
 518 }
 519 for my $reposdir (@reposdirs) {
 520   next unless -d $reposdir;
 521   next unless opendir(DIR, $reposdir);
 522   for my $reponame (sort(grep {/\.repo$/} readdir(DIR))) {
 523     my $cfg = new Config::IniFiles('-file' => "$reposdir/$reponame");
 524     for my $alias ($cfg->Sections()) {
 525       my $repoattr = {'alias' => $alias, 'enabled' => 0, 'priority' => 99, 'autorefresh' => 1, 'type' => 'rpm-md', 'metadata_expire' => 900};
 526       for my $p ($cfg->Parameters($alias)) {
 527         $repoattr->{$p} = $cfg->val($alias, $p);
 528       }
 529       my $repo;
 530       if ($repoattr->{'type'} eq 'rpm-md') {
 531         $repo = Repo::rpmmd->new($alias, 'repomd', $repoattr);
 532       } elsif ($repoattr->{'type'} eq 'yast2') {
 533         $repo = Repo::susetags->new($alias, 'susetags', $repoattr);
 534       } else {
 535         $repo = Repo::unknown->new($alias, 'unknown', $repoattr);
 536       }
 537       push @repos, $repo;
 538     }
 539   }
 540 }
 541
 542 my $pool = solv::Pool->new();
 543 $pool->setarch((POSIX::uname())[4]);
 544 $pool->set_loadcallback(\&load_stub);
 545
 546 my $sysrepo = Repo::system->new('@System', 'system');
 547 $sysrepo->load($pool);
 548 for my $repo (@repos) {
 549   $repo->load($pool) if $repo->{'enabled'};
 550 }
 551
 552 if ($cmd eq 'search') {
 553   my %matches;
 554   my $di = $pool->Dataiterator(0, $solv::SOLVABLE_NAME, $ARGV[0], $solv::Dataiterator::SEARCH_SUBSTRING | $solv::Dataiterator::SEARCH_NOCASE);
 555   for my $d (@$di) {
 556     $matches{$d->{'solvid'}} = 1;
 557   }
 558   for my $solvid (sort keys %matches) {
 559     my $s = $pool->{'solvables'}->[$solvid];
 560     print "- ".$s->str()." [$s->{'repo'}->{'name'}] ".$s->lookup_str($solv::SOLVABLE_SUMMARY)."\n";
 561   }
 562   exit(0);
 563 }
 564
 565 my @addedprovides = $pool->addfileprovides_queue();
 566 $pool->createwhatprovides();
 567
 568 my @jobs;
 569 for my $arg (@ARGV) {
 570   my $flags = $solv::Selection::SELECTION_NAME | $solv::Selection::SELECTION_PROVIDES | $solv::Selection::SELECTION_GLOB;
 571   if ($arg =~ /^\//) {
 572     $flags |= $solv::Selection::SELECTION_FILELIST;
 573     $flags |= $solv::Selection::SELECTION_INSTALLED_ONLY if $cmd eq 'erase';
 574   }
 575   my $sel = $pool->select($arg, $flags);
 576   if ($sel->isempty()) {
 577     $sel = $pool->select($arg, $flags | $solv::Selection::SELECTION_NOCASE);
 578     print "[ignoring case for '$arg']\n" unless $sel->isempty();
 579   }
 580   die("nothing matches '$arg'\n") if $sel->isempty();
 581   print "[using file list match for '$arg']\n" if $sel->flags() & $solv::Selection::SELECTION_FILELIST;
 582   print "[using capability match for '$arg']\n" if $sel->flags() & $solv::Selection::SELECTION_PROVIDES;
 583   push @jobs, $sel->jobs(0);
 584 }
 585 if (!@jobs && ($cmd eq 'up' || $cmd eq 'dup' || $cmd eq 'verify')) {
 586   my $sel = $pool->Selection();
 587   $sel->addsimple($solv::Job::SOLVER_SOLVABLE_ALL, 0);
 588   push @jobs, $sel->jobs(0);
 589 }
 590
 591 if ($cmd eq 'list' || $cmd eq 'info') {
 592   die("no package matched.\n") unless @jobs;
 593   for my $job (@jobs) {
 594     for my $s ($job->solvables()) {
 595       if ($cmd eq 'info') {
 596         printf "Name:        %s\n", $s->str();
 597         printf "Repo:        %s\n", $s->{'repo'}->{'name'};
 598         printf "Summary:     %s\n", $s->lookup_str($solv::SOLVABLE_SUMMARY);
 599         my $str = $s->lookup_str($solv::SOLVABLE_URL);
 600         printf "Url:         %s\n", $str if $str;
 601         $str = $s->lookup_str($solv::SOLVABLE_LICENSE);
 602         printf "License:     %s\n", $str if $str;
 603         printf "Description:\n%s\n", $s->lookup_str($solv::SOLVABLE_DESCRIPTION);
 604       } else {
 605         printf "  - %s [%s]\n", $s->str(), $s->{'repo'}->{'name'};
 606         printf "    %s\n", $s->lookup_str($solv::SOLVABLE_SUMMARY);
 607       }
 608     }
 609   }
 610   exit 0;
 611 }
 612
 613 if ($cmd eq 'install' || $cmd eq 'erase' || $cmd eq 'up' || $cmd eq 'dup' || $cmd eq 'verify') {
 614   die("no package matched.\n") unless @jobs;
 615   for my $job (@jobs) {
 616     if ($cmd eq 'up') {
 617       if ($job->{'how'} == $solv::Job::SOLVER_SOLVABLE_ALL || grep {$_->isinstalled()} $job->solvables()) {
 618         $job->{'how'} |= $solv::Job::SOLVER_UPDATE;
 619       } else {
 620         $job->{'how'} |= $solv::Job::SOLVER_INSTALL;
 621       }
 622     } elsif ($cmd eq 'install') {
 623         $job->{'how'} |= $solv::Job::SOLVER_INSTALL;
 624     } elsif ($cmd eq 'erase') {
 625         $job->{'how'} |= $solv::Job::SOLVER_ERASE;
 626     } elsif ($cmd eq 'dup') {
 627         $job->{'how'} |= $solv::Job::SOLVER_DISTUPGRADE;
 628     } elsif ($cmd eq 'verify') {
 629         $job->{'how'} |= $solv::Job::SOLVER_VERIFY;
 630     }
 631   }
 632   my $solver;
 633   while (1) {
 634     $solver = $pool->Solver();
 635     $solver->set_flag($solv::Solver::SOLVER_FLAG_SPLITPROVIDES, 1);
 636     $solver->set_flag($solv::Solver::SOLVER_FLAG_ALLOW_UNINSTALL, 1) if $cmd eq 'erase';
 637     my @problems = $solver->solve(\@jobs);
 638     last unless @problems;
 639     for my $problem (@problems) {
 640       print "Problem $problem->{'id'}/".@problems.":\n";
 641       my $r = $problem->findproblemrule();
 642       my $ri = $r->info();
 643       print $ri->problemstr()."\n";
 644       my @solutions = $problem->solutions();
 645       for my $solution (@solutions) {
 646         print "  Solution $solution->{'id'}:\n";
 647         for my $element ($solution->elements(1)) {
 648           print "  - ".$element->str()."\n";
 649         }
 650         print "\n";
 651       }
 652       my $sol;
 653       while (1) {
 654         print "Please choose a solution: ";
 655         $sol = <STDIN>;
 656         chomp $sol;
 657         last if $sol eq 's' || $sol eq 'q' || ($sol =~ /^\d+$/ && $sol >= 1 && $sol <= @solutions);
 658       }
 659       next if $sol eq 's';
 660       exit(1) if $sol eq 'q';
 661       my $solution = $solutions[$sol - 1];
 662       for my $element ($solution->elements()) {
 663         my $newjob = $element->Job();
 664         if ($element->{'type'} == $solv::Solver::SOLVER_SOLUTION_JOB) {
 665           $jobs[$element->{'jobidx'}] = $newjob;
 666         } else {
 667           push @jobs, $newjob if $newjob && !grep {$_ == $newjob} @jobs;
 668         }
 669       }
 670     }
 671   }
 672   my $trans = $solver->transaction();
 673   undef $solver;
 674   if ($trans->isempty()) {
 675     print "Nothing to do.\n";
 676     exit 0;
 677   }
 678   print "\nTransaction summary:\n\n";
 679   for my $c ($trans->classify()) {
 680     if ($c->{'type'} == $solv::Transaction::SOLVER_TRANSACTION_ERASE) {
 681       print "$c->{'count'} erased packages:\n";
 682     } elsif ($c->{'type'} == $solv::Transaction::SOLVER_TRANSACTION_INSTALL) {
 683       print "$c->{'count'} installed packages:\n";
 684     } elsif ($c->{'type'} == $solv::Transaction::SOLVER_TRANSACTION_REINSTALLED) {
 685       print "$c->{'count'} reinstalled packages:\n";
 686     } elsif ($c->{'type'} == $solv::Transaction::SOLVER_TRANSACTION_DOWNGRADED) {
 687       print "$c->{'count'} downgraded packages:\n";
 688     } elsif ($c->{'type'} == $solv::Transaction::SOLVER_TRANSACTION_CHANGED) {
 689       print "$c->{'count'} changed packages:\n";
 690     } elsif ($c->{'type'} == $solv::Transaction::SOLVER_TRANSACTION_UPGRADED) {
 691       print "$c->{'count'} upgraded packages:\n";
 692     } elsif ($c->{'type'} == $solv::Transaction::SOLVER_TRANSACTION_VENDORCHANGE) {
 693       printf "$c->{'count'} vendor changes from '%s' to '%s':\n", $pool->id2str($c->{'fromid'}), $pool->id2str($c->{'toid'});
 694     } elsif ($c->{'type'} == $solv::Transaction::SOLVER_TRANSACTION_ARCHCHANGE) {
 695       printf "$c->{'count'} arch changes from '%s' to '%s':\n", $pool->id2str($c->{'fromid'}), $pool->id2str($c->{'toid'});
 696     } else {
 697       next;
 698     }
 699     for my $p ($c->solvables()) {
 700       if ($c->{'type'} == $solv::Transaction::SOLVER_TRANSACTION_UPGRADED || $c->{'type'} == $solv::Transaction::SOLVER_TRANSACTION_DOWNGRADED) {
 701         my $other = $trans->othersolvable($p);
 702         printf "  - %s -> %s\n", $p->str(), $other->str();
 703       } else {
 704         printf "  - %s\n", $p->str();
 705       }
 706     }
 707     print "\n";
 708   }
 709   printf "install size change: %d K\n\n", $trans->calc_installsizechange();
 710   while (1) {
 711     print("OK to continue (y/n)? ");
 712     my $yn = <STDIN>;
 713     chomp $yn;
 714     last if $yn eq 'y';
 715     exit(1) if $yn eq 'n';
 716   }
 717   my @newpkgs = $trans->newpackages();
 718   my %newpkgsfps;
 719   if (@newpkgs) {
 720     my $downloadsize = 0;
 721     $downloadsize += $_->lookup_num($solv::SOLVABLE_DOWNLOADSIZE) for @newpkgs;
 722     printf "Downloading %d packages, %d K\n", scalar(@newpkgs), $downloadsize;
 723     for my $p (@newpkgs) {
 724       my $repo = $p->{'repo'}->{'appdata'};
 725       my ($location, $medianr) = $p->lookup_location();
 726       next unless $location;
 727       $location = $repo->packagespath() . $location;
 728       my $chksum = $p->lookup_checksum($solv::SOLVABLE_CHECKSUM);
 729       my $f = $repo->download($location, 0, $chksum);
 730       die("\n$repo->{'alias'}: $location not found in repository\n") unless $f;
 731       $newpkgsfps{$p->{'id'}} = $f;
 732       print ".";
 733       STDOUT->flush();
 734     }
 735     print "\n";
 736   }
 737   print "Committing transaction:\n\n";
 738   $trans->order(0);
 739   for my $p ($trans->steps()) {
 740     my $steptype = $trans->steptype($p, $solv::Transaction::SOLVER_TRANSACTION_RPM_ONLY);
 741     if ($steptype == $solv::Transaction::SOLVER_TRANSACTION_ERASE) {
 742       print "erase ".$p->str()."\n";
 743       next unless $p->lookup_num($solv::RPM_RPMDBID);
 744       my $evr = $p->{'evr'};
 745       $evr =~ s/^[0-9]+://;     # strip epoch
 746       system('rpm', '-e', '--nodeps', '--nodigest', '--nosignature', "$p->{'name'}-$evr.$p->{'arch'}") && die("rpm failed: $?\n");
 747     } elsif ($steptype == $solv::Transaction::SOLVER_TRANSACTION_INSTALL || $steptype == $solv::Transaction::SOLVER_TRANSACTION_MULTIINSTALL) {
 748       print "install ".$p->str()."\n";
 749       my $f = $newpkgsfps{$p->{'id'}};
 750       my $mode = $steptype == $solv::Transaction::SOLVER_TRANSACTION_INSTALL ? '-U' : '-i';
 751       system('rpm', $mode, '--force', '--nodeps', '--nodigest', '--nosignature', "/dev/fd/".solv::xfileno($f)) && die("rpm failed: $?\n");
 752       solv::xfclose($f);
 753       delete $newpkgsfps{$p->{'id'}};
 754     }
 755   }
 756 }
 757
 758 exit 0;