examples/demos/tweetsearch/tweetsearch.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42 import "content"
  43
  44 Rectangle {
  45     id: main
  46     width: 320
  47     height: 480
  48
  49     property string searchTerms: ""
  50     property int inAnimDur: 250
  51     property int counter: 0
  52     property alias isLoading: tweetsModel.isLoading
  53     property var idx
  54     property var ids
  55
  56     Component.onCompleted: ids = new Array()
  57
  58     function idInModel(id)
  59     {
  60         for (var j = 0; j < ids.length; j++)
  61             if (ids[j] === id)
  62                 return 1
  63         return 0
  64     }
  65
  66     TweetsModel {
  67         id: tweetsModel
  68         onIsLoaded: {
  69             console.debug("Reload")
  70             idx = new Array()
  71             for (var i = 0; i < tweetsModel.model.count; i++) {
  72                 var id = tweetsModel.model.get(i).id
  73                 if (!idInModel(id))
  74                     idx.push(i)
  75             }
  76             console.debug(idx.length + " new tweets")
  77             main.counter = idx.length
  78         }
  79     }
  80
  81     Timer {
  82         id: timer
  83         interval: 500; running: main.counter; repeat: true
  84         onTriggered: {
  85             main.counter--;
  86             var id = tweetsModel.model.get(idx[main.counter]).id
  87             mainListView.add( { "statusText": tweetsModel.model.get(main.counter).content,
  88                                  "name": tweetsModel.model.get(main.counter).name,
  89                                  "userImage": tweetsModel.model.get(main.counter).image,
  90                                  "source": tweetsModel.model.get(main.counter).source,
  91                                  "id": id,
  92                                  "uri": tweetsModel.model.get(main.counter).uri,
  93                                  "published": tweetsModel.model.get(main.counter).published } );
  94             ids.push(id)
  95         }
  96     }
  97
  98     ListView {
  99         id: mainListView
 100         anchors.fill: parent
 101         delegate: TweetDelegate { }
 102         model: ListModel { id: finalModel }
 103
 104         add: Transition {
 105             NumberAnimation { property: "hm"; from: 0; to: 1.0; duration: 300; easing.type: Easing.OutQuad }
 106             PropertyAction { property: "appear"; value: 250 }
 107         }
 108
 109         onDragEnded: if (header.refresh) { tweetsModel.model.reload() }
 110
 111         ListHeader {
 112             id: header
 113             y: -mainListView.contentY - height
 114         }
 115
 116         footer: ListFooter { }
 117
 118         function clear() {
 119             ids = new Array()
 120             model.clear()
 121         }
 122
 123         function add(obj) {
 124             model.insert(0, obj)
 125         }
 126
 127         signal autoSearch(string type, string str) // To communicate with Footer instance
 128     }
 129 }