examples/demos/samegame/content/BoomBlock.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42 import QtQuick.Particles 2.0
  43
  44 Item {
  45     id: block
  46     property bool dying: false
  47     property bool spawned: false
  48     property int type: 0
  49     property ParticleSystem particleSystem
  50
  51     Behavior on x {
  52         enabled: spawned;
  53         SpringAnimation{ spring: 2; damping: 0.2 }
  54     }
  55     Behavior on y {
  56         SpringAnimation{ spring: 2; damping: 0.2 }
  57     }
  58
  59     Image {
  60         id: img
  61         source: {
  62             if(type == 0){
  63                 "pics/redStone.png";
  64             } else if(type == 1) {
  65                 "pics/blueStone.png";
  66             } else {
  67                 "pics/greenStone.png";
  68             }
  69         }
  70         opacity: 0
  71         Behavior on opacity { NumberAnimation { duration: 200 } }
  72         anchors.fill: parent
  73     }
  74     Emitter {
  75         id: particles
  76         system: particleSystem
  77         group: {
  78             if(type == 0){
  79                 "red";
  80             } else if (type == 1) {
  81                 "blue";
  82             } else {
  83                 "green";
  84             }
  85         }
  86         anchors.fill: parent
  87
  88         velocity: TargetDirection{targetX: block.width/2; targetY: block.height/2; magnitude: -60; magnitudeVariation: 60}
  89         shape: EllipseShape{fill:true}
  90         enabled: false;
  91         lifeSpan: 700; lifeSpanVariation: 100
  92         emitRate: 1000
  93         maximumEmitted: 100 //only fires 0.1s bursts (still 2x old number)
  94         size: 28
  95         endSize: 14
  96     }
  97
  98     states: [
  99         State {
 100             name: "AliveState"; when: spawned == true && dying == false
 101             PropertyChanges { target: img; opacity: 1 }
 102         },
 103
 104         State {
 105             name: "DeathState"; when: dying == true
 106             StateChangeScript { script: {particleSystem.paused = false; particles.pulse(100);} }
 107             PropertyChanges { target: img; opacity: 0 }
 108             StateChangeScript { script: block.destroy(1000); }
 109         }
 110     ]
 111 }