examples/demos/maroon/content/towers/Factory.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Digia Plc and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/legal
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Digia Plc and its Subsidiary(-ies) nor the names
  21 **     of its contributors may be used to endorse or promote products derived
  22 **     from this software without specific prior written permission.
  23 **
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42 import "../logic.js" as Logic
  43 import ".."
  44
  45 TowerBase {
  46     id: container
  47     rof: 160
  48     income: 5
  49     SpriteSequence {
  50         id: sprite
  51         width: 64
  52         height: 64
  53         interpolate: false
  54         goalSprite: ""
  55
  56         Sprite {
  57             name: "idle"
  58             source: "../gfx/factory-idle.png"
  59             frameCount: 4
  60             frameDuration: 200
  61         }
  62
  63         Sprite {
  64             name: "action"
  65             source: "../gfx/factory-action.png"
  66             frameCount: 4
  67             frameDuration: 90
  68             to: { "idle" : 1 }
  69         }
  70
  71         SequentialAnimation on x {
  72             loops: Animation.Infinite
  73             NumberAnimation { from: x; to: x + 4; duration: 900; easing.type: Easing.InOutQuad }
  74             NumberAnimation { from: x + 4; to: x; duration: 900; easing.type: Easing.InOutQuad }
  75         }
  76         SequentialAnimation on y {
  77             loops: Animation.Infinite
  78             NumberAnimation { from: y; to: y - 4; duration: 900; easing.type: Easing.InOutQuad }
  79             NumberAnimation { from: y - 4; to: y; duration: 900; easing.type: Easing.InOutQuad }
  80         }
  81     }
  82
  83     SoundEffect {
  84         id: actionSound
  85         source: "../audio/factory-action.wav"
  86     }
  87
  88     function fire() {
  89         actionSound.play()
  90         sprite.jumpTo("action")
  91         coinLaunch.start()
  92     }
  93
  94     function spawn() {
  95         coin.target = Logic.gameState.mapToItem(container, 240, -32)
  96     }
  97
  98     Image {
  99         id: coin
 100         property var target: { "x" : 0, "y" : 0 }
 101         source: "../gfx/currency.png"
 102         visible: false
 103     }
 104
 105     SequentialAnimation {
 106         id: coinLaunch
 107         PropertyAction { target: coin; property: "visible"; value: true }
 108         ParallelAnimation {
 109             NumberAnimation { target: coin; property: "x"; from: 16; to: coin.target.x }
 110             NumberAnimation { target: coin; property: "y"; from: 16; to: coin.target.y }
 111         }
 112         PropertyAction { target: coin; property: "visible"; value: false }
 113     }
 114 }