examples/demos/calqlatr/calqlatr.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Digia Plc and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/legal
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Digia Plc and its Subsidiary(-ies) nor the names
  21 **     of its contributors may be used to endorse or promote products derived
  22 **     from this software without specific prior written permission.
  23 **
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42 import "content"
  43 import "content/calculator.js" as CalcEngine
  44
  45
  46 Rectangle {
  47     id: window
  48     width: 320
  49     height: 480
  50     focus: true
  51     color: "#272822"
  52
  53     onWidthChanged: controller.reload()
  54
  55     function operatorPressed(operator) { CalcEngine.operatorPressed(operator) }
  56     function digitPressed(digit) { CalcEngine.digitPressed(digit) }
  57
  58     Item {
  59         id: pad
  60         width: window.width * 0.58
  61         NumberPad { y: 10; anchors.horizontalCenter: parent.horizontalCenter }
  62     }
  63
  64     AnimationController {
  65         id: controller
  66         animation: ParallelAnimation {
  67             id: anim
  68             NumberAnimation { target: display; property: "x"; duration: 400; from: -16; to: window.width - display.width; easing.type: Easing.InOutQuad }
  69             NumberAnimation { target: pad; property: "x"; duration: 400; from: window.width - pad.width; to: 0; easing.type: Easing.InOutQuad }
  70             SequentialAnimation {
  71                 NumberAnimation { target: pad; property: "scale"; duration: 200; from: 1; to: 0.97; easing.type: Easing.InOutQuad }
  72                 NumberAnimation { target: pad; property: "scale"; duration: 200; from: 0.97; to: 1; easing.type: Easing.InOutQuad }
  73             }
  74         }
  75     }
  76
  77     Display {
  78         id: display
  79         x: -16
  80         width: window.width * 0.42
  81         height: parent.height
  82
  83         MouseArea {
  84             property real startX: 0
  85             property real oldP: 0
  86             property bool rewind: false
  87
  88             anchors.fill: parent
  89             onPositionChanged: {
  90                 var reverse = startX > window.width / 2
  91                 var mx = mapToItem(window, mouse.x).x
  92                 var p = Math.abs((mx - startX) / (window.width - display.width))
  93                 if (p < oldP)
  94                     rewind = reverse ? false : true
  95                 else
  96                     rewind = reverse ? true : false
  97                 controller.progress = reverse ? 1 - p : p
  98                 oldP = p
  99             }
 100             onPressed: startX = mapToItem(window, mouse.x).x
 101             onReleased: {
 102                 if (rewind)
 103                     controller.completeToBeginning()
 104                 else
 105                     controller.completeToEnd()
 106             }
 107         }
 108     }
 109
 110 }