examples/declarative/ui-components/slideswitch/content/Switch.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 //![0]
  42 import QtQuick 2.0
  43
  44 Item {
  45     id: toggleswitch
  46     width: background.width; height: background.height
  47
  48 //![1]
  49     property bool on: false
  50 //![1]
  51
  52 //![2]
  53     function toggle() {
  54         if (toggleswitch.state == "on")
  55             toggleswitch.state = "off";
  56         else
  57             toggleswitch.state = "on";
  58     }
  59 //![2]
  60
  61 //![3]
  62     function releaseSwitch() {
  63         if (knob.x == 1) {
  64             if (toggleswitch.state == "off") return;
  65         }
  66         if (knob.x == 78) {
  67             if (toggleswitch.state == "on") return;
  68         }
  69         toggle();
  70     }
  71 //![3]
  72
  73 //![4]
  74     Image {
  75         id: background
  76         source: "background.svg"
  77         MouseArea { anchors.fill: parent; onClicked: toggle() }
  78     }
  79 //![4]
  80
  81 //![5]
  82     Image {
  83         id: knob
  84         x: 1; y: 2
  85         source: "knob.svg"
  86
  87         MouseArea {
  88             anchors.fill: parent
  89             drag.target: knob; drag.axis: Drag.XAxis; drag.minimumX: 1; drag.maximumX: 78
  90             onClicked: toggle()
  91             onReleased: releaseSwitch()
  92         }
  93     }
  94 //![5]
  95
  96 //![6]
  97     states: [
  98         State {
  99             name: "on"
 100             PropertyChanges { target: knob; x: 78 }
 101             PropertyChanges { target: toggleswitch; on: true }
 102         },
 103         State {
 104             name: "off"
 105             PropertyChanges { target: knob; x: 1 }
 106             PropertyChanges { target: toggleswitch; on: false }
 107         }
 108     ]
 109 //![6]
 110
 111 //![7]
 112     transitions: Transition {
 113         NumberAnimation { properties: "x"; easing.type: Easing.InOutQuad; duration: 200 }
 114     }
 115 //![7]
 116 }
 117 //![0]