examples/declarative/ui-components/searchbox/SearchBox.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: http://www.qt-project.org/
   6 **
   7 ** This file is part of the examples of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42
  43 FocusScope {
  44     id: focusScope
  45     width: 250; height: 28
  46
  47     BorderImage {
  48         source: "images/lineedit-bg.png"
  49         width: parent.width; height: parent.height
  50         border { left: 4; top: 4; right: 4; bottom: 4 }
  51     }
  52
  53     BorderImage {
  54         source: "images/lineedit-bg-focus.png"
  55         width: parent.width; height: parent.height
  56         border { left: 4; top: 4; right: 4; bottom: 4 }
  57         visible: parent.activeFocus ? true : false
  58     }
  59
  60     Text {
  61         id: typeSomething
  62         anchors.fill: parent; anchors.leftMargin: 8
  63         verticalAlignment: Text.AlignVCenter
  64         text: "Type something..."
  65         color: "gray"
  66         font.italic: true
  67     }
  68
  69     MouseArea {
  70         anchors.fill: parent
  71         onClicked: { focusScope.focus = true; textInput.openSoftwareInputPanel(); }
  72     }
  73
  74     TextInput {
  75         id: textInput
  76         anchors { left: parent.left; leftMargin: 8; right: clear.left; rightMargin: 8; verticalCenter: parent.verticalCenter }
  77         focus: true
  78         selectByMouse: true
  79     }
  80
  81     Image {
  82         id: clear
  83         anchors { right: parent.right; rightMargin: 8; verticalCenter: parent.verticalCenter }
  84         source: "images/clear.png"
  85         opacity: 0
  86
  87         MouseArea {
  88             anchors.fill: parent
  89             onClicked: { textInput.text = ''; focusScope.focus = true; textInput.openSoftwareInputPanel(); }
  90         }
  91     }
  92
  93     states: State {
  94         name: "hasText"; when: textInput.text != ''
  95         PropertyChanges { target: typeSomething; opacity: 0 }
  96         PropertyChanges { target: clear; opacity: 1 }
  97     }
  98
  99     transitions: [
 100         Transition {
 101             from: ""; to: "hasText"
 102             NumberAnimation { exclude: typeSomething; properties: "opacity" }
 103         },
 104         Transition {
 105             from: "hasText"; to: ""
 106             NumberAnimation { properties: "opacity" }
 107         }
 108     ]
 109 }