examples/declarative/tutorials/samegame/samegame4/content/BoomBlock.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the examples of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 1.0
  42 import Qt.labs.particles 1.0
  43
  44 Item {
  45     id: block
  46
  47     property int type: 0
  48     property bool dying: false
  49
  50     //![1]
  51     property bool spawned: false
  52
  53     Behavior on x {
  54         enabled: spawned;
  55         SpringAnimation{ spring: 2; damping: 0.2 }
  56     }
  57     Behavior on y {
  58         SpringAnimation{ spring: 2; damping: 0.2 }
  59     }
  60     //![1]
  61
  62     //![2]
  63     Image {
  64         id: img
  65
  66         anchors.fill: parent
  67         source: {
  68             if (type == 0)
  69                 return "../../shared/pics/redStone.png";
  70             else if (type == 1)
  71                 return "../../shared/pics/blueStone.png";
  72             else
  73                 return "../../shared/pics/greenStone.png";
  74         }
  75         opacity: 0
  76
  77         Behavior on opacity {
  78             NumberAnimation { properties:"opacity"; duration: 200 }
  79         }
  80     }
  81     //![2]
  82
  83     //![3]
  84     Particles {
  85         id: particles
  86
  87         width: 1; height: 1
  88         anchors.centerIn: parent
  89
  90         emissionRate: 0
  91         lifeSpan: 700; lifeSpanDeviation: 600
  92         angle: 0; angleDeviation: 360;
  93         velocity: 100; velocityDeviation: 30
  94         source: {
  95             if (type == 0)
  96                 return "../../shared/pics/redStar.png";
  97             else if (type == 1)
  98                 return "../../shared/pics/blueStar.png";
  99             else
 100                 return "../../shared/pics/greenStar.png";
 101         }
 102     }
 103     //![3]
 104
 105     //![4]
 106     states: [
 107         State {
 108             name: "AliveState"
 109             when: spawned == true && dying == false
 110             PropertyChanges { target: img; opacity: 1 }
 111         },
 112
 113         State {
 114             name: "DeathState"
 115             when: dying == true
 116             StateChangeScript { script: particles.burst(50); }
 117             PropertyChanges { target: img; opacity: 0 }
 118             StateChangeScript { script: block.destroy(1000); }
 119         }
 120     ]
 121     //![4]
 122 }