examples/declarative/tutorials/dynamicview/dynamicview4/dynamicview.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42
  43 Rectangle {
  44     id: root
  45
  46     width: 300; height: 400
  47
  48     Component {
  49         id: dragDelegate
  50
  51         MouseArea {
  52             id: dragArea
  53
  54             property bool held: false
  55
  56             anchors { left: parent.left; right: parent.right }
  57             height: content.height
  58
  59             enabled: visualModel.sortOrder == visualModel.lessThan.length
  60
  61             drag.target: held ? content : undefined
  62             drag.axis: Drag.YAxis
  63
  64             onPressAndHold: held = true
  65             onReleased: held = false
  66
  67             Rectangle {
  68                 id: content
  69
  70                 anchors {
  71                     horizontalCenter: parent.horizontalCenter
  72                     verticalCenter: parent.verticalCenter
  73                 }
  74                 width: dragArea.width; height: column.implicitHeight + 4
  75
  76                 border.width: 1
  77                 border.color: "lightsteelblue"
  78
  79                 color: dragArea.held ? "lightsteelblue" : "white"
  80                 Behavior on color { ColorAnimation { duration: 100 } }
  81
  82                 radius: 2
  83
  84                 Drag.active: dragArea.held
  85                 Drag.source: dragArea
  86                 Drag.hotSpot.x: width / 2
  87                 Drag.hotSpot.y: height / 2
  88
  89                 states: State {
  90                     when: dragArea.held
  91
  92                     ParentChange { target: content; parent: root }
  93                     AnchorChanges {
  94                         target: content
  95                         anchors { horizontalCenter: undefined; verticalCenter: undefined }
  96                     }
  97                 }
  98
  99                 Column {
 100                     id: column
 101                     anchors { fill: parent; margins: 2 }
 102
 103                     Text { text: 'Name: ' + name }
 104                     Text { text: 'Type: ' + type }
 105                     Text { text: 'Age: ' + age }
 106                     Text { text: 'Size: ' + size }
 107                 }
 108             }
 109
 110             DropArea {
 111                 anchors { fill: parent; margins: 10 }
 112
 113                 onEntered: {
 114                     visualModel.items.move(
 115                             drag.source.VisualDataModel.itemsIndex,
 116                             dragArea.VisualDataModel.itemsIndex)
 117                 }
 118             }
 119         }
 120     }
 121 //![0]
 122     VisualDataModel {
 123         id: visualModel
 124 //![4]
 125         property var lessThan: [
 126             function(left, right) { return left.name < right.name },
 127             function(left, right) { return left.type < right.type },
 128             function(left, right) { return left.age < right.age },
 129             function(left, right) {
 130                 if (left.size == "Small")
 131                     return true
 132                 else if (right.size == "Small")
 133                     return false
 134                 else if (left.size == "Medium")
 135                     return true
 136                 else
 137                     return false
 138             }
 139         ]
 140 //![4]
 141 //![6]
 142
 143         property int sortOrder: orderSelector.selectedIndex
 144         onSortOrderChanged: items.setGroups(0, items.count, "unsorted")
 145
 146 //![6]
 147 //![3]
 148         function insertPosition(lessThan, item) {
 149             var lower = 0
 150             var upper = items.count
 151             while (lower < upper) {
 152                 var middle = Math.floor(lower + (upper - lower) / 2)
 153                 var result = lessThan(item.model, items.get(middle).model);
 154                 if (result) {
 155                     upper = middle
 156                 } else {
 157                     lower = middle + 1
 158                 }
 159             }
 160             return lower
 161         }
 162
 163         function sort(lessThan) {
 164             while (unsortedItems.count > 0) {
 165                 var item = unsortedItems.get(0)
 166                 var index = insertPosition(lessThan, item)
 167
 168                 item.groups = "items"
 169                 items.move(item.itemsIndex, index)
 170             }
 171         }
 172 //![3]
 173
 174 //![1]
 175         items.includeByDefault: false
 176 //![5]
 177         groups: VisualDataGroup {
 178             id: unsortedItems
 179             name: "unsorted"
 180
 181             includeByDefault: true
 182 //![1]
 183             onChanged: {
 184                 if (visualModel.sortOrder == visualModel.lessThan.length)
 185                     setGroups(0, count, "items")
 186                 else
 187                     visualModel.sort(visualModel.lessThan[visualModel.sortOrder])
 188             }
 189 //![2]
 190         }
 191 //![2]
 192 //![5]
 193         model: PetsModel {}
 194         delegate: dragDelegate
 195     }
 196 //![0]
 197     ListView {
 198         id: view
 199
 200         anchors {
 201             left: parent.left; top: parent.top; right: parent.right; bottom: orderSelector.top;
 202             margins: 2
 203         }
 204
 205         model: visualModel
 206
 207         spacing: 4
 208         cacheBuffer: 50
 209     }
 210
 211     ListSelector {
 212         id: orderSelector
 213
 214         anchors { left: parent.left; right: parent.right; bottom: parent.bottom; margins: 2 }
 215
 216         label: "Sort By"
 217         list: [ "Name", "Type", "Age", "Size", "Custom" ]
 218     }
 219 }