examples/declarative/tutorials/dynamicview/dynamicview3/dynamicview.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: http://www.qt-project.org/
   6 **
   7 ** This file is part of the examples of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42 //![0]
  43 Rectangle {
  44     id: root
  45
  46     width: 300; height: 400
  47
  48     Component {
  49         id: dragDelegate
  50
  51         MouseArea {
  52             id: dragArea
  53
  54             property bool held: false
  55
  56             anchors { left: parent.left; right: parent.right }
  57             height: content.height
  58
  59             drag.target: held ? content : undefined
  60             drag.axis: Drag.YAxis
  61
  62             onPressAndHold: held = true
  63             onReleased: held = false
  64
  65             Rectangle {
  66                 id: content
  67 //![0]
  68                 anchors {
  69                     horizontalCenter: parent.horizontalCenter
  70                     verticalCenter: parent.verticalCenter
  71                 }
  72                 width: dragArea.width; height: column.implicitHeight + 4
  73
  74                 border.width: 1
  75                 border.color: "lightsteelblue"
  76
  77                 color: dragArea.held ? "lightsteelblue" : "white"
  78                 Behavior on color { ColorAnimation { duration: 100 } }
  79
  80                 radius: 2
  81 //![1]
  82                 Drag.active: dragArea.held
  83                 Drag.source: dragArea
  84                 Drag.hotSpot.x: width / 2
  85                 Drag.hotSpot.y: height / 2
  86 //![1]
  87                 states: State {
  88                     when: dragArea.held
  89
  90                     ParentChange { target: content; parent: root }
  91                     AnchorChanges {
  92                         target: content
  93                         anchors { horizontalCenter: undefined; verticalCenter: undefined }
  94                     }
  95                 }
  96
  97                 Column {
  98                     id: column
  99                     anchors { fill: parent; margins: 2 }
 100
 101                     Text { text: 'Name: ' + name }
 102                     Text { text: 'Type: ' + type }
 103                     Text { text: 'Age: ' + age }
 104                     Text { text: 'Size: ' + size }
 105                 }
 106 //![2]
 107             }
 108 //![3]
 109             DropArea {
 110                 anchors { fill: parent; margins: 10 }
 111
 112                 onEntered: {
 113                     visualModel.items.move(
 114                             drag.source.VisualDataModel.itemsIndex,
 115                             dragArea.VisualDataModel.itemsIndex)
 116                 }
 117             }
 118 //![3]
 119         }
 120     }
 121 //![2]
 122 //![4]
 123     VisualDataModel {
 124         id: visualModel
 125
 126         model: PetsModel {}
 127         delegate: dragDelegate
 128     }
 129
 130     ListView {
 131         id: view
 132
 133         anchors { fill: parent; margins: 2 }
 134
 135         model: visualModel
 136
 137         spacing: 4
 138         cacheBuffer: 50
 139     }
 140 //![4]
 141 //![5]
 142 }
 143 //![5]