examples/declarative/toys/tvtennis/tvtennis.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42
  43 Rectangle {
  44     id: page
  45     width: 640; height: 480
  46     color: "Black"
  47
  48     // Make a ball to bounce
  49     Rectangle {
  50         id: ball
  51
  52         // Add a property for the target y coordinate
  53         property variant direction : "right"
  54
  55         x: 20; width: 20; height: 20; z: 1
  56         color: "Lime"
  57
  58         // Move the ball to the right and back to the left repeatedly
  59         SequentialAnimation on x {
  60             loops: Animation.Infinite
  61             NumberAnimation { to: page.width - 40; duration: 2000 }
  62             PropertyAction { target: ball; property: "direction"; value: "left" }
  63             NumberAnimation { to: 20; duration: 2000 }
  64             PropertyAction { target: ball; property: "direction"; value: "right" }
  65         }
  66
  67         // Make y move with a velocity of 200
  68         Behavior on y { SpringAnimation{ velocity: 200; }
  69         }
  70
  71         Component.onCompleted: y = page.height-10; // start the ball motion
  72
  73         // Detect the ball hitting the top or bottom of the view and bounce it
  74         onYChanged: {
  75             if (y <= 0) {
  76                 y = page.height - 20;
  77             } else if (y >= page.height - 20) {
  78                 y = 0;
  79             }
  80         }
  81     }
  82
  83     // Place bats to the left and right of the view, following the y
  84     // coordinates of the ball.
  85     Rectangle {
  86         id: leftBat
  87         color: "Lime"
  88         x: 2; width: 20; height: 90
  89         y: ball.direction == 'left' ? ball.y - 45 : page.height/2 -45;
  90         Behavior on y { SpringAnimation{ velocity: 300 } }
  91     }
  92     Rectangle {
  93         id: rightBat
  94         color: "Lime"
  95         x: page.width - 22; width: 20; height: 90
  96         y: ball.direction == 'right' ? ball.y - 45 : page.height/2 -45;
  97         Behavior on y { SpringAnimation{ velocity: 300 } }
  98     }
  99
 100     // The rest, to make it look realistic, if neither ever scores...
 101     Rectangle { color: "Lime"; x: page.width/2-80; y: 0; width: 40; height: 60 }
 102     Rectangle { color: "Black"; x: page.width/2-70; y: 10; width: 20; height: 40 }
 103     Rectangle { color: "Lime"; x: page.width/2+40; y: 0; width: 40; height: 60 }
 104     Rectangle { color: "Black"; x: page.width/2+50; y: 10; width: 20; height: 40 }
 105     Repeater {
 106         model: page.height / 20
 107         Rectangle { color: "Lime"; x: page.width/2-5; y: index * 20; width: 10; height: 10 }
 108     }
 109 }