examples/declarative/toys/corkboards/Day.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the examples of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 1.0
  42
  43 Component {
  44     Item {
  45         property variant stickies
  46
  47         id: page
  48         width: ListView.view.width+40; height: ListView.view.height
  49
  50
  51         Image {
  52             source: "cork.jpg"
  53             width: page.ListView.view.width
  54             height: page.ListView.view.height
  55             fillMode: Image.PreserveAspectCrop
  56             clip: true
  57         }
  58
  59         MouseArea {
  60             anchors.fill: parent
  61             onClicked: page.focus = false;
  62         }
  63
  64         Text {
  65             text: name; x: 15; y: 8; height: 40; width: 370
  66             font.pixelSize: 18; font.bold: true; color: "white"
  67             style: Text.Outline; styleColor: "black"
  68         }
  69
  70         Repeater {
  71             model: notes
  72             Item {
  73                 id: stickyPage
  74
  75                 property int randomX: Math.random() * (page.ListView.view.width-0.5*stickyImage.width) +100
  76                 property int randomY: Math.random() * (page.ListView.view.height-0.5*stickyImage.height) +50
  77
  78                 x: randomX; y: randomY
  79
  80                 rotation: -flickable.horizontalVelocity / 100;
  81                 Behavior on rotation {
  82                     SpringAnimation { spring: 2.0; damping: 0.15 }
  83                 }
  84
  85                 Item {
  86                     id: sticky
  87                     scale: 0.7
  88
  89                     Image {
  90                         id: stickyImage
  91                         x: 8 + -width * 0.6 / 2; y: -20
  92                         source: "note-yellow.png"
  93                         scale: 0.6; transformOrigin: Item.TopLeft
  94                         smooth: true
  95                     }
  96
  97                     TextEdit {
  98                         id: myText
  99                         x: -104; y: 36; width: 215; height: 200
 100                         smooth: true
 101                         font.pixelSize: 24
 102                         readOnly: false
 103                         rotation: -8
 104                         text: noteText
 105                     }
 106
 107                     Item {
 108                         x: stickyImage.x; y: -20
 109                         width: stickyImage.width * stickyImage.scale
 110                         height: stickyImage.height * stickyImage.scale
 111
 112                         MouseArea {
 113                             id: mouse
 114                             anchors.fill: parent
 115                             drag.target: stickyPage
 116                             drag.axis: Drag.XandYAxis
 117                             drag.minimumY: 0
 118                             drag.maximumY: page.height - 80
 119                             drag.minimumX: 100
 120                             drag.maximumX: page.width - 140
 121                             onClicked: { myText.focus = true; myText.openSoftwareInputPanel(); }
 122                         }
 123                     }
 124                 }
 125
 126                 Image {
 127                     x: -width / 2; y: -height * 0.5 / 2
 128                     source: "tack.png"
 129                     scale: 0.7; transformOrigin: Item.TopLeft
 130                 }
 131
 132                 states: State {
 133                     name: "pressed"
 134                     when: mouse.pressed
 135                     PropertyChanges { target: sticky; rotation: 8; scale: 1 }
 136                     PropertyChanges { target: page; z: 8 }
 137                 }
 138
 139                 transitions: Transition {
 140                     NumberAnimation { properties: "rotation,scale"; duration: 200 }
 141                 }
 142             }
 143         }
 144     }
 145 }
 146
 147
 148
 149
 150
 151
 152
 153