examples/declarative/toys/clocks/content/Clock.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the examples of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 1.0
  42
  43 Item {
  44     id: clock
  45     width: 200; height: 230
  46
  47     property alias city: cityLabel.text
  48     property int hours
  49     property int minutes
  50     property int seconds
  51     property real shift
  52     property bool night: false
  53
  54     function timeChanged() {
  55         var date = new Date;
  56         hours = shift ? date.getUTCHours() + Math.floor(clock.shift) : date.getHours()
  57         night = ( hours < 7 || hours > 19 )
  58         minutes = shift ? date.getUTCMinutes() + ((clock.shift % 1) * 60) : date.getMinutes()
  59         seconds = date.getUTCSeconds();
  60     }
  61
  62     Timer {
  63         interval: 100; running: true; repeat: true;
  64         onTriggered: clock.timeChanged()
  65     }
  66
  67     Image { id: background; source: "clock.png"; visible: clock.night == false }
  68     Image { source: "clock-night.png"; visible: clock.night == true }
  69
  70
  71     Image {
  72         x: 92.5; y: 27
  73         source: "hour.png"
  74         smooth: true
  75         transform: Rotation {
  76             id: hourRotation
  77             origin.x: 7.5; origin.y: 73;
  78             angle: (clock.hours * 30) + (clock.minutes * 0.5)
  79             Behavior on angle {
  80                 SpringAnimation { spring: 2; damping: 0.2; modulus: 360 }
  81             }
  82         }
  83     }
  84
  85     Image {
  86         x: 93.5; y: 17
  87         source: "minute.png"
  88         smooth: true
  89         transform: Rotation {
  90             id: minuteRotation
  91             origin.x: 6.5; origin.y: 83;
  92             angle: clock.minutes * 6
  93             Behavior on angle {
  94                 SpringAnimation { spring: 2; damping: 0.2; modulus: 360 }
  95             }
  96         }
  97     }
  98
  99     Image {
 100         x: 97.5; y: 20
 101         source: "second.png"
 102         smooth: true
 103         transform: Rotation {
 104             id: secondRotation
 105             origin.x: 2.5; origin.y: 80;
 106             angle: clock.seconds * 6
 107             Behavior on angle {
 108                 SpringAnimation { spring: 2; damping: 0.2; modulus: 360 }
 109             }
 110         }
 111     }
 112
 113     Image {
 114         anchors.centerIn: background; source: "center.png"
 115     }
 116
 117     Text {
 118         id: cityLabel
 119         y: 200; anchors.horizontalCenter: parent.horizontalCenter
 120         color: "white"
 121         font.bold: true; font.pixelSize: 14
 122         style: Text.Raised; styleColor: "black"
 123     }
 124 }