examples/declarative/touchinteraction/pincharea/flickresize.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42
  43 Rectangle {
  44     width: 640
  45     height: 360
  46     color: "gray"
  47
  48     Flickable {
  49         id: flick
  50         anchors.fill: parent
  51         contentWidth: 500
  52         contentHeight: 500
  53
  54         PinchArea {
  55             width: Math.max(flick.contentWidth, flick.width)
  56             height: Math.max(flick.contentHeight, flick.height)
  57
  58             property real initialWidth
  59             property real initialHeight
  60             onPinchStarted: {
  61                 initialWidth = flick.contentWidth
  62                 initialHeight = flick.contentHeight
  63             }
  64
  65             onPinchUpdated: {
  66                 // adjust content pos due to drag
  67                 flick.contentX += pinch.previousCenter.x - pinch.center.x
  68                 flick.contentY += pinch.previousCenter.y - pinch.center.y
  69
  70                 // resize content
  71                 flick.resizeContent(initialWidth * pinch.scale, initialHeight * pinch.scale, pinch.center)
  72             }
  73
  74             onPinchFinished: {
  75                 // Move its content within bounds.
  76                 flick.returnToBounds()
  77             }
  78
  79             Rectangle {
  80                 width: flick.contentWidth
  81                 height: flick.contentHeight
  82                 color: "white"
  83                 Image {
  84                     anchors.fill: parent
  85                     source: "qt-logo.jpg"
  86                     MouseArea {
  87                         anchors.fill: parent
  88                         onDoubleClicked: {
  89                             flick.contentWidth = 500
  90                             flick.contentHeight = 500
  91                         }
  92                     }
  93                 }
  94             }
  95         }
  96     }
  97 }