examples/declarative/snake/content/HighScoreModel.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: http://www.qt-project.org/
   6 **
   7 ** This file is part of the QtDeclarative module of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:LGPL$
  10 ** GNU Lesser General Public License Usage
  11 ** This file may be used under the terms of the GNU Lesser General Public
  12 ** License version 2.1 as published by the Free Software Foundation and
  13 ** appearing in the file LICENSE.LGPL included in the packaging of this
  14 ** file. Please review the following information to ensure the GNU Lesser
  15 ** General Public License version 2.1 requirements will be met:
  16 ** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  17 **
  18 ** In addition, as a special exception, Nokia gives you certain additional
  19 ** rights. These rights are described in the Nokia Qt LGPL Exception
  20 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  21 **
  22 ** GNU General Public License Usage
  23 ** Alternatively, this file may be used under the terms of the GNU General
  24 ** Public License version 3.0 as published by the Free Software Foundation
  25 ** and appearing in the file LICENSE.GPL included in the packaging of this
  26 ** file. Please review the following information to ensure the GNU General
  27 ** Public License version 3.0 requirements will be met:
  28 ** http://www.gnu.org/copyleft/gpl.html.
  29 **
  30 ** Other Usage
  31 ** Alternatively, this file may be used in accordance with the terms and
  32 ** conditions contained in a signed written agreement between you and Nokia.
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41
  42 import QtQuick 2.0
  43 import QtQuick.LocalStorage 2.0 as Sql
  44
  45 // Models a high score table.
  46 //
  47 // Use this component like this:
  48 //
  49 //  HighScoreModel {
  50 //      id: highScores
  51 //      game: "MyCoolGame"
  52 //  }
  53 //
  54 // Then use either use the top-score properties:
  55 //
  56 //  Text { text: "HI: " + highScores.topScore }
  57 //
  58 // or, use the model in a view:
  59 //
  60 //  ListView {
  61 //      model: highScore
  62 //      delegate: Component {
  63 //                    ... player ... score ...
  64 //                }
  65 //  }
  66 //
  67 // Add new scores via:
  68 //
  69 //  saveScore(newScore)
  70 //
  71 // or:
  72 //
  73 //  savePlayerScore(playerName,newScore)
  74 //
  75 // The best maxScore scores added by this method will be retained in an SQL database,
  76 // and presented in the model and in the topScore/topPlayer properties.
  77 //
  78
  79 ListModel {
  80     id: model
  81     property string game: ""
  82     property int topScore: 0
  83     property string topPlayer: ""
  84     property int maxScores: 10
  85
  86     function __db()
  87     {
  88         return Sql.openDatabaseSync("HighScoreModel", "1.0", "Generic High Score Functionality for QML", 1000000);
  89     }
  90     function __ensureTables(tx)
  91     {
  92         tx.executeSql('CREATE TABLE IF NOT EXISTS HighScores(game TEXT, score INT, player TEXT)', []);
  93     }
  94
  95     function fillModel() {
  96         __db().transaction(
  97             function(tx) {
  98                 __ensureTables(tx);
  99                 var rs = tx.executeSql("SELECT score,player FROM HighScores WHERE game=? ORDER BY score DESC", [game]);
 100                 model.clear();
 101                 if (rs.rows.length > 0) {
 102                     topScore = rs.rows.item(0).score
 103                     topPlayer = rs.rows.item(0).player
 104                     for (var i=0; i<rs.rows.length; ++i) {
 105                         if (i < maxScores)
 106                             model.append(rs.rows.item(i))
 107                     }
 108                     if (rs.rows.length > maxScores)
 109                         tx.executeSql("DELETE FROM HighScores WHERE game=? AND score <= ?",
 110                                             [game, rs.rows.item(maxScores).score]);
 111                 }
 112             }
 113         )
 114     }
 115
 116     function savePlayerScore(player,score) {
 117         __db().transaction(
 118             function(tx) {
 119                 __ensureTables(tx);
 120                 tx.executeSql("INSERT INTO HighScores VALUES(?,?,?)", [game,score,player]);
 121                 fillModel();
 122             }
 123         )
 124     }
 125
 126     function saveScore(score) {
 127         savePlayerScore("player",score);
 128     }
 129
 130     function clearScores() {
 131         __db().transaction(
 132             function(tx) {
 133                 tx.executeSql("DELETE FROM HighScores WHERE game=?", [game]);
 134                 fillModel();
 135             }
 136         )
 137     }
 138
 139     Component.onCompleted: { fillModel() }
 140 }