examples/declarative/snake/content/HighScoreModel.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the QtDeclarative module of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:LGPL$
  10 ** GNU Lesser General Public License Usage
  11 ** This file may be used under the terms of the GNU Lesser General Public
  12 ** License version 2.1 as published by the Free Software Foundation and
  13 ** appearing in the file LICENSE.LGPL included in the packaging of this
  14 ** file. Please review the following information to ensure the GNU Lesser
  15 ** General Public License version 2.1 requirements will be met:
  16 ** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  17 **
  18 ** In addition, as a special exception, Nokia gives you certain additional
  19 ** rights. These rights are described in the Nokia Qt LGPL Exception
  20 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  21 **
  22 ** GNU General Public License Usage
  23 ** Alternatively, this file may be used under the terms of the GNU General
  24 ** Public License version 3.0 as published by the Free Software Foundation
  25 ** and appearing in the file LICENSE.GPL included in the packaging of this
  26 ** file. Please review the following information to ensure the GNU General
  27 ** Public License version 3.0 requirements will be met:
  28 ** http://www.gnu.org/copyleft/gpl.html.
  29 **
  30 ** Other Usage
  31 ** Alternatively, this file may be used in accordance with the terms and
  32 ** conditions contained in a signed written agreement between you and Nokia.
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41
  42 import QtQuick 2.0
  43
  44 // Models a high score table.
  45 //
  46 // Use this component like this:
  47 //
  48 //  HighScoreModel {
  49 //      id: highScores
  50 //      game: "MyCoolGame"
  51 //  }
  52 //
  53 // Then use either use the top-score properties:
  54 //
  55 //  Text { text: "HI: " + highScores.topScore }
  56 //
  57 // or, use the model in a view:
  58 //
  59 //  ListView {
  60 //      model: highScore
  61 //      delegate: Component {
  62 //                    ... player ... score ...
  63 //                }
  64 //  }
  65 //
  66 // Add new scores via:
  67 //
  68 //  saveScore(newScore)
  69 //
  70 // or:
  71 //
  72 //  savePlayerScore(playerName,newScore)
  73 //
  74 // The best maxScore scores added by this method will be retained in an SQL database,
  75 // and presented in the model and in the topScore/topPlayer properties.
  76 //
  77
  78 ListModel {
  79     id: model
  80     property string game: ""
  81     property int topScore: 0
  82     property string topPlayer: ""
  83     property int maxScores: 10
  84
  85     function __db()
  86     {
  87         return openDatabaseSync("HighScoreModel", "1.0", "Generic High Score Functionality for QML", 1000000);
  88     }
  89     function __ensureTables(tx)
  90     {
  91         tx.executeSql('CREATE TABLE IF NOT EXISTS HighScores(game TEXT, score INT, player TEXT)', []);
  92     }
  93
  94     function fillModel() {
  95         __db().transaction(
  96             function(tx) {
  97                 __ensureTables(tx);
  98                 var rs = tx.executeSql("SELECT score,player FROM HighScores WHERE game=? ORDER BY score DESC", [game]);
  99                 model.clear();
 100                 if (rs.rows.length > 0) {
 101                     topScore = rs.rows.item(0).score
 102                     topPlayer = rs.rows.item(0).player
 103                     for (var i=0; i<rs.rows.length; ++i) {
 104                         if (i < maxScores)
 105                             model.append(rs.rows.item(i))
 106                     }
 107                     if (rs.rows.length > maxScores)
 108                         tx.executeSql("DELETE FROM HighScores WHERE game=? AND score <= ?",
 109                                             [game, rs.rows.item(maxScores).score]);
 110                 }
 111             }
 112         )
 113     }
 114
 115     function savePlayerScore(player,score) {
 116         __db().transaction(
 117             function(tx) {
 118                 __ensureTables(tx);
 119                 tx.executeSql("INSERT INTO HighScores VALUES(?,?,?)", [game,score,player]);
 120                 fillModel();
 121             }
 122         )
 123     }
 124
 125     function saveScore(score) {
 126         savePlayerScore("player",score);
 127     }
 128
 129     function clearScores() {
 130         __db().transaction(
 131             function(tx) {
 132                 tx.executeSql("DELETE FROM HighScores WHERE game=?", [game]);
 133                 fillModel();
 134             }
 135         )
 136     }
 137
 138     Component.onCompleted: { fillModel() }
 139 }