examples/declarative/qtquick1/ui-components/tabwidget/TabWidget.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 1.0
  42
  43 Item {
  44     id: tabWidget
  45
  46     // Setting the default property to stack.children means any child items
  47     // of the TabWidget are actually added to the 'stack' item's children.
  48     // See the "Property Binding"
  49     // documentation for details on default properties.
  50     default property alias content: stack.children
  51
  52     property int current: 0
  53
  54     onCurrentChanged: setOpacities()
  55     Component.onCompleted: setOpacities()
  56
  57     function setOpacities() {
  58         for (var i = 0; i < stack.children.length; ++i) {
  59             stack.children[i].opacity = (i == current ? 1 : 0)
  60         }
  61     }
  62
  63     Row {
  64         id: header
  65
  66         Repeater {
  67             model: stack.children.length
  68             delegate: Rectangle {
  69                 width: tabWidget.width / stack.children.length; height: 36
  70
  71                 Rectangle {
  72                     width: parent.width; height: 1
  73                     anchors { bottom: parent.bottom; bottomMargin: 1 }
  74                     color: "#acb2c2"
  75                 }
  76                 BorderImage {
  77                     anchors { fill: parent; leftMargin: 2; topMargin: 5; rightMargin: 1 }
  78                     border { left: 7; right: 7 }
  79                     source: "tab.png"
  80                     visible: tabWidget.current == index
  81                 }
  82                 Text {
  83                     horizontalAlignment: Qt.AlignHCenter; verticalAlignment: Qt.AlignVCenter
  84                     anchors.fill: parent
  85                     text: stack.children[index].title
  86                     elide: Text.ElideRight
  87                     font.bold: tabWidget.current == index
  88                 }
  89                 MouseArea {
  90                     anchors.fill: parent
  91                     onClicked: tabWidget.current = index
  92                 }
  93             }
  94         }
  95     }
  96
  97     Item {
  98         id: stack
  99         width: tabWidget.width
 100         anchors.top: header.bottom; anchors.bottom: tabWidget.bottom
 101     }
 102 }